matita/matita/lib/basics/lists/list.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_______________________________________________________________ *)
  11
  12 include "basics/types.ma".
  13 include "arithmetics/nat.ma".
  14
  15 inductive list (A:Type[0]) : Type[0] :=
  16   | nil: list A
  17   | cons: A -> list A -> list A.
  18
  19 notation "hvbox(hd break :: tl)"
  20   right associative with precedence 47
  21   for @{'cons $hd $tl}.
  22
  23 notation "[ list0 x sep ; ]"
  24   non associative with precedence 90
  25   for ${fold right @'nil rec acc @{'cons $x $acc}}.
  26
  27 notation "hvbox(l1 break @ l2)"
  28   right associative with precedence 47
  29   for @{'append $l1 $l2 }.
  30
  31 interpretation "nil" 'nil = (nil ?).
  32 interpretation "cons" 'cons hd tl = (cons ? hd tl).
  33
  34 definition is_nil: ∀A:Type[0].list A → Prop ≝
  35  λA.λl.match l with [ nil ⇒ True | cons hd tl ⇒ False ].
  36
  37 theorem nil_cons:
  38   ∀A:Type[0].∀l:list A.∀a:A. a::l ≠ [].
  39   #A #l #a @nmk #Heq (change with (is_nil ? (a::l))) >Heq //
  40 qed.
  41
  42 (*
  43 let rec id_list A (l: list A) on l :=
  44   match l with
  45   [ nil => []
  46   | (cons hd tl) => hd :: id_list A tl ]. *)
  47
  48 let rec append A (l1: list A) l2 on l1 ≝
  49   match l1 with
  50   [ nil ⇒  l2
  51   | cons hd tl ⇒  hd :: append A tl l2 ].
  52
  53 definition hd ≝ λA.λl: list A.λd:A.
  54   match l with [ nil ⇒ d | cons a _ ⇒ a].
  55
  56 definition tail ≝  λA.λl: list A.
  57   match l with [ nil ⇒  [] | cons hd tl ⇒  tl].
  58
  59 definition option_hd ≝
  60   λA.λl:list A. match l with
  61   [ nil ⇒ None ?
  62   | cons a _ ⇒ Some ? a ].
  63
  64 interpretation "append" 'append l1 l2 = (append ? l1 l2).
  65
  66 theorem append_nil: ∀A.∀l:list A.l @ [] = l.
  67 #A #l (elim l) normalize // qed.
  68
  69 theorem associative_append:
  70  ∀A.associative (list A) (append A).
  71 #A #l1 #l2 #l3 (elim l1) normalize // qed.
  72
  73 theorem append_cons:∀A.∀a:A.∀l,l1.l@(a::l1)=(l@[a])@l1.
  74 #A #a #l #l1 >associative_append // qed.
  75
  76 theorem nil_append_elim: ∀A.∀l1,l2: list A.∀P:?→?→Prop.
  77   l1@l2=[] → P (nil A) (nil A) → P l1 l2.
  78 #A #l1 #l2 #P (cases l1) normalize //
  79 #a #l3 #heq destruct
  80 qed.
  81
  82 theorem nil_to_nil:  ∀A.∀l1,l2:list A.
  83   l1@l2 = [] → l1 = [] ∧ l2 = [].
  84 #A #l1 #l2 #isnil @(nil_append_elim A l1 l2) /2/
  85 qed.
  86
  87 lemma cons_injective_l : ∀A.∀a1,a2:A.∀l1,l2.a1::l1 = a2::l2 → a1 = a2.
  88 #A #a1 #a2 #l1 #l2 #Heq destruct //
  89 qed.
  90
  91 lemma cons_injective_r : ∀A.∀a1,a2:A.∀l1,l2.a1::l1 = a2::l2 → l1 = l2.
  92 #A #a1 #a2 #l1 #l2 #Heq destruct //
  93 qed.
  94
  95 (**************************** iterators ******************************)
  96
  97 let rec map (A,B:Type[0]) (f: A → B) (l:list A) on l: list B ≝
  98  match l with [ nil ⇒ nil ? | cons x tl ⇒ f x :: (map A B f tl)].
  99
 100 lemma map_append : ∀A,B,f,l1,l2.
 101   (map A B f l1) @ (map A B f l2) = map A B f (l1@l2).
 102 #A #B #f #l1 elim l1
 103 [ #l2 @refl
 104 | #h #t #IH #l2 normalize //
 105 ] qed.
 106
 107 let rec foldr (A,B:Type[0]) (f:A → B → B) (b:B) (l:list A) on l :B ≝
 108  match l with [ nil ⇒ b | cons a l ⇒ f a (foldr A B f b l)].
 109
 110 definition filter ≝
 111   λT.λp:T → bool.
 112   foldr T (list T) (λx,l0.if p x then x::l0 else l0) (nil T).
 113
 114 (* compose f [a1;...;an] [b1;...;bm] =
 115   [f a1 b1; ... ;f an b1; ... ;f a1 bm; f an bm] *)
 116
 117 definition compose ≝ λA,B,C.λf:A→B→C.λl1,l2.
 118     foldr ?? (λi,acc.(map ?? (f i) l2)@acc) [ ] l1.
 119
 120 lemma filter_true : ∀A,l,a,p. p a = true →
 121   filter A p (a::l) = a :: filter A p l.
 122 #A #l #a #p #pa (elim l) normalize >pa normalize // qed.
 123
 124 lemma filter_false : ∀A,l,a,p. p a = false →
 125   filter A p (a::l) = filter A p l.
 126 #A #l #a #p #pa (elim l) normalize >pa normalize // qed.
 127
 128 theorem eq_map : ∀A,B,f,g,l. (∀x.f x = g x) → map A B f l = map A B g l.
 129 #A #B #f #g #l #eqfg (elim l) normalize // qed.
 130
 131 (**************************** reverse *****************************)
 132 let rec rev_append S (l1,l2:list S) on l1 ≝
 133   match l1 with
 134   [ nil ⇒ l2
 135   | cons a tl ⇒ rev_append S tl (a::l2)
 136   ]
 137 .
 138
 139 definition reverse ≝λS.λl.rev_append S l [].
 140
 141 lemma reverse_single : ∀S,a. reverse S [a] = [a].
 142 // qed.
 143
 144 lemma rev_append_def : ∀S,l1,l2.
 145   rev_append S l1 l2 = (reverse S l1) @ l2 .
 146 #S #l1 elim l1 normalize //
 147 qed.
 148
 149 lemma reverse_cons : ∀S,a,l. reverse S (a::l) = (reverse S l)@[a].
 150 #S #a #l whd in ⊢ (??%?); //
 151 qed.
 152
 153 lemma reverse_append: ∀S,l1,l2.
 154   reverse S (l1 @ l2) = (reverse S l2)@(reverse S l1).
 155 #S #l1 elim l1 [normalize // | #a #tl #Hind #l2 >reverse_cons
 156 >reverse_cons // qed.
 157
 158 lemma reverse_reverse : ∀S,l. reverse S (reverse S l) = l.
 159 #S #l elim l // #a #tl #Hind >reverse_cons >reverse_append
 160 normalize // qed.
 161
 162 (* an elimination principle for lists working on the tail;
 163 useful for strings *)
 164 lemma list_elim_left: ∀S.∀P:list S → Prop. P (nil S) →
 165 (∀a.∀tl.P tl → P (tl@[a])) → ∀l. P l.
 166 #S #P #Pnil #Pstep #l <(reverse_reverse … l)
 167 generalize in match (reverse S l); #l elim l //
 168 #a #tl #H >reverse_cons @Pstep //
 169 qed.
 170
 171 (**************************** length ******************************)
 172
 173 let rec length (A:Type[0]) (l:list A) on l ≝
 174   match l with
 175     [ nil ⇒ 0
 176     | cons a tl ⇒ S (length A tl)].
 177
 178 interpretation "list length" 'card l = (length ? l).
 179
 180 lemma length_tail: ∀A,l. length ? (tail A l) = pred (length ? l).
 181 #A #l elim l //
 182 qed.
 183
 184 lemma length_append: ∀A.∀l1,l2:list A.
 185   |l1@l2| = |l1|+|l2|.
 186 #A #l1 elim l1 // normalize /2/
 187 qed.
 188
 189 lemma length_map: ∀A,B,l.∀f:A→B. length ? (map ?? f l) = length ? l.
 190 #A #B #l #f elim l // #a #tl #Hind normalize //
 191 qed.
 192
 193 lemma length_reverse: ∀A.∀l:list A.
 194   |reverse A l| = |l|.
 195 #A #l elim l // #a #l0 #IH >reverse_cons >length_append normalize //
 196 qed.
 197
 198 lemma lenght_to_nil: ∀A.∀l:list A.
 199   |l| = 0 → l = [ ].
 200 #A * // #a #tl normalize #H destruct
 201 qed.
 202
 203 (****************** traversing two lists in parallel *****************)
 204 lemma list_ind2 :
 205   ∀T1,T2:Type[0].∀l1:list T1.∀l2:list T2.∀P:list T1 → list T2 → Prop.
 206   length ? l1 = length ? l2 →
 207   (P [] []) →
 208   (∀tl1,tl2,hd1,hd2. P tl1 tl2 → P (hd1::tl1) (hd2::tl2)) →
 209   P l1 l2.
 210 #T1 #T2 #l1 #l2 #P #Hl #Pnil #Pcons
 211 generalize in match Hl; generalize in match l2;
 212 elim l1
 213 [#l2 cases l2 // normalize #t2 #tl2 #H destruct
 214 |#t1 #tl1 #IH #l2 cases l2
 215    [normalize #H destruct
 216    |#t2 #tl2 #H @Pcons @IH normalize in H; destruct // ]
 217 ]
 218 qed.
 219
 220 lemma list_cases2 :
 221   ∀T1,T2:Type[0].∀l1:list T1.∀l2:list T2.∀P:Prop.
 222   length ? l1 = length ? l2 →
 223   (l1 = [] → l2 = [] → P) →
 224   (∀hd1,hd2,tl1,tl2.l1 = hd1::tl1 → l2 = hd2::tl2 → P) → P.
 225 #T1 #T2 #l1 #l2 #P #Hl @(list_ind2 … Hl)
 226 [ #Pnil #Pcons @Pnil //
 227 | #tl1 #tl2 #hd1 #hd2 #IH1 #IH2 #Hp @Hp // ]
 228 qed.
 229
 230 (*********************** properties of append ***********************)
 231 lemma append_l1_injective :
 232   ∀A.∀l1,l2,l3,l4:list A. |l1| = |l2| → l1@l3 = l2@l4 → l1 = l2.
 233 #a #l1 #l2 #l3 #l4 #Hlen @(list_ind2 … Hlen) //
 234 #tl1 #tl2 #hd1 #hd2 #IH normalize #Heq destruct @eq_f /2/
 235 qed.
 236
 237 lemma append_l2_injective :
 238   ∀A.∀l1,l2,l3,l4:list A. |l1| = |l2| → l1@l3 = l2@l4 → l3 = l4.
 239 #a #l1 #l2 #l3 #l4 #Hlen @(list_ind2 … Hlen) normalize //
 240 #tl1 #tl2 #hd1 #hd2 #IH normalize #Heq destruct /2/
 241 qed.
 242
 243 lemma append_l1_injective_r :
 244   ∀A.∀l1,l2,l3,l4:list A. |l3| = |l4| → l1@l3 = l2@l4 → l1 = l2.
 245 #a #l1 #l2 #l3 #l4 #Hlen #Heq lapply (eq_f … (reverse ?) … Heq)
 246 >reverse_append >reverse_append #Heq1
 247 lapply (append_l2_injective … Heq1) [ // ] #Heq2
 248 lapply (eq_f … (reverse ?) … Heq2) //
 249 qed.
 250
 251 lemma append_l2_injective_r :
 252   ∀A.∀l1,l2,l3,l4:list A. |l3| = |l4| → l1@l3 = l2@l4 → l3 = l4.
 253 #a #l1 #l2 #l3 #l4 #Hlen #Heq lapply (eq_f … (reverse ?) … Heq)
 254 >reverse_append >reverse_append #Heq1
 255 lapply (append_l1_injective … Heq1) [ // ] #Heq2
 256 lapply (eq_f … (reverse ?) … Heq2) //
 257 qed.
 258
 259 lemma length_rev_append: ∀A.∀l,acc:list A.
 260   |rev_append ? l acc| = |l|+|acc|.
 261 #A #l elim l // #a #tl #Hind normalize
 262 #acc >Hind normalize //
 263 qed.
 264
 265 (****************************** mem ********************************)
 266 let rec mem A (a:A) (l:list A) on l ≝
 267   match l with
 268   [ nil ⇒ False
 269   | cons hd tl ⇒ a=hd ∨ mem A a tl
 270   ].
 271
 272 lemma mem_map: ∀A,B.∀f:A→B.∀l,b.
 273   mem ? b (map … f l) → ∃a. mem ? a l ∧ f a = b.
 274 #A #B #f #l elim l
 275   [#b normalize @False_ind
 276   |#a #tl #Hind #b normalize *
 277     [#eqb @(ex_intro … a) /3/
 278     |#memb cases (Hind … memb) #a * #mema #eqb
 279      @(ex_intro … a) /3/
 280     ]
 281   ]
 282 qed.
 283
 284 lemma mem_map_forward: ∀A,B.∀f:A→B.∀a,l.
 285   mem A a l → mem B (f a) (map ?? f l).
 286  #A #B #f #a #l elim l
 287   [normalize @False_ind
 288   |#b #tl #Hind *
 289     [#eqab <eqab normalize %1 % |#memtl normalize %2 @Hind @memtl]
 290   ]
 291 qed.
 292
 293 (***************************** split *******************************)
 294 let rec split_rev A (l:list A) acc n on n ≝
 295   match n with
 296   [O ⇒ 〈acc,l〉
 297   |S m ⇒ match l with
 298     [nil ⇒ 〈acc,[]〉
 299     |cons a tl ⇒ split_rev A tl (a::acc) m
 300     ]
 301   ].
 302
 303 definition split ≝ λA,l,n.
 304   let 〈l1,l2〉 ≝ split_rev A l [] n in 〈reverse ? l1,l2〉.
 305
 306 lemma split_rev_len: ∀A,n,l,acc. n ≤ |l| →
 307   |\fst (split_rev A l acc n)| = n+|acc|.
 308 #A #n elim n // #m #Hind *
 309   [normalize #acc #Hfalse @False_ind /2/
 310   |#a #tl #acc #Hlen normalize >Hind
 311     [normalize // |@le_S_S_to_le //]
 312   ]
 313 qed.
 314
 315 lemma split_len: ∀A,n,l. n ≤ |l| →
 316   |\fst (split A l n)| = n.
 317 #A #n #l #Hlen normalize >(eq_pair_fst_snd ?? (split_rev …))
 318 normalize >length_reverse  >(split_rev_len … [ ] Hlen) normalize //
 319 qed.
 320
 321 lemma split_rev_eq: ∀A,n,l,acc. n ≤ |l| →
 322   reverse ? acc@ l =
 323     reverse ? (\fst (split_rev A l acc n))@(\snd (split_rev A l acc n)).
 324  #A #n elim n //
 325  #m #Hind *
 326    [#acc whd in ⊢ ((??%)→?); #False_ind /2/
 327    |#a #tl #acc #Hlen >append_cons <reverse_single <reverse_append
 328     @(Hind tl) @le_S_S_to_le @Hlen
 329    ]
 330 qed.
 331
 332 lemma split_eq: ∀A,n,l. n ≤ |l| →
 333   l = (\fst (split A l n))@(\snd (split A l n)).
 334 #A #n #l #Hlen change with ((reverse ? [ ])@l) in ⊢ (??%?);
 335 >(split_rev_eq … Hlen) normalize
 336 >(eq_pair_fst_snd ?? (split_rev A l [] n)) %
 337 qed.
 338
 339 lemma split_exists: ∀A,n.∀l:list A. n ≤ |l| →
 340   ∃l1,l2. l = l1@l2 ∧ |l1| = n.
 341 #A #n #l #Hlen @(ex_intro … (\fst (split A l n)))
 342 @(ex_intro … (\snd (split A l n))) % /2/
 343 qed.
 344
 345 (****************************** flatten ******************************)
 346 definition flatten ≝ λA.foldr (list A) (list A) (append A) [].
 347
 348 lemma flatten_to_mem: ∀A,n,l,l1,l2.∀a:list A. 0 < n →
 349   (∀x. mem ? x l → |x| = n) → |a| = n → flatten ? l = l1@a@l2  →
 350     (∃q.|l1| = n*q)  → mem ? a l.
 351 #A #n #l elim l
 352   [normalize #l1 #l2 #a #posn #Hlen #Ha #Hnil @False_ind
 353    cut (|a|=0) [@sym_eq @le_n_O_to_eq
 354    @(transitive_le ? (|nil A|)) // >Hnil >length_append >length_append //] /2/
 355   |#hd #tl #Hind #l1 #l2 #a #posn #Hlen #Ha
 356    whd in match (flatten ??); #Hflat * #q cases q
 357     [<times_n_O #Hl1
 358      cut (a = hd) [>(lenght_to_nil… Hl1) in Hflat;
 359      whd in ⊢ ((???%)→?); #Hflat @sym_eq @(append_l1_injective … Hflat)
 360      >Ha >Hlen // %1 //
 361      ] /2/
 362     |#q1 #Hl1 lapply (split_exists … n l1 ?) //
 363      * #l11 * #l12 * #Heql1 #Hlenl11 %2
 364      @(Hind l12 l2 … posn ? Ha)
 365       [#x #memx @Hlen %2 //
 366       |@(append_l2_injective ? hd l11)
 367         [>Hlenl11 @Hlen %1 %
 368         |>Hflat >Heql1 >associative_append %
 369         ]
 370       |@(ex_intro …q1) @(injective_plus_r n)
 371        <Hlenl11 in ⊢ (??%?); <length_append <Heql1 >Hl1 //
 372       ]
 373     ]
 374   ]
 375 qed.
 376
 377 (****************************** nth ********************************)
 378 let rec nth n (A:Type[0]) (l:list A) (d:A)  ≝
 379   match n with
 380     [O ⇒ hd A l d
 381     |S m ⇒ nth m A (tail A l) d].
 382
 383 lemma nth_nil: ∀A,a,i. nth i A ([]) a = a.
 384 #A #a #i elim i normalize //
 385 qed.
 386
 387 (****************************** nth_opt ********************************)
 388 let rec nth_opt (A:Type[0]) (n:nat) (l:list A) on l : option A ≝
 389 match l with
 390 [ nil ⇒ None ?
 391 | cons h t ⇒ match n with [ O ⇒ Some ? h | S m ⇒ nth_opt A m t ]
 392 ].
 393
 394 (**************************** All *******************************)
 395
 396 let rec All (A:Type[0]) (P:A → Prop) (l:list A) on l : Prop ≝
 397 match l with
 398 [ nil ⇒ True
 399 | cons h t ⇒ P h ∧ All A P t
 400 ].
 401
 402 lemma All_mp : ∀A,P,Q. (∀a.P a → Q a) → ∀l. All A P l → All A Q l.
 403 #A #P #Q #H #l elim l normalize //
 404 #h #t #IH * /3/
 405 qed.
 406
 407 lemma All_nth : ∀A,P,n,l.
 408   All A P l →
 409   ∀a.
 410   nth_opt A n l = Some A a →
 411   P a.
 412 #A #P #n elim n
 413 [ * [ #_ #a #E whd in E:(??%?); destruct
 414     | #hd #tl * #H #_ #a #E whd in E:(??%?); destruct @H
 415     ]
 416 | #m #IH *
 417   [ #_ #a #E whd in E:(??%?); destruct
 418   | #hd #tl * #_ whd in ⊢ (? → ∀_.??%? → ?); @IH
 419   ]
 420 ] qed.
 421
 422 (**************************** Exists *******************************)
 423
 424 let rec Exists (A:Type[0]) (P:A → Prop) (l:list A) on l : Prop ≝
 425 match l with
 426 [ nil ⇒ False
 427 | cons h t ⇒ (P h) ∨ (Exists A P t)
 428 ].
 429
 430 lemma Exists_append : ∀A,P,l1,l2.
 431   Exists A P (l1 @ l2) → Exists A P l1 ∨ Exists A P l2.
 432 #A #P #l1 elim l1
 433 [ normalize /2/
 434 | #h #t #IH #l2 *
 435   [ #H /3/
 436   | #H cases (IH l2 H) /3/
 437   ]
 438 ] qed.
 439
 440 lemma Exists_append_l : ∀A,P,l1,l2.
 441   Exists A P l1 → Exists A P (l1@l2).
 442 #A #P #l1 #l2 elim l1
 443 [ *
 444 | #h #t #IH *
 445   [ #H %1 @H
 446   | #H %2 @IH @H
 447   ]
 448 ] qed.
 449
 450 lemma Exists_append_r : ∀A,P,l1,l2.
 451   Exists A P l2 → Exists A P (l1@l2).
 452 #A #P #l1 #l2 elim l1
 453 [ #H @H
 454 | #h #t #IH #H %2 @IH @H
 455 ] qed.
 456
 457 lemma Exists_add : ∀A,P,l1,x,l2. Exists A P (l1@l2) → Exists A P (l1@x::l2).
 458 #A #P #l1 #x #l2 elim l1
 459 [ normalize #H %2 @H
 460 | #h #t #IH normalize * [ #H %1 @H | #H %2 @IH @H ]
 461 qed.
 462
 463 lemma Exists_mid : ∀A,P,l1,x,l2. P x → Exists A P (l1@x::l2).
 464 #A #P #l1 #x #l2 #H elim l1
 465 [ %1 @H
 466 | #h #t #IH %2 @IH
 467 ] qed.
 468
 469 lemma Exists_map : ∀A,B,P,Q,f,l.
 470 Exists A P l →
 471 (∀a.P a → Q (f a)) →
 472 Exists B Q (map A B f l).
 473 #A #B #P #Q #f #l elim l //
 474 #h #t #IH * [ #H #F %1 @F @H | #H #F %2 @IH [ @H | @F ] ] qed.
 475
 476 lemma Exists_All : ∀A,P,Q,l.
 477   Exists A P l →
 478   All A Q l →
 479   ∃x. P x ∧ Q x.
 480 #A #P #Q #l elim l [ * | #hd #tl #IH * [ #H1 * #H2 #_ %{hd} /2/ | #H1 * #_ #H2 @IH // ]
 481 qed.
 482
 483 (**************************** fold *******************************)
 484
 485 let rec fold (A,B:Type[0]) (op:B → B → B) (b:B) (p:A→bool) (f:A→B) (l:list A) on l :B ≝
 486  match l with
 487   [ nil ⇒ b
 488   | cons a l ⇒
 489      if p a then op (f a) (fold A B op b p f l)
 490      else fold A B op b p f l].
 491
 492 notation "\fold  [ op , nil ]_{ ident i ∈ l | p} f"
 493   with precedence 80
 494 for @{'fold $op $nil (λ${ident i}. $p) (λ${ident i}. $f) $l}.
 495
 496 notation "\fold [ op , nil ]_{ident i ∈ l } f"
 497   with precedence 80
 498 for @{'fold $op $nil (λ${ident i}.true) (λ${ident i}. $f) $l}.
 499
 500 interpretation "\fold" 'fold op nil p f l = (fold ? ? op nil p f l).
 501
 502 theorem fold_true:
 503 ∀A,B.∀a:A.∀l.∀p.∀op:B→B→B.∀nil.∀f:A→B. p a = true →
 504   \fold[op,nil]_{i ∈ a::l| p i} (f i) =
 505     op (f a) \fold[op,nil]_{i ∈ l| p i} (f i).
 506 #A #B #a #l #p #op #nil #f #pa normalize >pa // qed.
 507
 508 theorem fold_false:
 509 ∀A,B.∀a:A.∀l.∀p.∀op:B→B→B.∀nil.∀f.
 510 p a = false → \fold[op,nil]_{i ∈ a::l| p i} (f i) =
 511   \fold[op,nil]_{i ∈ l| p i} (f i).
 512 #A #B #a #l #p #op #nil #f #pa normalize >pa // qed.
 513
 514 theorem fold_filter:
 515 ∀A,B.∀a:A.∀l.∀p.∀op:B→B→B.∀nil.∀f:A →B.
 516   \fold[op,nil]_{i ∈ l| p i} (f i) =
 517     \fold[op,nil]_{i ∈ (filter A p l)} (f i).
 518 #A #B #a #l #p #op #nil #f elim l //
 519 #a #tl #Hind cases(true_or_false (p a)) #pa
 520   [ >filter_true // > fold_true // >fold_true //
 521   | >filter_false // >fold_false // ]
 522 qed.
 523
 524 record Aop (A:Type[0]) (nil:A) : Type[0] ≝
 525   {op :2> A → A → A;
 526    nill:∀a. op nil a = a;
 527    nilr:∀a. op a nil = a;
 528    assoc: ∀a,b,c.op a (op b c) = op (op a b) c
 529   }.
 530
 531 theorem fold_sum: ∀A,B. ∀I,J:list A.∀nil.∀op:Aop B nil.∀f.
 532   op (\fold[op,nil]_{i∈I} (f i)) (\fold[op,nil]_{i∈J} (f i)) =
 533     \fold[op,nil]_{i∈(I@J)} (f i).
 534 #A #B #I #J #nil #op #f (elim I) normalize
 535   [>nill //|#a #tl #Hind <assoc //]
 536 qed.
 537
 538 (********************** lhd and ltl ******************************)
 539
 540 let rec lhd (A:Type[0]) (l:list A) n on n ≝ match n with
 541    [ O   ⇒ nil …
 542    | S n ⇒ match l with [ nil ⇒ nil … | cons a l ⇒ a :: lhd A l n ]
 543    ].
 544
 545 let rec ltl (A:Type[0]) (l:list A) n on n ≝ match n with
 546    [ O   ⇒ l
 547    | S n ⇒ ltl A (tail … l) n
 548    ].
 549
 550 lemma lhd_nil: ∀A,n. lhd A ([]) n = [].
 551 #A #n elim n //
 552 qed.
 553
 554 lemma ltl_nil: ∀A,n. ltl A ([]) n = [].
 555 #A #n elim n normalize //
 556 qed.
 557
 558 lemma lhd_cons_ltl: ∀A,n,l. lhd A l n @ ltl A l n = l.
 559 #A #n elim n -n //
 560 #n #IHn #l elim l normalize //
 561 qed.
 562
 563 lemma length_ltl: ∀A,n,l. |ltl A l n| = |l| - n.
 564 #A #n elim n -n //
 565 #n #IHn *; normalize /2/
 566 qed.
 567
 568 (********************** find ******************************)
 569 let rec find (A,B:Type[0]) (f:A → option B) (l:list A) on l : option B ≝
 570 match l with
 571 [ nil ⇒ None B
 572 | cons h t ⇒
 573     match f h with
 574     [ None ⇒ find A B f t
 575     | Some b ⇒ Some B b
 576     ]
 577 ].
 578
 579 (********************** position_of ******************************)
 580 let rec position_of_aux (A:Type[0]) (found: A → bool) (l:list A) (acc:nat) on l : option nat ≝
 581 match l with
 582 [ nil ⇒ None ?
 583 | cons h t ⇒
 584    match found h with [true ⇒ Some … acc | false ⇒ position_of_aux … found t (S acc)]].
 585
 586 definition position_of: ∀A:Type[0]. (A → bool) → list A → option nat ≝
 587  λA,found,l. position_of_aux A found l 0.
 588
 589
 590 (********************** make_list ******************************)
 591 let rec make_list (A:Type[0]) (a:A) (n:nat) on n : list A ≝
 592 match n with
 593 [ O ⇒ [ ]
 594 | S m ⇒ a::(make_list A a m)
 595 ].