matita/matita/contribs/lambdadelta/ground/relocation/pr_sor_isf.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/relocation/pr_isf_eq.ma".
  16 include "ground/relocation/pr_sor_fcla.ma".
  17
  18 (* RELATIONAL UNION FOR PARTIAL RELOCATION MAPS *****************************)
  19
  20 (* Constructions with pr_isf ************************************************)
  21
  22 (*** sor_isfin_ex *)
  23 lemma pr_sor_isf_bi:
  24       ∀f1,f2. 𝐅❨f1❩ → 𝐅❨f2❩ → ∃∃f. f1 ⋓ f2 ≘ f & 𝐅❨f❩.
  25 #f1 #f2 * #n1 #H1 * #n2 #H2 elim (pr_sor_fcla_bi … H1 … H2) -H1 -H2
  26 /3 width=4 by ex2_intro, ex_intro/
  27 qed-.
  28
  29 (* Destructions with pr_isf *************************************************)
  30
  31 (*** sor_fwd_isfin_sn *)
  32 lemma pr_sor_des_isf_sn:
  33       ∀f. 𝐅❨f❩ → ∀f1,f2. f1 ⋓ f2 ≘ f → 𝐅❨f1❩.
  34 #f * #n #Hf #f1 #f2 #H
  35 elim (pr_sor_des_fcla_sn … Hf … H) -f -f2 /2 width=2 by ex_intro/
  36 qed-.
  37
  38 (*** sor_fwd_isfin_dx *)
  39 lemma pr_sor_des_isf_dx:
  40       ∀f. 𝐅❨f❩ → ∀f1,f2. f1 ⋓ f2 ≘ f → 𝐅❨f2❩.
  41 #f * #n #Hf #f1 #f2 #H
  42 elim (pr_sor_des_fcla_dx … Hf … H) -f -f1 /2 width=2 by ex_intro/
  43 qed-.
  44
  45 (* Inversions with pr_isf ***************************************************)
  46
  47 (*** sor_isfin *)
  48 lemma pr_sor_inv_isf_bi:
  49       ∀f1,f2. 𝐅❨f1❩ → 𝐅❨f2❩ → ∀f. f1 ⋓ f2 ≘ f → 𝐅❨f❩.
  50 #f1 #f2 #Hf1 #Hf2 #f #Hf elim (pr_sor_isf_bi … Hf1 … Hf2) -Hf1 -Hf2
  51 /3 width=6 by pr_sor_mono, pr_isf_eq_repl_back/
  52 qed-.
  53
  54 (*** sor_inv_isfin3 *)
  55 lemma pr_sor_inv_isf:
  56       ∀f1,f2,f. f1 ⋓ f2 ≘ f → 𝐅❨f❩ →
  57       ∧∧ 𝐅❨f1❩ & 𝐅❨f2❩.
  58 /3 width=4 by pr_sor_des_isf_dx, pr_sor_des_isf_sn, conj/ qed-.