matita/matita/contribs/lambdadelta/static_2/syntax/teqo_teqo.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/teqo.ma".
  16
  17 (* SORT-IRRELEVANT OUTER EQUIVALENCE FOR TERMS ******************************)
  18
  19 (* Main properties **********************************************************)
  20
  21 (* Basic_1: was: iso_trans *)
  22 (* Basic_2A1: was: tsts_trans *)
  23 theorem teqo_trans: Transitive … teqo.
  24 #T1 #T * -T1 -T
  25 [ #s1 #s #X #H
  26   elim (teqo_inv_sort1 … H) -s /2 width=1 by teqo_sort/
  27 | #i1 #i #H <(teqo_inv_lref1 … H) -H //
  28 | #l1 #l #H <(teqo_inv_gref1 … H) -H //
  29 | #I #V1 #V #T1 #T #X #H
  30   elim (teqo_inv_pair1 … H) -H #V2 #T2 #H destruct //
  31 ]
  32 qed-.
  33
  34 (* Basic_2A1: was: tsts_canc_sn *)
  35 theorem teqo_canc_sn: left_cancellable … teqo.
  36 /3 width=3 by teqo_trans, teqo_sym/ qed-.
  37
  38 (* Basic_2A1: was: tsts_canc_dx *)
  39 theorem teqo_canc_dx: right_cancellable … teqo.
  40 /3 width=3 by teqo_trans, teqo_sym/ qed-.