matita/matita/contribs/lambdadelta/static_2/static/lsuba_aaa.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/aaa_aaa.ma".
  16 include "static_2/static/lsuba.ma".
  17
  18 (* RESTRICTED REFINEMENT FOR ATOMIC ARITY ASSIGNMENT ************************)
  19
  20 (* Properties with atomic arity assignment **********************************)
  21
  22 lemma lsuba_aaa_conf: ∀G,L1,V,A. ❨G,L1❩ ⊢ V ⁝ A →
  23                       ∀L2. G ⊢ L1 ⫃⁝ L2 → ❨G,L2❩ ⊢ V ⁝ A.
  24 #G #L1 #V #A #H elim H -G -L1 -V -A
  25 [ //
  26 | #I #G #L1 #V #A #HA #IH #L2 #H
  27   elim (lsuba_inv_bind1 … H) -H * /3 width=1 by aaa_zero/
  28   #L0 #W0 #V0 #A0 #HV0 #HW0 #HL10 #H1 #H2 destruct
  29   lapply (aaa_mono … HV0 … HA) #H destruct -V0 -L1 /2 width=1 by aaa_zero/
  30 | #I #G #K1 #A #i #_ #IH #L2 #H
  31   elim (lsuba_inv_bind1 … H) -H * /3 width=1 by aaa_lref/
  32 | /4 width=2 by lsuba_bind, aaa_abbr/
  33 | /4 width=1 by lsuba_bind, aaa_abst/
  34 | /3 width=3 by aaa_appl/
  35 | /3 width=1 by aaa_cast/
  36 ]
  37 qed-.
  38
  39 lemma lsuba_aaa_trans: ∀G,L2,V,A. ❨G,L2❩ ⊢ V ⁝ A →
  40                        ∀L1. G ⊢ L1 ⫃⁝ L2 → ❨G,L1❩ ⊢ V ⁝ A.
  41 #G #L2 #V #A #H elim H -G -L2 -V -A
  42 [ //
  43 | #I #G #L2 #V #A #HA #IH #L1 #H
  44   elim (lsuba_inv_bind2 … H) -H * /3 width=1 by aaa_zero/
  45   #L0 #V0 #W0 #A0 #HV0 #HW0 #HL02 #H1 #H2 destruct
  46   lapply (aaa_mono … HW0 … HA) #H destruct -L2 /2 width=1 by aaa_zero/
  47 | #I #G #K2 #A #i #_ #IH #L1 #H
  48   elim (lsuba_inv_bind2 … H) -H * /3 width=1 by aaa_lref/
  49 | /4 width=2 by lsuba_bind, aaa_abbr/
  50 | /4 width=1 by lsuba_bind, aaa_abst/
  51 | /3 width=3 by aaa_appl/
  52 | /3 width=1 by aaa_cast/
  53 ]
  54 qed-.