matita/matita/contribs/lambdadelta/static_2/static/rex.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_1_2.ma".
  16 include "ground/xoa/ex_3_4.ma".
  17 include "ground/xoa/ex_4_4.ma".
  18 include "ground/xoa/ex_4_5.ma".
  19 include "ground/relocation/rtmap_id.ma".
  20 include "static_2/notation/relations/relation_4.ma".
  21 include "static_2/syntax/cext2.ma".
  22 include "static_2/relocation/sex.ma".
  23 include "static_2/static/frees.ma".
  24
  25 (* GENERIC EXTENSION ON REFERRED ENTRIES OF A CONTEXT-SENSITIVE REALTION ****)
  26
  27 definition rex (R) (T): relation lenv ≝
  28                λL1,L2. ∃∃f. L1 ⊢ 𝐅+❨T❩ ≘ f & L1 ⪤[cext2 R,cfull,f] L2.
  29
  30 interpretation
  31   "generic extension on referred entries (local environment)"
  32   'Relation R T L1 L2 = (rex R T L1 L2).
  33
  34 definition R_confluent2_rex:
  35            relation4 (relation3 lenv term term)
  36                      (relation3 lenv term term) … ≝
  37            λR1,R2,RP1,RP2.
  38            ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  39            ∀L1. L0 ⪤[RP1,T0] L1 → ∀L2. L0 ⪤[RP2,T0] L2 →
  40            ∃∃T. R2 L1 T1 T & R1 L2 T2 T.
  41
  42 definition R_replace3_rex:
  43            relation4 (relation3 lenv term term)
  44                      (relation3 lenv term term) … ≝
  45            λR1,R2,RP1,RP2.
  46            ∀L0,T0,T1. R1 L0 T0 T1 → ∀T2. R2 L0 T0 T2 →
  47            ∀L1. L0 ⪤[RP1,T0] L1 → ∀L2. L0 ⪤[RP2,T0] L2 →
  48            ∀T. R2 L1 T1 T → R1 L2 T2 T.
  49
  50 definition R_transitive_rex: relation3 ? (relation3 ?? term) … ≝
  51            λR1,R2,R3.
  52            ∀K1,K,V1. K1 ⪤[R1,V1] K →
  53            ∀V. R1 K1 V1 V → ∀V2. R2 K V V2 → R3 K1 V1 V2.
  54
  55 definition R_confluent1_rex: relation … ≝
  56            λR1,R2.
  57            ∀K1,K2,V1. K1 ⪤[R2,V1] K2 → ∀V2. R1 K1 V1 V2 → R1 K2 V1 V2.
  58
  59 definition rex_confluent: relation … ≝
  60            λR1,R2.
  61            ∀K1,K,V1. K1 ⪤[R1,V1] K → ∀V. R1 K1 V1 V →
  62            ∀K2. K ⪤[R2,V] K2 → K ⪤[R2,V1] K2.
  63
  64 (* Basic inversion lemmas ***************************************************)
  65
  66 lemma rex_inv_atom_sn (R):
  67       ∀Y2,T. ⋆ ⪤[R,T] Y2 → Y2 = ⋆.
  68 #R #Y2 #T * /2 width=4 by sex_inv_atom1/
  69 qed-.
  70
  71 lemma rex_inv_atom_dx (R):
  72       ∀Y1,T. Y1 ⪤[R,T] ⋆ → Y1 = ⋆.
  73 #R #I #Y1 * /2 width=4 by sex_inv_atom2/
  74 qed-.
  75
  76 lemma rex_inv_sort (R):
  77       ∀Y1,Y2,s. Y1 ⪤[R,⋆s] Y2 →
  78       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
  79        | ∃∃I1,I2,L1,L2. L1 ⪤[R,⋆s] L2 & Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
  80 #R * [ | #Y1 #I1 ] #Y2 #s * #f #H1 #H2
  81 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
  82 | lapply (frees_inv_sort … H1) -H1 #Hf
  83   elim (pr_isi_inv_gen … Hf) -Hf #g #Hg #H destruct
  84   elim (sex_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
  85   /5 width=7 by frees_sort, ex3_4_intro, ex2_intro, or_intror/
  86 ]
  87 qed-.
  88
  89 lemma rex_inv_zero (R):
  90       ∀Y1,Y2. Y1 ⪤[R,#0] Y2 →
  91       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
  92        | ∃∃I,L1,L2,V1,V2. L1 ⪤[R,V1] L2 & R L1 V1 V2 & Y1 = L1.ⓑ[I]V1 & Y2 = L2.ⓑ[I]V2
  93        | ∃∃f,I,L1,L2. 𝐈❨f❩ & L1 ⪤[cext2 R,cfull,f] L2 & Y1 = L1.ⓤ[I] & Y2 = L2.ⓤ[I].
  94 #R * [ | #Y1 * #I1 [ | #X ] ] #Y2 * #f #H1 #H2
  95 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or3_intro0, conj/
  96 | elim (frees_inv_unit … H1) -H1 #g #HX #H destruct
  97   elim (sex_inv_next1 … H2) -H2 #I2 #L2 #HL12 #H #H2 destruct
  98   >(ext2_inv_unit_sn … H) -H /3 width=8 by or3_intro2, ex4_4_intro/
  99 | elim (frees_inv_pair … H1) -H1 #g #Hg #H destruct
 100   elim (sex_inv_next1 … H2) -H2 #Z2 #L2 #HL12 #H
 101   elim (ext2_inv_pair_sn … H) -H
 102   /4 width=9 by or3_intro1, ex4_5_intro, ex2_intro/
 103 ]
 104 qed-.
 105
 106 lemma rex_inv_lref (R):
 107       ∀Y1,Y2,i. Y1 ⪤[R,#↑i] Y2 →
 108       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 109        | ∃∃I1,I2,L1,L2. L1 ⪤[R,#i] L2 & Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
 110 #R * [ | #Y1 #I1 ] #Y2 #i * #f #H1 #H2
 111 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 112 | elim (frees_inv_lref … H1) -H1 #g #Hg #H destruct
 113   elim (sex_inv_push1 … H2) -H2
 114   /4 width=7 by ex3_4_intro, ex2_intro, or_intror/
 115 ]
 116 qed-.
 117
 118 lemma rex_inv_gref (R):
 119       ∀Y1,Y2,l. Y1 ⪤[R,§l] Y2 →
 120       ∨∨ ∧∧ Y1 = ⋆ & Y2 = ⋆
 121        | ∃∃I1,I2,L1,L2. L1 ⪤[R,§l] L2 & Y1 = L1.ⓘ[I1] & Y2 = L2.ⓘ[I2].
 122 #R * [ | #Y1 #I1 ] #Y2 #l * #f #H1 #H2
 123 [ lapply (sex_inv_atom1 … H2) -H2 /3 width=1 by or_introl, conj/
 124 | lapply (frees_inv_gref … H1) -H1 #Hf
 125   elim (pr_isi_inv_gen … Hf) -Hf #g #Hg #H destruct
 126   elim (sex_inv_push1 … H2) -H2 #I2 #L2 #H12 #_ #H destruct
 127   /5 width=7 by frees_gref, ex3_4_intro, ex2_intro, or_intror/
 128 ]
 129 qed-.
 130
 131 (* Basic_2A1: uses: llpx_sn_inv_bind llpx_sn_inv_bind_O *)
 132 lemma rex_inv_bind (R):
 133       ∀p,I,L1,L2,V1,V2,T. L1 ⪤[R,ⓑ[p,I]V1.T] L2 → R L1 V1 V2 →
 134       ∧∧ L1 ⪤[R,V1] L2 & L1.ⓑ[I]V1 ⪤[R,T] L2.ⓑ[I]V2.
 135 #R #p #I #L1 #L2 #V1 #V2 #T * #f #Hf #HL #HV elim (frees_inv_bind … Hf) -Hf
 136 /6 width=6 by sle_sex_trans, sex_inv_tl, ext2_pair, pr_sor_inv_sle_dx, pr_sor_inv_sle_sn, ex2_intro, conj/
 137 qed-.
 138
 139 (* Basic_2A1: uses: llpx_sn_inv_flat *)
 140 lemma rex_inv_flat (R):
 141       ∀I,L1,L2,V,T. L1 ⪤[R,ⓕ[I]V.T] L2 →
 142       ∧∧ L1 ⪤[R,V] L2 & L1 ⪤[R,T] L2.
 143 #R #I #L1 #L2 #V #T * #f #Hf #HL elim (frees_inv_flat … Hf) -Hf
 144 /5 width=6 by sle_sex_trans, pr_sor_inv_sle_dx, pr_sor_inv_sle_sn, ex2_intro, conj/
 145 qed-.
 146
 147 (* Advanced inversion lemmas ************************************************)
 148
 149 lemma rex_inv_sort_bind_sn (R):
 150       ∀I1,K1,L2,s. K1.ⓘ[I1] ⪤[R,⋆s] L2 →
 151       ∃∃I2,K2. K1 ⪤[R,⋆s] K2 & L2 = K2.ⓘ[I2].
 152 #R #I1 #K1 #L2 #s #H elim (rex_inv_sort … H) -H *
 153 [ #H destruct
 154 | #Z1 #I2 #Y1 #K2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 155 ]
 156 qed-.
 157
 158 lemma rex_inv_sort_bind_dx (R):
 159       ∀I2,K2,L1,s. L1 ⪤[R,⋆s] K2.ⓘ[I2] →
 160       ∃∃I1,K1. K1 ⪤[R,⋆s] K2 & L1 = K1.ⓘ[I1].
 161 #R #I2 #K2 #L1 #s #H elim (rex_inv_sort … H) -H *
 162 [ #_ #H destruct
 163 | #I1 #Z2 #K1 #Y2 #Hs #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 164 ]
 165 qed-.
 166
 167 lemma rex_inv_zero_pair_sn (R):
 168       ∀I,L2,K1,V1. K1.ⓑ[I]V1 ⪤[R,#0] L2 →
 169       ∃∃K2,V2. K1 ⪤[R,V1] K2 & R K1 V1 V2 & L2 = K2.ⓑ[I]V2.
 170 #R #I #L2 #K1 #V1 #H elim (rex_inv_zero … H) -H *
 171 [ #H destruct
 172 | #Z #Y1 #K2 #X1 #V2 #HK12 #HV12 #H1 #H2 destruct
 173   /2 width=5 by ex3_2_intro/
 174 | #f #Z #Y1 #Y2 #_ #_ #H destruct
 175 ]
 176 qed-.
 177
 178 lemma rex_inv_zero_pair_dx (R):
 179       ∀I,L1,K2,V2. L1 ⪤[R,#0] K2.ⓑ[I]V2 →
 180       ∃∃K1,V1. K1 ⪤[R,V1] K2 & R K1 V1 V2 & L1 = K1.ⓑ[I]V1.
 181 #R #I #L1 #K2 #V2 #H elim (rex_inv_zero … H) -H *
 182 [ #_ #H destruct
 183 | #Z #K1 #Y2 #V1 #X2 #HK12 #HV12 #H1 #H2 destruct
 184   /2 width=5 by ex3_2_intro/
 185 | #f #Z #Y1 #Y2 #_ #_ #_ #H destruct
 186 ]
 187 qed-.
 188
 189 lemma rex_inv_zero_unit_sn (R):
 190       ∀I,K1,L2. K1.ⓤ[I] ⪤[R,#0] L2 →
 191       ∃∃f,K2. 𝐈❨f❩ & K1 ⪤[cext2 R,cfull,f] K2 & L2 = K2.ⓤ[I].
 192 #R #I #K1 #L2 #H elim (rex_inv_zero … H) -H *
 193 [ #H destruct
 194 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #H destruct
 195 | #f #Z #Y1 #K2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 196 ]
 197 qed-.
 198
 199 lemma rex_inv_zero_unit_dx (R):
 200       ∀I,L1,K2. L1 ⪤[R,#0] K2.ⓤ[I] →
 201       ∃∃f,K1. 𝐈❨f❩ & K1 ⪤[cext2 R,cfull,f] K2 & L1 = K1.ⓤ[I].
 202 #R #I #L1 #K2 #H elim (rex_inv_zero … H) -H *
 203 [ #_ #H destruct
 204 | #Z #Y1 #Y2 #X1 #X2 #_ #_ #_ #H destruct
 205 | #f #Z #K1 #Y2 #Hf #HK12 #H1 #H2 destruct /2 width=5 by ex3_2_intro/
 206 ]
 207 qed-.
 208
 209 lemma rex_inv_lref_bind_sn (R):
 210       ∀I1,K1,L2,i. K1.ⓘ[I1] ⪤[R,#↑i] L2 →
 211       ∃∃I2,K2. K1 ⪤[R,#i] K2 & L2 = K2.ⓘ[I2].
 212 #R #I1 #K1 #L2 #i #H elim (rex_inv_lref … H) -H *
 213 [ #H destruct
 214 | #Z1 #I2 #Y1 #K2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 215 ]
 216 qed-.
 217
 218 lemma rex_inv_lref_bind_dx (R):
 219       ∀I2,K2,L1,i. L1 ⪤[R,#↑i] K2.ⓘ[I2] →
 220       ∃∃I1,K1. K1 ⪤[R,#i] K2 & L1 = K1.ⓘ[I1].
 221 #R #I2 #K2 #L1 #i #H elim (rex_inv_lref … H) -H *
 222 [ #_ #H destruct
 223 | #I1 #Z2 #K1 #Y2 #Hi #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 224 ]
 225 qed-.
 226
 227 lemma rex_inv_gref_bind_sn (R):
 228       ∀I1,K1,L2,l. K1.ⓘ[I1] ⪤[R,§l] L2 →
 229       ∃∃I2,K2. K1 ⪤[R,§l] K2 & L2 = K2.ⓘ[I2].
 230 #R #I1 #K1 #L2 #l #H elim (rex_inv_gref … H) -H *
 231 [ #H destruct
 232 | #Z1 #I2 #Y1 #K2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 233 ]
 234 qed-.
 235
 236 lemma rex_inv_gref_bind_dx (R):
 237       ∀I2,K2,L1,l. L1 ⪤[R,§l] K2.ⓘ[I2] →
 238       ∃∃I1,K1. K1 ⪤[R,§l] K2 & L1 = K1.ⓘ[I1].
 239 #R #I2 #K2 #L1 #l #H elim (rex_inv_gref … H) -H *
 240 [ #_ #H destruct
 241 | #I1 #Z2 #K1 #Y2 #Hl #H1 #H2 destruct /2 width=4 by ex2_2_intro/
 242 ]
 243 qed-.
 244
 245 (* Basic forward lemmas *****************************************************)
 246
 247 lemma rex_fwd_zero_pair (R):
 248       ∀I,K1,K2,V1,V2. K1.ⓑ[I]V1 ⪤[R,#0] K2.ⓑ[I]V2 → K1 ⪤[R,V1] K2.
 249 #R #I #K1 #K2 #V1 #V2 #H
 250 elim (rex_inv_zero_pair_sn … H) -H #Y #X #HK12 #_ #H destruct //
 251 qed-.
 252
 253 (* Basic_2A1: uses: llpx_sn_fwd_pair_sn llpx_sn_fwd_bind_sn llpx_sn_fwd_flat_sn *)
 254 lemma rex_fwd_pair_sn (R):
 255       ∀I,L1,L2,V,T. L1 ⪤[R,②[I]V.T] L2 → L1 ⪤[R,V] L2.
 256 #R * [ #p ] #I #L1 #L2 #V #T * #f #Hf #HL
 257 [ elim (frees_inv_bind … Hf) | elim (frees_inv_flat … Hf) ] -Hf
 258 /4 width=6 by sle_sex_trans, pr_sor_inv_sle_sn, ex2_intro/
 259 qed-.
 260
 261 (* Basic_2A1: uses: llpx_sn_fwd_bind_dx llpx_sn_fwd_bind_O_dx *)
 262 lemma rex_fwd_bind_dx (R):
 263       ∀p,I,L1,L2,V1,V2,T. L1 ⪤[R,ⓑ[p,I]V1.T] L2 →
 264       R L1 V1 V2 → L1.ⓑ[I]V1 ⪤[R,T] L2.ⓑ[I]V2.
 265 #R #p #I #L1 #L2 #V1 #V2 #T #H #HV elim (rex_inv_bind … H HV) -H -HV //
 266 qed-.
 267
 268 (* Basic_2A1: uses: llpx_sn_fwd_flat_dx *)
 269 lemma rex_fwd_flat_dx (R):
 270       ∀I,L1,L2,V,T. L1 ⪤[R,ⓕ[I]V.T] L2 → L1 ⪤[R,T] L2.
 271 #R #I #L1 #L2 #V #T #H elim (rex_inv_flat … H) -H //
 272 qed-.
 273
 274 lemma rex_fwd_dx (R):
 275       ∀I2,L1,K2,T. L1 ⪤[R,T] K2.ⓘ[I2] →
 276       ∃∃I1,K1. L1 = K1.ⓘ[I1].
 277 #R #I2 #L1 #K2 #T * #f elim (pr_map_split_tl f) * #g #Hg #_ #Hf destruct
 278 [ elim (sex_inv_push2 … Hf) | elim (sex_inv_next2 … Hf) ] -Hf #I1 #K1 #_ #_ #H destruct
 279 /2 width=3 by ex1_2_intro/
 280 qed-.
 281
 282 (* Basic properties *********************************************************)
 283
 284 lemma rex_atom (R):
 285       ∀I. ⋆ ⪤[R,⓪[I]] ⋆.
 286 #R * /3 width=3 by frees_sort, frees_atom, frees_gref, sex_atom, ex2_intro/
 287 qed.
 288
 289 lemma rex_sort (R):
 290       ∀I1,I2,L1,L2,s. L1 ⪤[R,⋆s] L2 → L1.ⓘ[I1] ⪤[R,⋆s] L2.ⓘ[I2].
 291 #R #I1 #I2 #L1 #L2 #s * #f #Hf #H12
 292 lapply (frees_inv_sort … Hf) -Hf
 293 /4 width=3 by frees_sort, sex_push, pr_isi_push, ex2_intro/
 294 qed.
 295
 296 lemma rex_pair (R):
 297       ∀I,L1,L2,V1,V2. L1 ⪤[R,V1] L2 →
 298       R L1 V1 V2 → L1.ⓑ[I]V1 ⪤[R,#0] L2.ⓑ[I]V2.
 299 #R #I1 #I2 #L1 #L2 #V1 *
 300 /4 width=3 by ext2_pair, frees_pair, sex_next, ex2_intro/
 301 qed.
 302
 303 lemma rex_unit (R):
 304       ∀f,I,L1,L2. 𝐈❨f❩ → L1 ⪤[cext2 R,cfull,f] L2 →
 305       L1.ⓤ[I] ⪤[R,#0] L2.ⓤ[I].
 306 /4 width=3 by frees_unit, sex_next, ext2_unit, ex2_intro/ qed.
 307
 308 lemma rex_lref (R):
 309       ∀I1,I2,L1,L2,i. L1 ⪤[R,#i] L2 → L1.ⓘ[I1] ⪤[R,#↑i] L2.ⓘ[I2].
 310 #R #I1 #I2 #L1 #L2 #i * /3 width=3 by sex_push, frees_lref, ex2_intro/
 311 qed.
 312
 313 lemma rex_gref (R):
 314       ∀I1,I2,L1,L2,l. L1 ⪤[R,§l] L2 → L1.ⓘ[I1] ⪤[R,§l] L2.ⓘ[I2].
 315 #R #I1 #I2 #L1 #L2 #l * #f #Hf #H12
 316 lapply (frees_inv_gref … Hf) -Hf
 317 /4 width=3 by frees_gref, sex_push, pr_isi_push, ex2_intro/
 318 qed.
 319
 320 lemma rex_bind_repl_dx (R):
 321       ∀I,I1,L1,L2,T. L1.ⓘ[I] ⪤[R,T] L2.ⓘ[I1] →
 322       ∀I2. cext2 R L1 I I2 → L1.ⓘ[I] ⪤[R,T] L2.ⓘ[I2].
 323 #R #I #I1 #L1 #L2 #T * #f #Hf #HL12 #I2 #HR
 324 /3 width=5 by sex_pair_repl, ex2_intro/
 325 qed-.
 326
 327 (* Basic_2A1: uses: llpx_sn_co *)
 328 lemma rex_co (R1) (R2):
 329       (∀L,T1,T2. R1 L T1 T2 → R2 L T1 T2) →
 330       ∀L1,L2,T. L1 ⪤[R1,T] L2 → L1 ⪤[R2,T] L2.
 331 #R1 #R2 #HR #L1 #L2 #T * /5 width=7 by sex_co, cext2_co, ex2_intro/
 332 qed-.
 333
 334 lemma rex_isid (R1) (R2):
 335       ∀L1,L2,T1,T2.
 336       (∀f. L1 ⊢ 𝐅+❨T1❩ ≘ f → 𝐈❨f❩) →
 337       (∀f. 𝐈❨f❩ → L1 ⊢ 𝐅+❨T2❩ ≘ f) →
 338       L1 ⪤[R1,T1] L2 → L1 ⪤[R2,T2] L2.
 339 #R1 #R2 #L1 #L2 #T1 #T2 #H1 #H2 *
 340 /4 width=7 by sex_co_isid, ex2_intro/
 341 qed-.
 342
 343 lemma rex_unit_sn (R1) (R2):
 344       ∀I,K1,L2. K1.ⓤ[I] ⪤[R1,#0] L2 → K1.ⓤ[I] ⪤[R2,#0] L2.
 345 #R1 #R2 #I #K1 #L2 #H
 346 elim (rex_inv_zero_unit_sn … H) -H #f #K2 #Hf #HK12 #H destruct
 347 /3 width=7 by rex_unit, sex_co_isid/
 348 qed-.
 349
 350 (* Basic_2A1: removed theorems 9:
 351               llpx_sn_skip llpx_sn_lref llpx_sn_free
 352               llpx_sn_fwd_lref
 353               llpx_sn_Y llpx_sn_ge_up llpx_sn_ge
 354               llpx_sn_fwd_drop_sn llpx_sn_fwd_drop_dx
 355 *)