matita/matita/contribs/lambdadelta/ground/relocation/pr_isf.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/notation/relations/predicate_f_1.ma".
  16 include "ground/relocation/pr_fcla.ma".
  17
  18 (* FINITE COLENGTH CONDITION FOR PARTIAL RELOCATION MAPS ********************)
  19
  20 (*** isfin *)
  21 definition pr_isf: predicate pr_map ≝
  22            λf. ∃n. 𝐂❨f❩ ≘ n.
  23
  24 interpretation
  25   "finite colength condition (partial relocation maps)"
  26   'PredicateF f = (pr_isf f).
  27
  28 (* Basic eliminations *******************************************************)
  29
  30 (*** isfin_ind *)
  31 lemma pr_isf_ind (Q:predicate …):
  32       (∀f.  𝐈❨f❩ → Q f) →
  33       (∀f. 𝐅❨f❩ → Q f → Q (⫯f)) →
  34       (∀f. 𝐅❨f❩ → Q f → Q (↑f)) →
  35       ∀f. 𝐅❨f❩ → Q f.
  36 #Q #IH1 #IH2 #IH3 #f #H elim H -H
  37 #n #H elim H -f -n /3 width=2 by ex_intro/
  38 qed-.
  39
  40 (* Basic inversions *********************************************************)
  41
  42 (*** isfin_inv_push *)
  43 lemma pr_isf_inv_push (g): 𝐅❨g❩ → ∀f. ⫯f = g → 𝐅❨f❩.
  44 #g * /3 width=4 by pr_fcla_inv_push, ex_intro/
  45 qed-.
  46
  47 (*** isfin_inv_next *)
  48 lemma pr_isf_inv_next (g): 𝐅❨g❩ → ∀f. ↑f = g → 𝐅❨f❩.
  49 #g * #n #H #f #H0 elim (pr_fcla_inv_next … H … H0) -g
  50 /2 width=2 by ex_intro/
  51 qed-.
  52
  53 (* Basic constructions ******************************************************)
  54
  55 (*** isfin_isid *)
  56 lemma pr_isf_isi (f): 𝐈❨f❩ → 𝐅❨f❩.
  57 /3 width=2 by pr_fcla_isi, ex_intro/ qed.
  58
  59 (*** isfin_push *)
  60 lemma pr_isf_push (f): 𝐅❨f❩ → 𝐅❨⫯f❩.
  61 #f * /3 width=2 by pr_fcla_push, ex_intro/
  62 qed.
  63
  64 (*** isfin_next *)
  65 lemma pr_isf_next (f): 𝐅❨f❩ → 𝐅❨↑f❩.
  66 #f * /3 width=2 by pr_fcla_next, ex_intro/
  67 qed.