matita/matita/lib/basics/star1.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "basics/star.ma".
  13
  14 (* added from λδ *)
  15
  16 lemma TC_strap: ∀A. ∀R:relation A. ∀a1,a,a2.
  17                 R a1 a → TC … R a a2 → TC … R a1 a2.
  18 /3 width=3/ qed.
  19
  20 lemma TC_reflexive: ∀A,R. reflexive A R → reflexive A (TC … R).
  21 /2 width=1/ qed.
  22
  23 lemma TC_star_ind: ∀A,R. reflexive A R → ∀a1. ∀P:predicate A.
  24                    P a1 → (∀a,a2. TC … R a1 a → R a a2 → P a → P a2) →
  25                    ∀a2. TC … R a1 a2 → P a2.
  26 #A #R #H #a1 #P #Ha1 #IHa1 #a2 #Ha12 elim Ha12 -a2 /3 width=4/
  27 qed-.
  28
  29 inductive TC_dx (A:Type[0]) (R:relation A): A → A → Prop ≝
  30   |inj_dx: ∀a,c. R a c → TC_dx A R a c
  31   |step_dx : ∀a,b,c. R a b → TC_dx A R b c → TC_dx A R a c.
  32
  33 lemma TC_dx_strap: ∀A. ∀R: relation A.
  34                    ∀a,b,c. TC_dx A R a b → R b c → TC_dx A R a c.
  35 #A #R #a #b #c #Hab elim Hab -a -b /3 width=3/
  36 qed.
  37
  38 lemma TC_to_TC_dx: ∀A. ∀R: relation A.
  39                    ∀a1,a2. TC … R a1 a2 → TC_dx … R a1 a2.
  40 #A #R #a1 #a2 #Ha12 elim Ha12 -a2 /2 width=3/
  41 qed.
  42
  43 lemma TC_dx_to_TC: ∀A. ∀R: relation A.
  44                    ∀a1,a2. TC_dx … R a1 a2 → TC … R a1 a2.
  45 #A #R #a1 #a2 #Ha12 elim Ha12 -a1 -a2 /2 width=3/
  46 qed.
  47
  48 fact TC_ind_dx_aux: ∀A,R,a2. ∀P:predicate A.
  49                     (∀a1. R a1 a2 → P a1) →
  50                     (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
  51                     ∀a1,a. TC … R a1 a → a = a2 → P a1.
  52 #A #R #a2 #P #H1 #H2 #a1 #a #Ha1
  53 elim (TC_to_TC_dx ???? Ha1) -a1 -a
  54 [ #a #c #Hac #H destruct /2 width=1/
  55 | #a #b #c #Hab #Hbc #IH #H destruct /3 width=4/
  56 ]
  57 qed-.
  58
  59 lemma TC_ind_dx: ∀A,R,a2. ∀P:predicate A.
  60                  (∀a1. R a1 a2 → P a1) →
  61                  (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
  62                  ∀a1. TC … R a1 a2 → P a1.
  63 #A #R #a2 #P #H1 #H2 #a1 #Ha12
  64 @(TC_ind_dx_aux … H1 H2 … Ha12) //
  65 qed-.
  66
  67 lemma TC_symmetric: ∀A,R. symmetric A R → symmetric A (TC … R).
  68 #A #R #HR #x #y #H @(TC_ind_dx ??????? H) -x /3 width=1/ /3 width=3/
  69 qed.
  70
  71 lemma TC_star_ind_dx: ∀A,R. reflexive A R →
  72                       ∀a2. ∀P:predicate A. P a2 →
  73                       (∀a1,a. R a1 a → TC … R a a2 → P a → P a1) →
  74                       ∀a1. TC … R a1 a2 → P a1.
  75 #A #R #HR #a2 #P #Ha2 #H #a1 #Ha12
  76 @(TC_ind_dx … P ? H … Ha12) /3 width=4/
  77 qed-.
  78
  79 lemma TC_Conf3: ∀A,B,S,R. Conf3 A B S R → Conf3 A B S (TC … R).
  80 #A #B #S #R #HSR #b #a1 #Ha1 #a2 #H elim H -a2 /2 width=3/
  81 qed.
  82
  83 (* ************ confluence of star *****************)
  84
  85 lemma star_strip: ∀A,R. confluent A R →
  86                   ∀a0,a1. star … R a0 a1 → ∀a2. R a0 a2 →
  87                   ∃∃a. R a1 a & star … R a2 a.
  88 #A #R #HR #a0 #a1 #H elim H -a1 /2 width=3/
  89 #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  90 elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  91 elim (HR … Ha1 … Ha0) -a /3 width=5/
  92 qed-.
  93
  94 lemma star_confluent: ∀A,R. confluent A R → confluent A (star … R).
  95 #A #R #HR #a0 #a1 #H elim H -a1 /2 width=3/
  96 #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  97 elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  98 elim (star_strip … HR … Ha0 … Ha1) -a /3 width=5/
  99 qed-.
 100
 101 (* relations on unboxed pairs ***********************************************)
 102
 103 inductive bi_TC (A,B) (R:bi_relation A B) (a:A) (b:B): relation2 A B ≝
 104   |bi_inj : ∀c,d. R a b c d → bi_TC A B R a b c d
 105   |bi_step: ∀c,d,e,f. bi_TC A B R a b c d → R c d e f → bi_TC A B R a b e f.
 106
 107 lemma bi_TC_strap: ∀A,B. ∀R:bi_relation A B. ∀a1,a,a2,b1,b,b2.
 108                    R a1 b1 a b → bi_TC … R a b a2 b2 → bi_TC … R a1 b1 a2 b2.
 109 #A #B #R #a1 #a #a2 #b1 #b #b2 #HR #H elim H -a2 -b2 /2 width=4/ /3 width=4/
 110 qed.
 111
 112 lemma bi_TC_reflexive: ∀A,B,R. bi_reflexive A B R →
 113                        bi_reflexive … (bi_TC … R).
 114 /2 width=1/ qed.
 115
 116 inductive bi_TC_dx (A,B) (R:bi_relation A B): bi_relation A B ≝
 117   |bi_inj_dx  : ∀a1,a2,b1,b2. R a1 b1 a2 b2 → bi_TC_dx A B R a1 b1 a2 b2
 118   |bi_step_dx : ∀a1,a,a2,b1,b,b2. R a1 b1 a b → bi_TC_dx A B R a b a2 b2 →
 119                 bi_TC_dx A B R a1 b1 a2 b2.
 120
 121 lemma bi_TC_dx_strap: ∀A,B. ∀R: bi_relation A B.
 122                       ∀a1,a,a2,b1,b,b2. bi_TC_dx A B R a1 b1 a b →
 123                       R a b a2 b2 → bi_TC_dx A B R a1 b1 a2 b2.
 124 #A #B #R #a1 #a #a2 #b1 #b #b2 #H1 elim H1 -a -b /3 width=4/
 125 qed.
 126
 127 lemma bi_TC_to_bi_TC_dx: ∀A,B. ∀R: bi_relation A B.
 128                          ∀a1,a2,b1,b2. bi_TC … R a1 b1 a2 b2 →
 129                          bi_TC_dx … R a1 b1 a2 b2.
 130 #A #B #R #a1 #a2 #b1 #b2 #H12 elim H12 -a2 -b2 /2 width=4/
 131 qed.
 132
 133 lemma bi_TC_dx_to_bi_TC: ∀A,B. ∀R: bi_relation A B.
 134                          ∀a1,a2,b1,b2. bi_TC_dx … R a1 b1 a2 b2 →
 135                          bi_TC … R a1 b1 a2 b2.
 136 #A #B #R #a1 #a2 #b1 #b2 #H12 elim H12 -a1 -a2 -b1 -b2 /2 width=4/
 137 qed.
 138
 139 fact bi_TC_ind_dx_aux: ∀A,B,R,a2,b2. ∀P:relation2 A B.
 140                        (∀a1,b1. R a1 b1 a2 b2 → P a1 b1) →
 141                        (∀a1,a,b1,b. R a1 b1 a b → bi_TC … R a b a2 b2 → P a b → P a1 b1) →
 142                        ∀a1,a,b1,b. bi_TC … R a1 b1 a b → a = a2 → b = b2 → P a1 b1.
 143 #A #B #R #a2 #b2 #P #H1 #H2 #a1 #a #b1 #b #H1
 144 elim (bi_TC_to_bi_TC_dx … a1 a b1 b H1) -a1 -a -b1 -b
 145 [ #a1 #x #b1 #y #H1 #Hx #Hy destruct /2 width=1/
 146 | #a1 #a #x #b1 #b #y #H1 #H #IH #Hx #Hy destruct /3 width=5/
 147 ]
 148 qed-.
 149
 150 lemma bi_TC_ind_dx: ∀A,B,R,a2,b2. ∀P:relation2 A B.
 151                     (∀a1,b1. R a1 b1 a2 b2 → P a1 b1) →
 152                     (∀a1,a,b1,b. R a1 b1 a b → bi_TC … R a b a2 b2 → P a b → P a1 b1) →
 153                     ∀a1,b1. bi_TC … R a1 b1 a2 b2 → P a1 b1.
 154 #A #B #R #a2 #b2 #P #H1 #H2 #a1 #b1 #H12
 155 @(bi_TC_ind_dx_aux ?????? H1 H2 … H12) //
 156 qed-.
 157
 158 lemma bi_TC_symmetric: ∀A,B,R. bi_symmetric A B R →
 159                        bi_symmetric A B (bi_TC … R).
 160 #A #B #R #HR #a1 #a2 #b1 #b2 #H21
 161 @(bi_TC_ind_dx … a2 b2 H21) -a2 -b2 /3 width=1/ /3 width=4/
 162 qed.
 163
 164 lemma bi_TC_transitive: ∀A,B,R. bi_transitive A B (bi_TC … R).
 165 #A #B #R #a1 #a #b1 #b #H elim H -a -b /2 width=4/ /3 width=4/
 166 qed.
 167
 168 definition bi_Conf3: ∀A,B,C. relation3 A B C → predicate (bi_relation A B) ≝
 169                      λA,B,C,S,R.
 170                      ∀c,a1,b1. S a1 b1 c → ∀a2,b2. R a1 b1 a2 b2 → S a2 b2 c.
 171
 172 lemma bi_TC_Conf3: ∀A,B,C,S,R. bi_Conf3 A B C S R → bi_Conf3 A B C S (bi_TC … R).
 173 #A #B #C #S #R #HSR #c #a1 #b1 #Hab1 #a2 #b2 #H elim H -a2 -b2 /2 width=4/
 174 qed.
 175
 176 lemma bi_TC_star_ind: ∀A,B,R. bi_reflexive A B R → ∀a1,b1. ∀P:relation2 A B.
 177                       P a1 b1 → (∀a,a2,b,b2. bi_TC … R a1 b1 a b → R a b a2 b2 → P a b → P a2 b2) →
 178                       ∀a2,b2. bi_TC … R a1 b1 a2 b2 → P a2 b2.
 179 #A #B #R #HR #a1 #b1 #P #H1 #IH #a2 #b2 #H12 elim H12 -a2 -b2 /3 width=5/
 180 qed-.
 181
 182 lemma bi_TC_star_ind_dx: ∀A,B,R. bi_reflexive A B R →
 183                          ∀a2,b2. ∀P:relation2 A B. P a2 b2 →
 184                          (∀a1,a,b1,b. R a1 b1 a b → bi_TC … R a b a2 b2 → P a b → P a1 b1) →
 185                          ∀a1,b1. bi_TC … R a1 b1 a2 b2 → P a1 b1.
 186 #A #B #R #HR #a2 #b2 #P #H2 #IH #a1 #b1 #H12
 187 @(bi_TC_ind_dx … IH … a1 b1 H12) /3 width=5/
 188 qed-.
 189
 190 definition bi_star: ∀A,B,R. bi_relation A B ≝
 191                     λA,B,R. bi_RC A B (bi_TC … R).
 192
 193 lemma bi_star_bi_reflexive: ∀A,B,R. bi_reflexive A B (bi_star … R).
 194 /2 width=1/ qed.
 195
 196 lemma bi_TC_to_bi_star: ∀A,B,R,a1,b1,a2,b2.
 197                         bi_TC A B R a1 b1 a2 b2 → bi_star A B R a1 b1 a2 b2.
 198 /2 width=1/ qed.
 199
 200 lemma bi_R_to_bi_star: ∀A,B,R,a1,b1,a2,b2.
 201                        R a1 b1 a2 b2 → bi_star A B R a1 b1 a2 b2.
 202 /3 width=1/ qed.
 203
 204 lemma bi_star_strap1: ∀A,B,R,a1,a,a2,b1,b,b2. bi_star A B R a1 b1 a b →
 205                       R a b a2 b2 → bi_star A B R a1 b1 a2 b2.
 206 #A #B #R #a1 #a #a2 #b1 #b #b2 *
 207 [ /3 width=4/
 208 | * #H1 #H2 destruct /2 width=1/
 209 ]
 210 qed.
 211
 212 lemma bi_star_strap2: ∀A,B,R,a1,a,a2,b1,b,b2. R a1 b1 a b →
 213                       bi_star A B R a b a2 b2 → bi_star A B R a1 b1 a2 b2.
 214 #A #B #R #a1 #a #a2 #b1 #b #b2 #H *
 215 [ /3 width=4/
 216 | * #H1 #H2 destruct /2 width=1/
 217 ]
 218 qed.
 219
 220 lemma bi_star_to_bi_TC_to_bi_TC: ∀A,B,R,a1,a,a2,b1,b,b2. bi_star A B R a1 b1 a b →
 221                                  bi_TC A B R a b a2 b2 → bi_TC A B R a1 b1 a2 b2.
 222 #A #B #R #a1 #a #a2 #b1 #b #b2 *
 223 [ /2 width=4/
 224 | * #H1 #H2 destruct /2 width=1/
 225 ]
 226 qed.
 227
 228 lemma bi_TC_to_bi_star_to_bi_TC: ∀A,B,R,a1,a,a2,b1,b,b2. bi_TC A B R a1 b1 a b →
 229                                  bi_star A B R a b a2 b2 → bi_TC A B R a1 b1 a2 b2.
 230 #A #B #R #a1 #a #a2 #b1 #b #b2 #H *
 231 [ /2 width=4/
 232 | * #H1 #H2 destruct /2 width=1/
 233 ]
 234 qed.
 235
 236 lemma bi_tansitive_bi_star: ∀A,B,R. bi_transitive A B (bi_star … R).
 237 #A #B #R #a1 #a #b1 #b #H #a2 #b2 *
 238 [ /3 width=4/
 239 | * #H1 #H2 destruct /2 width=1/
 240 ]
 241 qed.
 242
 243 lemma bi_star_ind: ∀A,B,R,a1,b1. ∀P:relation2 A B. P a1 b1 →
 244                    (∀a,a2,b,b2. bi_star … R a1 b1 a b → R a b a2 b2 → P a b → P a2 b2) →
 245                    ∀a2,b2. bi_star … R a1 b1 a2 b2 → P a2 b2.
 246 #A #B #R #a1 #b1 #P #H #IH #a2 #b2 *
 247 [ #H12 elim H12 -a2 -b2 /2 width=5/ -H /3 width=5/
 248 | * #H1 #H2 destruct //
 249 ]
 250 qed-.
 251
 252 lemma bi_star_ind_dx: ∀A,B,R,a2,b2. ∀P:relation2 A B. P a2 b2 →
 253                       (∀a1,a,b1,b. R a1 b1 a b → bi_star … R a b a2 b2 → P a b → P a1 b1) →
 254                       ∀a1,b1. bi_star … R a1 b1 a2 b2 → P a1 b1.
 255 #A #B #R #a2 #b2 #P #H #IH #a1 #b1 *
 256 [ #H12 @(bi_TC_ind_dx … a1 b1 H12) -a1 -b1 /2 width=5/ -H /3 width=5/
 257 | * #H1 #H2 destruct //
 258 ]
 259 qed-.
 260
 261 (* relations on unboxed triples *********************************************)
 262
 263 inductive tri_TC (A,B,C) (R:tri_relation A B C) (a1:A) (b1:B) (c1:C): relation3 A B C ≝
 264   |tri_inj : ∀a2,b2,c2. R a1 b1 c1 a2 b2 c2 → tri_TC A B C R a1 b1 c1 a2 b2 c2
 265   |tri_step: ∀a,a2,b,b2,c,c2.
 266              tri_TC A B C R a1 b1 c1 a b c → R a b c a2 b2 c2 →
 267              tri_TC A B C R a1 b1 c1 a2 b2 c2.
 268
 269 lemma tri_TC_strap: ∀A,B,C. ∀R:tri_relation A B C. ∀a1,a,a2,b1,b,b2,c1,c,c2.
 270                     R a1 b1 c1 a b c → tri_TC … R a b c a2 b2 c2 →
 271                     tri_TC … R a1 b1 c1 a2 b2 c2.
 272 #A #B #C #R #a1 #a #a2 #b1 #b #b2 #c1 #c #c2 #HR #H elim H -a2 -b2 -c2 /2 width=5/ /3 width=5/
 273 qed.
 274
 275 lemma tri_TC_reflexive: ∀A,B,C,R. tri_reflexive A B C R →
 276                         tri_reflexive … (tri_TC … R).
 277 /2 width=1/ qed.
 278
 279 inductive tri_TC_dx (A,B,C) (R:tri_relation A B C): tri_relation A B C ≝
 280   |tri_inj_dx  : ∀a1,a2,b1,b2,c1,c2. R a1 b1 c1 a2 b2 c2 → tri_TC_dx A B C R a1 b1 c1 a2 b2 c2
 281   |tri_step_dx : ∀a1,a,a2,b1,b,b2,c1,c,c2.
 282                  R a1 b1 c1 a b c → tri_TC_dx A B C R a b c a2 b2 c2 →
 283                  tri_TC_dx A B C R a1 b1 c1 a2 b2 c2.
 284
 285 lemma tri_TC_dx_strap: ∀A,B,C. ∀R: tri_relation A B C.
 286                        ∀a1,a,a2,b1,b,b2,c1,c,c2.
 287                        tri_TC_dx A B C R a1 b1 c1 a b c →
 288                        R a b c a2 b2 c2 → tri_TC_dx A B C R a1 b1 c1 a2 b2 c2.
 289 #A #B #C #R #a1 #a #a2 #b1 #b #b2 #c1 #c #c2 #H1 elim H1 -a -b -c /3 width=5/
 290 qed.
 291
 292 lemma tri_TC_to_tri_TC_dx: ∀A,B,C. ∀R: tri_relation A B C.
 293                            ∀a1,a2,b1,b2,c1,c2. tri_TC … R a1 b1 c1 a2 b2 c2 →
 294                            tri_TC_dx … R a1 b1 c1 a2 b2 c2.
 295 #A #B #C #R #a1 #a2 #b1 #b2 #c1 #c2 #H12 elim H12 -a2 -b2 -c2 /2 width=1/ /2 width=5/
 296 qed.
 297
 298 lemma tri_TC_dx_to_tri_TC: ∀A,B,C. ∀R: tri_relation A B C.
 299                            ∀a1,a2,b1,b2,c1,c2. tri_TC_dx … R a1 b1 c1 a2 b2 c2 →
 300                            tri_TC … R a1 b1 c1 a2 b2 c2.
 301 #A #B #C #R #a1 #a2 #b1 #b2 #c1 #c2 #H12 elim H12 -a1 -a2 -b1 -b2 -c1 -c2
 302 /2 width=1/ /2 width=5/
 303 qed.
 304
 305 fact tri_TC_ind_dx_aux: ∀A,B,C,R,a2,b2,c2. ∀P:relation3 A B C.
 306                         (∀a1,b1,c1. R a1 b1 c1 a2 b2 c2→ P a1 b1 c1) →
 307                         (∀a1,a,b1,b,c1,c. R a1 b1 c1 a b c → tri_TC … R a b c a2 b2 c2 → P a b c → P a1 b1 c1) →
 308                         ∀a1,a,b1,b,c1,c. tri_TC … R a1 b1 c1 a b c → a = a2 → b = b2 → c = c2 → P a1 b1 c1.
 309 #A #B #C #R #a2 #b2 #c2 #P #H1 #H2 #a1 #a #b1 #b #c1 #c #H1
 310 elim (tri_TC_to_tri_TC_dx … a1 a b1 b c1 c H1) -a1 -a -b1 -b -c1 -c
 311 [ #a1 #x #b1 #y #c1 #z #H1 #Hx #Hy #Hz destruct /2 width=1/
 312 | #a1 #a #x #b1 #b #y #c1 #c #z #H1 #H #IH #Hx #Hy #Hz destruct /3 width=6/
 313 ]
 314 qed-.
 315
 316 lemma tri_TC_ind_dx: ∀A,B,C,R,a2,b2,c2. ∀P:relation3 A B C.
 317                      (∀a1,b1,c1. R a1 b1 c1 a2 b2 c2 → P a1 b1 c1) →
 318                      (∀a1,a,b1,b,c1,c. R a1 b1 c1 a b c → tri_TC … R a b c a2 b2 c2 → P a b c → P a1 b1 c1) →
 319                      ∀a1,b1,c1. tri_TC … R a1 b1 c1 a2 b2 c2 → P a1 b1 c1.
 320 #A #B #C #R #a2 #b2 #c2 #P #H1 #H2 #a1 #b1 #c1 #H12
 321 @(tri_TC_ind_dx_aux ???????? H1 H2 … H12) //
 322 qed-.
 323
 324 lemma tri_TC_symmetric: ∀A,B,C,R. tri_symmetric A B C R →
 325                         tri_symmetric … (tri_TC … R).
 326 #A #B #C #R #HR #a1 #a2 #b1 #b2 #c1 #c2 #H21
 327 @(tri_TC_ind_dx … a2 b2 c2 H21) -a2 -b2 -c2 /3 width=1/ /3 width=5/
 328 qed.
 329
 330 lemma tri_TC_transitive: ∀A,B,C,R. tri_transitive A B C (tri_TC … R).
 331 #A #B #C #R #a1 #a #b1 #b #c1 #c #H elim H -a -b -c /2 width=5/ /3 width=5/
 332 qed.
 333
 334 definition tri_Conf4: ∀A,B,C,D. relation4 A B C D → predicate (tri_relation A B C) ≝
 335                       λA,B,C,D,S,R.
 336                       ∀d,a1,b1,c1. S a1 b1 c1 d → ∀a2,b2,c2. R a1 b1 c1 a2 b2 c2 → S a2 b2 c2 d.
 337
 338 lemma tri_TC_Conf4: ∀A,B,C,D,S,R.
 339                     tri_Conf4 A B C D S R → tri_Conf4 A B C D S (tri_TC … R).
 340 #A #B #C #D #S #R #HSR #d #a1 #b1 #c1 #Habc1 #a2 #b2 #c2 #H elim H -a2 -b2 -c2
 341 /2 width=5/
 342 qed.
 343
 344 lemma tri_TC_star_ind: ∀A,B,C,R. tri_reflexive A B C R →
 345                        ∀a1,b1,c1. ∀P:relation3 A B C.
 346                        P a1 b1 c1 → (∀a,a2,b,b2,c,c2. tri_TC … R a1 b1 c1 a b c → R a b c a2 b2 c2 → P a b c → P a2 b2 c2) →
 347                        ∀a2,b2,c2. tri_TC … R a1 b1 c1 a2 b2 c2 → P a2 b2 c2.
 348 #A #B #C #R #HR #a1 #b1 #c1 #P #H1 #IH #a2 #b2 #c2 #H12 elim H12 -a2 -b2 -c2
 349 /2 width=6/ /3 width=6/
 350 qed-.
 351
 352 lemma tri_TC_star_ind_dx: ∀A,B,C,R. tri_reflexive A B C R →
 353                           ∀a2,b2,c2. ∀P:relation3 A B C. P a2 b2 c2 →
 354                           (∀a1,a,b1,b,c1,c. R a1 b1 c1 a b c → tri_TC … R a b c a2 b2 c2 → P a b c → P a1 b1 c1) →
 355                           ∀a1,b1,c1. tri_TC … R a1 b1 c1 a2 b2 c2 → P a1 b1 c1.
 356 #A #B #C #R #HR #a2 #b2 #c2 #P #H2 #IH #a1 #b1 #c1 #H12
 357 @(tri_TC_ind_dx  … IH … a1 b1 c1 H12) /3 width=6/
 358 qed-.