matita/matita/lib/basics/lists/listb.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_______________________________________________________________ *)
  11
  12
  13 (* boolean functions over lists *)
  14
  15 include "basics/lists/list.ma".
  16 include "basics/sets.ma".
  17
  18 (********* search *********)
  19
  20 let rec memb (S:DeqSet) (x:S) (l: list S) on l  ≝
  21   match l with
  22   [ nil ⇒ false
  23   | cons a tl ⇒ (a == x) ∨ memb S x tl
  24   ].
  25
  26 lemma memb_hd: ∀S,a,l. memb S a (a::l) = true.
  27 #S #a #l normalize >(proj2 … (eqb_true S …) (refl S a)) //
  28 qed.
  29
  30 lemma memb_cons: ∀S,a,b,l.
  31   memb S a l = true → memb S a (b::l) = true.
  32 #S #a #b #l normalize cases (b==a) normalize //
  33 qed.
  34
  35 lemma memb_append: ∀S,a,l1,l2.
  36 memb S a (l1@l2) = true →
  37   memb S a l1= true ∨ memb S a l2 = true.
  38 #S #a #l1 elim l1 normalize [#l2 #H %2 //]
  39 #b #tl #Hind #l2 cases (b==a) normalize /2/
  40 qed.
  41
  42 lemma memb_append_l1: ∀S,a,l1,l2.
  43  memb S a l1= true → memb S a (l1@l2) = true.
  44 #S #a #l1 elim l1 normalize
  45   [normalize #le #abs @False_ind /2/
  46   |#b #tl #Hind #l2 cases (b==a) normalize /2/
  47   ]
  48 qed.
  49
  50 lemma memb_append_l2: ∀S,a,l1,l2.
  51  memb S a l2= true → memb S a (l1@l2) = true.
  52 #S #a #l1 elim l1 normalize //
  53 #b #tl #Hind #l2 cases (b==a) normalize /2/
  54 qed.
  55
  56 lemma memb_exists: ∀S,a,l.memb S a l = true →
  57   ∃l1,l2.l=l1@(a::l2).
  58 #S #a #l elim l [normalize #abs @False_ind /2/]
  59 #b #tl #Hind #H cases (orb_true_l … H)
  60   [#eqba @(ex_intro … (nil S)) @(ex_intro … tl)
  61    >(proj1 … (eqb_true …) eqba) //
  62   |#mem_tl cases (Hind mem_tl) #l1 * #l2 #eqtl
  63    @(ex_intro … (b::l1)) @(ex_intro … l2) >eqtl //
  64   ]
  65 qed.
  66
  67 lemma not_memb_to_not_eq: ∀S,a,b,l.
  68  memb S a l = false → memb S b l = true → a==b = false.
  69 #S #a #b #l cases (true_or_false (a==b)) //
  70 #eqab >(proj1 … (eqb_true …) eqab) #H >H #abs @False_ind /2/
  71 qed.
  72
  73 lemma memb_map: ∀S1,S2,f,a,l. memb S1 a l= true →
  74   memb S2 (f a) (map … f l) = true.
  75 #S1 #S2 #f #a #l elim l normalize [//]
  76 #x #tl #memba cases (true_or_false (x==a))
  77   [#eqx >eqx >(proj1 … (eqb_true …) eqx)
  78    >(proj2 … (eqb_true …) (refl … (f a))) normalize //
  79   |#eqx >eqx cases (f x==f a) normalize /2/
  80   ]
  81 qed.
  82
  83 lemma memb_compose: ∀S1,S2,S3,op,a1,a2,l1,l2.
  84   memb S1 a1 l1 = true → memb S2 a2 l2 = true →
  85   memb S3 (op a1 a2) (compose S1 S2 S3 op l1 l2) = true.
  86 #S1 #S2 #S3 #op #a1 #a2 #l1 elim l1 [normalize //]
  87 #x #tl #Hind #l2 #memba1 #memba2 cases (orb_true_l … memba1)
  88   [#eqa1 >(proj1 … (eqb_true …) eqa1) @memb_append_l1 @memb_map //
  89   |#membtl @memb_append_l2 @Hind //
  90   ]
  91 qed.
  92
  93 (**************** unicity test *****************)
  94
  95 let rec uniqueb (S:DeqSet) l on l : bool ≝
  96   match l with
  97   [ nil ⇒ true
  98   | cons a tl ⇒ notb (memb S a tl) ∧ uniqueb S tl
  99   ].
 100
 101 (* unique_append l1 l2 add l1 in fornt of l2, but preserving unicity *)
 102
 103 let rec unique_append (S:DeqSet) (l1,l2: list S) on l1 ≝
 104   match l1 with
 105   [ nil ⇒ l2
 106   | cons a tl ⇒
 107      let r ≝ unique_append S tl l2 in
 108      if (memb S a r) then r else a::r
 109   ].
 110
 111 axiom unique_append_elim: ∀S:DeqSet.∀P: S → Prop.∀l1,l2.
 112 (∀x. memb S x l1 = true → P x) → (∀x. memb S x l2 = true → P x) →
 113 ∀x. memb S x (unique_append S l1 l2) = true → P x.
 114
 115 lemma unique_append_unique: ∀S,l1,l2. uniqueb S l2 = true →
 116   uniqueb S (unique_append S l1 l2) = true.
 117 #S #l1 elim l1 normalize // #a #tl #Hind #l2 #uniquel2
 118 cases (true_or_false … (memb S a (unique_append S tl l2)))
 119 #H >H normalize [@Hind //] >H normalize @Hind //
 120 qed.
 121
 122 (******************* sublist *******************)
 123 definition sublist ≝
 124   λS,l1,l2.∀a. memb S a l1 = true → memb S a l2 = true.
 125
 126 lemma sublist_length: ∀S,l1,l2.
 127  uniqueb S l1 = true → sublist S l1 l2 → |l1| ≤ |l2|.
 128 #S #l1 elim l1 //
 129 #a #tl #Hind #l2 #unique #sub
 130 cut (∃l3,l4.l2=l3@(a::l4)) [@memb_exists @sub //]
 131 * #l3 * #l4 #eql2 >eql2 >length_append normalize
 132 applyS le_S_S <length_append @Hind [@(andb_true_r … unique)]
 133 >eql2 in sub; #sub #x #membx
 134 cases (memb_append … (sub x (orb_true_r2 … membx)))
 135   [#membxl3 @memb_append_l1 //
 136   |#membxal4 cases (orb_true_l … membxal4)
 137     [#eqax @False_ind lapply (andb_true_l … unique)
 138      >(proj1 … (eqb_true …) eqax) >membx normalize /2/
 139     |#membxl4 @memb_append_l2 //
 140     ]
 141   ]
 142 qed.
 143
 144 lemma sublist_unique_append_l1:
 145   ∀S,l1,l2. sublist S l1 (unique_append S l1 l2).
 146 #S #l1 elim l1 normalize [#l2 #S #abs @False_ind /2/]
 147 #x #tl #Hind #l2 #a
 148 normalize cases (true_or_false … (x==a)) #eqxa >eqxa
 149 [>(proj1 … (eqb_true …) eqxa) cases (true_or_false (memb S a (unique_append S tl l2)))
 150   [#H >H normalize // | #H >H normalize >(proj2 … (eqb_true …) (refl … a)) //]
 151 |cases (memb S x (unique_append S tl l2)) normalize
 152   [/2/ |>eqxa normalize /2/]
 153 ]
 154 qed.
 155
 156 lemma sublist_unique_append_l2:
 157   ∀S,l1,l2. sublist S l2 (unique_append S l1 l2).
 158 #S #l1 elim l1 [normalize //] #x #tl #Hind normalize
 159 #l2 #a cases (memb S x (unique_append S tl l2)) normalize
 160 [@Hind | cases (x==a) normalize // @Hind]
 161 qed.
 162
 163 (********************* filtering *****************)
 164
 165 lemma filter_true: ∀S,f,a,l.
 166   memb S a (filter S f l) = true → f a = true.
 167 #S #f #a #l elim l [normalize #H @False_ind /2/]
 168 #b #tl #Hind cases (true_or_false (f b)) #H
 169 normalize >H normalize [2:@Hind]
 170 cases (true_or_false (b==a)) #eqab
 171   [#_ <(proj1 … (eqb_true …) eqab) // | >eqab normalize @Hind]
 172 qed.
 173
 174 lemma memb_filter_memb: ∀S,f,a,l.
 175   memb S a (filter S f l) = true → memb S a l = true.
 176 #S #f #a #l elim l [normalize //]
 177 #b #tl #Hind normalize (cases (f b)) normalize
 178 cases (b==a) normalize // @Hind
 179 qed.
 180
 181 lemma memb_filter: ∀S,f,l,x. memb S x (filter ? f l) = true →
 182 memb S x l = true ∧ (f x = true).
 183 /3/ qed.
 184
 185 lemma memb_filter_l: ∀S,f,x,l. (f x = true) → memb S x l = true →
 186 memb S x (filter ? f l) = true.
 187 #S #f #x #l #fx elim l normalize //
 188 #b #tl #Hind cases (true_or_false (b==x)) #eqbx
 189   [>(proj1 … (eqb_true … ) eqbx) >(proj2 … (eqb_true …) (refl … x))
 190    >fx normalize >(proj2 … (eqb_true …) (refl … x)) normalize //
 191   |>eqbx cases (f b) normalize [>eqbx normalize @Hind| @Hind]
 192   ]
 193 qed.
 194
 195
 196