matita/matita/lib/basics/star.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "basics/relations.ma".
  13
  14 (********** relations **********)
  15
  16 definition subR ≝ λA.λR,S:relation A.(∀a,b. R a b → S a b).
  17
  18 definition inv ≝ λA.λR:relation A.λa,b.R b a.
  19
  20 (* transitive closcure (plus) *)
  21
  22 inductive TC (A:Type[0]) (R:relation A) (a:A): A → Prop ≝
  23   |inj: ∀c. R a c → TC A R a c
  24   |step : ∀b,c.TC A R a b → R b c → TC A R a c.
  25
  26 theorem trans_TC: ∀A,R,a,b,c.
  27   TC A R a b → TC A R b c → TC A R a c.
  28 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
  29 qed.
  30
  31 theorem TC_idem: ∀A,R. exteqR … (TC A R) (TC A (TC A R)).
  32 #A #R #a #b % /2/ #H (elim H) /2/
  33 qed.
  34
  35 lemma monotonic_TC: ∀A,R,S. subR A R S → subR A (TC A R) (TC A S).
  36 #A #R #S #subRS #a #b #H (elim H) /3/
  37 qed.
  38
  39 lemma sub_TC: ∀A,R,S. subR A R (TC A S) → subR A (TC A R) (TC A S).
  40 #A #R #S #Hsub #a #b #H (elim H) /3/
  41 qed.
  42
  43 theorem sub_TC_to_eq: ∀A,R,S. subR A R S → subR A S (TC A R) →
  44   exteqR … (TC A R) (TC A S).
  45 #A #R #S #sub1 #sub2 #a #b % /2/
  46 qed.
  47
  48 theorem TC_inv: ∀A,R. exteqR ?? (TC A (inv A R)) (inv A (TC A R)).
  49 #A #R #a #b %
  50 #H (elim H) /2/ normalize #c #d #H1 #H2 #H3 @(trans_TC … H3) /2/
  51 qed.
  52
  53 (* star *)
  54 inductive star (A:Type[0]) (R:relation A) (a:A): A → Prop ≝
  55   |inj: ∀b,c.star A R a b → R b c → star A R a c
  56   |refl: star A R a a.
  57
  58 lemma R_to_star: ∀A,R,a,b. R a b → star A R a b.
  59 #A #R #a #b /2/
  60 qed.
  61
  62 theorem trans_star: ∀A,R,a,b,c.
  63   star A R a b → star A R b c → star A R a c.
  64 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
  65 qed.
  66
  67 theorem star_star: ∀A,R. exteqR … (star A R) (star A (star A R)).
  68 #A #R #a #b % /2/ #H (elim H) /2/
  69 qed.
  70
  71 lemma monotonic_star: ∀A,R,S. subR A R S → subR A (star A R) (star A S).
  72 #A #R #S #subRS #a #b #H (elim H) /3/
  73 qed.
  74
  75 lemma sub_star: ∀A,R,S. subR A R (star A S) →
  76   subR A (star A R) (star A S).
  77 #A #R #S #Hsub #a #b #H (elim H) /3/
  78 qed.
  79
  80 theorem sub_star_to_eq: ∀A,R,S. subR A R S → subR A S (star A R) →
  81   exteqR … (star A R) (star A S).
  82 #A #R #S #sub1 #sub2 #a #b % /2/
  83 qed.
  84
  85 theorem star_inv: ∀A,R.
  86   exteqR ?? (star A (inv A R)) (inv A (star A R)).
  87 #A #R #a #b %
  88 #H (elim H) /2/ normalize #c #d #H1 #H2 #H3 @(trans_star … H3) /2/
  89 qed.
  90
  91 lemma star_decomp_l :
  92   ∀A,R,x,y.star A R x y → x = y ∨ ∃z.R x z ∧ star A R z y.
  93 #A #R #x #y #Hstar elim Hstar
  94 [ #b #c #Hleft #Hright *
  95   [ #H1 %2 @(ex_intro ?? c) % //
  96   | * #x0 * #H1 #H2 %2 @(ex_intro ?? x0) % /2/ ]
  97 | /2/ ]
  98 qed.
  99
 100 axiom star_ind_l :
 101   ∀A:Type[0].∀R:relation A.∀Q:A → A → Prop.
 102   (∀a.Q a a) →
 103   (∀a,b,c.R a b → star A R b c → Q b c → Q a c) →
 104   ∀x,y.star A R x y → Q x y.
 105 (* #A #R #Q #H1 #H2 #x #y #H0 elim H0
 106 [ #b #c #Hleft #Hright #IH
 107   cases (star_decomp_l ???? Hleft)
 108   [ #Hx @H2 //
 109   | * #z * #H3 #H4 @(H2 … H3) /2/
 110 [
 111 |
 112 generalize in match (λb.H2 x b y); elim H0
 113 [#b #c #Hleft #Hright #H2' #H3 @H3
 114  @(H3 b)
 115  elim H0
 116 [ #b #c #Hleft #Hright #IH //
 117 | *)
 118
 119 (* RC and star *)
 120
 121 lemma TC_to_star: ∀A,R,a,b.TC A R a b → star A R a b.
 122 #R #A #a #b #TCH (elim TCH) /2/
 123 qed.
 124
 125 lemma star_case: ∀A,R,a,b. star A R a b → a = b ∨ TC A R a b.
 126 #A #R #a #b #H (elim H) /2/ #c #d #star_ac #Rcd * #H1 %2 /2/.
 127 qed.
 128
 129 (* equiv -- smallest equivalence relation containing R *)
 130
 131 inductive equiv (A:Type[0]) (R:relation A) : A → A → Prop ≝
 132   |inje: ∀a,b,c.equiv A R a b → R b c → equiv A R a c
 133   |refle: ∀a,b.equiv A R a b
 134   |syme: ∀a,b.equiv A R a b → equiv A R b a.
 135
 136 theorem trans_equiv: ∀A,R,a,b,c.
 137   equiv A R a b → equiv A R b c → equiv A R a c.
 138 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
 139 qed.
 140
 141 theorem equiv_equiv: ∀A,R. exteqR … (equiv A R) (equiv A (equiv A R)).
 142 #A #R #a #b % /2/
 143 qed.
 144
 145 lemma monotonic_equiv: ∀A,R,S. subR A R S → subR A (equiv A R) (equiv A S).
 146 #A #R #S #subRS #a #b #H (elim H) /3/
 147 qed.
 148
 149 lemma sub_equiv: ∀A,R,S. subR A R (equiv A S) →
 150   subR A (equiv A R) (equiv A S).
 151 #A #R #S #Hsub #a #b #H (elim H) /2/
 152 qed.
 153
 154 theorem sub_equiv_to_eq: ∀A,R,S. subR A R S → subR A S (equiv A R) →
 155   exteqR … (equiv A R) (equiv A S).
 156 #A #R #S #sub1 #sub2 #a #b % /2/
 157 qed.
 158
 159 (* well founded part of a relation *)
 160
 161 inductive WF (A:Type[0]) (R:relation A) : A → Prop ≝
 162   | wf : ∀b.(∀a. R a b → WF A R a) → WF A R b.
 163
 164 lemma WF_antimonotonic: ∀A,R,S. subR A R S →
 165   ∀a. WF A S a → WF A R a.
 166 #A #R #S #subRS #a #HWF (elim HWF) #b
 167 #H #Hind % #c #Rcb @Hind @subRS //
 168 qed.
 169
 170 (* added from lambda_delta *)
 171
 172 lemma TC_strap: ∀A. ∀R:relation A. ∀a1,a,a2.
 173                 R a1 a → TC … R a a2 → TC … R a1 a2.
 174 /3 width=3/ qed.
 175
 176 lemma TC_reflexive: ∀A,R. reflexive A R → reflexive A (TC … R).
 177 /2 width=1/ qed.
 178
 179 lemma TC_star_ind: ∀A,R. reflexive A R → ∀a1. ∀P:predicate A.
 180                    P a1 → (∀a,a2. TC … R a1 a → R a a2 → P a → P a2) →
 181                    ∀a2. TC … R a1 a2 → P a2.
 182 #A #R #H #a1 #P #Ha1 #IHa1 #a2 #Ha12 elim Ha12 -a2 /3 width=4/
 183 qed.
 184
 185 inductive TC_dx (A:Type[0]) (R:relation A): A → A → Prop ≝
 186   |inj_dx: ∀a,c. R a c → TC_dx A R a c
 187   |step_dx : ∀a,b,c. R a b → TC_dx A R b c → TC_dx A R a c.
 188
 189 lemma TC_dx_strap: ∀A. ∀R: relation A.
 190                    ∀a,b,c. TC_dx A R a b → R b c → TC_dx A R a c.
 191 #A #R #a #b #c #Hab elim Hab -a -b /3 width=3/
 192 qed.
 193
 194 lemma TC_to_TC_dx: ∀A. ∀R: relation A.
 195                    ∀a1,a2. TC … R a1 a2 → TC_dx … R a1 a2.
 196 #A #R #a1 #a2 #Ha12 elim Ha12 -a2 /2 width=3/
 197 qed.
 198
 199 lemma TC_dx_to_TC: ∀A. ∀R: relation A.
 200                    ∀a1,a2. TC_dx … R a1 a2 → TC … R a1 a2.
 201 #A #R #a1 #a2 #Ha12 elim Ha12 -a1 -a2 /2 width=3/
 202 qed.
 203
 204 fact TC_star_ind_dx_aux: ∀A,R. reflexive A R →
 205                          ∀a2. ∀P:predicate A. P a2 →
 206                          (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
 207                          ∀a1,a. TC … R a1 a → a = a2 → P a1.
 208 #A #R #HR #a2 #P #Ha2 #H #a1 #a #Ha1
 209 elim (TC_to_TC_dx ???? Ha1) -a1 -a
 210 [ #a #c #Hac #H destruct /3 width=4/
 211 | #a #b #c #Hab #Hbc #IH #H destruct /3 width=4/
 212 ]
 213 qed-.
 214
 215 lemma TC_star_ind_dx: ∀A,R. reflexive A R →
 216                       ∀a2. ∀P:predicate A. P a2 →
 217                       (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
 218                       ∀a1. TC … R a1 a2 → P a1.
 219 #A #R #HR #a2 #P #Ha2 #H #a1 #Ha12
 220 @(TC_star_ind_dx_aux … HR … Ha2 H … Ha12) //
 221 qed-.
 222
 223 definition Conf3: ∀A,B. relation2 A B → relation A → Prop ≝ λA,B,S,R.
 224                   ∀b,a1. S a1 b → ∀a2. R a1 a2 → S a2 b.
 225
 226 lemma TC_Conf3: ∀A,B,S,R. Conf3 A B S R → Conf3 A B S (TC … R).
 227 #A #B #S #R #HSR #b #a1 #Ha1 #a2 #H elim H -a2 /2 width=3/
 228 qed.