matita/matita/lib/basics/star.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "basics/relations.ma".
  13
  14 (* transitive closcure (plus) *)
  15
  16 inductive TC (A:Type[0]) (R:relation A) (a:A): A → Prop ≝
  17   |inj: ∀c. R a c → TC A R a c
  18   |step : ∀b,c.TC A R a b → R b c → TC A R a c.
  19
  20 theorem trans_TC: ∀A,R,a,b,c.
  21   TC A R a b → TC A R b c → TC A R a c.
  22 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
  23 qed.
  24
  25 theorem TC_idem: ∀A,R. exteqR … (TC A R) (TC A (TC A R)).
  26 #A #R #a #b % /2/ #H (elim H) /2/
  27 qed.
  28
  29 lemma monotonic_TC: ∀A,R,S. subR A R S → subR A (TC A R) (TC A S).
  30 #A #R #S #subRS #a #b #H (elim H) /3/
  31 qed.
  32
  33 lemma sub_TC: ∀A,R,S. subR A R (TC A S) → subR A (TC A R) (TC A S).
  34 #A #R #S #Hsub #a #b #H (elim H) /3/
  35 qed.
  36
  37 theorem sub_TC_to_eq: ∀A,R,S. subR A R S → subR A S (TC A R) →
  38   exteqR … (TC A R) (TC A S).
  39 #A #R #S #sub1 #sub2 #a #b % /2/
  40 qed.
  41
  42 theorem TC_inv: ∀A,R. exteqR ?? (TC A (inv A R)) (inv A (TC A R)).
  43 #A #R #a #b %
  44 #H (elim H) /2/ normalize #c #d #H1 #H2 #H3 @(trans_TC … H3) /2/
  45 qed.
  46
  47 (* star *)
  48 inductive star (A:Type[0]) (R:relation A) (a:A): A → Prop ≝
  49   |sstep: ∀b,c.star A R a b → R b c → star A R a c
  50   |srefl: star A R a a.
  51
  52 lemma R_to_star: ∀A,R,a,b. R a b → star A R a b.
  53 #A #R #a #b /2/
  54 qed.
  55
  56 theorem trans_star: ∀A,R,a,b,c.
  57   star A R a b → star A R b c → star A R a c.
  58 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
  59 qed.
  60
  61 theorem star_star: ∀A,R. exteqR … (star A R) (star A (star A R)).
  62 #A #R #a #b % /2/ #H (elim H) /2/
  63 qed.
  64
  65 lemma monotonic_star: ∀A,R,S. subR A R S → subR A (star A R) (star A S).
  66 #A #R #S #subRS #a #b #H (elim H) /3/
  67 qed.
  68
  69 lemma sub_star: ∀A,R,S. subR A R (star A S) →
  70   subR A (star A R) (star A S).
  71 #A #R #S #Hsub #a #b #H (elim H) /3/
  72 qed.
  73
  74 theorem sub_star_to_eq: ∀A,R,S. subR A R S → subR A S (star A R) →
  75   exteqR … (star A R) (star A S).
  76 #A #R #S #sub1 #sub2 #a #b % /2/
  77 qed.
  78
  79 theorem star_inv: ∀A,R.
  80   exteqR ?? (star A (inv A R)) (inv A (star A R)).
  81 #A #R #a #b %
  82 #H (elim H) /2/ normalize #c #d #H1 #H2 #H3 @(trans_star … H3) /2/
  83 qed.
  84
  85 lemma star_decomp_l :
  86   ∀A,R,x,y.star A R x y → x = y ∨ ∃z.R x z ∧ star A R z y.
  87 #A #R #x #y #Hstar elim Hstar
  88 [ #b #c #Hleft #Hright *
  89   [ #H1 %2 @(ex_intro ?? c) % //
  90   | * #x0 * #H1 #H2 %2 @(ex_intro ?? x0) % /2/ ]
  91 | /2/ ]
  92 qed.
  93
  94 (* right associative version of star *)
  95 inductive starl (A:Type[0]) (R:relation A) : A → A → Prop ≝
  96   |sstepl: ∀a,b,c.R a b → starl A R b c → starl A R a c
  97   |refll: ∀a.starl A R a a.
  98
  99 lemma starl_comp : ∀A,R,a,b,c.
 100   starl A R a b → R b c → starl A R a c.
 101 #A #R #a #b #c #Hstar elim Hstar
 102   [#a1 #b1 #c1 #Rab #sbc #Hind #a1 @(sstepl … Rab) @Hind //
 103   |#a1 #Rac @(sstepl … Rac) //
 104   ]
 105 qed.
 106
 107 lemma star_compl : ∀A,R,a,b,c.
 108   R a b → star A R b c → star A R a c.
 109 #A #R #a #b #c #Rab #Hstar elim Hstar
 110   [#b1 #c1 #sbb1 #Rb1c1 #Hind @(sstep … Rb1c1) @Hind
 111   |@(sstep … Rab) //
 112   ]
 113 qed.
 114
 115 lemma star_to_starl: ∀A,R,a,b.star A R a b → starl A R a b.
 116 #A #R #a #b #Hs elim Hs //
 117 #d #c #sad #Rdc #sad @(starl_comp … Rdc) //
 118 qed.
 119
 120 lemma starl_to_star: ∀A,R,a,b.starl A R a b → star A R a b.
 121 #A #R #a #b #Hs elim Hs // -Hs -b -a
 122 #a #b #c #Rab #sbc #sbc @(star_compl … Rab) //
 123 qed.
 124
 125 lemma star_ind_l :
 126   ∀A:Type[0].∀R:relation A.∀Q:A → A → Prop.
 127   (∀a.Q a a) →
 128   (∀a,b,c.R a b → star A R b c → Q b c → Q a c) →
 129   ∀a,b.star A R a b → Q a b.
 130 #A #R #Q #H1 #H2 #a #b #H0
 131 elim (star_to_starl ???? H0) // -H0 -b -a
 132 #a #b #c #Rab #slbc @H2 // @starl_to_star //
 133 qed.
 134
 135 (* RC and star *)
 136
 137 lemma TC_to_star: ∀A,R,a,b.TC A R a b → star A R a b.
 138 #R #A #a #b #TCH (elim TCH) /2/
 139 qed.
 140
 141 lemma star_case: ∀A,R,a,b. star A R a b → a = b ∨ TC A R a b.
 142 #A #R #a #b #H (elim H) /2/ #c #d #star_ac #Rcd * #H1 %2 /2/.
 143 qed.
 144
 145 (* equiv -- smallest equivalence relation containing R *)
 146
 147 inductive equiv (A:Type[0]) (R:relation A) : A → A → Prop ≝
 148   |inje: ∀a,b,c.equiv A R a b → R b c → equiv A R a c
 149   |refle: ∀a,b.equiv A R a b
 150   |syme: ∀a,b.equiv A R a b → equiv A R b a.
 151
 152 theorem trans_equiv: ∀A,R,a,b,c.
 153   equiv A R a b → equiv A R b c → equiv A R a c.
 154 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
 155 qed.
 156
 157 theorem equiv_equiv: ∀A,R. exteqR … (equiv A R) (equiv A (equiv A R)).
 158 #A #R #a #b % /2/
 159 qed.
 160
 161 lemma monotonic_equiv: ∀A,R,S. subR A R S → subR A (equiv A R) (equiv A S).
 162 #A #R #S #subRS #a #b #H (elim H) /3/
 163 qed.
 164
 165 lemma sub_equiv: ∀A,R,S. subR A R (equiv A S) →
 166   subR A (equiv A R) (equiv A S).
 167 #A #R #S #Hsub #a #b #H (elim H) /2/
 168 qed.
 169
 170 theorem sub_equiv_to_eq: ∀A,R,S. subR A R S → subR A S (equiv A R) →
 171   exteqR … (equiv A R) (equiv A S).
 172 #A #R #S #sub1 #sub2 #a #b % /2/
 173 qed.
 174
 175 (* well founded part of a relation *)
 176
 177 inductive WF (A:Type[0]) (R:relation A) : A → Prop ≝
 178   | wf : ∀b.(∀a. R a b → WF A R a) → WF A R b.
 179
 180 lemma WF_antimonotonic: ∀A,R,S. subR A R S →
 181   ∀a. WF A S a → WF A R a.
 182 #A #R #S #subRS #a #HWF (elim HWF) #b
 183 #H #Hind % #c #Rcb @Hind @subRS //
 184 qed.
 185
 186 (* added from lambda_delta *)
 187
 188 lemma TC_strap: ∀A. ∀R:relation A. ∀a1,a,a2.
 189                 R a1 a → TC … R a a2 → TC … R a1 a2.
 190 /3 width=3/ qed.
 191
 192 lemma TC_reflexive: ∀A,R. reflexive A R → reflexive A (TC … R).
 193 /2 width=1/ qed.
 194
 195 lemma TC_star_ind: ∀A,R. reflexive A R → ∀a1. ∀P:predicate A.
 196                    P a1 → (∀a,a2. TC … R a1 a → R a a2 → P a → P a2) →
 197                    ∀a2. TC … R a1 a2 → P a2.
 198 #A #R #H #a1 #P #Ha1 #IHa1 #a2 #Ha12 elim Ha12 -a2 /3 width=4/
 199 qed-.
 200
 201 inductive TC_dx (A:Type[0]) (R:relation A): A → A → Prop ≝
 202   |inj_dx: ∀a,c. R a c → TC_dx A R a c
 203   |step_dx : ∀a,b,c. R a b → TC_dx A R b c → TC_dx A R a c.
 204
 205 lemma TC_dx_strap: ∀A. ∀R: relation A.
 206                    ∀a,b,c. TC_dx A R a b → R b c → TC_dx A R a c.
 207 #A #R #a #b #c #Hab elim Hab -a -b /3 width=3/
 208 qed.
 209
 210 lemma TC_to_TC_dx: ∀A. ∀R: relation A.
 211                    ∀a1,a2. TC … R a1 a2 → TC_dx … R a1 a2.
 212 #A #R #a1 #a2 #Ha12 elim Ha12 -a2 /2 width=3/
 213 qed.
 214
 215 lemma TC_dx_to_TC: ∀A. ∀R: relation A.
 216                    ∀a1,a2. TC_dx … R a1 a2 → TC … R a1 a2.
 217 #A #R #a1 #a2 #Ha12 elim Ha12 -a1 -a2 /2 width=3/
 218 qed.
 219
 220 fact TC_ind_dx_aux: ∀A,R,a2. ∀P:predicate A.
 221                     (∀a1. R a1 a2 → P a1) →
 222                     (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
 223                     ∀a1,a. TC … R a1 a → a = a2 → P a1.
 224 #A #R #a2 #P #H1 #H2 #a1 #a #Ha1
 225 elim (TC_to_TC_dx ???? Ha1) -a1 -a
 226 [ #a #c #Hac #H destruct /2 width=1/
 227 | #a #b #c #Hab #Hbc #IH #H destruct /3 width=4/
 228 ]
 229 qed-.
 230
 231 lemma TC_ind_dx: ∀A,R,a2. ∀P:predicate A.
 232                  (∀a1. R a1 a2 → P a1) →
 233                  (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
 234                  ∀a1. TC … R a1 a2 → P a1.
 235 #A #R #a2 #P #H1 #H2 #a1 #Ha12
 236 @(TC_ind_dx_aux … H1 H2 … Ha12) //
 237 qed-.
 238
 239 lemma TC_symmetric: ∀A,R. symmetric A R → symmetric A (TC … R).
 240 #A #R #HR #x #y #H @(TC_ind_dx ??????? H) -x /3 width=1/ /3 width=3/
 241 qed.
 242
 243 lemma TC_star_ind_dx: ∀A,R. reflexive A R →
 244                       ∀a2. ∀P:predicate A. P a2 →
 245                       (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
 246                       ∀a1. TC … R a1 a2 → P a1.
 247 #A #R #HR #a2 #P #Ha2 #H #a1 #Ha12
 248 @(TC_ind_dx … P ? H … Ha12) /3 width=4/
 249 qed-.
 250
 251 definition Conf3: ∀A,B. relation2 A B → relation A → Prop ≝ λA,B,S,R.
 252                   ∀b,a1. S a1 b → ∀a2. R a1 a2 → S a2 b.
 253
 254 lemma TC_Conf3: ∀A,B,S,R. Conf3 A B S R → Conf3 A B S (TC … R).
 255 #A #B #S #R #HSR #b #a1 #Ha1 #a2 #H elim H -a2 /2 width=3/
 256 qed.
 257
 258 inductive bi_TC (A,B:Type[0]) (R:bi_relation A B) (a:A) (b:B): relation2 A B ≝
 259   |bi_inj : ∀c,d. R a b c d → bi_TC A B R a b c d
 260   |bi_step: ∀c,d,e,f. bi_TC A B R a b c d → R c d e f → bi_TC A B R a b e f.
 261
 262 lemma bi_TC_strap: ∀A,B. ∀R:bi_relation A B. ∀a1,a,a2,b1,b,b2.
 263                    R a1 b1 a b → bi_TC … R a b a2 b2 → bi_TC … R a1 b1 a2 b2.
 264 #A #B #R #a1 #a #a2 #b1 #b #b2 #HR #H elim H -a2 -b2 /2 width=4/ /3 width=4/
 265 qed.
 266
 267 lemma bi_TC_reflexive: ∀A,B,R. bi_reflexive A B R →
 268                        bi_reflexive A B (bi_TC … R).
 269 /2 width=1/ qed.
 270
 271 inductive bi_TC_dx (A,B:Type[0]) (R:bi_relation A B): bi_relation A B ≝
 272   |bi_inj_dx  : ∀a1,a2,b1,b2. R a1 b1 a2 b2 → bi_TC_dx A B R a1 b1 a2 b2
 273   |bi_step_dx : ∀a1,a,a2,b1,b,b2. R a1 b1 a b → bi_TC_dx A B R a b a2 b2 →
 274                 bi_TC_dx A B R a1 b1 a2 b2.
 275
 276 lemma bi_TC_dx_strap: ∀A,B. ∀R: bi_relation A B.
 277                       ∀a1,a,a2,b1,b,b2. bi_TC_dx A B R a1 b1 a b →
 278                       R a b a2 b2 → bi_TC_dx A B R a1 b1 a2 b2.
 279 #A #B #R #a1 #a #a2 #b1 #b #b2 #H1 elim H1 -a -b /3 width=4/
 280 qed.
 281
 282 lemma bi_TC_to_bi_TC_dx: ∀A,B. ∀R: bi_relation A B.
 283                          ∀a1,a2,b1,b2. bi_TC … R a1 b1 a2 b2 →
 284                          bi_TC_dx … R a1 b1 a2 b2.
 285 #A #B #R #a1 #a2 #b1 #b2 #H12 elim H12 -a2 -b2 /2 width=4/
 286 qed.
 287
 288 lemma bi_TC_dx_to_bi_TC: ∀A,B. ∀R: bi_relation A B.
 289                          ∀a1,a2,b1,b2. bi_TC_dx … R a1 b1 a2 b2 →
 290                          bi_TC … R a1 b1 a2 b2.
 291 #A #b #R #a1 #a2 #b1 #b2 #H12 elim H12 -a1 -a2 -b1 -b2 /2 width=4/
 292 qed.
 293
 294 fact bi_TC_ind_dx_aux: ∀A,B,R,a2,b2. ∀P:relation2 A B.
 295                        (∀a1,b1. R a1 b1 a2 b2 → P a1 b1) →
 296                        (∀a1,a,b1,b. R a1 b1 a b → bi_TC … R a b a2 b2 → P a b → P a1 b1) →
 297                        ∀a1,a,b1,b. bi_TC … R a1 b1 a b → a = a2 → b = b2 → P a1 b1.
 298 #A #B #R #a2 #b2 #P #H1 #H2 #a1 #a #b1 #b #H1
 299 elim (bi_TC_to_bi_TC_dx ??????? H1) -a1 -a -b1 -b
 300 [ #a1 #x #b1 #y #H1 #Hx #Hy destruct /2 width=1/
 301 | #a1 #a #x #b1 #b #y #H1 #H #IH #Hx #Hy destruct /3 width=5/
 302 ]
 303 qed-.
 304
 305 lemma bi_TC_ind_dx: ∀A,B,R,a2,b2. ∀P:relation2 A B.
 306                     (∀a1,b1. R a1 b1 a2 b2 → P a1 b1) →
 307                     (∀a1,a,b1,b. R a1 b1 a b → bi_TC … R a b a2 b2 → P a b → P a1 b1) →
 308                     ∀a1,b1. bi_TC … R a1 b1 a2 b2 → P a1 b1.
 309 #A #B #R #a2 #b2 #P #H1 #H2 #a1 #b1 #H12
 310 @(bi_TC_ind_dx_aux ?????? H1 H2 … H12) //
 311 qed-.
 312
 313 lemma bi_TC_symmetric: ∀A,B,R. bi_symmetric A B R →
 314                        bi_symmetric A B (bi_TC … R).
 315 #A #B #R #HR #a1 #a2 #b1 #b2 #H21
 316 @(bi_TC_ind_dx ?????????? H21) -a2 -b2 /3 width=1/ /3 width=4/
 317 qed.
 318
 319 lemma bi_TC_transitive: ∀A,B,R. bi_transitive A B (bi_TC … R).
 320 #A #B #R #a1 #a #b1 #b #H elim H -a -b /2 width=4/ /3 width=4/
 321 qed.
 322
 323 definition bi_Conf3: ∀A,B,C. relation3 A B C → bi_relation A B → Prop ≝ λA,B,C,S,R.
 324                      ∀c,a1,b1. S a1 b1 c → ∀a2,b2. R a1 b1 a2 b2 → S a2 b2 c.
 325
 326 lemma bi_TC_Conf3: ∀A,B,C,S,R. bi_Conf3 A B C S R → bi_Conf3 A B C S (bi_TC … R).
 327 #A #B #C #S #R #HSR #c #a1 #b1 #Hab1 #a2 #b2 #H elim H -a2 -b2 /2 width=4/
 328 qed.
 329
 330 lemma bi_TC_star_ind: ∀A,B,R. bi_reflexive A B R → ∀a1,b1. ∀P:relation2 A B.
 331                       P a1 b1 → (∀a,a2,b,b2. bi_TC … R a1 b1 a b → R a b a2 b2 → P a b → P a2 b2) →
 332                       ∀a2,b2. bi_TC … R a1 b1 a2 b2 → P a2 b2.
 333 #A #B #R #HR #a1 #b1 #P #H1 #IH #a2 #b2 #H12 elim H12 -a2 -b2 /3 width=5/
 334 qed-.
 335
 336 lemma bi_TC_star_ind_dx: ∀A,B,R. bi_reflexive A B R →
 337                          ∀a2,b2. ∀P:relation2 A B. P a2 b2 →
 338                          (∀a1,a,b1,b. R a1 b1 a b → bi_TC … R a b a2 b2 → P a b → P a1 b1) →
 339                          ∀a1,b1. bi_TC … R a1 b1 a2 b2 → P a1 b1.
 340 #A #B #R #HR #a2 #b2 #P #H2 #IH #a1 #b1 #H12
 341 @(bi_TC_ind_dx … P ? IH … H12) /3 width=5/
 342 qed-.
 343
 344 definition bi_star: ∀A,B,R. bi_relation A B ≝ λA,B,R,a1,b1,a2,b2.
 345                     (a1 = a2 ∧ b1 = b2) ∨ bi_TC A B R a1 b1 a2 b2.
 346
 347 lemma bi_star_bi_reflexive: ∀A,B,R. bi_reflexive A B (bi_star … R).
 348 /3 width=1/ qed.
 349
 350 lemma bi_TC_to_bi_star: ∀A,B,R,a1,b1,a2,b2.
 351                         bi_TC A B R a1 b1 a2 b2 → bi_star A B R a1 b1 a2 b2.
 352 /2 width=1/ qed.
 353
 354 lemma bi_R_to_bi_star: ∀A,B,R,a1,b1,a2,b2.
 355                        R a1 b1 a2 b2 → bi_star A B R a1 b1 a2 b2.
 356 /3 width=1/ qed.
 357
 358 lemma bi_star_strap1: ∀A,B,R,a1,a,a2,b1,b,b2. bi_star A B R a1 b1 a b →
 359                       R a b a2 b2 → bi_star A B R a1 b1 a2 b2.
 360 #A #B #R #a1 #a #a2 #b1 #b #b2 *
 361 [ * #H1 #H2 destruct /2 width=1/
 362 | /3 width=4/
 363 ]
 364 qed.
 365
 366 lemma bi_star_strap2: ∀A,B,R,a1,a,a2,b1,b,b2. R a1 b1 a b →
 367                       bi_star A B R a b a2 b2 → bi_star A B R a1 b1 a2 b2.
 368 #A #B #R #a1 #a #a2 #b1 #b #b2 #H *
 369 [ * #H1 #H2 destruct /2 width=1/
 370 | /3 width=4/
 371 ]
 372 qed.
 373
 374 lemma bi_star_to_bi_TC_to_bi_TC: ∀A,B,R,a1,a,a2,b1,b,b2. bi_star A B R a1 b1 a b →
 375                                  bi_TC A B R a b a2 b2 → bi_TC A B R a1 b1 a2 b2.
 376 #A #B #R #a1 #a #a2 #b1 #b #b2 *
 377 [ * #H1 #H2 destruct /2 width=1/
 378 | /2 width=4/
 379 ]
 380 qed.
 381
 382 lemma bi_TC_to_bi_star_to_bi_TC: ∀A,B,R,a1,a,a2,b1,b,b2. bi_TC A B R a1 b1 a b →
 383                                  bi_star A B R a b a2 b2 → bi_TC A B R a1 b1 a2 b2.
 384 #A #B #R #a1 #a #a2 #b1 #b #b2 #H *
 385 [ * #H1 #H2 destruct /2 width=1/
 386 | /2 width=4/
 387 ]
 388 qed.
 389
 390 lemma bi_tansitive_bi_star: ∀A,B,R. bi_transitive A B (bi_star … R).
 391 #A #B #R #a1 #a #b1 #b #H #a2 #b2 *
 392 [ * #H1 #H2 destruct /2 width=1/
 393 | /3 width=4/
 394 ]
 395 qed.
 396
 397 lemma bi_star_ind: ∀A,B,R,a1,b1. ∀P:relation2 A B. P a1 b1 →
 398                    (∀a,a2,b,b2. bi_star … R a1 b1 a b → R a b a2 b2 → P a b → P a2 b2) →
 399                    ∀a2,b2. bi_star … R a1 b1 a2 b2 → P a2 b2.
 400 #A #B #R #a1 #b1 #P #H #IH #a2 #b2 *
 401 [ * #H1 #H2 destruct //
 402 | #H12 elim H12 -a2 -b2 /2 width=5/ -H /3 width=5/
 403 ]
 404 qed-.
 405
 406 lemma bi_star_ind_dx: ∀A,B,R,a2,b2. ∀P:relation2 A B. P a2 b2 →
 407                       (∀a1,a,b1,b. R a1 b1 a b → bi_star … R a b a2 b2 → P a b → P a1 b1) →
 408                       ∀a1,b1. bi_star … R a1 b1 a2 b2 → P a1 b1.
 409 #A #B #R #a2 #b2 #P #H #IH #a1 #b1 *
 410 [ * #H1 #H2 destruct //
 411 | #H12 @(bi_TC_ind_dx ?????????? H12) -a1 -b1 /2 width=5/ -H /3 width=5/
 412 ]
 413 qed-.