matita/matita/contribs/lambdadelta/static_2/static/reqg_length.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/relocation/lifts_teqg.ma".
  16 include "static_2/static/rex_length.ma".
  17 include "static_2/static/rex_fsle.ma".
  18 include "static_2/static/reqg.ma".
  19
  20 (* GENERIC EQUIVALENCE FOR LOCAL ENVIRONMENTS ON REFERRED ENTRIES ***********)
  21
  22 (* Advanced properties with free variables inclusion ************************)
  23
  24 lemma reqg_fsge_comp (S):
  25       reflexive … S →
  26       rex_fsge_compatible (ceqg S).
  27 #S #HS #L1 #L2 #T * #f1 #Hf1 #HL12
  28 lapply (frees_seqg_conf … Hf1 … HL12)
  29 lapply (sex_fwd_length … HL12)
  30 /3 width=8 by lveq_length_eq, ex4_4_intro/ (**) (* full auto fails *)
  31 qed-.
  32
  33 (* Properties with length for local environments ****************************)
  34
  35 (* Basic_2A1: uses: lleq_sort *)
  36 lemma reqg_sort_length (S):
  37       ∀L1,L2. |L1| = |L2| → ∀s. L1 ≛[S,⋆s] L2.
  38 /2 width=1 by rex_sort_length/ qed.
  39
  40 (* Basic_2A1: uses: lleq_gref *)
  41 lemma reqg_gref_length (S):
  42       ∀L1,L2. |L1| = |L2| → ∀l. L1 ≛[S,§l] L2.
  43 /2 width=1 by rex_gref_length/ qed.
  44
  45 lemma reqg_unit_length (S):
  46       ∀L1,L2. |L1| = |L2| →
  47       ∀I. L1.ⓤ[I] ≛[S,#0] L2.ⓤ[I].
  48 /2 width=1 by rex_unit_length/ qed.
  49
  50 (* Basic_2A1: uses: lleq_lift_le lleq_lift_ge *)
  51 lemma reqg_lifts_bi (S):
  52       ∀L1,L2. |L1| = |L2| → ∀K1,K2,T. K1 ≛[S,T] K2 →
  53       ∀b,f. ⇩*[b,f] L1 ≘ K1 → ⇩*[b,f] L2 ≘ K2 →
  54       ∀U. ⇧*[f] T ≘ U → L1 ≛[S,U] L2.
  55 /3 width=9 by rex_lifts_bi, teqg_lifts_sn/ qed-.
  56
  57 (* Forward lemmas with length for local environments ************************)
  58
  59 (* Basic_2A1: lleq_fwd_length *)
  60 lemma reqg_fwd_length (S):
  61       ∀L1,L2. ∀T:term. L1 ≛[S,T] L2 → |L1| = |L2|.
  62 /2 width=3 by rex_fwd_length/ qed-.