matita/matita/lib/basics/lists/list.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_______________________________________________________________ *)
  11
  12 include "basics/types.ma".
  13 include "arithmetics/nat.ma".
  14
  15 inductive list (A:Type[0]) : Type[0] :=
  16   | nil: list A
  17   | cons: A -> list A -> list A.
  18
  19 notation "hvbox(hd break :: tl)"
  20   right associative with precedence 47
  21   for @{'cons $hd $tl}.
  22
  23 notation "[ list0 x sep ; ]"
  24   non associative with precedence 90
  25   for ${fold right @'nil rec acc @{'cons $x $acc}}.
  26
  27 notation "hvbox(l1 break @ l2)"
  28   right associative with precedence 47
  29   for @{'append $l1 $l2 }.
  30
  31 interpretation "nil" 'nil = (nil ?).
  32 interpretation "cons" 'cons hd tl = (cons ? hd tl).
  33
  34 definition not_nil: ∀A:Type[0].list A → Prop ≝
  35  λA.λl.match l with [ nil ⇒ True | cons hd tl ⇒ False ].
  36
  37 theorem nil_cons:
  38   ∀A:Type[0].∀l:list A.∀a:A. a::l ≠ [].
  39   #A #l #a @nmk #Heq (change with (not_nil ? (a::l))) >Heq //
  40 qed.
  41
  42 (*
  43 let rec id_list A (l: list A) on l :=
  44   match l with
  45   [ nil => []
  46   | (cons hd tl) => hd :: id_list A tl ]. *)
  47
  48 let rec append A (l1: list A) l2 on l1 ≝
  49   match l1 with
  50   [ nil ⇒  l2
  51   | cons hd tl ⇒  hd :: append A tl l2 ].
  52
  53 definition hd ≝ λA.λl: list A.λd:A.
  54   match l with [ nil ⇒ d | cons a _ ⇒ a].
  55
  56 definition tail ≝  λA.λl: list A.
  57   match l with [ nil ⇒  [] | cons hd tl ⇒  tl].
  58
  59 interpretation "append" 'append l1 l2 = (append ? l1 l2).
  60
  61 theorem append_nil: ∀A.∀l:list A.l @ [] = l.
  62 #A #l (elim l) normalize // qed.
  63
  64 theorem associative_append:
  65  ∀A.associative (list A) (append A).
  66 #A #l1 #l2 #l3 (elim l1) normalize // qed.
  67
  68 (* deleterio per auto
  69 ntheorem cons_append_commute:
  70   ∀A:Type.∀l1,l2:list A.∀a:A.
  71     a :: (l1 @ l2) = (a :: l1) @ l2.
  72 //; nqed. *)
  73
  74 theorem append_cons:∀A.∀a:A.∀l,l1.l@(a::l1)=(l@[a])@l1.
  75 #A #a #l #l1 >associative_append // qed.
  76
  77 theorem nil_append_elim: ∀A.∀l1,l2: list A.∀P:?→?→Prop.
  78   l1@l2=[] → P (nil A) (nil A) → P l1 l2.
  79 #A #l1 #l2 #P (cases l1) normalize //
  80 #a #l3 #heq destruct
  81 qed.
  82
  83 theorem nil_to_nil:  ∀A.∀l1,l2:list A.
  84   l1@l2 = [] → l1 = [] ∧ l2 = [].
  85 #A #l1 #l2 #isnil @(nil_append_elim A l1 l2) /2/
  86 qed.
  87
  88 (**************************** iterators ******************************)
  89
  90 let rec map (A,B:Type[0]) (f: A → B) (l:list A) on l: list B ≝
  91  match l with [ nil ⇒ nil ? | cons x tl ⇒ f x :: (map A B f tl)].
  92
  93 lemma map_append : ∀A,B,f,l1,l2.
  94   (map A B f l1) @ (map A B f l2) = map A B f (l1@l2).
  95 #A #B #f #l1 elim l1
  96 [ #l2 @refl
  97 | #h #t #IH #l2 normalize //
  98 ] qed.
  99
 100 let rec foldr (A,B:Type[0]) (f:A → B → B) (b:B) (l:list A) on l :B ≝
 101  match l with [ nil ⇒ b | cons a l ⇒ f a (foldr A B f b l)].
 102
 103 definition filter ≝
 104   λT.λp:T → bool.
 105   foldr T (list T) (λx,l0.if p x then x::l0 else l0) (nil T).
 106
 107 (* compose f [a1;...;an] [b1;...;bm] =
 108   [f a1 b1; ... ;f an b1; ... ;f a1 bm; f an bm] *)
 109
 110 definition compose ≝ λA,B,C.λf:A→B→C.λl1,l2.
 111     foldr ?? (λi,acc.(map ?? (f i) l2)@acc) [ ] l1.
 112
 113 lemma filter_true : ∀A,l,a,p. p a = true →
 114   filter A p (a::l) = a :: filter A p l.
 115 #A #l #a #p #pa (elim l) normalize >pa normalize // qed.
 116
 117 lemma filter_false : ∀A,l,a,p. p a = false →
 118   filter A p (a::l) = filter A p l.
 119 #A #l #a #p #pa (elim l) normalize >pa normalize // qed.
 120
 121 theorem eq_map : ∀A,B,f,g,l. (∀x.f x = g x) → map A B f l = map A B g l.
 122 #A #B #f #g #l #eqfg (elim l) normalize // qed.
 123
 124 (**************************** length ******************************)
 125
 126 let rec length (A:Type[0]) (l:list A) on l ≝
 127   match l with
 128     [ nil ⇒ 0
 129     | cons a tl ⇒ S (length A tl)].
 130
 131 notation "|M|" non associative with precedence 60 for @{'norm $M}.
 132 interpretation "norm" 'norm l = (length ? l).
 133
 134 lemma length_append: ∀A.∀l1,l2:list A.
 135   |l1@l2| = |l1|+|l2|.
 136 #A #l1 elim l1 // normalize /2/
 137 qed.
 138
 139 (****************************** nth ********************************)
 140 let rec nth n (A:Type[0]) (l:list A) (d:A)  ≝
 141   match n with
 142     [O ⇒ hd A l d
 143     |S m ⇒ nth m A (tail A l) d].
 144
 145 lemma nth_nil: ∀A,a,i. nth i A ([]) a = a.
 146 #A #a #i elim i normalize //
 147 qed.
 148
 149 (****************************** nth_opt ********************************)
 150 let rec nth_opt (A:Type[0]) (n:nat) (l:list A) on l : option A ≝
 151 match l with
 152 [ nil ⇒ None ?
 153 | cons h t ⇒ match n with [ O ⇒ Some ? h | S m ⇒ nth_opt A m t ]
 154 ].
 155
 156 (**************************** All *******************************)
 157
 158 let rec All (A:Type[0]) (P:A → Prop) (l:list A) on l : Prop ≝
 159 match l with
 160 [ nil ⇒ True
 161 | cons h t ⇒ P h ∧ All A P t
 162 ].
 163
 164 lemma All_mp : ∀A,P,Q. (∀a.P a → Q a) → ∀l. All A P l → All A Q l.
 165 #A #P #Q #H #l elim l normalize //
 166 #h #t #IH * /3/
 167 qed.
 168
 169 lemma All_nth : ∀A,P,n,l.
 170   All A P l →
 171   ∀a.
 172   nth_opt A n l = Some A a →
 173   P a.
 174 #A #P #n elim n
 175 [ * [ #_ #a #E whd in E:(??%?); destruct
 176     | #hd #tl * #H #_ #a #E whd in E:(??%?); destruct @H
 177     ]
 178 | #m #IH *
 179   [ #_ #a #E whd in E:(??%?); destruct
 180   | #hd #tl * #_ whd in ⊢ (? → ∀_.??%? → ?); @IH
 181   ]
 182 ] qed.
 183
 184 (**************************** Exists *******************************)
 185
 186 let rec Exists (A:Type[0]) (P:A → Prop) (l:list A) on l : Prop ≝
 187 match l with
 188 [ nil ⇒ False
 189 | cons h t ⇒ (P h) ∨ (Exists A P t)
 190 ].
 191
 192 lemma Exists_append : ∀A,P,l1,l2.
 193   Exists A P (l1 @ l2) → Exists A P l1 ∨ Exists A P l2.
 194 #A #P #l1 elim l1
 195 [ normalize /2/
 196 | #h #t #IH #l2 *
 197   [ #H /3/
 198   | #H cases (IH l2 H) /3/
 199   ]
 200 ] qed.
 201
 202 lemma Exists_append_l : ∀A,P,l1,l2.
 203   Exists A P l1 → Exists A P (l1@l2).
 204 #A #P #l1 #l2 elim l1
 205 [ *
 206 | #h #t #IH *
 207   [ #H %1 @H
 208   | #H %2 @IH @H
 209   ]
 210 ] qed.
 211
 212 lemma Exists_append_r : ∀A,P,l1,l2.
 213   Exists A P l2 → Exists A P (l1@l2).
 214 #A #P #l1 #l2 elim l1
 215 [ #H @H
 216 | #h #t #IH #H %2 @IH @H
 217 ] qed.
 218
 219 lemma Exists_add : ∀A,P,l1,x,l2. Exists A P (l1@l2) → Exists A P (l1@x::l2).
 220 #A #P #l1 #x #l2 elim l1
 221 [ normalize #H %2 @H
 222 | #h #t #IH normalize * [ #H %1 @H | #H %2 @IH @H ]
 223 qed.
 224
 225 lemma Exists_mid : ∀A,P,l1,x,l2. P x → Exists A P (l1@x::l2).
 226 #A #P #l1 #x #l2 #H elim l1
 227 [ %1 @H
 228 | #h #t #IH %2 @IH
 229 ] qed.
 230
 231 lemma Exists_map : ∀A,B,P,Q,f,l.
 232 Exists A P l →
 233 (∀a.P a → Q (f a)) →
 234 Exists B Q (map A B f l).
 235 #A #B #P #Q #f #l elim l //
 236 #h #t #IH * [ #H #F %1 @F @H | #H #F %2 @IH [ @H | @F ] ] qed.
 237
 238 lemma Exists_All : ∀A,P,Q,l.
 239   Exists A P l →
 240   All A Q l →
 241   ∃x. P x ∧ Q x.
 242 #A #P #Q #l elim l [ * | #hd #tl #IH * [ #H1 * #H2 #_ %{hd} /2/ | #H1 * #_ #H2 @IH // ]
 243 qed.
 244
 245 (**************************** fold *******************************)
 246
 247 let rec fold (A,B:Type[0]) (op:B → B → B) (b:B) (p:A→bool) (f:A→B) (l:list A) on l :B ≝
 248  match l with
 249   [ nil ⇒ b
 250   | cons a l ⇒
 251      if p a then op (f a) (fold A B op b p f l)
 252      else fold A B op b p f l].
 253
 254 notation "\fold  [ op , nil ]_{ ident i ∈ l | p} f"
 255   with precedence 80
 256 for @{'fold $op $nil (λ${ident i}. $p) (λ${ident i}. $f) $l}.
 257
 258 notation "\fold [ op , nil ]_{ident i ∈ l } f"
 259   with precedence 80
 260 for @{'fold $op $nil (λ${ident i}.true) (λ${ident i}. $f) $l}.
 261
 262 interpretation "\fold" 'fold op nil p f l = (fold ? ? op nil p f l).
 263
 264 theorem fold_true:
 265 ∀A,B.∀a:A.∀l.∀p.∀op:B→B→B.∀nil.∀f:A→B. p a = true →
 266   \fold[op,nil]_{i ∈ a::l| p i} (f i) =
 267     op (f a) \fold[op,nil]_{i ∈ l| p i} (f i).
 268 #A #B #a #l #p #op #nil #f #pa normalize >pa // qed.
 269
 270 theorem fold_false:
 271 ∀A,B.∀a:A.∀l.∀p.∀op:B→B→B.∀nil.∀f.
 272 p a = false → \fold[op,nil]_{i ∈ a::l| p i} (f i) =
 273   \fold[op,nil]_{i ∈ l| p i} (f i).
 274 #A #B #a #l #p #op #nil #f #pa normalize >pa // qed.
 275
 276 theorem fold_filter:
 277 ∀A,B.∀a:A.∀l.∀p.∀op:B→B→B.∀nil.∀f:A →B.
 278   \fold[op,nil]_{i ∈ l| p i} (f i) =
 279     \fold[op,nil]_{i ∈ (filter A p l)} (f i).
 280 #A #B #a #l #p #op #nil #f elim l //
 281 #a #tl #Hind cases(true_or_false (p a)) #pa
 282   [ >filter_true // > fold_true // >fold_true //
 283   | >filter_false // >fold_false // ]
 284 qed.
 285
 286 record Aop (A:Type[0]) (nil:A) : Type[0] ≝
 287   {op :2> A → A → A;
 288    nill:∀a. op nil a = a;
 289    nilr:∀a. op a nil = a;
 290    assoc: ∀a,b,c.op a (op b c) = op (op a b) c
 291   }.
 292
 293 theorem fold_sum: ∀A,B. ∀I,J:list A.∀nil.∀op:Aop B nil.∀f.
 294   op (\fold[op,nil]_{i∈I} (f i)) (\fold[op,nil]_{i∈J} (f i)) =
 295     \fold[op,nil]_{i∈(I@J)} (f i).
 296 #A #B #I #J #nil #op #f (elim I) normalize
 297   [>nill //|#a #tl #Hind <assoc //]
 298 qed.
 299
 300 (********************** lhd and ltl ******************************)
 301
 302 let rec lhd (A:Type[0]) (l:list A) n on n ≝ match n with
 303    [ O   ⇒ nil …
 304    | S n ⇒ match l with [ nil ⇒ nil … | cons a l ⇒ a :: lhd A l n ]
 305    ].
 306
 307 let rec ltl (A:Type[0]) (l:list A) n on n ≝ match n with
 308    [ O   ⇒ l
 309    | S n ⇒ ltl A (tail … l) n
 310    ].
 311
 312 lemma lhd_nil: ∀A,n. lhd A ([]) n = [].
 313 #A #n elim n //
 314 qed.
 315
 316 lemma ltl_nil: ∀A,n. ltl A ([]) n = [].
 317 #A #n elim n normalize //
 318 qed.
 319
 320 lemma lhd_cons_ltl: ∀A,n,l. lhd A l n @ ltl A l n = l.
 321 #A #n elim n -n //
 322 #n #IHn #l elim l normalize //
 323 qed.
 324
 325 lemma length_ltl: ∀A,n,l. |ltl A l n| = |l| - n.
 326 #A #n elim n -n /2/
 327 #n #IHn *; normalize /2/
 328 qed.
 329
 330 (********************** find ******************************)
 331 let rec find (A,B:Type[0]) (f:A → option B) (l:list A) on l : option B ≝
 332 match l with
 333 [ nil ⇒ None B
 334 | cons h t ⇒
 335     match f h with
 336     [ None ⇒ find A B f t
 337     | Some b ⇒ Some B b
 338     ]
 339 ].
 340
 341 (********************** position_of ******************************)
 342 let rec position_of_aux (A:Type[0]) (found: A → bool) (l:list A) (acc:nat) on l : option nat ≝
 343 match l with
 344 [ nil ⇒ None ?
 345 | cons h t ⇒
 346    match found h with [true ⇒ Some … acc | false ⇒ position_of_aux … found t (S acc)]].
 347
 348 definition position_of: ∀A:Type[0]. (A → bool) → list A → option nat ≝
 349  λA,found,l. position_of_aux A found l 0.
 350
 351
 352 (********************** make_list ******************************)
 353 let rec make_list (A:Type[0]) (a:A) (n:nat) on n : list A ≝
 354 match n with
 355 [ O ⇒ [ ]
 356 | S m ⇒ a::(make_list A a m)
 357 ].