matita/matita/lib/basics/star.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "basics/relations.ma".
  13
  14 (********** relations **********)
  15
  16 definition subR ≝ λA.λR,S:relation A.(∀a,b. R a b → S a b).
  17
  18 definition inv ≝ λA.λR:relation A.λa,b.R b a.
  19
  20 (* transitive closcure (plus) *)
  21
  22 inductive TC (A:Type[0]) (R:relation A) (a:A): A → Prop ≝
  23   |inj: ∀c. R a c → TC A R a c
  24   |step : ∀b,c.TC A R a b → R b c → TC A R a c.
  25
  26 theorem trans_TC: ∀A,R,a,b,c.
  27   TC A R a b → TC A R b c → TC A R a c.
  28 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
  29 qed.
  30
  31 theorem TC_idem: ∀A,R. exteqR … (TC A R) (TC A (TC A R)).
  32 #A #R #a #b % /2/ #H (elim H) /2/
  33 qed.
  34
  35 lemma monotonic_TC: ∀A,R,S. subR A R S → subR A (TC A R) (TC A S).
  36 #A #R #S #subRS #a #b #H (elim H) /3/
  37 qed.
  38
  39 lemma sub_TC: ∀A,R,S. subR A R (TC A S) → subR A (TC A R) (TC A S).
  40 #A #R #S #Hsub #a #b #H (elim H) /3/
  41 qed.
  42
  43 theorem sub_TC_to_eq: ∀A,R,S. subR A R S → subR A S (TC A R) →
  44   exteqR … (TC A R) (TC A S).
  45 #A #R #S #sub1 #sub2 #a #b % /2/
  46 qed.
  47
  48 theorem TC_inv: ∀A,R. exteqR ?? (TC A (inv A R)) (inv A (TC A R)).
  49 #A #R #a #b %
  50 #H (elim H) /2/ normalize #c #d #H1 #H2 #H3 @(trans_TC … H3) /2/
  51 qed.
  52
  53 (* star *)
  54 inductive star (A:Type[0]) (R:relation A) (a:A): A → Prop ≝
  55   |inj: ∀b,c.star A R a b → R b c → star A R a c
  56   |refl: star A R a a.
  57
  58 lemma R_to_star: ∀A,R,a,b. R a b → star A R a b.
  59 #A #R #a #b /2/
  60 qed.
  61
  62 theorem trans_star: ∀A,R,a,b,c.
  63   star A R a b → star A R b c → star A R a c.
  64 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
  65 qed.
  66
  67 theorem star_star: ∀A,R. exteqR … (star A R) (star A (star A R)).
  68 #A #R #a #b % /2/ #H (elim H) /2/
  69 qed.
  70
  71 lemma monotonic_star: ∀A,R,S. subR A R S → subR A (star A R) (star A S).
  72 #A #R #S #subRS #a #b #H (elim H) /3/
  73 qed.
  74
  75 lemma sub_star: ∀A,R,S. subR A R (star A S) →
  76   subR A (star A R) (star A S).
  77 #A #R #S #Hsub #a #b #H (elim H) /3/
  78 qed.
  79
  80 theorem sub_star_to_eq: ∀A,R,S. subR A R S → subR A S (star A R) →
  81   exteqR … (star A R) (star A S).
  82 #A #R #S #sub1 #sub2 #a #b % /2/
  83 qed.
  84
  85 theorem star_inv: ∀A,R.
  86   exteqR ?? (star A (inv A R)) (inv A (star A R)).
  87 #A #R #a #b %
  88 #H (elim H) /2/ normalize #c #d #H1 #H2 #H3 @(trans_star … H3) /2/
  89 qed.
  90
  91 lemma star_decomp_l :
  92   ∀A,R,x,y.star A R x y → x = y ∨ ∃z.R x z ∧ star A R z y.
  93 #A #R #x #y #Hstar elim Hstar
  94 [ #b #c #Hleft #Hright *
  95   [ #H1 %2 @(ex_intro ?? c) % //
  96   | * #x0 * #H1 #H2 %2 @(ex_intro ?? x0) % /2/ ]
  97 | /2/ ]
  98 qed.
  99
 100 (* right associative version of star *)
 101 inductive starl (A:Type[0]) (R:relation A) : A → A → Prop ≝
 102   |injl: ∀a,b,c.R a b → starl A R b c → starl A R a c
 103   |refll: ∀a.starl A R a a.
 104
 105 lemma starl_comp : ∀A,R,a,b,c.
 106   starl A R a b → R b c → starl A R a c.
 107 #A #R #a #b #c #Hstar elim Hstar
 108   [#a1 #b1 #c1 #Rab #sbc #Hind #a1 @(injl … Rab) @Hind //
 109   |#a1 #Rac @(injl … Rac) //
 110   ]
 111 qed.
 112
 113 lemma star_compl : ∀A,R,a,b,c.
 114   R a b → star A R b c → star A R a c.
 115 #A #R #a #b #c #Rab #Hstar elim Hstar
 116   [#b1 #c1 #sbb1 #Rb1c1 #Hind @(inj … Rb1c1) @Hind
 117   |@(inj … Rab) //
 118   ]
 119 qed.
 120
 121 lemma star_to_starl: ∀A,R,a,b.star A R a b → starl A R a b.
 122 #A #R #a #b #Hs elim Hs //
 123 #d #c #sad #Rdc #sad @(starl_comp … Rdc) //
 124 qed.
 125
 126 lemma starl_to_star: ∀A,R,a,b.starl A R a b → star A R a b.
 127 #A #R #a #b #Hs elim Hs // -Hs -b -a
 128 #a #b #c #Rab #sbc #sbc @(star_compl … Rab) //
 129 qed.
 130
 131 lemma star_ind_l :
 132   ∀A:Type[0].∀R:relation A.∀Q:A → A → Prop.
 133   (∀a.Q a a) →
 134   (∀a,b,c.R a b → star A R b c → Q b c → Q a c) →
 135   ∀a,b.star A R a b → Q a b.
 136 #A #R #Q #H1 #H2 #a #b #H0
 137 elim (star_to_starl ???? H0) // -H0 -b -a
 138 #a #b #c #Rab #slbc @H2 // @starl_to_star //
 139 qed.
 140
 141 (* RC and star *)
 142
 143 lemma TC_to_star: ∀A,R,a,b.TC A R a b → star A R a b.
 144 #R #A #a #b #TCH (elim TCH) /2/
 145 qed.
 146
 147 lemma star_case: ∀A,R,a,b. star A R a b → a = b ∨ TC A R a b.
 148 #A #R #a #b #H (elim H) /2/ #c #d #star_ac #Rcd * #H1 %2 /2/.
 149 qed.
 150
 151 (* equiv -- smallest equivalence relation containing R *)
 152
 153 inductive equiv (A:Type[0]) (R:relation A) : A → A → Prop ≝
 154   |inje: ∀a,b,c.equiv A R a b → R b c → equiv A R a c
 155   |refle: ∀a,b.equiv A R a b
 156   |syme: ∀a,b.equiv A R a b → equiv A R b a.
 157
 158 theorem trans_equiv: ∀A,R,a,b,c.
 159   equiv A R a b → equiv A R b c → equiv A R a c.
 160 #A #R #a #b #c #Hab #Hbc (elim Hbc) /2/
 161 qed.
 162
 163 theorem equiv_equiv: ∀A,R. exteqR … (equiv A R) (equiv A (equiv A R)).
 164 #A #R #a #b % /2/
 165 qed.
 166
 167 lemma monotonic_equiv: ∀A,R,S. subR A R S → subR A (equiv A R) (equiv A S).
 168 #A #R #S #subRS #a #b #H (elim H) /3/
 169 qed.
 170
 171 lemma sub_equiv: ∀A,R,S. subR A R (equiv A S) →
 172   subR A (equiv A R) (equiv A S).
 173 #A #R #S #Hsub #a #b #H (elim H) /2/
 174 qed.
 175
 176 theorem sub_equiv_to_eq: ∀A,R,S. subR A R S → subR A S (equiv A R) →
 177   exteqR … (equiv A R) (equiv A S).
 178 #A #R #S #sub1 #sub2 #a #b % /2/
 179 qed.
 180
 181 (* well founded part of a relation *)
 182
 183 inductive WF (A:Type[0]) (R:relation A) : A → Prop ≝
 184   | wf : ∀b.(∀a. R a b → WF A R a) → WF A R b.
 185
 186 lemma WF_antimonotonic: ∀A,R,S. subR A R S →
 187   ∀a. WF A S a → WF A R a.
 188 #A #R #S #subRS #a #HWF (elim HWF) #b
 189 #H #Hind % #c #Rcb @Hind @subRS //
 190 qed.
 191
 192 (* added from lambda_delta *)
 193
 194 lemma TC_strap: ∀A. ∀R:relation A. ∀a1,a,a2.
 195                 R a1 a → TC … R a a2 → TC … R a1 a2.
 196 /3 width=3/ qed.
 197
 198 lemma TC_reflexive: ∀A,R. reflexive A R → reflexive A (TC … R).
 199 /2 width=1/ qed.
 200
 201 lemma TC_star_ind: ∀A,R. reflexive A R → ∀a1. ∀P:predicate A.
 202                    P a1 → (∀a,a2. TC … R a1 a → R a a2 → P a → P a2) →
 203                    ∀a2. TC … R a1 a2 → P a2.
 204 #A #R #H #a1 #P #Ha1 #IHa1 #a2 #Ha12 elim Ha12 -a2 /3 width=4/
 205 qed.
 206
 207 inductive TC_dx (A:Type[0]) (R:relation A): A → A → Prop ≝
 208   |inj_dx: ∀a,c. R a c → TC_dx A R a c
 209   |step_dx : ∀a,b,c. R a b → TC_dx A R b c → TC_dx A R a c.
 210
 211 lemma TC_dx_strap: ∀A. ∀R: relation A.
 212                    ∀a,b,c. TC_dx A R a b → R b c → TC_dx A R a c.
 213 #A #R #a #b #c #Hab elim Hab -a -b /3 width=3/
 214 qed.
 215
 216 lemma TC_to_TC_dx: ∀A. ∀R: relation A.
 217                    ∀a1,a2. TC … R a1 a2 → TC_dx … R a1 a2.
 218 #A #R #a1 #a2 #Ha12 elim Ha12 -a2 /2 width=3/
 219 qed.
 220
 221 lemma TC_dx_to_TC: ∀A. ∀R: relation A.
 222                    ∀a1,a2. TC_dx … R a1 a2 → TC … R a1 a2.
 223 #A #R #a1 #a2 #Ha12 elim Ha12 -a1 -a2 /2 width=3/
 224 qed.
 225
 226 fact TC_star_ind_dx_aux: ∀A,R. reflexive A R →
 227                          ∀a2. ∀P:predicate A. P a2 →
 228                          (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
 229                          ∀a1,a. TC … R a1 a → a = a2 → P a1.
 230 #A #R #HR #a2 #P #Ha2 #H #a1 #a #Ha1
 231 elim (TC_to_TC_dx ???? Ha1) -a1 -a
 232 [ #a #c #Hac #H destruct /3 width=4/
 233 | #a #b #c #Hab #Hbc #IH #H destruct /3 width=4/
 234 ]
 235 qed-.
 236
 237 lemma TC_star_ind_dx: ∀A,R. reflexive A R →
 238                       ∀a2. ∀P:predicate A. P a2 →
 239                       (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
 240                       ∀a1. TC … R a1 a2 → P a1.
 241 #A #R #HR #a2 #P #Ha2 #H #a1 #Ha12
 242 @(TC_star_ind_dx_aux … HR … Ha2 H … Ha12) //
 243 qed-.
 244
 245 definition Conf3: ∀A,B. relation2 A B → relation A → Prop ≝ λA,B,S,R.
 246                   ∀b,a1. S a1 b → ∀a2. R a1 a2 → S a2 b.
 247
 248 lemma TC_Conf3: ∀A,B,S,R. Conf3 A B S R → Conf3 A B S (TC … R).
 249 #A #B #S #R #HSR #b #a1 #Ha1 #a2 #H elim H -a2 /2 width=3/
 250 qed.