matita/matita/lib/lambda/lift.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda/terms.ma".
  13
  14 (* arguments: k is the depth (starts from 0), p is the height (starts from 0) *)
  15 let rec lift t k p ≝
  16   match t with
  17     [ Sort n ⇒ Sort n
  18     | Rel n ⇒ if_then_else T (leb (S n) k) (Rel n) (Rel (n+p))
  19     | App m n ⇒ App (lift m k p) (lift n k p)
  20     | Lambda m n ⇒ Lambda (lift m k p) (lift n (k+1) p)
  21     | Prod m n ⇒ Prod (lift m k p) (lift n (k+1) p)
  22     | D n ⇒ D (lift n k p)
  23     ].
  24
  25 (*
  26 ndefinition lift ≝ λt.λp.lift_aux t 0 p.
  27
  28 notation "↑ ^ n ( M )" non associative with precedence 40 for @{'Lift O $M}.
  29 notation "↑ _ k ^ n ( M )" non associative with precedence 40 for @{'Lift $n $k $M}.
  30 *)
  31 (* interpretation "Lift" 'Lift n M = (lift M n). *)
  32 interpretation "Lift" 'Lift n k M = (lift M k n).
  33
  34 (*** properties of lift ***)
  35
  36 lemma lift_0: ∀t:T.∀k. lift t k 0 = t.
  37 #t (elim t) normalize // #n #k cases (leb (S n) k) normalize //
  38 qed.
  39
  40 (* nlemma lift_0: ∀t:T. lift t 0 = t.
  41 #t; nelim t; nnormalize; //; nqed. *)
  42
  43 lemma lift_sort: ∀i,k,n. lift (Sort i) k n = Sort i.
  44 // qed.
  45
  46 lemma lift_rel: ∀i,n. lift (Rel i) 0 n = Rel (i+n).
  47 // qed.
  48
  49 lemma lift_rel1: ∀i.lift (Rel i) 0 1 = Rel (S i).
  50 #i (change with (lift (Rel i) 0 1 = Rel (1 + i))) //
  51 qed.
  52
  53 lemma lift_rel_lt : ∀n,k,i. i < k → lift (Rel i) k n = Rel i.
  54 #n #k #i #ltik change with
  55 (if_then_else ? (leb (S i) k) (Rel i) (Rel (i+n)) = Rel i)
  56 >(le_to_leb_true … ltik) //
  57 qed.
  58
  59 lemma lift_rel_ge : ∀n,k,i. k ≤ i → lift (Rel i) k n = Rel (i+n).
  60 #n #k #i #leki change with
  61 (if_then_else ? (leb (S i) k) (Rel i) (Rel (i+n)) = Rel (i+n))
  62 >lt_to_leb_false // @le_S_S //
  63 qed.
  64
  65 lemma lift_lift: ∀t.∀m,j.j ≤ m  → ∀n,k.
  66   lift (lift t k m) (j+k) n = lift t k (m+n).
  67 #t #i #j #h (elim t) normalize // #n #h #k
  68 @(leb_elim (S n) k) #Hnk normalize
  69   [>(le_to_leb_true (S n) (j+k) ?) normalize /2/
  70   |>(lt_to_leb_false (S n+i) (j+k) ?)
  71      normalize // @le_S_S >(commutative_plus j k)
  72      @le_plus // @not_lt_to_le /2/
  73   ]
  74 qed.
  75
  76 lemma lift_lift_up: ∀n,m,t,k,i.
  77   lift (lift t i m) (m+k+i) n = lift (lift t (k+i) n) i m.
  78 #n #m #N (elim N)
  79   [1,3,4,5,6: normalize //
  80   |#p #k #i @(leb_elim i p);
  81     [#leip >lift_rel_ge // @(leb_elim (k+i) p);
  82       [#lekip >lift_rel_ge;
  83         [>lift_rel_ge // >lift_rel_ge // @(transitive_le … leip) //
  84         |>associative_plus >commutative_plus @monotonic_le_plus_l //
  85         ]
  86       |#lefalse (cut (p < k+i)) [@not_le_to_lt //] #ltpki
  87        >lift_rel_lt; [|>associative_plus >commutative_plus @monotonic_lt_plus_r //]
  88        >lift_rel_lt // >lift_rel_ge //
  89       ]
  90     |#lefalse (cut (p < i)) [@not_le_to_lt //] #ltpi
  91      >lift_rel_lt // >lift_rel_lt; [|@(lt_to_le_to_lt … ltpi) //]
  92      >lift_rel_lt; [|@(lt_to_le_to_lt … ltpi) //]
  93      >lift_rel_lt //
  94     ]
  95   ]
  96 qed.
  97
  98 lemma lift_lift_up_sym: ∀n,m,t,k,i.
  99   lift (lift t i m) (m+i+k) n = lift (lift t (i+k) n) i m.
 100 // qed.
 101
 102 lemma lift_lift_up_01: ∀t,k,p. (lift (lift t k p) 0 1 = lift (lift t 0 1) (k+1) p).
 103 #t #k #p <(lift_lift_up_sym ? ? ? ? 0) //
 104 qed.
 105
 106 lemma lift_lift1: ∀t.∀i,j,k.
 107   lift(lift t k j) k i = lift t k (j+i).
 108 /2/ qed.
 109
 110 lemma lift_lift2: ∀t.∀i,j,k.
 111   lift (lift t k j) (j+k) i = lift t k (j+i).
 112 /2/ qed.
 113
 114 (*
 115 nlemma lift_lift: ∀t.∀i,j. lift (lift t j) i = lift t (j+i).
 116 nnormalize; //; nqed. *)
 117
 118 (********************* context lifting ********************)
 119
 120 let rec Lift G p ≝ match G with
 121    [ nil      ⇒ nil …
 122    | cons t F ⇒ cons … (lift t (|F|) p) (Lift F p)
 123    ].
 124
 125 interpretation "Lift (context)" 'Lift p G = (Lift G p).
 126
 127 lemma Lift_cons: ∀k,Gk. k = |Gk| →
 128                  ∀p,t. Lift (t::Gk) p = lift t k p :: Lift Gk p.
 129 #k #Gk #H >H //
 130 qed.
 131
 132 lemma Lift_length: ∀p,G. |Lift G p| = |G|.
 133 #p #G elim G -G; normalize //
 134 qed.