matita/matita/lib/basics/lists/list.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_______________________________________________________________ *)
  11
  12 include "basics/types.ma".
  13 include "arithmetics/nat.ma".
  14
  15 inductive list (A:Type[0]) : Type[0] :=
  16   | nil: list A
  17   | cons: A -> list A -> list A.
  18
  19 notation "hvbox(hd break :: tl)"
  20   right associative with precedence 47
  21   for @{'cons $hd $tl}.
  22
  23 notation "[ list0 x sep ; ]"
  24   non associative with precedence 90
  25   for ${fold right @'nil rec acc @{'cons $x $acc}}.
  26
  27 notation "hvbox(l1 break @ l2)"
  28   right associative with precedence 47
  29   for @{'append $l1 $l2 }.
  30
  31 interpretation "nil" 'nil = (nil ?).
  32 interpretation "cons" 'cons hd tl = (cons ? hd tl).
  33
  34 definition is_nil: ∀A:Type[0].list A → Prop ≝
  35  λA.λl.match l with [ nil ⇒ True | cons hd tl ⇒ False ].
  36
  37 theorem nil_cons:
  38   ∀A:Type[0].∀l:list A.∀a:A. a::l ≠ [].
  39   #A #l #a @nmk #Heq (change with (is_nil ? (a::l))) >Heq //
  40 qed.
  41
  42 (*
  43 let rec id_list A (l: list A) on l :=
  44   match l with
  45   [ nil => []
  46   | (cons hd tl) => hd :: id_list A tl ]. *)
  47
  48 let rec append A (l1: list A) l2 on l1 ≝
  49   match l1 with
  50   [ nil ⇒  l2
  51   | cons hd tl ⇒  hd :: append A tl l2 ].
  52
  53 definition hd ≝ λA.λl: list A.λd:A.
  54   match l with [ nil ⇒ d | cons a _ ⇒ a].
  55
  56 definition tail ≝  λA.λl: list A.
  57   match l with [ nil ⇒  [] | cons hd tl ⇒  tl].
  58
  59 definition option_hd ≝
  60   λA.λl:list A. match l with
  61   [ nil ⇒ None ?
  62   | cons a _ ⇒ Some ? a ].
  63
  64 interpretation "append" 'append l1 l2 = (append ? l1 l2).
  65
  66 theorem append_nil: ∀A.∀l:list A.l @ [] = l.
  67 #A #l (elim l) normalize // qed.
  68
  69 theorem associative_append:
  70  ∀A.associative (list A) (append A).
  71 #A #l1 #l2 #l3 (elim l1) normalize // qed.
  72
  73 theorem append_cons:∀A.∀a:A.∀l,l1.l@(a::l1)=(l@[a])@l1.
  74 #A #a #l #l1 >associative_append // qed.
  75
  76 theorem nil_append_elim: ∀A.∀l1,l2: list A.∀P:?→?→Prop.
  77   l1@l2=[] → P (nil A) (nil A) → P l1 l2.
  78 #A #l1 #l2 #P (cases l1) normalize //
  79 #a #l3 #heq destruct
  80 qed.
  81
  82 theorem nil_to_nil:  ∀A.∀l1,l2:list A.
  83   l1@l2 = [] → l1 = [] ∧ l2 = [].
  84 #A #l1 #l2 #isnil @(nil_append_elim A l1 l2) /2/
  85 qed.
  86
  87 lemma cons_injective_l : ∀A.∀a1,a2:A.∀l1,l2.a1::l1 = a2::l2 → a1 = a2.
  88 #A #a1 #a2 #l1 #l2 #Heq destruct //
  89 qed.
  90
  91 lemma cons_injective_r : ∀A.∀a1,a2:A.∀l1,l2.a1::l1 = a2::l2 → l1 = l2.
  92 #A #a1 #a2 #l1 #l2 #Heq destruct //
  93 qed.
  94
  95 (**************************** iterators ******************************)
  96
  97 let rec map (A,B:Type[0]) (f: A → B) (l:list A) on l: list B ≝
  98  match l with [ nil ⇒ nil ? | cons x tl ⇒ f x :: (map A B f tl)].
  99
 100 lemma map_append : ∀A,B,f,l1,l2.
 101   (map A B f l1) @ (map A B f l2) = map A B f (l1@l2).
 102 #A #B #f #l1 elim l1
 103 [ #l2 @refl
 104 | #h #t #IH #l2 normalize //
 105 ] qed.
 106
 107 let rec foldr (A,B:Type[0]) (f:A → B → B) (b:B) (l:list A) on l :B ≝
 108  match l with [ nil ⇒ b | cons a l ⇒ f a (foldr A B f b l)].
 109
 110 definition filter ≝
 111   λT.λp:T → bool.
 112   foldr T (list T) (λx,l0.if p x then x::l0 else l0) (nil T).
 113
 114 (* compose f [a1;...;an] [b1;...;bm] =
 115   [f a1 b1; ... ;f an b1; ... ;f a1 bm; f an bm] *)
 116
 117 definition compose ≝ λA,B,C.λf:A→B→C.λl1,l2.
 118     foldr ?? (λi,acc.(map ?? (f i) l2)@acc) [ ] l1.
 119
 120 lemma filter_true : ∀A,l,a,p. p a = true →
 121   filter A p (a::l) = a :: filter A p l.
 122 #A #l #a #p #pa (elim l) normalize >pa normalize // qed.
 123
 124 lemma filter_false : ∀A,l,a,p. p a = false →
 125   filter A p (a::l) = filter A p l.
 126 #A #l #a #p #pa (elim l) normalize >pa normalize // qed.
 127
 128 theorem eq_map : ∀A,B,f,g,l. (∀x.f x = g x) → map A B f l = map A B g l.
 129 #A #B #f #g #l #eqfg (elim l) normalize // qed.
 130
 131 (**************************** reverse *****************************)
 132 let rec rev_append S (l1,l2:list S) on l1 ≝
 133   match l1 with
 134   [ nil ⇒ l2
 135   | cons a tl ⇒ rev_append S tl (a::l2)
 136   ]
 137 .
 138
 139 definition reverse ≝λS.λl.rev_append S l [].
 140
 141 lemma reverse_single : ∀S,a. reverse S [a] = [a].
 142 // qed.
 143
 144 lemma rev_append_def : ∀S,l1,l2.
 145   rev_append S l1 l2 = (reverse S l1) @ l2 .
 146 #S #l1 elim l1 normalize //
 147 qed.
 148
 149 lemma reverse_cons : ∀S,a,l. reverse S (a::l) = (reverse S l)@[a].
 150 #S #a #l whd in ⊢ (??%?); //
 151 qed.
 152
 153 lemma reverse_append: ∀S,l1,l2.
 154   reverse S (l1 @ l2) = (reverse S l2)@(reverse S l1).
 155 #S #l1 elim l1 [normalize // | #a #tl #Hind #l2 >reverse_cons
 156 >reverse_cons // qed.
 157
 158 lemma reverse_reverse : ∀S,l. reverse S (reverse S l) = l.
 159 #S #l elim l // #a #tl #Hind >reverse_cons >reverse_append
 160 normalize // qed.
 161
 162 (* an elimination principle for lists working on the tail;
 163 useful for strings *)
 164 lemma list_elim_left: ∀S.∀P:list S → Prop. P (nil S) →
 165 (∀a.∀tl.P tl → P (tl@[a])) → ∀l. P l.
 166 #S #P #Pnil #Pstep #l <(reverse_reverse … l)
 167 generalize in match (reverse S l); #l elim l //
 168 #a #tl #H >reverse_cons @Pstep //
 169 qed.
 170
 171 (**************************** length ******************************)
 172
 173 let rec length (A:Type[0]) (l:list A) on l ≝
 174   match l with
 175     [ nil ⇒ 0
 176     | cons a tl ⇒ S (length A tl)].
 177
 178 notation "|M|" non associative with precedence 65 for @{'norm $M}.
 179 interpretation "norm" 'norm l = (length ? l).
 180
 181 lemma length_tail: ∀A,l. length ? (tail A l) = pred (length ? l).
 182 #A #l elim l //
 183 qed.
 184
 185 lemma length_append: ∀A.∀l1,l2:list A.
 186   |l1@l2| = |l1|+|l2|.
 187 #A #l1 elim l1 // normalize /2/
 188 qed.
 189
 190 lemma length_map: ∀A,B,l.∀f:A→B. length ? (map ?? f l) = length ? l.
 191 #A #B #l #f elim l // #a #tl #Hind normalize //
 192 qed.
 193
 194 lemma length_reverse: ∀A.∀l:list A.
 195   |reverse A l| = |l|.
 196 #A #l elim l // #a #l0 #IH >reverse_cons >length_append normalize //
 197 qed.
 198
 199 (****************** traversing two lists in parallel *****************)
 200 lemma list_ind2 :
 201   ∀T1,T2:Type[0].∀l1:list T1.∀l2:list T2.∀P:list T1 → list T2 → Prop.
 202   length ? l1 = length ? l2 →
 203   (P [] []) →
 204   (∀tl1,tl2,hd1,hd2. P tl1 tl2 → P (hd1::tl1) (hd2::tl2)) →
 205   P l1 l2.
 206 #T1 #T2 #l1 #l2 #P #Hl #Pnil #Pcons
 207 generalize in match Hl; generalize in match l2;
 208 elim l1
 209 [#l2 cases l2 // normalize #t2 #tl2 #H destruct
 210 |#t1 #tl1 #IH #l2 cases l2
 211    [normalize #H destruct
 212    |#t2 #tl2 #H @Pcons @IH normalize in H; destruct // ]
 213 ]
 214 qed.
 215
 216 lemma list_cases2 :
 217   ∀T1,T2:Type[0].∀l1:list T1.∀l2:list T2.∀P:Prop.
 218   length ? l1 = length ? l2 →
 219   (l1 = [] → l2 = [] → P) →
 220   (∀hd1,hd2,tl1,tl2.l1 = hd1::tl1 → l2 = hd2::tl2 → P) → P.
 221 #T1 #T2 #l1 #l2 #P #Hl @(list_ind2 … Hl)
 222 [ #Pnil #Pcons @Pnil //
 223 | #tl1 #tl2 #hd1 #hd2 #IH1 #IH2 #Hp @Hp // ]
 224 qed.
 225
 226 (*********************** properties of append ***********************)
 227 lemma append_l1_injective :
 228   ∀A.∀l1,l2,l3,l4:list A. |l1| = |l2| → l1@l3 = l2@l4 → l1 = l2.
 229 #a #l1 #l2 #l3 #l4 #Hlen @(list_ind2 … Hlen) //
 230 #tl1 #tl2 #hd1 #hd2 #IH normalize #Heq destruct @eq_f /2/
 231 qed.
 232
 233 lemma append_l2_injective :
 234   ∀A.∀l1,l2,l3,l4:list A. |l1| = |l2| → l1@l3 = l2@l4 → l3 = l4.
 235 #a #l1 #l2 #l3 #l4 #Hlen @(list_ind2 … Hlen) normalize //
 236 #tl1 #tl2 #hd1 #hd2 #IH normalize #Heq destruct /2/
 237 qed.
 238
 239 lemma append_l1_injective_r :
 240   ∀A.∀l1,l2,l3,l4:list A. |l3| = |l4| → l1@l3 = l2@l4 → l1 = l2.
 241 #a #l1 #l2 #l3 #l4 #Hlen #Heq lapply (eq_f … (reverse ?) … Heq)
 242 >reverse_append >reverse_append #Heq1
 243 lapply (append_l2_injective … Heq1) [ // ] #Heq2
 244 lapply (eq_f … (reverse ?) … Heq2) //
 245 qed.
 246
 247 lemma append_l2_injective_r :
 248   ∀A.∀l1,l2,l3,l4:list A. |l3| = |l4| → l1@l3 = l2@l4 → l3 = l4.
 249 #a #l1 #l2 #l3 #l4 #Hlen #Heq lapply (eq_f … (reverse ?) … Heq)
 250 >reverse_append >reverse_append #Heq1
 251 lapply (append_l1_injective … Heq1) [ // ] #Heq2
 252 lapply (eq_f … (reverse ?) … Heq2) //
 253 qed.
 254
 255 lemma length_rev_append: ∀A.∀l,acc:list A.
 256   |rev_append ? l acc| = |l|+|acc|.
 257 #A #l elim l // #a #tl #Hind normalize
 258 #acc >Hind normalize //
 259 qed.
 260
 261 (****************************** mem ********************************)
 262 let rec mem A (a:A) (l:list A) on l ≝
 263   match l with
 264   [ nil ⇒ False
 265   | cons hd tl ⇒ a=hd ∨ mem A a tl
 266   ].
 267
 268 (***************************** split *******************************)
 269 let rec split_rev A (l:list A) acc n on n ≝
 270   match n with
 271   [O ⇒ 〈acc,l〉
 272   |S m ⇒ match l with
 273     [nil ⇒ 〈acc,[]〉
 274     |cons a tl ⇒ split_rev A tl (a::acc) m
 275     ]
 276   ].
 277
 278 definition split ≝ λA,l,n.
 279   let 〈l1,l2〉 ≝ split_rev A l [] n in 〈reverse ? l1,l2〉.
 280
 281 lemma split_rev_len: ∀A,n,l,acc. n ≤ |l| →
 282   |\fst (split_rev A l acc n)| = n+|acc|.
 283 #A #n elim n // #m #Hind *
 284   [normalize #acc #Hfalse @False_ind /2/
 285   |#a #tl #acc #Hlen normalize >Hind
 286     [normalize // |@le_S_S_to_le //]
 287   ]
 288 qed.
 289
 290 lemma split_len: ∀A,n,l. n ≤ |l| →
 291   |\fst (split A l n)| = n.
 292 #A #n #l #Hlen normalize >(eq_pair_fst_snd ?? (split_rev …))
 293 normalize >length_reverse  >(split_rev_len … [ ] Hlen) normalize //
 294 qed.
 295
 296 lemma split_rev_eq: ∀A,n,l,acc. n ≤ |l| →
 297   reverse ? acc@ l =
 298     reverse ? (\fst (split_rev A l acc n))@(\snd (split_rev A l acc n)).
 299  #A #n elim n //
 300  #m #Hind *
 301    [#acc whd in ⊢ ((??%)→?); #False_ind /2/
 302    |#a #tl #acc #Hlen >append_cons <reverse_single <reverse_append
 303     @(Hind tl) @le_S_S_to_le @Hlen
 304    ]
 305 qed.
 306
 307 lemma split_eq: ∀A,n,l. n ≤ |l| →
 308   l = (\fst (split A l n))@(\snd (split A l n)).
 309 #A #n #l #Hlen change with ((reverse ? [ ])@l) in ⊢ (??%?);
 310 >(split_rev_eq … Hlen) normalize
 311 >(eq_pair_fst_snd ?? (split_rev A l [] n)) %
 312 qed.
 313
 314 lemma split_exists: ∀A,n.∀l:list A. n ≤ |l| →
 315   ∃l1,l2. l = l1@l2 ∧ |l1| = n.
 316 #A #n #l #Hlen @(ex_intro … (\fst (split A l n)))
 317 @(ex_intro … (\snd (split A l n))) % /2/
 318 qed.
 319
 320 (****************************** nth ********************************)
 321 let rec nth n (A:Type[0]) (l:list A) (d:A)  ≝
 322   match n with
 323     [O ⇒ hd A l d
 324     |S m ⇒ nth m A (tail A l) d].
 325
 326 lemma nth_nil: ∀A,a,i. nth i A ([]) a = a.
 327 #A #a #i elim i normalize //
 328 qed.
 329
 330 (****************************** nth_opt ********************************)
 331 let rec nth_opt (A:Type[0]) (n:nat) (l:list A) on l : option A ≝
 332 match l with
 333 [ nil ⇒ None ?
 334 | cons h t ⇒ match n with [ O ⇒ Some ? h | S m ⇒ nth_opt A m t ]
 335 ].
 336
 337 (**************************** All *******************************)
 338
 339 let rec All (A:Type[0]) (P:A → Prop) (l:list A) on l : Prop ≝
 340 match l with
 341 [ nil ⇒ True
 342 | cons h t ⇒ P h ∧ All A P t
 343 ].
 344
 345 lemma All_mp : ∀A,P,Q. (∀a.P a → Q a) → ∀l. All A P l → All A Q l.
 346 #A #P #Q #H #l elim l normalize //
 347 #h #t #IH * /3/
 348 qed.
 349
 350 lemma All_nth : ∀A,P,n,l.
 351   All A P l →
 352   ∀a.
 353   nth_opt A n l = Some A a →
 354   P a.
 355 #A #P #n elim n
 356 [ * [ #_ #a #E whd in E:(??%?); destruct
 357     | #hd #tl * #H #_ #a #E whd in E:(??%?); destruct @H
 358     ]
 359 | #m #IH *
 360   [ #_ #a #E whd in E:(??%?); destruct
 361   | #hd #tl * #_ whd in ⊢ (? → ∀_.??%? → ?); @IH
 362   ]
 363 ] qed.
 364
 365 (**************************** Exists *******************************)
 366
 367 let rec Exists (A:Type[0]) (P:A → Prop) (l:list A) on l : Prop ≝
 368 match l with
 369 [ nil ⇒ False
 370 | cons h t ⇒ (P h) ∨ (Exists A P t)
 371 ].
 372
 373 lemma Exists_append : ∀A,P,l1,l2.
 374   Exists A P (l1 @ l2) → Exists A P l1 ∨ Exists A P l2.
 375 #A #P #l1 elim l1
 376 [ normalize /2/
 377 | #h #t #IH #l2 *
 378   [ #H /3/
 379   | #H cases (IH l2 H) /3/
 380   ]
 381 ] qed.
 382
 383 lemma Exists_append_l : ∀A,P,l1,l2.
 384   Exists A P l1 → Exists A P (l1@l2).
 385 #A #P #l1 #l2 elim l1
 386 [ *
 387 | #h #t #IH *
 388   [ #H %1 @H
 389   | #H %2 @IH @H
 390   ]
 391 ] qed.
 392
 393 lemma Exists_append_r : ∀A,P,l1,l2.
 394   Exists A P l2 → Exists A P (l1@l2).
 395 #A #P #l1 #l2 elim l1
 396 [ #H @H
 397 | #h #t #IH #H %2 @IH @H
 398 ] qed.
 399
 400 lemma Exists_add : ∀A,P,l1,x,l2. Exists A P (l1@l2) → Exists A P (l1@x::l2).
 401 #A #P #l1 #x #l2 elim l1
 402 [ normalize #H %2 @H
 403 | #h #t #IH normalize * [ #H %1 @H | #H %2 @IH @H ]
 404 qed.
 405
 406 lemma Exists_mid : ∀A,P,l1,x,l2. P x → Exists A P (l1@x::l2).
 407 #A #P #l1 #x #l2 #H elim l1
 408 [ %1 @H
 409 | #h #t #IH %2 @IH
 410 ] qed.
 411
 412 lemma Exists_map : ∀A,B,P,Q,f,l.
 413 Exists A P l →
 414 (∀a.P a → Q (f a)) →
 415 Exists B Q (map A B f l).
 416 #A #B #P #Q #f #l elim l //
 417 #h #t #IH * [ #H #F %1 @F @H | #H #F %2 @IH [ @H | @F ] ] qed.
 418
 419 lemma Exists_All : ∀A,P,Q,l.
 420   Exists A P l →
 421   All A Q l →
 422   ∃x. P x ∧ Q x.
 423 #A #P #Q #l elim l [ * | #hd #tl #IH * [ #H1 * #H2 #_ %{hd} /2/ | #H1 * #_ #H2 @IH // ]
 424 qed.
 425
 426 (**************************** fold *******************************)
 427
 428 let rec fold (A,B:Type[0]) (op:B → B → B) (b:B) (p:A→bool) (f:A→B) (l:list A) on l :B ≝
 429  match l with
 430   [ nil ⇒ b
 431   | cons a l ⇒
 432      if p a then op (f a) (fold A B op b p f l)
 433      else fold A B op b p f l].
 434
 435 notation "\fold  [ op , nil ]_{ ident i ∈ l | p} f"
 436   with precedence 80
 437 for @{'fold $op $nil (λ${ident i}. $p) (λ${ident i}. $f) $l}.
 438
 439 notation "\fold [ op , nil ]_{ident i ∈ l } f"
 440   with precedence 80
 441 for @{'fold $op $nil (λ${ident i}.true) (λ${ident i}. $f) $l}.
 442
 443 interpretation "\fold" 'fold op nil p f l = (fold ? ? op nil p f l).
 444
 445 theorem fold_true:
 446 ∀A,B.∀a:A.∀l.∀p.∀op:B→B→B.∀nil.∀f:A→B. p a = true →
 447   \fold[op,nil]_{i ∈ a::l| p i} (f i) =
 448     op (f a) \fold[op,nil]_{i ∈ l| p i} (f i).
 449 #A #B #a #l #p #op #nil #f #pa normalize >pa // qed.
 450
 451 theorem fold_false:
 452 ∀A,B.∀a:A.∀l.∀p.∀op:B→B→B.∀nil.∀f.
 453 p a = false → \fold[op,nil]_{i ∈ a::l| p i} (f i) =
 454   \fold[op,nil]_{i ∈ l| p i} (f i).
 455 #A #B #a #l #p #op #nil #f #pa normalize >pa // qed.
 456
 457 theorem fold_filter:
 458 ∀A,B.∀a:A.∀l.∀p.∀op:B→B→B.∀nil.∀f:A →B.
 459   \fold[op,nil]_{i ∈ l| p i} (f i) =
 460     \fold[op,nil]_{i ∈ (filter A p l)} (f i).
 461 #A #B #a #l #p #op #nil #f elim l //
 462 #a #tl #Hind cases(true_or_false (p a)) #pa
 463   [ >filter_true // > fold_true // >fold_true //
 464   | >filter_false // >fold_false // ]
 465 qed.
 466
 467 record Aop (A:Type[0]) (nil:A) : Type[0] ≝
 468   {op :2> A → A → A;
 469    nill:∀a. op nil a = a;
 470    nilr:∀a. op a nil = a;
 471    assoc: ∀a,b,c.op a (op b c) = op (op a b) c
 472   }.
 473
 474 theorem fold_sum: ∀A,B. ∀I,J:list A.∀nil.∀op:Aop B nil.∀f.
 475   op (\fold[op,nil]_{i∈I} (f i)) (\fold[op,nil]_{i∈J} (f i)) =
 476     \fold[op,nil]_{i∈(I@J)} (f i).
 477 #A #B #I #J #nil #op #f (elim I) normalize
 478   [>nill //|#a #tl #Hind <assoc //]
 479 qed.
 480
 481 (********************** lhd and ltl ******************************)
 482
 483 let rec lhd (A:Type[0]) (l:list A) n on n ≝ match n with
 484    [ O   ⇒ nil …
 485    | S n ⇒ match l with [ nil ⇒ nil … | cons a l ⇒ a :: lhd A l n ]
 486    ].
 487
 488 let rec ltl (A:Type[0]) (l:list A) n on n ≝ match n with
 489    [ O   ⇒ l
 490    | S n ⇒ ltl A (tail … l) n
 491    ].
 492
 493 lemma lhd_nil: ∀A,n. lhd A ([]) n = [].
 494 #A #n elim n //
 495 qed.
 496
 497 lemma ltl_nil: ∀A,n. ltl A ([]) n = [].
 498 #A #n elim n normalize //
 499 qed.
 500
 501 lemma lhd_cons_ltl: ∀A,n,l. lhd A l n @ ltl A l n = l.
 502 #A #n elim n -n //
 503 #n #IHn #l elim l normalize //
 504 qed.
 505
 506 lemma length_ltl: ∀A,n,l. |ltl A l n| = |l| - n.
 507 #A #n elim n -n //
 508 #n #IHn *; normalize /2/
 509 qed.
 510
 511 (********************** find ******************************)
 512 let rec find (A,B:Type[0]) (f:A → option B) (l:list A) on l : option B ≝
 513 match l with
 514 [ nil ⇒ None B
 515 | cons h t ⇒
 516     match f h with
 517     [ None ⇒ find A B f t
 518     | Some b ⇒ Some B b
 519     ]
 520 ].
 521
 522 (********************** position_of ******************************)
 523 let rec position_of_aux (A:Type[0]) (found: A → bool) (l:list A) (acc:nat) on l : option nat ≝
 524 match l with
 525 [ nil ⇒ None ?
 526 | cons h t ⇒
 527    match found h with [true ⇒ Some … acc | false ⇒ position_of_aux … found t (S acc)]].
 528
 529 definition position_of: ∀A:Type[0]. (A → bool) → list A → option nat ≝
 530  λA,found,l. position_of_aux A found l 0.
 531
 532
 533 (********************** make_list ******************************)
 534 let rec make_list (A:Type[0]) (a:A) (n:nat) on n : list A ≝
 535 match n with
 536 [ O ⇒ [ ]
 537 | S m ⇒ a::(make_list A a m)
 538 ].