matita/matita/contribs/lambdadelta/ground/relocation/tr_compose_pn.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/relocation/tr_pn_tls.ma".
  16 include "ground/relocation/tr_pap_pn.ma".
  17 include "ground/relocation/tr_compose.ma".
  18
  19 (* COMPOSITION FOR TOTAL RELOCATION MAPS ************************************)
  20
  21 (* Constructions with tr_push and tr_next ***********************************)
  22
  23 lemma tr_compose_push_bi (f2) (f1):
  24       (⫯(f2∘f1)) = (⫯f2)∘(⫯f1).
  25 #f2 #f1
  26 <tr_compose_unfold //
  27 qed.
  28
  29 lemma tr_compose_push_next (f2) (f1):
  30       ↑(f2∘f1) = (⫯f2)∘(↑f1).
  31 #f2 * #p1 #f1
  32 <tr_next_unfold <tr_compose_unfold <tr_compose_unfold <tr_next_unfold
  33 <tr_pap_push >nsucc_inj //
  34 qed.
  35
  36 (* Note: to be removed *)
  37 (*** compose_next *)
  38 fact tr_compose_next_sn_aux (f2) (f1):
  39      ∀f. f2∘f1 = f → (↑f2)∘f1 = ↑f.
  40 #f2 * #p1 #f1 #f
  41 <tr_compose_unfold <tr_compose_unfold * -f
  42 <tr_pap_next
  43 /3 width=1 by compose_repl_fwd_dx/
  44 qed-.
  45
  46 lemma tr_compose_next_sn (f2) (f1):
  47       ↑(f2∘f1) = (↑f2)∘f1.
  48 /2 width=1 by tr_compose_next_sn_aux/ qed.
  49
  50 (* Inversions with tr_push and tr_next **************************************)
  51
  52 (*** compose_inv_O2 *)
  53 lemma tr_compose_inv_push_dx (f2) (f1):
  54       ∀f,p2,p. (p2⨮f2)∘(⫯f1) = p⨮f →
  55       ∧∧ p2 = p & f2∘f1 = f.
  56 #f2 #f1 #f #p2 #p
  57 <tr_compose_unfold #H destruct
  58 /2 width=1 by conj/
  59 qed-.
  60
  61 (*** compose_inv_S1 *)
  62 lemma tr_compose_inv_next_sn (f2) (f1):
  63       ∀f,p1,p. (↑f2)∘(p1⨮f1) = p⨮f →
  64       ∧∧ ↑(f2＠⧣❨p1❩) = p & f2∘(p1⨮f1) = f2＠⧣❨p1❩⨮f.
  65 #f2 #f1 #f #p1 #p
  66 <tr_compose_unfold #H destruct
  67 /2 width=1 by conj/
  68 qed-.