matita/matita/contribs/lambdadelta/ground/relocation/pr_after_uni.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/arith/nat_plus.ma".
  16 (* * it should not depend on pr_isi *)
  17 include "ground/relocation/pr_isi_uni.ma".
  18 include "ground/relocation/pr_after_isi.ma".
  19
  20 (* RELATIONAL COMPOSITION FOR PARTIAL RELOCATION MAPS ***********************)
  21
  22 (* Constructions with pr_uni ************************************************)
  23
  24 (*** after_uni *)
  25 lemma pr_after_uni (h1) (h2): 𝐮❨h1❩ ⊚ 𝐮❨h2❩ ≘ 𝐮❨h2+h1❩.
  26 #h1 @(nat_ind_succ … h1) -h1
  27 /3 width=5 by pr_after_isi_sn, pr_after_next, eq_f/
  28 qed.
  29
  30 (*** after_uni_sn_pushs *)
  31 lemma pr_after_uni_sn_pushs (h):
  32       ∀f. 𝐮❨h❩ ⊚ f ≘ ↑*[h]f.
  33 #h @(nat_ind_succ … h) -h
  34 /2 width=5 by pr_after_isi_sn, pr_after_next/
  35 qed.
  36
  37 lemma pr_after_uni_isi_next (h1):
  38       ∀f2. 𝐈❨f2❩ → 𝐮❨h1❩ ⊚ ↑f2 ≘ ↑𝐮❨h1❩.
  39 #h1 @(nat_ind_succ … h1) -h1
  40 /5 width=7 by pr_after_isi_dx, pr_after_eq_repl_back_sn, pr_after_next, pr_after_push, pr_isi_inv_eq_push/
  41 qed.
  42
  43 lemma pr_after_uni_next_sn (h2):
  44       ∀f1,f. ↑𝐮❨h2❩ ⊚ f1 ≘ f → 𝐮❨h2❩ ⊚ ↑f1 ≘ f.
  45 #h2 @(nat_ind_succ … h2) -h2
  46 [ #f1 #f #Hf
  47   elim (pr_after_inv_next_sn … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
  48   /4 width=7 by pr_after_isi_inv_sn, pr_after_isi_sn, pr_after_eq_repl_back, pr_eq_next/
  49 | #h2 #IH #f1 #f #Hf
  50   elim (pr_after_inv_next_sn … Hf) -Hf [2,3: // ] #g #Hg #H0 destruct
  51   /3 width=5 by pr_after_next/
  52 ]
  53 qed.