matita/matita/contribs/lambdadelta/static_2/static/reqg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/notation/relations/stareqsn_4.ma".
  16 include "static_2/syntax/teqg_ext.ma".
  17 include "static_2/static/rex.ma".
  18
  19 (* GENERIC EQUIVALENCE FOR LOCAL ENVIRONMENTS ON REFERRED ENTRIES ***********)
  20
  21 definition reqg (S): relation3 … ≝
  22            rex (ceqg S).
  23
  24 interpretation
  25   "generic equivalence on selected entries (local environment)"
  26   'StarEqSn S f L1 L2 = (sex (ceqg_ext S) cfull f L1 L2).
  27
  28 interpretation
  29   "generic equivalence on referred entries (local environment)"
  30   'StarEqSn S T L1 L2 = (reqg S T L1 L2).
  31
  32 (* Basic properties ***********************************************************)
  33
  34 lemma frees_teqg_conf_seqg (S):
  35       ∀f,L1,T1. L1 ⊢ 𝐅+❨T1❩ ≘ f → ∀T2. T1 ≛[S] T2 →
  36       ∀L2. L1 ≛[S,f] L2 → L2 ⊢ 𝐅+❨T2❩ ≘ f.
  37 #S #f #L1 #T1 #H elim H -f -L1 -T1
  38 [ #f #L1 #s1 #Hf #X #H1 #L2 #_
  39   elim (teqg_inv_sort1 … H1) -H1 #s2 #_ #H destruct
  40   /2 width=3 by frees_sort/
  41 | #f #i #Hf #X #H1
  42   >(teqg_inv_lref1 … H1) -X #Y #H2
  43   >(sex_inv_atom1 … H2) -Y
  44   /2 width=1 by frees_atom/
  45 | #f #I #L1 #V1 #_ #IH #X #H1
  46   >(teqg_inv_lref1 … H1) -X #Y #H2
  47   elim (sex_inv_next1 … H2) -H2 #Z #L2 #HL12 #HZ #H destruct
  48   elim (ext2_inv_pair_sn … HZ) -HZ #V2 #HV12 #H destruct
  49   /3 width=1 by frees_pair/
  50 | #f #I #L1 #Hf #X #H1
  51   >(teqg_inv_lref1 … H1) -X #Y #H2
  52   elim (sex_inv_next1 … H2) -H2 #Z #L2 #_ #HZ #H destruct
  53   >(ext2_inv_unit_sn … HZ) -Z /2 width=1 by frees_unit/
  54 | #f #I #L1 #i #_ #IH #X #H1
  55   >(teqg_inv_lref1 … H1) -X #Y #H2
  56   elim (sex_inv_push1 … H2) -H2 #J #L2 #HL12 #_ #H destruct
  57   /3 width=1 by frees_lref/
  58 | #f #L1 #l #Hf #X #H1 #L2 #_
  59   >(teqg_inv_gref1 … H1) -X /2 width=1 by frees_gref/
  60 | #f1V #f1T #f1 #p #I #L1 #V1 #T1 #_ #_ #Hf1 #IHV #IHT #X #H1
  61   elim (teqg_inv_pair1 … H1) -H1 #V2 #T2 #HV12 #HT12 #H1 #L2 #HL12 destruct
  62   /6 width=5 by frees_bind, sex_inv_tl, ext2_pair, sle_sex_trans, pr_sor_inv_sle_dx, pr_sor_inv_sle_sn/
  63 | #f1V #f1T #f1 #I #L1 #V1 #T1 #_ #_ #Hf1 #IHV #IHT #X #H1
  64   elim (teqg_inv_pair1 … H1) -H1 #V2 #T2 #HV12 #HT12 #H1 #L2 #HL12 destruct
  65   /5 width=5 by frees_flat, sle_sex_trans, pr_sor_inv_sle_dx, pr_sor_inv_sle_sn/
  66 ]
  67 qed-.
  68
  69 lemma frees_teqg_conf (S):
  70       reflexive … S →
  71       ∀f,L,T1. L ⊢ 𝐅+❨T1❩ ≘ f →
  72       ∀T2. T1 ≛[S] T2 → L ⊢ 𝐅+❨T2❩ ≘ f.
  73 /5 width=6 by frees_teqg_conf_seqg, sex_refl, teqg_refl, ext2_refl/ qed-.
  74
  75 lemma frees_seqg_conf (S):
  76       reflexive … S →
  77       ∀f,L1,T. L1 ⊢ 𝐅+❨T❩ ≘ f →
  78       ∀L2. L1 ≛[S,f] L2 → L2 ⊢ 𝐅+❨T❩ ≘ f.
  79 /3 width=6 by frees_teqg_conf_seqg, teqg_refl/ qed-.
  80
  81 lemma teqg_rex_conf_sn (S) (R):
  82       reflexive … S →
  83       s_r_confluent1 … (ceqg S) (rex R).
  84 #S #R #HS #L1 #T1 #T2 #HT12 #L2 *
  85 /3 width=5 by frees_teqg_conf, ex2_intro/
  86 qed-.
  87
  88 lemma teqg_rex_div (S) (R):
  89       reflexive … S → symmetric … S →
  90       ∀T1,T2. T1 ≛[S] T2 →
  91       ∀L1,L2. L1 ⪤[R,T2] L2 → L1 ⪤[R,T1] L2.
  92 /3 width=5 by teqg_rex_conf_sn, teqg_sym/ qed-.
  93
  94 lemma teqg_reqg_conf_sn (S1) (S2):
  95       reflexive … S1 →
  96       s_r_confluent1 … (ceqg S1) (reqg S2).
  97 /2 width=5 by teqg_rex_conf_sn/ qed-.
  98
  99 lemma teqg_reqg_div (S1) (S2):
 100       reflexive … S1 → symmetric … S1 →
 101       ∀T1,T2. T1 ≛[S1] T2 →
 102       ∀L1,L2. L1 ≛[S2,T2] L2 → L1 ≛[S2,T1] L2.
 103 /2 width=6 by teqg_rex_div/ qed-.
 104
 105 lemma reqg_atom (S):
 106       ∀I. ⋆ ≛[S,⓪[I]] ⋆.
 107 /2 width=1 by rex_atom/ qed.
 108
 109 lemma reqg_sort (S):
 110       ∀I1,I2,L1,L2,s.
 111       L1 ≛[S,⋆s] L2 → L1.ⓘ[I1] ≛[S,⋆s] L2.ⓘ[I2].
 112 /2 width=1 by rex_sort/ qed.
 113
 114 lemma reqg_pair (S):
 115       ∀I,L1,L2,V1,V2.
 116       L1 ≛[S,V1] L2 → V1 ≛[S] V2 → L1.ⓑ[I]V1 ≛[S,#0] L2.ⓑ[I]V2.
 117 /2 width=1 by rex_pair/ qed.
 118
 119 lemma reqg_unit (S):
 120       ∀f,I,L1,L2. 𝐈❨f❩ → L1 ≛[S,f] L2 →
 121       L1.ⓤ[I] ≛[S,#0] L2.ⓤ[I].
 122 /2 width=3 by rex_unit/ qed.
 123
 124 lemma reqg_lref (S):
 125       ∀I1,I2,L1,L2,i.
 126       L1 ≛[S,#i] L2 → L1.ⓘ[I1] ≛[S,#↑i] L2.ⓘ[I2].
 127 /2 width=1 by rex_lref/ qed.
 128
 129 lemma reqg_gref (S):
 130       ∀I1,I2,L1,L2,l.
 131       L1 ≛[S,§l] L2 → L1.ⓘ[I1] ≛[S,§l] L2.ⓘ[I2].
 132 /2 width=1 by rex_gref/ qed.
 133
 134 lemma reqg_bind_repl_dx (S):
 135       ∀I,I1,L1,L2.∀T:term. L1.ⓘ[I] ≛[S,T] L2.ⓘ[I1] →
 136       ∀I2. I ≛[S] I2 → L1.ⓘ[I] ≛[S,T] L2.ⓘ[I2].
 137 /2 width=2 by rex_bind_repl_dx/ qed-.
 138
 139 lemma reqg_co (S1) (S2):
 140       S1 ⊆ S2 →
 141       ∀T:term. ∀L1,L2. L1 ≛[S1,T] L2 → L1 ≛[S2,T] L2.
 142 /3 width=3 by rex_co, teqg_co/ qed-.
 143
 144 (* Basic inversion lemmas ***************************************************)
 145
 146 lemma reqg_inv_atom_sn (S):
 147       ∀Y2. ∀T:term. ⋆ ≛[S,T] Y2 → Y2 = ⋆.
 148 /2 width=3 by rex_inv_atom_sn/ qed-.
 149
 150 lemma reqg_inv_atom_dx (S):
 151       ∀Y1. ∀T:term. Y1 ≛[S,T] ⋆ → Y1 = ⋆.
 152 /2 width=3 by rex_inv_atom_dx/ qed-.
 153
 154 lemma reqg_inv_zero (S):
 155       ∀Y1,Y2. Y1 ≛[S,#0] Y2 →
 156       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 157        | ∃∃I,L1,L2,V1,V2. L1 ≛[S,V1] L2 & V1 ≛[S] V2 & Y1 = L1.ⓑ[I]V1 & Y2 = L2.ⓑ[I]V2
 158        | ∃∃f,I,L1,L2. 𝐈❨f❩ & L1 ≛[S,f] L2 & Y1 = L1.ⓤ[I] & Y2 = L2.ⓤ[I].
 159 #S #Y1 #Y2 #H elim (rex_inv_zero … H) -H *
 160 /3 width=9 by or3_intro0, or3_intro1, or3_intro2, ex4_5_intro, ex4_4_intro, conj/
 161 qed-.
 162
 163 lemma reqg_inv_lref (S):
 164       ∀Y1,Y2,i. Y1 ≛[S,#↑i] Y2 →
 165       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 166        | ∃∃I1,I2,L1,L2. L1 ≛[S,#i] L2 & Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
 167 /2 width=1 by rex_inv_lref/ qed-.
 168
 169 (* Basic_2A1: uses: lleq_inv_bind lleq_inv_bind_O *)
 170 lemma reqg_inv_bind_refl (S):
 171       reflexive … S →
 172       ∀p,I,L1,L2,V,T. L1 ≛[S,ⓑ[p,I]V.T] L2 →
 173       ∧∧ L1 ≛[S,V] L2 & L1.ⓑ[I]V ≛[S,T] L2.ⓑ[I]V.
 174 /3 width=2 by rex_inv_bind, teqg_refl/ qed-.
 175
 176 (* Basic_2A1: uses: lleq_inv_flat *)
 177 lemma reqg_inv_flat (S):
 178       ∀I,L1,L2,V,T. L1 ≛[S,ⓕ[I]V.T] L2 →
 179       ∧∧ L1 ≛[S,V] L2 & L1 ≛[S,T] L2.
 180 /2 width=2 by rex_inv_flat/ qed-.
 181
 182 (* Advanced inversion lemmas ************************************************)
 183
 184 lemma reqg_inv_zero_pair_sn (S):
 185       ∀I,Y2,L1,V1. L1.ⓑ[I]V1 ≛[S,#0] Y2 →
 186       ∃∃L2,V2. L1 ≛[S,V1] L2 & V1 ≛[S] V2 & Y2 = L2.ⓑ[I]V2.
 187 /2 width=1 by rex_inv_zero_pair_sn/ qed-.
 188
 189 lemma reqg_inv_zero_pair_dx (S):
 190       ∀I,Y1,L2,V2. Y1 ≛[S,#0] L2.ⓑ[I]V2 →
 191       ∃∃L1,V1. L1 ≛[S,V1] L2 & V1 ≛[S] V2 & Y1 = L1.ⓑ[I]V1.
 192 /2 width=1 by rex_inv_zero_pair_dx/ qed-.
 193
 194 lemma reqg_inv_lref_bind_sn (S):
 195       ∀I1,Y2,L1,i. L1.ⓘ[I1] ≛[S,#↑i] Y2 →
 196       ∃∃I2,L2. L1 ≛[S,#i] L2 & Y2 = L2.ⓘ[I2].
 197 /2 width=2 by rex_inv_lref_bind_sn/ qed-.
 198
 199 lemma reqg_inv_lref_bind_dx (S):
 200       ∀I2,Y1,L2,i. Y1 ≛[S,#↑i] L2.ⓘ[I2] →
 201       ∃∃I1,L1. L1 ≛[S,#i] L2 & Y1 = L1.ⓘ[I1].
 202 /2 width=2 by rex_inv_lref_bind_dx/ qed-.
 203
 204 (* Basic forward lemmas *****************************************************)
 205
 206 lemma reqg_fwd_zero_pair (S):
 207       ∀I,K1,K2,V1,V2.
 208       K1.ⓑ[I]V1 ≛[S,#0] K2.ⓑ[I]V2 → K1 ≛[S,V1] K2.
 209 /2 width=3 by rex_fwd_zero_pair/ qed-.
 210
 211 (* Basic_2A1: uses: lleq_fwd_bind_sn lleq_fwd_flat_sn *)
 212 lemma reqg_fwd_pair_sn (S):
 213       ∀I,L1,L2,V,T. L1 ≛[S,②[I]V.T] L2 → L1 ≛[S,V] L2.
 214 /2 width=3 by rex_fwd_pair_sn/ qed-.
 215
 216 (* Basic_2A1: uses: lleq_fwd_bind_dx lleq_fwd_bind_O_dx *)
 217 lemma reqg_fwd_bind_dx (S):
 218       reflexive … S →
 219       ∀p,I,L1,L2,V,T.
 220       L1 ≛[S,ⓑ[p,I]V.T] L2 → L1.ⓑ[I]V ≛[S,T] L2.ⓑ[I]V.
 221 /3 width=2 by rex_fwd_bind_dx, teqg_refl/ qed-.
 222
 223 (* Basic_2A1: uses: lleq_fwd_flat_dx *)
 224 lemma reqg_fwd_flat_dx (S):
 225       ∀I,L1,L2,V,T. L1 ≛[S,ⓕ[I]V.T] L2 → L1 ≛[S,T] L2.
 226 /2 width=3 by rex_fwd_flat_dx/ qed-.
 227
 228 lemma reqg_fwd_dx (S):
 229       ∀I2,L1,K2. ∀T:term. L1 ≛[S,T] K2.ⓘ[I2] →
 230       ∃∃I1,K1. L1 = K1.ⓘ[I1].
 231 /2 width=5 by rex_fwd_dx/ qed-.