matita/matita/lib/arithmetics/bigops.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "basics/types.ma".
  13 include "arithmetics/div_and_mod.ma".
  14
  15 definition sameF_upto: nat → ∀A.relation(nat→A)  ≝
  16 λk.λA.λf,g.∀i. i < k → f i = g i.
  17
  18 definition sameF_p: nat → (nat → bool) →∀A.relation(nat→A)  ≝
  19 λk,p,A,f,g.∀i. i < k → p i = true → f i = g i.
  20
  21 lemma sameF_upto_le: ∀A,f,g,n,m.
  22  n ≤m → sameF_upto m A f g → sameF_upto n A f g.
  23 #A #f #g #n #m #lenm #samef #i #ltin @samef /2 by lt_to_le_to_lt/
  24 qed.
  25
  26 lemma sameF_p_le: ∀A,p,f,g,n,m.
  27  n ≤m → sameF_p m p A f g → sameF_p n p A f g.
  28 #A #p #f #g #n #m #lenm #samef #i #ltin #pi @samef /2 by lt_to_le_to_lt/
  29 qed.
  30
  31 (*
  32 definition sumF ≝ λA.λf,g:nat → A.λn,i.
  33 if_then_else ? (leb n i) (g (i-n)) (f i).
  34
  35 lemma sumF_unfold: ∀A,f,g,n,i.
  36 sumF A f g n i = if_then_else ? (leb n i) (g (i-n)) (f i).
  37 // qed. *)
  38
  39 definition prodF ≝
  40  λA,B.λf:nat→A.λg:nat→B.λm,x.〈 f(div x m), g(mod x m) 〉.
  41
  42 (* bigop *)
  43 let rec bigop (n:nat) (p:nat → bool) (B:Type[0])
  44    (nil: B) (op: B → B → B)  (f: nat → B) ≝
  45   match n with
  46    [ O ⇒ nil
  47    | S k ⇒
  48       match p k with
  49       [true ⇒ op (f k) (bigop k p B nil op f)
  50       |false ⇒ bigop k p B nil op f]
  51    ].
  52
  53 notation "\big  [ op , nil ]_{ ident i < n | p } f"
  54   with precedence 80
  55 for @{'bigop $n $op $nil (λ${ident i}. $p) (λ${ident i}. $f)}.
  56
  57 notation "\big [ op , nil ]_{ ident i < n } f"
  58   with precedence 80
  59 for @{'bigop $n $op $nil (λ${ident i}.true) (λ${ident i}. $f)}.
  60
  61 interpretation "bigop" 'bigop n op nil p f = (bigop n p ? nil op f).
  62
  63 notation "\big  [ op , nil ]_{ ident j ∈ [a,b[ | p } f"
  64   with precedence 80
  65 for @{'bigop ($b-$a) $op $nil (λ${ident j}.((λ${ident j}.$p) (${ident j}+$a)))
  66   (λ${ident j}.((λ${ident j}.$f)(${ident j}+$a)))}.
  67
  68 notation "\big  [ op , nil ]_{ ident j ∈ [a,b[ } f"
  69   with precedence 80
  70 for @{'bigop ($b-$a) $op $nil (λ${ident j}.((λ${ident j}.true) (${ident j}+$a)))
  71   (λ${ident j}.((λ${ident j}.$f)(${ident j}+$a)))}.
  72
  73 (* notation "\big  [ op , nil ]_{( term 55) a ≤ ident j < b | p } f"
  74   with precedence 80
  75 for @{\big[$op,$nil]_{${ident j} < ($b-$a) | ((λ${ident j}.$p) (${ident j}+$a))}((λ${ident j}.$f)(${ident j}+$a))}.
  76 *)
  77
  78 interpretation "bigop" 'bigop n op nil p f = (bigop n p ? nil op f).
  79
  80 lemma bigop_Strue: ∀k,p,B,nil,op.∀f:nat→B. p k = true →
  81   \big[op,nil]_{i < S k | p i}(f i) =
  82     op (f k) (\big[op,nil]_{i < k | p i}(f i)).
  83 #k #p #B #nil #op #f #H normalize >H // qed.
  84
  85 lemma bigop_Sfalse: ∀k,p,B,nil,op.∀f:nat→B. p k = false →
  86   \big[op,nil]_{ i < S k | p i}(f i) =
  87     \big[op,nil]_{i < k | p i}(f i).
  88 #k #p #B #nil #op #f #H normalize >H // qed.
  89
  90 lemma same_bigop : ∀k,p1,p2,B,nil,op.∀f,g:nat→B.
  91   sameF_upto k bool p1 p2 → sameF_p k p1 B f g →
  92   \big[op,nil]_{i < k | p1 i}(f i) =
  93     \big[op,nil]_{i < k | p2 i}(g i).
  94 #k #p1 #p2 #B #nil #op #f #g (elim k) //
  95 #n #Hind #samep #samef normalize >Hind /2/
  96 <(samep … (le_n …)) cases(true_or_false (p1 n)) #H1 >H1
  97 normalize // <(samef … (le_n …) H1) //
  98 qed.
  99
 100 theorem pad_bigop: ∀k,n,p,B,nil,op.∀f:nat→B. n ≤ k →
 101 \big[op,nil]_{i < n | p i}(f i)
 102   = \big[op,nil]_{i < k | if leb n i then false else p i}(f i).
 103 #k #n #p #B #nil #op #f #lenk (elim lenk)
 104   [@same_bigop #i #lti // >(not_le_to_leb_false …) /2/
 105   |#j #leup #Hind >bigop_Sfalse >(le_to_leb_true … leup) //
 106   ] qed.
 107
 108 theorem pad_bigop1: ∀k,n,p,B,nil,op.∀f:nat→B. n ≤ k →
 109   (∀i. n ≤ i → i < k → p i = false) →
 110   \big[op,nil]_{i < n | p i}(f i)
 111     = \big[op,nil]_{i < k | p i}(f i).
 112 #k #n #p #B #nil #op #f #lenk (elim lenk)
 113   [#_ @same_bigop #i #lti //
 114   |#j #leup #Hind #Hfalse >bigop_Sfalse
 115     [@Hind #i #leni #ltij @Hfalse // @le_S //
 116     |@Hfalse //
 117     ]
 118   ]
 119 qed.
 120
 121 theorem bigop_false: ∀n,B,nil,op.∀f:nat→B.
 122   \big[op,nil]_{i < n | false }(f i) = nil.
 123 #n #B #nil #op #f elim n // #n1 #Hind
 124 >bigop_Sfalse //
 125 qed.
 126
 127 record Aop (A:Type[0]) (nil:A) : Type[0] ≝
 128   {op :2> A → A → A;
 129    nill:∀a. op nil a = a;
 130    nilr:∀a. op a nil = a;
 131    assoc: ∀a,b,c.op a (op b c) = op (op a b) c
 132   }.
 133
 134 theorem pad_bigop_nil: ∀k,n,p,B,nil.∀op:Aop B nil.∀f:nat→B. n ≤ k →
 135   (∀i. n ≤ i → i < k → p i = false ∨ f i = nil) →
 136   \big[op,nil]_{i < n | p i}(f i)
 137     = \big[op,nil]_{i < k | p i}(f i).
 138 #k #n #p #B #nil #op #f #lenk (elim lenk)
 139   [#_ @same_bigop #i #lti //
 140   |#j #leup #Hind #Hfalse cases (true_or_false (p j)) #Hpj
 141     [>bigop_Strue //
 142      cut (f j = nil)
 143       [cases (Hfalse j leup (le_n … )) // >Hpj #H destruct (H)] #Hfj
 144      >Hfj >nill @Hind #i #leni #ltij
 145      cases (Hfalse i leni (le_S … ltij)) /2/
 146     |>bigop_Sfalse // @Hind #i #leni #ltij
 147      cases (Hfalse i leni (le_S … ltij)) /2/
 148     ]
 149   ]
 150 qed.
 151
 152 theorem bigop_sum: ∀k1,k2,p1,p2,B.∀nil.∀op:Aop B nil.∀f,g:nat→B.
 153 op (\big[op,nil]_{i<k1|p1 i}(f i)) \big[op,nil]_{i<k2|p2 i}(g i) =
 154       \big[op,nil]_{i<k1+k2|if leb k2 i then p1 (i-k2) else p2 i}
 155         (if leb k2 i then f (i-k2) else g i).
 156 #k1 #k2 #p1 #p2 #B #nil #op #f #g (elim k1)
 157   [normalize >nill @same_bigop #i #lti
 158    >(lt_to_leb_false … lti) normalize /2/
 159   |#i #Hind normalize <minus_plus_m_m (cases (p1 i))
 160    >(le_to_leb_true … (le_plus_n …)) normalize <Hind //
 161    <assoc //
 162   ]
 163 qed.
 164
 165 lemma plus_minus1: ∀a,b,c. c ≤ b → a + (b -c) = a + b -c.
 166 #a #b #c #lecb @sym_eq @plus_to_minus >(commutative_plus c)
 167 >associative_plus <plus_minus_m_m //
 168 qed.
 169
 170 theorem bigop_I: ∀n,p,B.∀nil.∀op:Aop B nil.∀f:nat→B.
 171 \big[op,nil]_{i∈[0,n[ |p i}(f i) = \big[op,nil]_{i < n|p i}(f i).
 172 #n #p #B #nil #op #f <minus_n_O @same_bigop //
 173 qed.
 174
 175 theorem bigop_sumI: ∀a,b,c,p,B.∀nil.∀op:Aop B nil.∀f:nat→B.
 176 a ≤ b → b ≤ c →
 177 \big[op,nil]_{i∈[a,c[ |p i}(f i) =
 178   op (\big[op,nil]_{i ∈ [b,c[ |p i}(f i))
 179       \big[op,nil]_{i ∈ [a,b[ |p i}(f i).
 180 #a #b # c #p #B #nil #op #f #leab #lebc
 181 >(plus_minus_m_m (c-a) (b-a)) in ⊢ (??%?); /2/
 182 >minus_plus >(commutative_plus a) <plus_minus_m_m //
 183 >bigop_sum (cut (∀i. b -a ≤ i → i+a = i-(b-a)+b))
 184   [#i #lei >plus_minus // <plus_minus1
 185      [@eq_f @sym_eq @plus_to_minus /2/ | /2/]]
 186 #H @same_bigop #i #ltic @leb_elim normalize // #lei <H //
 187 qed.
 188
 189 theorem bigop_a: ∀a,b,B.∀nil.∀op:Aop B nil.∀f:nat→B. a ≤ b →
 190 \big[op,nil]_{i∈[a,S b[ }(f i) =
 191   op (\big[op,nil]_{i ∈ [a,b[ }(f (S i))) (f a).
 192 #a #b #B #nil #op #f #leab
 193 >(bigop_sumI a (S a) (S b)) [|@le_S_S //|//] @eq_f2
 194   [@same_bigop // |<minus_Sn_n normalize @nilr]
 195 qed.
 196
 197 theorem bigop_0: ∀n,B.∀nil.∀op:Aop B nil.∀f:nat→B.
 198 \big[op,nil]_{i < S n}(f i) =
 199   op (\big[op,nil]_{i < n}(f (S i))) (f 0).
 200 #n #B #nil #op #f
 201 <bigop_I >bigop_a [|//] @eq_f2 [|//] <minus_n_O
 202 @same_bigop //
 203 qed.
 204
 205 theorem bigop_prod: ∀k1,k2,p1,p2,B.∀nil.∀op:Aop B nil.∀f: nat →nat → B.
 206 \big[op,nil]_{x<k1|p1 x}(\big[op,nil]_{i<k2|p2 x i}(f x i)) =
 207   \big[op,nil]_{i<k1*k2|andb (p1 (i/k2)) (p2 (i/k2) (i \mod k2))}
 208      (f (i/k2) (i \mod k2)).
 209 #k1 #k2 #p1 #p2 #B #nil #op #f (elim k1) //
 210 #n #Hind cases(true_or_false (p1 n)) #Hp1
 211   [>bigop_Strue // >Hind >bigop_sum @same_bigop
 212    #i #lti @leb_elim // #lei cut (i = n*k2+(i-n*k2)) /2 by plus_minus/
 213    #eqi [|#H] >eqi in ⊢ (???%);
 214      >div_plus_times /2 by monotonic_lt_minus_l/
 215      >Hp1 >(mod_plus_times …) /2 by refl, monotonic_lt_minus_l, eq_f/
 216   |>bigop_Sfalse // >Hind >(pad_bigop (S n*k2)) // @same_bigop
 217    #i #lti @leb_elim // #lei cut (i = n*k2+(i-n*k2)) /2/
 218    #eqi >eqi in ⊢ (???%); >div_plus_times /2/
 219   ]
 220 qed.
 221
 222 record ACop (A:Type[0]) (nil:A) : Type[0] ≝
 223   {aop :> Aop A nil;
 224    comm: ∀a,b.aop a b = aop b a
 225   }.
 226
 227 lemma bigop_op: ∀k,p,B.∀nil.∀op:ACop B nil.∀f,g: nat → B.
 228 op (\big[op,nil]_{i<k|p i}(f i)) (\big[op,nil]_{i<k|p i}(g i)) =
 229   \big[op,nil]_{i<k|p i}(op (f i) (g i)).
 230 #k #p #B #nil #op #f #g (elim k) [normalize @nill]
 231 -k #k #Hind (cases (true_or_false (p k))) #H
 232   [>bigop_Strue // >bigop_Strue // >bigop_Strue //
 233    normalize <assoc <assoc in ⊢ (???%); @eq_f >assoc >comm in ⊢ (??(????%?)?);
 234    <assoc @eq_f @Hind
 235   |>bigop_Sfalse // >bigop_Sfalse // >bigop_Sfalse //
 236   ]
 237 qed.
 238
 239 lemma bigop_diff: ∀p,B.∀nil.∀op:ACop B nil.∀f:nat → B.∀i,n.
 240   i < n → p i = true →
 241   \big[op,nil]_{x<n|p x}(f x)=
 242     op (f i) (\big[op,nil]_{x<n|andb(notb(eqb i x))(p x)}(f x)).
 243 #p #B #nil #op #f #i #n (elim n)
 244   [#ltO @False_ind /2/
 245   |#n #Hind #lein #pi cases (le_to_or_lt_eq … (le_S_S_to_le …lein)) #Hi
 246     [cut (andb(notb(eqb i n))(p n) = (p n))
 247       [>(not_eq_to_eqb_false … (lt_to_not_eq … Hi)) //] #Hcut
 248      cases (true_or_false (p n)) #pn
 249       [>bigop_Strue // >bigop_Strue //
 250        normalize >assoc >(comm ?? op (f i) (f n)) <assoc >Hind //
 251       |>bigop_Sfalse // >bigop_Sfalse // >Hind //
 252       ]
 253     |<Hi >bigop_Strue // @eq_f >bigop_Sfalse
 254        [@same_bigop // #k #ltki >not_eq_to_eqb_false /2/
 255        |>eq_to_eqb_true //
 256        ]
 257      ]
 258    ]
 259 qed.
 260
 261 (* range *)
 262 record range (A:Type[0]): Type[0] ≝
 263   {enum:nat→A; upto:nat; filter:nat→bool}.
 264
 265 definition sub_hk: (nat→nat)→(nat→nat)→∀A:Type[0].relation (range A) ≝
 266 λh,k,A,I,J.∀i.i<(upto A I) → (filter A I i)=true →
 267   (h i < upto A J
 268   ∧ filter A J (h i) = true
 269   ∧ k (h i) = i).
 270
 271 definition iso: ∀A:Type[0].relation (range A) ≝
 272   λA,I,J.∃h,k.
 273     (∀i. i < (upto A I) → (filter A I i) = true →
 274        enum A I i = enum A J (h i)) ∧
 275     sub_hk h k A I J ∧ sub_hk k h A J I.
 276
 277 lemma sub_hkO: ∀h,k,A,I,J. upto A I = 0 → sub_hk h k A I J.
 278 #h #k #A #I #J #up0 #i #lti >up0 @False_ind /2/
 279 qed.
 280
 281 lemma sub0_to_false: ∀h,k,A,I,J. upto A I = 0 → sub_hk h k A J I →
 282   ∀i. i < upto A J → filter A J i = false.
 283 #h #k #A #I #J #up0 #sub #i #lti cases(true_or_false (filter A J i)) //
 284 #ptrue (cases (sub i lti ptrue)) * #hi @False_ind /2/
 285 qed.
 286
 287 lemma sub_lt: ∀A,e,p,n,m. n ≤ m →
 288   sub_hk (λx.x) (λx.x) A (mk_range A e n p) (mk_range A e m p).
 289 #A #e #f #n #m #lenm #i #lti #fi % // % /2 by lt_to_le_to_lt/
 290 qed.
 291
 292 theorem transitive_sub: ∀h1,k1,h2,k2,A,I,J,K.
 293   sub_hk h1 k1 A I J → sub_hk h2 k2 A J K →
 294     sub_hk (λx.h2(h1 x)) (λx.k1(k2 x)) A I K.
 295 #h1 #k1 #h2 #k2 #A #I #J #K #sub1 #sub2 #i #lti #fi
 296 cases(sub1 i lti fi) * #lth1i #fh1i #ei
 297 cases(sub2 (h1 i) lth1i fh1i) * #H1 #H2 #H3 % // % //
 298 qed.
 299
 300 theorem bigop_iso: ∀n1,n2,p1,p2,B.∀nil.∀op:ACop B nil.∀f1,f2.
 301   iso B (mk_range B f1 n1 p1) (mk_range B f2 n2 p2) →
 302   \big[op,nil]_{i<n1|p1 i}(f1 i) = \big[op,nil]_{i<n2|p2 i}(f2 i).
 303 #n1 #n2 #p1 #p2 #B #nil #op #f1 #f2 * #h * #k * * #same
 304 @(le_gen ? n1) #i lapply p2 (elim i)
 305   [(elim n2) // #m #Hind #p2 #_ #sub1 #sub2
 306    >bigop_Sfalse
 307     [@(Hind ? (le_O_n ?)) [/2/ | @(transitive_sub … (sub_lt …) sub2) //]
 308     |@(sub0_to_false … sub2) //
 309     ]
 310   |#n #Hind #p2 #ltn #sub1 #sub2 (cut (n ≤n1)) [/2/] #len
 311    cases(true_or_false (p1 n)) #p1n
 312     [>bigop_Strue // (cases (sub1 n (le_n …) p1n)) * #hn #p2hn #eqn
 313      >(bigop_diff … (h n) n2) // >same //
 314      @eq_f @(Hind ? len)
 315       [#i #ltin #p1i (cases (sub1 i (le_S … ltin) p1i)) *
 316        #h1i #p2h1i #eqi % // % // >not_eq_to_eqb_false normalize //
 317        @(not_to_not ??? (lt_to_not_eq ? ? ltin)) //
 318       |#j #ltj #p2j (cases (sub2 j ltj (andb_true_r …p2j))) *
 319        #ltkj #p1kj #eqj % // % //
 320        (cases (le_to_or_lt_eq …(le_S_S_to_le …ltkj))) //
 321        #eqkj @False_ind lapply p2j @eqb_elim
 322        normalize /2/
 323       ]
 324     |>bigop_Sfalse // @(Hind ? len)
 325       [@(transitive_sub … (sub_lt …) sub1) //
 326       |#i #lti #p2i cases(sub2 i lti p2i) * #ltki #p1ki #eqi
 327        % // % // cases(le_to_or_lt_eq …(le_S_S_to_le …ltki)) //
 328        #eqki @False_ind /2/
 329       ]
 330     ]
 331   ]
 332 qed.
 333
 334 (* lemma div_mod_exchange: ∀i,n,m. i < n*m → i\n = i mod m. *)
 335
 336 (* commutation *)
 337 theorem bigop_commute: ∀n,m,p11,p12,p21,p22,B.∀nil.∀op:ACop B nil.∀f.
 338 0 < n → 0 < m →
 339 (∀i,j. i < n → j < m → (p11 i ∧ p12 i j) = (p21 j ∧ p22 i j)) →
 340 \big[op,nil]_{i<n|p11 i}(\big[op,nil]_{j<m|p12 i j}(f i j)) =
 341    \big[op,nil]_{j<m|p21 j}(\big[op,nil]_{i<n|p22 i j}(f i j)).
 342 #n #m #p11 #p12 #p21 #p22 #B #nil #op #f #posn #posm #Heq
 343 >bigop_prod >bigop_prod @bigop_iso
 344 %{(λi.(i\mod m)*n + i/m)} %{(λi.(i\mod n)*m + i/n)} %
 345   [%
 346     [#i #lti #Heq (* whd in ⊢ (???(?(?%?)?)); *) @eq_f2
 347       [@sym_eq @mod_plus_times /2 by lt_times_to_lt_div/
 348       |@sym_eq @div_plus_times /2 by lt_times_to_lt_div/
 349       ]
 350     |#i #lti #Hi
 351      cut ((i\mod m*n+i/m)\mod n=i/m)
 352       [@mod_plus_times @lt_times_to_lt_div //] #H1
 353      cut ((i\mod m*n+i/m)/n=i \mod m)
 354       [@div_plus_times @lt_times_to_lt_div //] #H2
 355      %[%[@(lt_to_le_to_lt ? (i\mod m*n+n))
 356           [whd >plus_n_Sm @monotonic_le_plus_r @lt_times_to_lt_div //
 357           |>commutative_plus @(le_times (S(i \mod m)) m n n) // @lt_mod_m_m //
 358           ]
 359         |lapply (Heq (i/m) (i \mod m) ??)
 360           [@lt_mod_m_m // |@lt_times_to_lt_div //|>Hi >H1 >H2 //]
 361         ]
 362       |>H1 >H2 //
 363       ]
 364     ]
 365   |#i #lti #Hi
 366    cut ((i\mod n*m+i/n)\mod m=i/n)
 367     [@mod_plus_times @lt_times_to_lt_div //] #H1
 368    cut ((i\mod n*m+i/n)/m=i \mod n)
 369     [@div_plus_times @lt_times_to_lt_div //] #H2
 370    %[%[@(lt_to_le_to_lt ? (i\mod n*m+m))
 371         [whd >plus_n_Sm @monotonic_le_plus_r @lt_times_to_lt_div //
 372         |>commutative_plus @(le_times (S(i \mod n)) n m m) // @lt_mod_m_m //
 373         ]
 374       |lapply (Heq (i \mod n) (i/n) ??)
 375         [@lt_times_to_lt_div // |@lt_mod_m_m // |>Hi >H1 >H2 //]
 376       ]
 377     |>H1 >H2 //
 378     ]
 379   ]
 380 qed.
 381
 382 (* distributivity *)
 383
 384 record Dop (A:Type[0]) (nil:A): Type[0] ≝
 385   {sum : ACop A nil;
 386    prod: A → A →A;
 387    null: \forall a. prod a nil = nil;
 388    distr: ∀a,b,c:A. prod a (sum b c) = sum (prod a b) (prod a c)
 389   }.
 390
 391 theorem bigop_distr: ∀n,p,B,nil.∀R:Dop B nil.∀f,a.
 392   let aop ≝ sum B nil R in
 393   let mop ≝ prod B nil R in
 394   mop a \big[aop,nil]_{i<n|p i}(f i) =
 395    \big[aop,nil]_{i<n|p i}(mop a (f i)).
 396 #n #p #B #nil #R #f #a normalize (elim n) [@null]
 397 #n #Hind (cases (true_or_false (p n))) #H
 398   [>bigop_Strue // >bigop_Strue // >(distr B nil R) >Hind //
 399   |>bigop_Sfalse // >bigop_Sfalse //
 400   ]
 401 qed.