matita/matita/lib/basics/star.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "basics/relations.ma".
  13
  14 (********** relations **********)
  15
  16 definition subR ≝ λA.λR,S:relation A.(∀a,b. R a b → S a b).
  17
  18 definition inv ≝ λA.λR:relation A.λa,b.R b a.
  19
  20 (* transitive closcure (plus) *)
  21
  22 inductive TC (A:Type[0]) (R:relation A) (a:A): A → Prop ≝
  23   |inj: ∀c. R a c → TC A R a c
  24   |step : ∀b,c.TC A R a b → R b c → TC A R a c.
  25
  26 theorem trans_TC: ∀A,R,a,b,c.
  27   TC A R a b → TC A R b c → TC A R a c.
  28 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
  29 qed.
  30
  31 theorem TC_idem: ∀A,R. exteqR … (TC A R) (TC A (TC A R)).
  32 #A #R #a #b % /2/ #H (elim H) /2/
  33 qed.
  34
  35 lemma monotonic_TC: ∀A,R,S. subR A R S → subR A (TC A R) (TC A S).
  36 #A #R #S #subRS #a #b #H (elim H) /3/
  37 qed.
  38
  39 lemma sub_TC: ∀A,R,S. subR A R (TC A S) → subR A (TC A R) (TC A S).
  40 #A #R #S #Hsub #a #b #H (elim H) /3/
  41 qed.
  42
  43 theorem sub_TC_to_eq: ∀A,R,S. subR A R S → subR A S (TC A R) →
  44   exteqR … (TC A R) (TC A S).
  45 #A #R #S #sub1 #sub2 #a #b % /2/
  46 qed.
  47
  48 theorem TC_inv: ∀A,R. exteqR ?? (TC A (inv A R)) (inv A (TC A R)).
  49 #A #R #a #b %
  50 #H (elim H) /2/ normalize #c #d #H1 #H2 #H3 @(trans_TC … H3) /2/
  51 qed.
  52
  53 (* star *)
  54 inductive star (A:Type[0]) (R:relation A) (a:A): A → Prop ≝
  55   |inj: ∀b,c.star A R a b → R b c → star A R a c
  56   |refl: star A R a a.
  57
  58 lemma R_to_star: ∀A,R,a,b. R a b → star A R a b.
  59 #A #R #a #b /2/
  60 qed.
  61
  62 theorem trans_star: ∀A,R,a,b,c.
  63   star A R a b → star A R b c → star A R a c.
  64 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
  65 qed.
  66
  67 theorem star_star: ∀A,R. exteqR … (star A R) (star A (star A R)).
  68 #A #R #a #b % /2/ #H (elim H) /2/
  69 qed.
  70
  71 lemma monotonic_star: ∀A,R,S. subR A R S → subR A (star A R) (star A S).
  72 #A #R #S #subRS #a #b #H (elim H) /3/
  73 qed.
  74
  75 lemma sub_star: ∀A,R,S. subR A R (star A S) →
  76   subR A (star A R) (star A S).
  77 #A #R #S #Hsub #a #b #H (elim H) /3/
  78 qed.
  79
  80 theorem sub_star_to_eq: ∀A,R,S. subR A R S → subR A S (star A R) →
  81   exteqR … (star A R) (star A S).
  82 #A #R #S #sub1 #sub2 #a #b % /2/
  83 qed.
  84
  85 theorem star_inv: ∀A,R.
  86   exteqR ?? (star A (inv A R)) (inv A (star A R)).
  87 #A #R #a #b %
  88 #H (elim H) /2/ normalize #c #d #H1 #H2 #H3 @(trans_star … H3) /2/
  89 qed.
  90
  91 (* RC and star *)
  92
  93 lemma TC_to_star: ∀A,R,a,b.TC A R a b → star A R a b.
  94 #R #A #a #b #TCH (elim TCH) /2/
  95 qed.
  96
  97 lemma star_case: ∀A,R,a,b. star A R a b → a = b ∨ TC A R a b.
  98 #A #R #a #b #H (elim H) /2/ #c #d #star_ac #Rcd * #H1 %2 /2/.
  99 qed.
 100
 101 (* equiv -- smallest equivalence relation containing R *)
 102
 103 inductive equiv (A:Type[0]) (R:relation A) : A → A → Prop ≝
 104   |inje: ∀a,b,c.equiv A R a b → R b c → equiv A R a c
 105   |refle: ∀a,b.equiv A R a b
 106   |syme: ∀a,b.equiv A R a b → equiv A R b a.
 107
 108 theorem trans_equiv: ∀A,R,a,b,c.
 109   equiv A R a b → equiv A R b c → equiv A R a c.
 110 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
 111 qed.
 112
 113 theorem equiv_equiv: ∀A,R. exteqR … (equiv A R) (equiv A (equiv A R)).
 114 #A #R #a #b % /2/
 115 qed.
 116
 117 lemma monotonic_equiv: ∀A,R,S. subR A R S → subR A (equiv A R) (equiv A S).
 118 #A #R #S #subRS #a #b #H (elim H) /3/
 119 qed.
 120
 121 lemma sub_equiv: ∀A,R,S. subR A R (equiv A S) →
 122   subR A (equiv A R) (equiv A S).
 123 #A #R #S #Hsub #a #b #H (elim H) /2/
 124 qed.
 125
 126 theorem sub_equiv_to_eq: ∀A,R,S. subR A R S → subR A S (equiv A R) →
 127   exteqR … (equiv A R) (equiv A S).
 128 #A #R #S #sub1 #sub2 #a #b % /2/
 129 qed.
 130
 131 (* well founded part of a relation *)
 132
 133 inductive WF (A:Type[0]) (R:relation A) : A → Prop ≝
 134   | wf : ∀b.(∀a. R a b → WF A R a) → WF A R b.
 135
 136 lemma WF_antimonotonic: ∀A,R,S. subR A R S →
 137   ∀a. WF A S a → WF A R a.
 138 #A #R #S #subRS #a #HWF (elim HWF) #b
 139 #H #Hind % #c #Rcb @Hind @subRS //
 140 qed.
 141
 142 (* added from lambda_delta *)
 143
 144 lemma TC_strap: ∀A. ∀R:relation A. ∀a1,a,a2.
 145                 R a1 a → TC … R a a2 → TC … R a1 a2.
 146 /3 width=3/ qed.
 147
 148 lemma TC_reflexive: ∀A,R. reflexive A R → reflexive A (TC … R).
 149 /2 width=1/ qed.
 150
 151 lemma TC_star_ind: ∀A,R. reflexive A R → ∀a1. ∀P:predicate A.
 152                    P a1 → (∀a,a2. TC … R a1 a → R a a2 → P a → P a2) →
 153                    ∀a2. TC … R a1 a2 → P a2.
 154 #A #R #H #a1 #P #Ha1 #IHa1 #a2 #Ha12 elim Ha12 -a2 /3 width=4/
 155 qed.
 156
 157 inductive TC_dx (A:Type[0]) (R:relation A): A → A → Prop ≝
 158   |inj_dx: ∀a,c. R a c → TC_dx A R a c
 159   |step_dx : ∀a,b,c. R a b → TC_dx A R b c → TC_dx A R a c.
 160
 161 lemma TC_dx_strap: ∀A. ∀R: relation A.
 162                    ∀a,b,c. TC_dx A R a b → R b c → TC_dx A R a c.
 163 #A #R #a #b #c #Hab elim Hab -a -b /3 width=3/
 164 qed.
 165
 166 lemma TC_to_TC_dx: ∀A. ∀R: relation A.
 167                    ∀a1,a2. TC … R a1 a2 → TC_dx … R a1 a2.
 168 #A #R #a1 #a2 #Ha12 elim Ha12 -a2 /2 width=3/
 169 qed.
 170
 171 lemma TC_dx_to_TC: ∀A. ∀R: relation A.
 172                    ∀a1,a2. TC_dx … R a1 a2 → TC … R a1 a2.
 173 #A #R #a1 #a2 #Ha12 elim Ha12 -a1 -a2 /2 width=3/
 174 qed.
 175
 176 fact TC_star_ind_dx_aux: ∀A,R. reflexive A R →
 177                          ∀a2. ∀P:predicate A. P a2 →
 178                          (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
 179                          ∀a1,a. TC … R a1 a → a = a2 → P a1.
 180 #A #R #HR #a2 #P #Ha2 #H #a1 #a #Ha1
 181 elim (TC_to_TC_dx ???? Ha1) -a1 -a
 182 [ #a #c #Hac #H destruct /3 width=4/
 183 | #a #b #c #Hab #Hbc #IH #H destruct /3 width=4/
 184 ]
 185 qed-.
 186
 187 lemma TC_star_ind_dx: ∀A,R. reflexive A R →
 188                       ∀a2. ∀P:predicate A. P a2 →
 189                       (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
 190                       ∀a1. TC … R a1 a2 → P a1.
 191 #A #R #HR #a2 #P #Ha2 #H #a1 #Ha12
 192 @(TC_star_ind_dx_aux … HR … Ha2 H … Ha12) //
 193 qed-.