matita/matita/lib/basics/lists/listb.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_______________________________________________________________ *)
  11
  12
  13 (* boolean functions over lists *)
  14
  15 include "basics/lists/list.ma".
  16 include "basics/sets.ma".
  17 include "basics/deqsets.ma".
  18
  19 (********* isnilb *********)
  20 let rec isnilb A (l: list A) on l ≝
  21 match l with
  22 [ nil ⇒ true
  23 | cons hd tl ⇒ false
  24 ].
  25
  26 (********* search *********)
  27
  28 let rec memb (S:DeqSet) (x:S) (l: list S) on l  ≝
  29   match l with
  30   [ nil ⇒ false
  31   | cons a tl ⇒ (x == a) ∨ memb S x tl
  32   ].
  33
  34 notation < "\memb x l" non associative with precedence 90 for @{'memb $x $l}.
  35 interpretation "boolean membership" 'memb a l = (memb ? a l).
  36
  37 lemma memb_hd: ∀S,a,l. memb S a (a::l) = true.
  38 #S #a #l normalize >(proj2 … (eqb_true S …) (refl S a)) //
  39 qed.
  40
  41 lemma memb_cons: ∀S,a,b,l.
  42   memb S a l = true → memb S a (b::l) = true.
  43 #S #a #b #l normalize cases (a==b) normalize //
  44 qed.
  45
  46 lemma memb_single: ∀S,a,x. memb S a [x] = true → a = x.
  47 #S #a #x normalize cases (true_or_false … (a==x)) #H
  48   [#_ >(\P H) // |>H normalize #abs @False_ind /2/]
  49 qed.
  50
  51 lemma memb_append: ∀S,a,l1,l2.
  52 memb S a (l1@l2) = true →
  53   memb S a l1= true ∨ memb S a l2 = true.
  54 #S #a #l1 elim l1 normalize [#l2 #H %2 //]
  55 #b #tl #Hind #l2 cases (a==b) normalize /2/
  56 qed.
  57
  58 lemma memb_append_l1: ∀S,a,l1,l2.
  59  memb S a l1= true → memb S a (l1@l2) = true.
  60 #S #a #l1 elim l1 normalize
  61   [normalize #le #abs @False_ind /2/
  62   |#b #tl #Hind #l2 cases (a==b) normalize /2/
  63   ]
  64 qed.
  65
  66 lemma memb_append_l2: ∀S,a,l1,l2.
  67  memb S a l2= true → memb S a (l1@l2) = true.
  68 #S #a #l1 elim l1 normalize //
  69 #b #tl #Hind #l2 cases (a==b) normalize /2/
  70 qed.
  71
  72 lemma memb_exists: ∀S,a,l.memb S a l = true →
  73   ∃l1,l2.l=l1@(a::l2).
  74 #S #a #l elim l [normalize #abs @False_ind /2/]
  75 #b #tl #Hind #H cases (orb_true_l … H)
  76   [#eqba @(ex_intro … (nil S)) @(ex_intro … tl) >(\P eqba) //
  77   |#mem_tl cases (Hind mem_tl) #l1 * #l2 #eqtl
  78    @(ex_intro … (b::l1)) @(ex_intro … l2) >eqtl //
  79   ]
  80 qed.
  81
  82 lemma not_memb_to_not_eq: ∀S,a,b,l.
  83  memb S a l = false → memb S b l = true → a==b = false.
  84 #S #a #b #l cases (true_or_false (a==b)) //
  85 #eqab >(\P eqab) #H >H #abs @False_ind /2/
  86 qed.
  87
  88 lemma memb_map: ∀S1,S2,f,a,l. memb S1 a l= true →
  89   memb S2 (f a) (map … f l) = true.
  90 #S1 #S2 #f #a #l elim l normalize [//]
  91 #x #tl #memba cases (true_or_false (a==x))
  92   [#eqx >eqx >(\P eqx) >(\b (refl … (f x))) normalize //
  93   |#eqx >eqx cases (f a==f x) normalize /2/
  94   ]
  95 qed.
  96
  97 lemma memb_compose: ∀S1,S2,S3,op,a1,a2,l1,l2.
  98   memb S1 a1 l1 = true → memb S2 a2 l2 = true →
  99   memb S3 (op a1 a2) (compose S1 S2 S3 op l1 l2) = true.
 100 #S1 #S2 #S3 #op #a1 #a2 #l1 elim l1 [normalize //]
 101 #x #tl #Hind #l2 #memba1 #memba2 cases (orb_true_l … memba1)
 102   [#eqa1 >(\P eqa1) @memb_append_l1 @memb_map //
 103   |#membtl @memb_append_l2 @Hind //
 104   ]
 105 qed.
 106
 107 (**************** unicity test *****************)
 108
 109 let rec uniqueb (S:DeqSet) l on l : bool ≝
 110   match l with
 111   [ nil ⇒ true
 112   | cons a tl ⇒ notb (memb S a tl) ∧ uniqueb S tl
 113   ].
 114
 115 (* unique_append l1 l2 add l1 in fornt of l2, but preserving unicity *)
 116
 117 let rec unique_append (S:DeqSet) (l1,l2: list S) on l1 ≝
 118   match l1 with
 119   [ nil ⇒ l2
 120   | cons a tl ⇒
 121      let r ≝ unique_append S tl l2 in
 122      if memb S a r then r else a::r
 123   ].
 124
 125 lemma memb_unique_append: ∀S,a,l1,l2.
 126 memb S a (unique_append S l1 l2) = true →
 127   memb S a l1= true ∨ memb S a l2 = true.
 128 #S #a #l1 elim l1 normalize [#l2 #H %2 //]
 129 #b #tl #Hind #l2 cases (true_or_false … (a==b)) #Hab >Hab normalize /2/
 130 cases (memb S b (unique_append S tl l2)) normalize
 131   [@Hind | >Hab normalize @Hind]
 132 qed.
 133
 134 lemma unique_append_elim: ∀S:DeqSet.∀P: S → Prop.∀l1,l2.
 135 (∀x. memb S x l1 = true → P x) → (∀x. memb S x l2 = true → P x) →
 136 ∀x. memb S x (unique_append S l1 l2) = true → P x.
 137 #S #P #l1 #l2 #Hl1 #Hl2 #x #membx cases (memb_unique_append … membx)
 138 /2/
 139 qed.
 140
 141 lemma unique_append_unique: ∀S,l1,l2. uniqueb S l2 = true →
 142   uniqueb S (unique_append S l1 l2) = true.
 143 #S #l1 elim l1 normalize // #a #tl #Hind #l2 #uniquel2
 144 cases (true_or_false … (memb S a (unique_append S tl l2)))
 145 #H >H normalize [@Hind //] >H normalize @Hind //
 146 qed.
 147
 148 (******************* sublist *******************)
 149 definition sublist ≝
 150   λS,l1,l2.∀a. memb S a l1 = true → memb S a l2 = true.
 151
 152 lemma sublist_length: ∀S,l1,l2.
 153  uniqueb S l1 = true → sublist S l1 l2 → |l1| ≤ |l2|.
 154 #S #l1 elim l1 //
 155 #a #tl #Hind #l2 #unique #sub
 156 cut (∃l3,l4.l2=l3@(a::l4)) [@memb_exists @sub //]
 157 * #l3 * #l4 #eql2 >eql2 >length_append normalize
 158 applyS le_S_S <length_append @Hind [@(andb_true_r … unique)]
 159 >eql2 in sub; #sub #x #membx
 160 cases (memb_append … (sub x (orb_true_r2 … membx)))
 161   [#membxl3 @memb_append_l1 //
 162   |#membxal4 cases (orb_true_l … membxal4)
 163     [#eqxa @False_ind lapply (andb_true_l … unique)
 164      <(\P eqxa) >membx normalize /2/ |#membxl4 @memb_append_l2 //
 165     ]
 166   ]
 167 qed.
 168
 169 lemma sublist_unique_append_l1:
 170   ∀S,l1,l2. sublist S l1 (unique_append S l1 l2).
 171 #S #l1 elim l1 normalize [#l2 #S #abs @False_ind /2/]
 172 #x #tl #Hind #l2 #a
 173 normalize cases (true_or_false … (a==x)) #eqax >eqax
 174 [<(\P eqax) cases (true_or_false (memb S a (unique_append S tl l2)))
 175   [#H >H normalize // | #H >H normalize >(\b (refl … a)) //]
 176 |cases (memb S x (unique_append S tl l2)) normalize
 177   [/2/ |>eqax normalize /2/]
 178 ]
 179 qed.
 180
 181 lemma sublist_unique_append_l2:
 182   ∀S,l1,l2. sublist S l2 (unique_append S l1 l2).
 183 #S #l1 elim l1 [normalize //] #x #tl #Hind normalize
 184 #l2 #a cases (memb S x (unique_append S tl l2)) normalize
 185 [@Hind | cases (a==x) normalize // @Hind]
 186 qed.
 187
 188 lemma decidable_sublist:∀S,l1,l2.
 189   (sublist S l1 l2) ∨ ¬(sublist S l1 l2).
 190 #S #l1 #l2 elim l1
 191   [%1 #a normalize in ⊢ (%→?); #abs @False_ind /2/
 192   |#a #tl * #subtl
 193     [cases (true_or_false (memb S a l2)) #memba
 194       [%1 whd #x #membx cases (orb_true_l … membx)
 195         [#eqax >(\P eqax) // |@subtl]
 196       |%2 @(not_to_not … (eqnot_to_noteq … true memba)) #H1 @H1 @memb_hd
 197       ]
 198     |%2 @(not_to_not … subtl) #H1 #x #H2 @H1 @memb_cons //
 199     ]
 200   ]
 201 qed.
 202
 203 (********************* filtering *****************)
 204
 205 lemma filter_true: ∀S,f,a,l.
 206   memb S a (filter S f l) = true → f a = true.
 207 #S #f #a #l elim l [normalize #H @False_ind /2/]
 208 #b #tl #Hind cases (true_or_false (f b)) #H
 209 normalize >H normalize [2:@Hind]
 210 cases (true_or_false (a==b)) #eqab
 211   [#_ >(\P eqab) // | >eqab normalize @Hind]
 212 qed.
 213
 214 lemma memb_filter_memb: ∀S,f,a,l.
 215   memb S a (filter S f l) = true → memb S a l = true.
 216 #S #f #a #l elim l [normalize //]
 217 #b #tl #Hind normalize (cases (f b)) normalize
 218 cases (a==b) normalize // @Hind
 219 qed.
 220
 221 lemma memb_filter: ∀S,f,l,x. memb S x (filter ? f l) = true →
 222 memb S x l = true ∧ (f x = true).
 223 /3/ qed.
 224
 225 lemma memb_filter_l: ∀S,f,x,l. (f x = true) → memb S x l = true →
 226 memb S x (filter ? f l) = true.
 227 #S #f #x #l #fx elim l normalize //
 228 #b #tl #Hind cases (true_or_false (x==b)) #eqxb
 229   [<(\P eqxb) >(\b (refl … x)) >fx normalize >(\b (refl … x)) normalize //
 230   |>eqxb cases (f b) normalize [>eqxb normalize @Hind| @Hind]
 231   ]
 232 qed.
 233
 234 (********************* exists *****************)
 235
 236 let rec exists (A:Type[0]) (p:A → bool) (l:list A) on l : bool ≝
 237 match l with
 238 [ nil ⇒ false
 239 | cons h t ⇒ orb (p h) (exists A p t)
 240 ].
 241
 242 lemma Exists_exists : ∀A,P,l.
 243   Exists A P l →
 244   ∃x. P x.
 245 #A #P #l elim l [ * | #hd #tl #IH * [ #H %{hd} @H | @IH ]
 246 qed.