matita/matita/lib/basics/lists/listb.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_______________________________________________________________ *)
  11
  12
  13 (* boolean functions over lists *)
  14
  15 include "basics/lists/list.ma".
  16 include "basics/sets.ma".
  17 include "basics/deqsets.ma".
  18
  19 (********* search *********)
  20
  21 let rec memb (S:DeqSet) (x:S) (l: list S) on l  ≝
  22   match l with
  23   [ nil ⇒ false
  24   | cons a tl ⇒ (x == a) ∨ memb S x tl
  25   ].
  26
  27 notation < "\memb x l" non associative with precedence 90 for @{'memb $x $l}.
  28 interpretation "boolean membership" 'memb a l = (memb ? a l).
  29
  30 lemma memb_hd: ∀S,a,l. memb S a (a::l) = true.
  31 #S #a #l normalize >(proj2 … (eqb_true S …) (refl S a)) //
  32 qed.
  33
  34 lemma memb_cons: ∀S,a,b,l.
  35   memb S a l = true → memb S a (b::l) = true.
  36 #S #a #b #l normalize cases (a==b) normalize //
  37 qed.
  38
  39 lemma memb_single: ∀S,a,x. memb S a [x] = true → a = x.
  40 #S #a #x normalize cases (true_or_false … (a==x)) #H
  41   [#_ >(\P H) // |>H normalize #abs @False_ind /2/]
  42 qed.
  43
  44 lemma memb_append: ∀S,a,l1,l2.
  45 memb S a (l1@l2) = true →
  46   memb S a l1= true ∨ memb S a l2 = true.
  47 #S #a #l1 elim l1 normalize [#l2 #H %2 //]
  48 #b #tl #Hind #l2 cases (a==b) normalize /2/
  49 qed.
  50
  51 lemma memb_append_l1: ∀S,a,l1,l2.
  52  memb S a l1= true → memb S a (l1@l2) = true.
  53 #S #a #l1 elim l1 normalize
  54   [normalize #le #abs @False_ind /2/
  55   |#b #tl #Hind #l2 cases (a==b) normalize /2/
  56   ]
  57 qed.
  58
  59 lemma memb_append_l2: ∀S,a,l1,l2.
  60  memb S a l2= true → memb S a (l1@l2) = true.
  61 #S #a #l1 elim l1 normalize //
  62 #b #tl #Hind #l2 cases (a==b) normalize /2/
  63 qed.
  64
  65 lemma memb_exists: ∀S,a,l.memb S a l = true →
  66   ∃l1,l2.l=l1@(a::l2).
  67 #S #a #l elim l [normalize #abs @False_ind /2/]
  68 #b #tl #Hind #H cases (orb_true_l … H)
  69   [#eqba @(ex_intro … (nil S)) @(ex_intro … tl) >(\P eqba) //
  70   |#mem_tl cases (Hind mem_tl) #l1 * #l2 #eqtl
  71    @(ex_intro … (b::l1)) @(ex_intro … l2) >eqtl //
  72   ]
  73 qed.
  74
  75 lemma not_memb_to_not_eq: ∀S,a,b,l.
  76  memb S a l = false → memb S b l = true → a==b = false.
  77 #S #a #b #l cases (true_or_false (a==b)) //
  78 #eqab >(\P eqab) #H >H #abs @False_ind /2/
  79 qed.
  80
  81 lemma memb_map: ∀S1,S2,f,a,l. memb S1 a l= true →
  82   memb S2 (f a) (map … f l) = true.
  83 #S1 #S2 #f #a #l elim l normalize [//]
  84 #x #tl #memba cases (true_or_false (a==x))
  85   [#eqx >eqx >(\P eqx) >(\b (refl … (f x))) normalize //
  86   |#eqx >eqx cases (f a==f x) normalize /2/
  87   ]
  88 qed.
  89
  90 lemma memb_compose: ∀S1,S2,S3,op,a1,a2,l1,l2.
  91   memb S1 a1 l1 = true → memb S2 a2 l2 = true →
  92   memb S3 (op a1 a2) (compose S1 S2 S3 op l1 l2) = true.
  93 #S1 #S2 #S3 #op #a1 #a2 #l1 elim l1 [normalize //]
  94 #x #tl #Hind #l2 #memba1 #memba2 cases (orb_true_l … memba1)
  95   [#eqa1 >(\P eqa1) @memb_append_l1 @memb_map //
  96   |#membtl @memb_append_l2 @Hind //
  97   ]
  98 qed.
  99
 100 (**************** unicity test *****************)
 101
 102 let rec uniqueb (S:DeqSet) l on l : bool ≝
 103   match l with
 104   [ nil ⇒ true
 105   | cons a tl ⇒ notb (memb S a tl) ∧ uniqueb S tl
 106   ].
 107
 108 (* unique_append l1 l2 add l1 in fornt of l2, but preserving unicity *)
 109
 110 let rec unique_append (S:DeqSet) (l1,l2: list S) on l1 ≝
 111   match l1 with
 112   [ nil ⇒ l2
 113   | cons a tl ⇒
 114      let r ≝ unique_append S tl l2 in
 115      if memb S a r then r else a::r
 116   ].
 117
 118 axiom unique_append_elim: ∀S:DeqSet.∀P: S → Prop.∀l1,l2.
 119 (∀x. memb S x l1 = true → P x) → (∀x. memb S x l2 = true → P x) →
 120 ∀x. memb S x (unique_append S l1 l2) = true → P x.
 121
 122 lemma unique_append_unique: ∀S,l1,l2. uniqueb S l2 = true →
 123   uniqueb S (unique_append S l1 l2) = true.
 124 #S #l1 elim l1 normalize // #a #tl #Hind #l2 #uniquel2
 125 cases (true_or_false … (memb S a (unique_append S tl l2)))
 126 #H >H normalize [@Hind //] >H normalize @Hind //
 127 qed.
 128
 129 (******************* sublist *******************)
 130 definition sublist ≝
 131   λS,l1,l2.∀a. memb S a l1 = true → memb S a l2 = true.
 132
 133 lemma sublist_length: ∀S,l1,l2.
 134  uniqueb S l1 = true → sublist S l1 l2 → |l1| ≤ |l2|.
 135 #S #l1 elim l1 //
 136 #a #tl #Hind #l2 #unique #sub
 137 cut (∃l3,l4.l2=l3@(a::l4)) [@memb_exists @sub //]
 138 * #l3 * #l4 #eql2 >eql2 >length_append normalize
 139 applyS le_S_S <length_append @Hind [@(andb_true_r … unique)]
 140 >eql2 in sub; #sub #x #membx
 141 cases (memb_append … (sub x (orb_true_r2 … membx)))
 142   [#membxl3 @memb_append_l1 //
 143   |#membxal4 cases (orb_true_l … membxal4)
 144     [#eqxa @False_ind lapply (andb_true_l … unique)
 145      <(\P eqxa) >membx normalize /2/ |#membxl4 @memb_append_l2 //
 146     ]
 147   ]
 148 qed.
 149
 150 lemma sublist_unique_append_l1:
 151   ∀S,l1,l2. sublist S l1 (unique_append S l1 l2).
 152 #S #l1 elim l1 normalize [#l2 #S #abs @False_ind /2/]
 153 #x #tl #Hind #l2 #a
 154 normalize cases (true_or_false … (a==x)) #eqax >eqax
 155 [<(\P eqax) cases (true_or_false (memb S a (unique_append S tl l2)))
 156   [#H >H normalize // | #H >H normalize >(\b (refl … a)) //]
 157 |cases (memb S x (unique_append S tl l2)) normalize
 158   [/2/ |>eqax normalize /2/]
 159 ]
 160 qed.
 161
 162 lemma sublist_unique_append_l2:
 163   ∀S,l1,l2. sublist S l2 (unique_append S l1 l2).
 164 #S #l1 elim l1 [normalize //] #x #tl #Hind normalize
 165 #l2 #a cases (memb S x (unique_append S tl l2)) normalize
 166 [@Hind | cases (a==x) normalize // @Hind]
 167 qed.
 168
 169 lemma decidable_sublist:∀S,l1,l2.
 170   (sublist S l1 l2) ∨ ¬(sublist S l1 l2).
 171 #S #l1 #l2 elim l1
 172   [%1 #a normalize in ⊢ (%→?); #abs @False_ind /2/
 173   |#a #tl * #subtl
 174     [cases (true_or_false (memb S a l2)) #memba
 175       [%1 whd #x #membx cases (orb_true_l … membx)
 176         [#eqax >(\P eqax) // |@subtl]
 177       |%2 @(not_to_not … (eqnot_to_noteq … true memba)) #H1 @H1 @memb_hd
 178       ]
 179     |%2 @(not_to_not … subtl) #H1 #x #H2 @H1 @memb_cons //
 180     ]
 181   ]
 182 qed.
 183
 184 (********************* filtering *****************)
 185
 186 lemma filter_true: ∀S,f,a,l.
 187   memb S a (filter S f l) = true → f a = true.
 188 #S #f #a #l elim l [normalize #H @False_ind /2/]
 189 #b #tl #Hind cases (true_or_false (f b)) #H
 190 normalize >H normalize [2:@Hind]
 191 cases (true_or_false (a==b)) #eqab
 192   [#_ >(\P eqab) // | >eqab normalize @Hind]
 193 qed.
 194
 195 lemma memb_filter_memb: ∀S,f,a,l.
 196   memb S a (filter S f l) = true → memb S a l = true.
 197 #S #f #a #l elim l [normalize //]
 198 #b #tl #Hind normalize (cases (f b)) normalize
 199 cases (a==b) normalize // @Hind
 200 qed.
 201
 202 lemma memb_filter: ∀S,f,l,x. memb S x (filter ? f l) = true →
 203 memb S x l = true ∧ (f x = true).
 204 /3/ qed.
 205
 206 lemma memb_filter_l: ∀S,f,x,l. (f x = true) → memb S x l = true →
 207 memb S x (filter ? f l) = true.
 208 #S #f #x #l #fx elim l normalize //
 209 #b #tl #Hind cases (true_or_false (x==b)) #eqxb
 210   [<(\P eqxb) >(\b (refl … x)) >fx normalize >(\b (refl … x)) normalize //
 211   |>eqxb cases (f b) normalize [>eqxb normalize @Hind| @Hind]
 212   ]
 213 qed.
 214
 215 (********************* exists *****************)
 216
 217 let rec exists (A:Type[0]) (p:A → bool) (l:list A) on l : bool ≝
 218 match l with
 219 [ nil ⇒ false
 220 | cons h t ⇒ orb (p h) (exists A p t)
 221 ].
 222
 223 lemma Exists_exists : ∀A,P,l.
 224   Exists A P l →
 225   ∃x. P x.
 226 #A #P #l elim l [ * | #hd #tl #IH * [ #H %{hd} @H | @IH ]
 227 qed.