matita/matita/contribs/lambdadelta/ground/relocation/pr_coafter_ist_isf.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/relocation/pr_pat_tls.ma".
  16 include "ground/relocation/pr_isf_tls.ma".
  17 include "ground/relocation/pr_ist_tls.ma".
  18 include "ground/relocation/pr_coafter_nat_tls.ma".
  19 include "ground/relocation/pr_coafter_isi.ma".
  20
  21 (* RELATIONAL CO-COMPOSITION FOR PARTIAL RELOCATION MAPS ********************)
  22
  23 (*** H_coafter_isfin2_fwd *)
  24 definition H_pr_coafter_des_ist_isf: predicate pr_map ≝
  25            λf1. ∀f2. 𝐅❪f2❫ → 𝐓❪f1❫ → ∀f. f1 ~⊚ f2 ≘ f →  𝐅❪f❫.
  26
  27 (* Destructions with pr_ist and pr_isf **************************************)
  28
  29 (*** coafter_isfin2_fwd_O_aux *)
  30 fact pr_coafter_des_ist_isf_unit_aux:
  31      ∀f1. @❪𝟏, f1❫ ≘ 𝟏 → H_pr_coafter_des_ist_isf f1.
  32 #f1 #Hf1 #f2 #H
  33 generalize in match Hf1; generalize in match f1; -f1
  34 @(pr_isf_ind … H) -f2
  35 [ /3 width=4 by pr_coafter_isi_inv_dx, pr_isf_isi/ ]
  36 #f2 #_ #IH #f1 #H #Hf1 #f #Hf
  37 elim (pr_pat_inv_unit_bi … H) -H [ |*: // ] #g1 #H1
  38 lapply (pr_ist_inv_push … Hf1 … H1) -Hf1 #Hg1
  39 elim (Hg1 (𝟏)) #n #Hn
  40 [ elim (pr_coafter_inv_push_bi … Hf) | elim (pr_coafter_inv_push_next … Hf)
  41 ] -Hf [1,6: |*: // ] #g #Hg #H0 destruct
  42 /5 width=6 by pr_isf_next, pr_isf_push, pr_isf_inv_tls, pr_ist_tls, pr_pat_unit_succ_tls, pr_coafter_tls_sn_tls/
  43 qed-.
  44
  45 (*** coafter_isfin2_fwd_aux *)
  46 fact pr_coafter_des_ist_isf_aux:
  47      (∀f1. @❪𝟏, f1❫ ≘ 𝟏 → H_pr_coafter_des_ist_isf f1) →
  48      ∀i2,f1. @❪𝟏, f1❫ ≘ i2 → H_pr_coafter_des_ist_isf f1.
  49 #H0 #i2 elim i2 -i2 /2 width=1 by/ -H0
  50 #i2 #IH #f1 #H1f1 #f2 #Hf2 #H2f1 #f #Hf
  51 elim (pr_pat_inv_unit_succ … H1f1) -H1f1 [ |*: // ] #g1 #Hg1 #H1
  52 elim (pr_coafter_inv_next_sn … Hf … H1) -Hf #g #Hg #H0
  53 lapply (IH … Hg1 … Hg) -i2 -Hg
  54 /2 width=4 by pr_ist_inv_next, pr_isf_push/ (* * full auto fails *)
  55 qed-.
  56
  57 (*** coafter_isfin2_fwd *)
  58 lemma pr_coafter_des_ist_isf: ∀f1. H_pr_coafter_des_ist_isf f1.
  59 #f1 #f2 #Hf2 #Hf1 cases (Hf1 (𝟏))
  60 /3 width=7 by pr_coafter_des_ist_isf_aux, pr_coafter_des_ist_isf_unit_aux/
  61 qed-.