matita/matita/lib/arithmetics/nat.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "basics/relations.ma".
  13
  14 (* Definitions **************************************************************)
  15
  16 (* natural numbers *)
  17
  18 inductive nat : Type[0] ≝
  19   | O : nat
  20   | S : nat → nat.
  21
  22 interpretation "Natural numbers" 'N = nat.
  23
  24 alias num (instance 0) = "natural number".
  25
  26 definition pred ≝
  27  λn. match n with [ O ⇒ O | S p ⇒ p].
  28
  29 definition not_zero: nat → Prop ≝
  30  λn: nat. match n with [ O ⇒ False | (S p) ⇒ True ].
  31
  32 (* order relations *)
  33
  34 inductive le (n:nat) : nat → Prop ≝
  35   | le_n : le n n
  36   | le_S : ∀ m:nat. le n m → le n (S m).
  37
  38 interpretation "natural 'less or equal to'" 'leq x y = (le x y).
  39
  40 interpretation "natural 'neither less nor equal to'" 'nleq x y = (Not (le x y)).
  41
  42 definition lt: nat → nat → Prop ≝ λn,m. S n ≤ m.
  43
  44 interpretation "natural 'less than'" 'lt x y = (lt x y).
  45
  46 interpretation "natural 'not less than'" 'nless x y = (Not (lt x y)).
  47
  48 definition ge: nat → nat → Prop ≝ λn,m.m ≤ n.
  49
  50 interpretation "natural 'greater or equal to'" 'geq x y = (ge x y).
  51
  52 definition gt: nat → nat → Prop ≝ λn,m.m<n.
  53
  54 interpretation "natural 'greater than'" 'gt x y = (gt x y).
  55
  56 interpretation "natural 'not greater than'" 'ngtr x y = (Not (gt x y)).
  57
  58 (* abstract properties *)
  59
  60 definition increasing ≝ λf:nat → nat. ∀n:nat. f n < f (S n).
  61
  62 (* arithmetic operations *)
  63
  64 let rec plus n m ≝
  65  match n with [ O ⇒ m | S p ⇒ S (plus p m) ].
  66
  67 interpretation "natural plus" 'plus x y = (plus x y).
  68
  69 let rec times n m ≝
  70  match n with [ O ⇒ 0 | S p ⇒ m + (times p m) ].
  71
  72 interpretation "natural times" 'times x y = (times x y).
  73
  74 let rec minus n m ≝
  75  match n with
  76  [ O ⇒ O
  77  | S p ⇒
  78         match m with
  79           [ O ⇒ S p
  80     | S q ⇒ minus p q ]].
  81
  82 interpretation "natural minus" 'minus x y = (minus x y).
  83
  84 (* Generic conclusion ******************************************************)
  85
  86 theorem nat_case:
  87  ∀n:nat.∀P:nat → Prop.
  88   (n=O → P O) → (∀m:nat. n= S m → P (S m)) → P n.
  89 #n #P (elim n) /2/ qed.
  90
  91 theorem nat_elim2 :
  92  ∀R:nat → nat → Prop.
  93   (∀n:nat. R O n)
  94   → (∀n:nat. R (S n) O)
  95   → (∀n,m:nat. R n m → R (S n) (S m))
  96   → ∀n,m:nat. R n m.
  97 #R #ROn #RSO #RSS #n (elim n) // #n0 #Rn0m #m (cases m) /2/ qed.
  98
  99 lemma le_gen: ∀P:nat → Prop.∀n.(∀i. i ≤ n → P i) → P n.
 100 /2/ qed.
 101
 102 (* Equalities ***************************************************************)
 103
 104 theorem pred_Sn : ∀n. n = pred (S n).
 105 // qed.
 106
 107 theorem injective_S : injective nat nat S.
 108 // qed.
 109
 110 theorem S_pred: ∀n. 0 < n → S(pred n) = n.
 111 #n #posn (cases posn) //
 112 qed.
 113
 114 theorem plus_O_n: ∀n:nat. n = 0 + n.
 115 // qed.
 116
 117 theorem plus_n_O: ∀n:nat. n = n + 0.
 118 #n (elim n) normalize // qed.
 119
 120 theorem plus_n_Sm : ∀n,m:nat. S (n+m) = n + S m.
 121 #n (elim n) normalize // qed.
 122
 123 theorem commutative_plus: commutative ? plus.
 124 #n (elim n) normalize // qed.
 125
 126 theorem associative_plus : associative nat plus.
 127 #n (elim n) normalize // qed.
 128
 129 theorem assoc_plus1: ∀a,b,c. c + (b + a) = b + c + a.
 130 // qed.
 131
 132 theorem injective_plus_r: ∀n:nat.injective nat nat (λm.n+m).
 133 #n (elim n) normalize /3/ qed.
 134
 135 theorem injective_plus_l: ∀n:nat.injective nat nat (λm.m+n).
 136 /2/ qed.
 137
 138 theorem times_Sn_m: ∀n,m:nat. m+n*m = S n*m.
 139 // qed.
 140
 141 theorem times_O_n: ∀n:nat. 0 = 0 * n.
 142 // qed.
 143
 144 theorem times_n_O: ∀n:nat. 0 = n * 0.
 145 #n (elim n) // qed.
 146
 147 theorem times_n_Sm : ∀n,m:nat. n+(n*m) = n*(S m).
 148 #n (elim n) normalize // qed.
 149
 150 theorem commutative_times : commutative nat times.
 151 #n (elim n) normalize // qed.
 152
 153 theorem distributive_times_plus : distributive nat times plus.
 154 #n (elim n) normalize // qed.
 155
 156 theorem distributive_times_plus_r :
 157   ∀a,b,c:nat. (b+c)*a = b*a + c*a.
 158 // qed.
 159
 160 theorem associative_times: associative nat times.
 161 #n (elim n) normalize // qed.
 162
 163 lemma times_times: ∀x,y,z. x*(y*z) = y*(x*z).
 164 // qed.
 165
 166 theorem times_n_1 : ∀n:nat. n = n * 1.
 167 #n // qed.
 168
 169 theorem minus_S_S: ∀n,m:nat.S n - S m = n -m.
 170 // qed.
 171
 172 theorem minus_O_n: ∀n:nat.0=0-n.
 173 #n (cases n) // qed.
 174
 175 theorem minus_n_O: ∀n:nat.n=n-0.
 176 #n (cases n) // qed.
 177
 178 theorem minus_n_n: ∀n:nat.0=n-n.
 179 #n (elim n) // qed.
 180
 181 theorem minus_Sn_n: ∀n:nat. S 0 = (S n)-n.
 182 #n (elim n) normalize // qed.
 183
 184 theorem eq_minus_S_pred: ∀n,m. n - (S m) = pred(n -m).
 185 @nat_elim2 normalize // qed.
 186
 187 lemma plus_plus_comm_23: ∀x,y,z. x + y + z = x + z + y.
 188 // qed.
 189
 190 (* Negated equalities *******************************************************)
 191
 192 theorem not_eq_S: ∀n,m:nat. n ≠ m → S n ≠ S m.
 193 /2/ qed.
 194
 195 theorem not_eq_O_S : ∀n:nat. 0 ≠ S n.
 196 #n @nmk #eqOS (change with (not_zero O)) >eqOS // qed.
 197
 198 theorem not_eq_n_Sn: ∀n:nat. n ≠ S n.
 199 #n (elim n) /2/ qed.
 200
 201 (* Atomic conclusion *******************************************************)
 202
 203 (* not_zero *)
 204
 205 theorem lt_to_not_zero : ∀n,m:nat. n < m → not_zero m.
 206 #n #m #Hlt (elim Hlt) // qed.
 207
 208 (* le *)
 209
 210 theorem le_S_S: ∀n,m:nat. n ≤ m → S n ≤ S m.
 211 #n #m #lenm (elim lenm) /2/ qed.
 212
 213 theorem le_O_n : ∀n:nat. 0 ≤ n.
 214 #n (elim n) /2/ qed.
 215
 216 theorem le_n_Sn : ∀n:nat. n ≤ S n.
 217 /2/ qed.
 218
 219 theorem transitive_le : transitive nat le.
 220 #a #b #c #leab #lebc (elim lebc) /2/
 221 qed.
 222
 223 theorem le_pred_n : ∀n:nat. pred n ≤ n.
 224 #n (elim n) // qed.
 225
 226 theorem monotonic_pred: monotonic ? le pred.
 227 #n #m #lenm (elim lenm) /2/ qed.
 228
 229 theorem le_S_S_to_le: ∀n,m:nat. S n ≤ S m → n ≤ m.
 230 (* demo *)
 231 /2/ qed-.
 232
 233 theorem monotonic_le_plus_r:
 234 ∀n:nat.monotonic nat le (λm.n + m).
 235 #n #a #b (elim n) normalize //
 236 #m #H #leab @le_S_S /2/ qed.
 237
 238 theorem monotonic_le_plus_l:
 239 ∀m:nat.monotonic nat le (λn.n + m).
 240 /2/ qed.
 241
 242 theorem le_plus: ∀n1,n2,m1,m2:nat. n1 ≤ n2  → m1 ≤ m2
 243 → n1 + m1 ≤ n2 + m2.
 244 #n1 #n2 #m1 #m2 #len #lem @(transitive_le ? (n1+m2))
 245 /2/ qed.
 246
 247 theorem le_plus_n :∀n,m:nat. m ≤ n + m.
 248 /2/ qed.
 249
 250 lemma le_plus_a: ∀a,n,m. n ≤ m → n ≤ a + m.
 251 /2/ qed.
 252
 253 lemma le_plus_b: ∀b,n,m. n + b ≤ m → n ≤ m.
 254 /2/ qed.
 255
 256 theorem le_plus_n_r :∀n,m:nat. m ≤ m + n.
 257 /2/ qed.
 258
 259 theorem eq_plus_to_le: ∀n,m,p:nat.n=m+p → m ≤ n.
 260 // qed-.
 261
 262 theorem le_plus_to_le: ∀a,n,m. a + n ≤ a + m → n ≤ m.
 263 #a (elim a) normalize /3/ qed.
 264
 265 theorem le_plus_to_le_r: ∀a,n,m. n + a ≤ m +a → n ≤ m.
 266 /2/ qed-.
 267
 268 theorem monotonic_le_times_r:
 269 ∀n:nat.monotonic nat le (λm. n * m).
 270 #n #x #y #lexy (elim n) normalize//(* lento /2/*)
 271 #a #lea @le_plus //
 272 qed.
 273
 274 theorem le_times: ∀n1,n2,m1,m2:nat.
 275 n1 ≤ n2  → m1 ≤ m2 → n1*m1 ≤ n2*m2.
 276 #n1 #n2 #m1 #m2 #len #lem @(transitive_le ? (n1*m2)) /2/
 277 qed.
 278
 279 (* interessante *)
 280 theorem lt_times_n: ∀n,m:nat. O < n → m ≤ n*m.
 281 #n #m #H /2/ qed.
 282
 283 theorem le_times_to_le:
 284 ∀a,n,m. O < a → a * n ≤ a * m → n ≤ m.
 285 #a @nat_elim2 normalize
 286   [//
 287   |#n #H1 #H2
 288      @(transitive_le ? (a*S n)) /2/
 289   |#n #m #H #lta #le
 290      @le_S_S @H /2/
 291   ]
 292 qed-.
 293
 294 theorem le_plus_minus_m_m: ∀n,m:nat. n ≤ (n-m)+m.
 295 #n (elim n) // #a #Hind #m (cases m) // normalize #n/2/
 296 qed.
 297
 298 theorem le_plus_to_minus_r: ∀a,b,c. a + b ≤ c → a ≤ c -b.
 299 #a #b #c #H @(le_plus_to_le_r … b) /2/
 300 qed.
 301
 302 lemma lt_to_le: ∀x,y. x < y → x ≤ y.
 303 /2 width=2/ qed.
 304
 305 lemma inv_eq_minus_O: ∀x,y. x - y = 0 → x ≤ y.
 306 // qed-.
 307
 308 (* lt *)
 309
 310 theorem transitive_lt: transitive nat lt.
 311 #a #b #c #ltab #ltbc (elim ltbc) /2/
 312 qed.
 313
 314 theorem lt_to_le_to_lt: ∀n,m,p:nat. n < m → m ≤ p → n < p.
 315 #n #m #p #H #H1 (elim H1) /2/ qed.
 316
 317 theorem le_to_lt_to_lt: ∀n,m,p:nat. n ≤ m → m < p → n < p.
 318 #n #m #p #H (elim H) /3/ qed.
 319
 320 theorem lt_S_to_lt: ∀n,m. S n < m → n < m.
 321 /2/ qed.
 322
 323 theorem ltn_to_ltO: ∀n,m:nat. n < m → 0 < m.
 324 /2/ qed.
 325
 326 theorem lt_O_S : ∀n:nat. O < S n.
 327 /2/ qed.
 328
 329 theorem monotonic_lt_plus_r:
 330 ∀n:nat.monotonic nat lt (λm.n+m).
 331 /2/ qed.
 332
 333 theorem monotonic_lt_plus_l:
 334 ∀n:nat.monotonic nat lt (λm.m+n).
 335 /2/ qed.
 336
 337 theorem lt_plus: ∀n,m,p,q:nat. n < m → p < q → n + p < m + q.
 338 #n #m #p #q #ltnm #ltpq
 339 @(transitive_lt ? (n+q))/2/ qed.
 340
 341 theorem lt_plus_to_lt_l :∀n,p,q:nat. p+n < q+n → p<q.
 342 /2/ qed.
 343
 344 theorem lt_plus_to_lt_r :∀n,p,q:nat. n+p < n+q → p<q.
 345 /2/ qed-.
 346
 347 theorem increasing_to_monotonic: ∀f:nat → nat.
 348   increasing f → monotonic nat lt f.
 349 #f #incr #n #m #ltnm (elim ltnm) /2/
 350 qed.
 351
 352 theorem monotonic_lt_times_r:
 353   ∀c:nat. O < c → monotonic nat lt (λt.(c*t)).
 354 #c #posc #n #m #ltnm
 355 (elim ltnm) normalize
 356   [/2/
 357   |#a #_ #lt1 @(transitive_le … lt1) //
 358   ]
 359 qed.
 360
 361 theorem monotonic_lt_times_l:
 362   ∀c:nat. 0 < c → monotonic nat lt (λt.(t*c)).
 363 /2/
 364 qed.
 365
 366 theorem lt_to_le_to_lt_times:
 367 ∀n,m,p,q:nat. n < m → p ≤ q → O < q → n*p < m*q.
 368 #n #m #p #q #ltnm #lepq #posq
 369 @(le_to_lt_to_lt ? (n*q))
 370   [@monotonic_le_times_r //
 371   |@monotonic_lt_times_l //
 372   ]
 373 qed.
 374
 375 theorem lt_times:∀n,m,p,q:nat. n<m → p<q → n*p < m*q.
 376 #n #m #p #q #ltnm #ltpq @lt_to_le_to_lt_times/2/
 377 qed.
 378
 379 theorem lt_plus_to_minus_r: ∀a,b,c. a + b < c → a < c - b.
 380 #a #b #c #H @le_plus_to_minus_r //
 381 qed.
 382
 383 lemma lt_plus_Sn_r: ∀a,x,n. a < a + x + (S n).
 384 /2 width=1/ qed.
 385
 386 theorem lt_S_S_to_lt: ∀n,m:nat. S n < S m → n < m.
 387 (* demo *)
 388 /2/ qed-.
 389
 390 (* not le, lt *)
 391
 392 theorem not_le_Sn_O: ∀ n:nat. S n ≰ 0.
 393 #n @nmk #Hlen0 @(lt_to_not_zero ?? Hlen0) qed.
 394
 395 theorem not_le_to_not_le_S_S: ∀ n,m:nat. n ≰ m → S n ≰ S m.
 396 /3/ qed.
 397
 398 theorem not_le_S_S_to_not_le: ∀ n,m:nat. S n ≰ S m → n ≰ m.
 399 /3/ qed.
 400
 401 theorem not_le_Sn_n: ∀n:nat. S n ≰ n.
 402 #n (elim n) /2/ qed.
 403
 404 theorem lt_to_not_le: ∀n,m. n < m → m ≰ n.
 405 #n #m #Hltnm (elim Hltnm) /3/ qed.
 406
 407 theorem not_le_to_lt: ∀n,m. n ≰ m → m < n.
 408 @nat_elim2 #n
 409  [#abs @False_ind /2/
 410  |/2/
 411  |#m #Hind #HnotleSS @le_S_S @Hind /2/
 412  ]
 413 qed.
 414
 415 (* not lt, le *)
 416
 417 theorem not_lt_to_le: ∀n,m:nat. n ≮ m → m ≤ n.
 418 #n #m #H @le_S_S_to_le @not_le_to_lt /2/ qed.
 419
 420 theorem le_to_not_lt: ∀n,m:nat. n ≤ m → m ≮ n.
 421 #n #m #H @lt_to_not_le /2/ (* /3/ *) qed.
 422
 423 (* Compound conclusion ******************************************************)
 424
 425 theorem decidable_eq_nat : ∀n,m:nat.decidable (n=m).
 426 @nat_elim2 #n [ (cases n) /2/ | /3/ | #m #Hind (cases Hind) /3/]
 427 qed.
 428
 429 theorem decidable_le: ∀n,m. decidable (n≤m).
 430 @nat_elim2 #n /2/ #m * /3/ qed.
 431
 432 theorem decidable_lt: ∀n,m. decidable (n < m).
 433 #n #m @decidable_le  qed.
 434
 435 theorem le_to_or_lt_eq: ∀n,m:nat. n ≤ m → n < m ∨ n = m.
 436 #n #m #lenm (elim lenm) /3/ qed.
 437
 438 theorem increasing_to_le2: ∀f:nat → nat. increasing f →
 439   ∀m:nat. f 0 ≤ m → ∃i. f i ≤ m ∧ m < f (S i).
 440 #f #incr #m #lem (elim lem)
 441   [@(ex_intro ? ? O) /2/
 442   |#n #len * #a * #len #ltnr (cases(le_to_or_lt_eq … ltnr)) #H
 443     [@(ex_intro ? ? a) % /2/
 444     |@(ex_intro ? ? (S a)) % //
 445     ]
 446   ]
 447 qed.
 448
 449 lemma le_inv_plus_l: ∀x,y,z. x + y ≤ z → x ≤ z - y ∧ y ≤ z.
 450 /3/ qed-.
 451
 452 lemma lt_inv_plus_l: ∀x,y,z. x + y < z → x < z ∧ y < z - x.
 453 /3/ qed-.
 454
 455 lemma lt_or_ge: ∀m,n. m < n ∨ n ≤ m.
 456 #m #n elim (decidable_lt m n) /2/ /3/
 457 qed-.
 458
 459 lemma le_or_ge: ∀m,n. m ≤ n ∨ n ≤ m.
 460 #m #n elim (decidable_le m n) /2/ /4/
 461 qed-.
 462
 463 (* More general conclusion **************************************************)
 464
 465 theorem nat_ind_plus: ∀R:predicate nat.
 466                       R 0 → (∀n. R n → R (n + 1)) → ∀n. R n.
 467 /3 by nat_ind/ qed-.
 468
 469 theorem lt_O_n_elim: ∀n:nat. 0 < n →
 470   ∀P:nat → Prop.(∀m:nat.P (S m)) → P n.
 471 #n (elim n) // #abs @False_ind /2/ @absurd
 472 qed.
 473
 474 theorem le_n_O_elim: ∀n:nat. n ≤ O → ∀P: nat →Prop. P O → P n.
 475 #n (cases n) // #a #abs @False_ind /2/ qed.
 476
 477 theorem le_n_Sm_elim : ∀n,m:nat.n ≤ S m →
 478 ∀P:Prop. (S n ≤ S m → P) → (n=S m → P) → P.
 479 #n #m #Hle #P (elim Hle) /3/ qed.
 480
 481 theorem nat_elim1 : ∀n:nat.∀P:nat → Prop.
 482 (∀m.(∀p. p < m → P p) → P m) → P n.
 483 #n #P #H
 484 cut (∀q:nat. q ≤ n → P q) /2/
 485 (elim n)
 486  [#q #HleO (* applica male *)
 487     @(le_n_O_elim ? HleO)
 488     @H #p #ltpO @False_ind /2/ (* 3 *)
 489  |#p #Hind #q #HleS
 490     @H #a #lta @Hind @le_S_S_to_le /2/
 491  ]
 492 qed.
 493
 494 (* More negated equalities **************************************************)
 495
 496 theorem lt_to_not_eq : ∀n,m:nat. n < m → n ≠ m.
 497 #n #m #H @not_to_not /2/ qed.
 498
 499 (* More equalities **********************************************************)
 500
 501 theorem le_n_O_to_eq : ∀n:nat. n ≤ 0 → 0=n.
 502 #n (cases n) // #a  #abs @False_ind /2/ qed.
 503
 504 theorem le_to_le_to_eq: ∀n,m. n ≤ m → m ≤ n → n = m.
 505 @nat_elim2 /4 by le_n_O_to_eq, monotonic_pred, eq_f, sym_eq/
 506 qed.
 507
 508 theorem increasing_to_injective: ∀f:nat → nat.
 509   increasing f → injective nat nat f.
 510 #f #incr #n #m cases(decidable_le n m)
 511   [#lenm cases(le_to_or_lt_eq … lenm) //
 512    #lenm #eqf @False_ind @(absurd … eqf) @lt_to_not_eq
 513    @increasing_to_monotonic //
 514   |#nlenm #eqf @False_ind @(absurd … eqf) @sym_not_eq
 515    @lt_to_not_eq @increasing_to_monotonic /2/
 516   ]
 517 qed.
 518
 519 theorem minus_Sn_m: ∀m,n:nat. m ≤ n → S n -m = S (n-m).
 520 (* qualcosa da capire qui
 521 #n #m #lenm nelim lenm napplyS refl_eq. *)
 522 @nat_elim2
 523   [//
 524   |#n #abs @False_ind /2/
 525   |#n #m #Hind #c applyS Hind /2/
 526   ]
 527 qed.
 528
 529 theorem plus_minus:
 530 ∀m,n,p:nat. m ≤ n → (n-m)+p = (n+p)-m.
 531 @nat_elim2
 532   [//
 533   |#n #p #abs @False_ind /2/
 534   |normalize/3/
 535   ]
 536 qed.
 537
 538 theorem minus_plus_m_m: ∀n,m:nat.n = (n+m)-m.
 539 /2/ qed.
 540
 541 theorem plus_minus_m_m: ∀n,m:nat.
 542   m ≤ n → n = (n-m)+m.
 543 #n #m #lemn @sym_eq /2/ qed.
 544
 545 theorem minus_to_plus :∀n,m,p:nat.
 546   m ≤ n → n-m = p → n = m+p.
 547 #n #m #p #lemn #eqp (applyS plus_minus_m_m) //
 548 qed.
 549
 550 theorem plus_to_minus :∀n,m,p:nat.n = m+p → n-m = p.
 551 #n #m #p #eqp @sym_eq (applyS (minus_plus_m_m p m))
 552 qed.
 553
 554 theorem minus_pred_pred : ∀n,m:nat. O < n → O < m →
 555 pred n - pred m = n - m.
 556 #n #m #posn #posm @(lt_O_n_elim n posn) @(lt_O_n_elim m posm) //.
 557 qed.
 558
 559 theorem plus_minus_commutative: ∀x,y,z. z ≤ y → x + (y - z) = x + y - z.
 560 /2 by plus_minus/ qed.
 561
 562 (* More atomic conclusion ***************************************************)
 563
 564 (* le *)
 565
 566 theorem le_n_fn: ∀f:nat → nat.
 567   increasing f → ∀n:nat. n ≤ f n.
 568 #f #incr #n (elim n) /2/
 569 qed-.
 570
 571 theorem monotonic_le_minus_l:
 572 ∀p,q,n:nat. q ≤ p → q-n ≤ p-n.
 573 @nat_elim2 #p #q
 574   [#lePO @(le_n_O_elim ? lePO) //
 575   |//
 576   |#Hind #n (cases n) // #a #leSS @Hind /2/
 577   ]
 578 qed.
 579
 580 theorem le_minus_to_plus: ∀n,m,p. n-m ≤ p → n≤ p+m.
 581 #n #m #p #lep @transitive_le
 582   [|@le_plus_minus_m_m | @monotonic_le_plus_l // ]
 583 qed.
 584
 585 theorem le_minus_to_plus_r: ∀a,b,c. c ≤ b → a ≤ b - c → a + c ≤ b.
 586 #a #b #c #Hlecb #H >(plus_minus_m_m … Hlecb) /2/
 587 qed.
 588
 589 theorem le_plus_to_minus: ∀n,m,p. n ≤ p+m → n-m ≤ p.
 590 #n #m #p #lep /2/ qed.
 591
 592 theorem monotonic_le_minus_r:
 593 ∀p,q,n:nat. q ≤ p → n-p ≤ n-q.
 594 #p #q #n #lepq @le_plus_to_minus
 595 @(transitive_le … (le_plus_minus_m_m ? q)) /2/
 596 qed.
 597
 598 theorem increasing_to_le: ∀f:nat → nat.
 599   increasing f → ∀m:nat.∃i.m ≤ f i.
 600 #f #incr #m (elim m) /2/#n * #a #lenfa
 601 @(ex_intro ?? (S a)) /2/
 602 qed.
 603
 604 (* thus is le_plus
 605 lemma le_plus_compatible: ∀x1,x2,y1,y2. x1 ≤ y1 → x2 ≤ y2 → x1 + x2 ≤ y1 + y2.
 606 #x1 #y1 #x2 #y2 #H1 #H2 /2/ @le_plus // /2/ /3 by le_minus_to_plus, monotonic_le_plus_r, transitive_le/ qed.
 607 *)
 608
 609 lemma minus_le: ∀x,y. x - y ≤ x.
 610 /2 width=1/ qed.
 611
 612 (* lt *)
 613
 614 theorem not_eq_to_le_to_lt: ∀n,m. n≠m → n≤m → n<m.
 615 #n #m #Hneq #Hle cases (le_to_or_lt_eq ?? Hle) //
 616 #Heq @not_le_to_lt /2/ qed-.
 617
 618 theorem lt_times_n_to_lt_l:
 619 ∀n,p,q:nat. p*n < q*n → p < q.
 620 #n #p #q #Hlt (elim (decidable_lt p q)) //
 621 #nltpq @False_ind @(absurd ? ? (lt_to_not_le ? ? Hlt))
 622 applyS monotonic_le_times_r /2/
 623 qed.
 624
 625 theorem lt_times_n_to_lt_r:
 626 ∀n,p,q:nat. n*p < n*q → p < q.
 627 /2/ qed-.
 628
 629 theorem lt_minus_to_plus: ∀a,b,c. a - b < c → a < c + b.
 630 #a #b #c #H @not_le_to_lt
 631 @(not_to_not … (lt_to_not_le …H)) /2/
 632 qed.
 633
 634 theorem lt_minus_to_plus_r: ∀a,b,c. a < b - c → a + c < b.
 635 #a #b #c #H @not_le_to_lt @(not_to_not … (le_plus_to_minus …))
 636 @lt_to_not_le //
 637 qed.
 638
 639 theorem lt_plus_to_minus: ∀n,m,p. m ≤ n → n < p+m → n-m < p.
 640 #n #m #p #lenm #H normalize <minus_Sn_m // @le_plus_to_minus //
 641 qed.
 642
 643 theorem monotonic_lt_minus_l: ∀p,q,n. n ≤ q → q < p → q - n < p - n.
 644 #p #q #n #H1 #H2
 645 @lt_plus_to_minus_r <plus_minus_m_m //
 646 qed.
 647
 648 (* Still more equalities ****************************************************)
 649
 650 theorem eq_minus_O: ∀n,m:nat.
 651   n ≤ m → n-m = O.
 652 #n #m #lenm @(le_n_O_elim (n-m)) /2/
 653 qed.
 654
 655 theorem distributive_times_minus: distributive ? times minus.
 656 #a #b #c
 657 (cases (decidable_lt b c)) #Hbc
 658  [> eq_minus_O [2:/2/] >eq_minus_O //
 659   @monotonic_le_times_r /2/
 660  |@sym_eq (applyS plus_to_minus) <distributive_times_plus
 661   @eq_f (applyS plus_minus_m_m) /2/
 662 qed.
 663
 664 theorem minus_plus: ∀n,m,p. n-m-p = n -(m+p).
 665 #n #m #p
 666 cases (decidable_le (m+p) n) #Hlt
 667   [@plus_to_minus @plus_to_minus <associative_plus
 668    @minus_to_plus //
 669   |cut (n ≤ m+p) [@(transitive_le … (le_n_Sn …)) @not_le_to_lt //]
 670    #H >eq_minus_O /2/ (* >eq_minus_O // *)
 671   ]
 672 qed.
 673
 674 theorem minus_minus: ∀n,m,p:nat. p ≤ m → m ≤ n →
 675   p+(n-m) = n-(m-p).
 676 #n #m #p #lepm #lemn
 677 @sym_eq @plus_to_minus <associative_plus <plus_minus_m_m //
 678 <commutative_plus <plus_minus_m_m //
 679 qed.
 680
 681 lemma minus_minus_comm: ∀a,b,c. a - b - c = a - c - b.
 682 /3 by monotonic_le_minus_l, le_to_le_to_eq/ qed.
 683
 684 lemma minus_le_minus_minus_comm: ∀b,c,a. c ≤ b → a - (b - c) = a + c - b.
 685 #b #c #a #H >(plus_minus_m_m b c) in ⊢ (? ? ?%); //
 686 qed.
 687
 688 lemma minus_minus_m_m: ∀m,n. n ≤ m → m - (m - n) = n.
 689 /2 width=1/ qed.
 690
 691 lemma discr_minus_x_xy: ∀x,y. x = x - y → x = 0 ∨ y = 0.
 692 * /2 width=1/ #x * /2 width=1/ #y normalize #H
 693 lapply (minus_le x y) <H -H #H
 694 elim (not_le_Sn_n x) #H0 elim (H0 ?) //
 695 qed-.
 696
 697 (* Stilll more atomic conclusion ********************************************)
 698
 699 (* le *)
 700
 701 lemma le_fwd_plus_plus_ge: ∀m1,m2. m2 ≤ m1 → ∀n1,n2. m1 + n1 ≤ m2 + n2 → n1 ≤ n2.
 702 #m1 #m2 #H #n1 #n2 >commutative_plus
 703 #H elim (le_inv_plus_l … H) -H >commutative_plus <minus_le_minus_minus_comm //
 704 #H #_ @(transitive_le … H) /2 width=1/
 705 qed-.
 706
 707 (*********************** boolean arithmetics ********************)
 708
 709 include "basics/bool.ma".
 710
 711 let rec eqb n m ≝
 712 match n with
 713   [ O ⇒ match m with [ O ⇒ true | S q ⇒ false]
 714   | S p ⇒ match m with [ O ⇒ false | S q ⇒ eqb p q]
 715   ].
 716
 717 theorem eqb_elim : ∀ n,m:nat.∀ P:bool → Prop.
 718 (n=m → (P true)) → (n ≠ m → (P false)) → (P (eqb n m)).
 719 @nat_elim2
 720   [#n (cases n) normalize /3/
 721   |normalize /3/
 722   |normalize /4/
 723   ]
 724 qed.
 725
 726 theorem eqb_n_n: ∀n. eqb n n = true.
 727 #n (elim n) normalize // qed.
 728
 729 theorem eqb_true_to_eq: ∀n,m:nat. eqb n m = true → n = m.
 730 #n #m @(eqb_elim n m) // #_ #abs @False_ind /2/ qed.
 731
 732 theorem eqb_false_to_not_eq: ∀n,m:nat. eqb n m = false → n ≠ m.
 733 #n #m @(eqb_elim n m) /2/ qed.
 734
 735 theorem eq_to_eqb_true: ∀n,m:nat.n = m → eqb n m = true.
 736 // qed.
 737
 738 theorem not_eq_to_eqb_false: ∀n,m:nat.
 739   n ≠  m → eqb n m = false.
 740 #n #m #noteq @eqb_elim// #Heq @False_ind /2/ qed.
 741
 742 let rec leb n m ≝
 743 match n with
 744     [ O ⇒ true
 745     | (S p) ⇒
 746         match m with
 747         [ O ⇒ false
 748               | (S q) ⇒ leb p q]].
 749
 750 theorem leb_elim: ∀n,m:nat. ∀P:bool → Prop.
 751 (n ≤ m → P true) → (n ≰ m → P false) → P (leb n m).
 752 @nat_elim2 normalize
 753   [/2/
 754   |/3/
 755   |#n #m #Hind #P #Pt #Pf @Hind
 756     [#lenm @Pt @le_S_S // |#nlenm @Pf /2/ ]
 757   ]
 758 qed.
 759
 760 theorem leb_true_to_le:∀n,m.leb n m = true → n ≤ m.
 761 #n #m @leb_elim // #_ #abs @False_ind /2/ qed.
 762
 763 theorem leb_false_to_not_le:∀n,m.
 764   leb n m = false → n ≰ m.
 765 #n #m @leb_elim // #_ #abs @False_ind /2/ qed.
 766
 767 theorem le_to_leb_true: ∀n,m. n ≤ m → leb n m = true.
 768 #n #m @leb_elim // #H #H1 @False_ind /2/ qed.
 769
 770 theorem not_le_to_leb_false: ∀n,m. n ≰ m → leb n m = false.
 771 #n #m @leb_elim // #H #H1 @False_ind /2/ qed.
 772
 773 theorem lt_to_leb_false: ∀n,m. m < n → leb n m = false.
 774 /3/ qed.
 775
 776 (* min e max *)
 777 definition min: nat →nat →nat ≝
 778 λn.λm. if leb n m then n else m.
 779
 780 definition max: nat →nat →nat ≝
 781 λn.λm. if leb n m then m else n.
 782
 783 lemma commutative_min: commutative ? min.
 784 #n #m normalize @leb_elim
 785   [@leb_elim normalize /2/
 786   |#notle >(le_to_leb_true …) // @(transitive_le ? (S m)) /2/
 787   ] qed.
 788
 789 lemma le_minr: ∀i,n,m. i ≤ min n m → i ≤ m.
 790 #i #n #m normalize @leb_elim normalize /2/ qed.
 791
 792 lemma le_minl: ∀i,n,m. i ≤ min n m → i ≤ n.
 793 /2/ qed-.
 794
 795 lemma to_min: ∀i,n,m. i ≤ n → i ≤ m → i ≤ min n m.
 796 #i #n #m #lein #leim normalize (cases (leb n m))
 797 normalize // qed.
 798
 799 lemma commutative_max: commutative ? max.
 800 #n #m normalize @leb_elim
 801   [@leb_elim normalize /2/
 802   |#notle >(le_to_leb_true …) // @(transitive_le ? (S m)) /2/
 803   ] qed.
 804
 805 lemma le_maxl: ∀i,n,m. max n m ≤ i → n ≤ i.
 806 #i #n #m normalize @leb_elim normalize /2/ qed.
 807
 808 lemma le_maxr: ∀i,n,m. max n m ≤ i → m ≤ i.
 809 /2/ qed-.
 810
 811 lemma to_max: ∀i,n,m. n ≤ i → m ≤ i → max n m ≤ i.
 812 #i #n #m #leni #lemi normalize (cases (leb n m))
 813 normalize // qed.