matita/matita/lib/basics/lists/listb.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_______________________________________________________________ *)
  11
  12
  13 (* boolean functions over lists *)
  14
  15 include "basics/lists/list.ma".
  16 include "basics/sets.ma".
  17 include "basics/deqsets.ma".
  18
  19 (********* search *********)
  20
  21 let rec memb (S:DeqSet) (x:S) (l: list S) on l  ≝
  22   match l with
  23   [ nil ⇒ false
  24   | cons a tl ⇒ (a == x) ∨ memb S x tl
  25   ].
  26
  27 notation < "\memb x l" non associative with precedence 90 for @{'memb $x $l}.
  28 interpretation "boolean membership" 'memb a l = (memb ? a l).
  29
  30 lemma memb_hd: ∀S,a,l. memb S a (a::l) = true.
  31 #S #a #l normalize >(proj2 … (eqb_true S …) (refl S a)) //
  32 qed.
  33
  34 lemma memb_cons: ∀S,a,b,l.
  35   memb S a l = true → memb S a (b::l) = true.
  36 #S #a #b #l normalize cases (b==a) normalize //
  37 qed.
  38
  39 lemma memb_append: ∀S,a,l1,l2.
  40 memb S a (l1@l2) = true →
  41   memb S a l1= true ∨ memb S a l2 = true.
  42 #S #a #l1 elim l1 normalize [#l2 #H %2 //]
  43 #b #tl #Hind #l2 cases (b==a) normalize /2/
  44 qed.
  45
  46 lemma memb_append_l1: ∀S,a,l1,l2.
  47  memb S a l1= true → memb S a (l1@l2) = true.
  48 #S #a #l1 elim l1 normalize
  49   [normalize #le #abs @False_ind /2/
  50   |#b #tl #Hind #l2 cases (b==a) normalize /2/
  51   ]
  52 qed.
  53
  54 lemma memb_append_l2: ∀S,a,l1,l2.
  55  memb S a l2= true → memb S a (l1@l2) = true.
  56 #S #a #l1 elim l1 normalize //
  57 #b #tl #Hind #l2 cases (b==a) normalize /2/
  58 qed.
  59
  60 lemma memb_exists: ∀S,a,l.memb S a l = true →
  61   ∃l1,l2.l=l1@(a::l2).
  62 #S #a #l elim l [normalize #abs @False_ind /2/]
  63 #b #tl #Hind #H cases (orb_true_l … H)
  64   [#eqba @(ex_intro … (nil S)) @(ex_intro … tl)
  65    >(proj1 … (eqb_true …) eqba) //
  66   |#mem_tl cases (Hind mem_tl) #l1 * #l2 #eqtl
  67    @(ex_intro … (b::l1)) @(ex_intro … l2) >eqtl //
  68   ]
  69 qed.
  70
  71 lemma not_memb_to_not_eq: ∀S,a,b,l.
  72  memb S a l = false → memb S b l = true → a==b = false.
  73 #S #a #b #l cases (true_or_false (a==b)) //
  74 #eqab >(proj1 … (eqb_true …) eqab) #H >H #abs @False_ind /2/
  75 qed.
  76
  77 lemma memb_map: ∀S1,S2,f,a,l. memb S1 a l= true →
  78   memb S2 (f a) (map … f l) = true.
  79 #S1 #S2 #f #a #l elim l normalize [//]
  80 #x #tl #memba cases (true_or_false (x==a))
  81   [#eqx >eqx >(proj1 … (eqb_true …) eqx)
  82    >(proj2 … (eqb_true …) (refl … (f a))) normalize //
  83   |#eqx >eqx cases (f x==f a) normalize /2/
  84   ]
  85 qed.
  86
  87 lemma memb_compose: ∀S1,S2,S3,op,a1,a2,l1,l2.
  88   memb S1 a1 l1 = true → memb S2 a2 l2 = true →
  89   memb S3 (op a1 a2) (compose S1 S2 S3 op l1 l2) = true.
  90 #S1 #S2 #S3 #op #a1 #a2 #l1 elim l1 [normalize //]
  91 #x #tl #Hind #l2 #memba1 #memba2 cases (orb_true_l … memba1)
  92   [#eqa1 >(proj1 … (eqb_true …) eqa1) @memb_append_l1 @memb_map //
  93   |#membtl @memb_append_l2 @Hind //
  94   ]
  95 qed.
  96
  97 (**************** unicity test *****************)
  98
  99 let rec uniqueb (S:DeqSet) l on l : bool ≝
 100   match l with
 101   [ nil ⇒ true
 102   | cons a tl ⇒ notb (memb S a tl) ∧ uniqueb S tl
 103   ].
 104
 105 (* unique_append l1 l2 add l1 in fornt of l2, but preserving unicity *)
 106
 107 let rec unique_append (S:DeqSet) (l1,l2: list S) on l1 ≝
 108   match l1 with
 109   [ nil ⇒ l2
 110   | cons a tl ⇒
 111      let r ≝ unique_append S tl l2 in
 112      if memb S a r then r else a::r
 113   ].
 114
 115 axiom unique_append_elim: ∀S:DeqSet.∀P: S → Prop.∀l1,l2.
 116 (∀x. memb S x l1 = true → P x) → (∀x. memb S x l2 = true → P x) →
 117 ∀x. memb S x (unique_append S l1 l2) = true → P x.
 118
 119 lemma unique_append_unique: ∀S,l1,l2. uniqueb S l2 = true →
 120   uniqueb S (unique_append S l1 l2) = true.
 121 #S #l1 elim l1 normalize // #a #tl #Hind #l2 #uniquel2
 122 cases (true_or_false … (memb S a (unique_append S tl l2)))
 123 #H >H normalize [@Hind //] >H normalize @Hind //
 124 qed.
 125
 126 (******************* sublist *******************)
 127 definition sublist ≝
 128   λS,l1,l2.∀a. memb S a l1 = true → memb S a l2 = true.
 129
 130 lemma sublist_length: ∀S,l1,l2.
 131  uniqueb S l1 = true → sublist S l1 l2 → |l1| ≤ |l2|.
 132 #S #l1 elim l1 //
 133 #a #tl #Hind #l2 #unique #sub
 134 cut (∃l3,l4.l2=l3@(a::l4)) [@memb_exists @sub //]
 135 * #l3 * #l4 #eql2 >eql2 >length_append normalize
 136 applyS le_S_S <length_append @Hind [@(andb_true_r … unique)]
 137 >eql2 in sub; #sub #x #membx
 138 cases (memb_append … (sub x (orb_true_r2 … membx)))
 139   [#membxl3 @memb_append_l1 //
 140   |#membxal4 cases (orb_true_l … membxal4)
 141     [#eqax @False_ind lapply (andb_true_l … unique)
 142      >(proj1 … (eqb_true …) eqax) >membx normalize /2/
 143     |#membxl4 @memb_append_l2 //
 144     ]
 145   ]
 146 qed.
 147
 148 lemma sublist_unique_append_l1:
 149   ∀S,l1,l2. sublist S l1 (unique_append S l1 l2).
 150 #S #l1 elim l1 normalize [#l2 #S #abs @False_ind /2/]
 151 #x #tl #Hind #l2 #a
 152 normalize cases (true_or_false … (x==a)) #eqxa >eqxa
 153 [>(proj1 … (eqb_true …) eqxa) cases (true_or_false (memb S a (unique_append S tl l2)))
 154   [#H >H normalize // | #H >H normalize >(proj2 … (eqb_true …) (refl … a)) //]
 155 |cases (memb S x (unique_append S tl l2)) normalize
 156   [/2/ |>eqxa normalize /2/]
 157 ]
 158 qed.
 159
 160 lemma sublist_unique_append_l2:
 161   ∀S,l1,l2. sublist S l2 (unique_append S l1 l2).
 162 #S #l1 elim l1 [normalize //] #x #tl #Hind normalize
 163 #l2 #a cases (memb S x (unique_append S tl l2)) normalize
 164 [@Hind | cases (x==a) normalize // @Hind]
 165 qed.
 166
 167 (********************* filtering *****************)
 168
 169 lemma filter_true: ∀S,f,a,l.
 170   memb S a (filter S f l) = true → f a = true.
 171 #S #f #a #l elim l [normalize #H @False_ind /2/]
 172 #b #tl #Hind cases (true_or_false (f b)) #H
 173 normalize >H normalize [2:@Hind]
 174 cases (true_or_false (b==a)) #eqab
 175   [#_ <(proj1 … (eqb_true …) eqab) // | >eqab normalize @Hind]
 176 qed.
 177
 178 lemma memb_filter_memb: ∀S,f,a,l.
 179   memb S a (filter S f l) = true → memb S a l = true.
 180 #S #f #a #l elim l [normalize //]
 181 #b #tl #Hind normalize (cases (f b)) normalize
 182 cases (b==a) normalize // @Hind
 183 qed.
 184
 185 lemma memb_filter: ∀S,f,l,x. memb S x (filter ? f l) = true →
 186 memb S x l = true ∧ (f x = true).
 187 /3/ qed.
 188
 189 lemma memb_filter_l: ∀S,f,x,l. (f x = true) → memb S x l = true →
 190 memb S x (filter ? f l) = true.
 191 #S #f #x #l #fx elim l normalize //
 192 #b #tl #Hind cases (true_or_false (b==x)) #eqbx
 193   [>(proj1 … (eqb_true … ) eqbx) >(proj2 … (eqb_true …) (refl … x))
 194    >fx normalize >(proj2 … (eqb_true …) (refl … x)) normalize //
 195   |>eqbx cases (f b) normalize [>eqbx normalize @Hind| @Hind]
 196   ]
 197 qed.
 198
 199 (********************* exists *****************)
 200
 201 let rec exists (A:Type[0]) (p:A → bool) (l:list A) on l : bool ≝
 202 match l with
 203 [ nil ⇒ false
 204 | cons h t ⇒ orb (p h) (exists A p t)
 205 ].
 206
 207 lemma Exists_exists : ∀A,P,l.
 208   Exists A P l →
 209   ∃x. P x.
 210 #A #P #l elim l [ * | #hd #tl #IH * [ #H %{hd} @H | @IH ]
 211 qed.