matita/matita/lib/lambda-delta/reduction/tpr_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "lambda-delta/substitution/tps_lift.ma".
  16 include "lambda-delta/reduction/tpr.ma".
  17
  18 (* Relocation properties ****************************************************)
  19
  20 lemma tpr_lift: ∀T1,T2. T1 ⇒ T2 →
  21                 ∀d,e,U1. ↑[d, e] T1 ≡ U1 → ∀U2. ↑[d, e] T2 ≡ U2 → U1 ⇒ U2.
  22 #T1 #T2 #H elim H -H T1 T2
  23 [ #k #d #e #U1 #HU1 #U2 #HU2
  24   lapply (lift_mono … HU1 … HU2) -HU1 #H destruct -U1;
  25   lapply (lift_inv_sort1 … HU2) -HU2 #H destruct -U2 //
  26 | #i #d #e #U1 #HU1 #U2 #HU2
  27   lapply (lift_mono … HU1 … HU2) -HU1 #H destruct -U1;
  28   lapply (lift_inv_lref1 … HU2) * * #Hid #H destruct -U2 //
  29 | #I #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #d #e #X1 #HX1 #X2 #HX2
  30   elim (lift_inv_bind1 … HX1) -HX1 #W1 #U1 #HVW1 #HTU1 #HX1 destruct -X1;
  31   elim (lift_inv_bind1 … HX2) -HX2 #W2 #U2 #HVW2 #HTU2 #HX2 destruct -X2 /3/
  32 | #I #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #d #e #X1 #HX1 #X2 #HX2
  33   elim (lift_inv_flat1 … HX1) -HX1 #W1 #U1 #HVW1 #HTU1 #HX1 destruct -X1;
  34   elim (lift_inv_flat1 … HX2) -HX2 #W2 #U2 #HVW2 #HTU2 #HX2 destruct -X2 /3/
  35 | #V1 #V2 #W #T1 #T2 #_ #_ #IHV12 #IHT12 #d #e #X1 #HX1 #X2 #HX2
  36   elim (lift_inv_flat1 … HX1) -HX1 #V0 #X #HV10 #HX #HX1 destruct -X1;
  37   elim (lift_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT10 #HX destruct -X;
  38   elim (lift_inv_bind1 … HX2) -HX2 #V3 #T3 #HV23 #HT23 #HX2 destruct -X2 /3/
  39 | #V1 #V2 #T1 #T2 #T0 #HV12 #HT12 #HT2 #IHV12 #IHT12 #d #e #X1 #HX1 #X2 #HX2
  40   elim (lift_inv_bind1 … HX1) -HX1 #W1 #U1 #HVW1 #HTU1 #HX1 destruct -X1;
  41   elim (lift_inv_bind1 … HX2) -HX2 #W2 #U0 #HVW2 #HTU0 #HX2 destruct -X2;
  42   elim (lift_total T2 (d + 1) e) #U2 #HTU2
  43   @tpr_delta
  44   [4: @(tps_lift_le … HT2 … HTU2 HTU0 ?) /2/ |1: skip |2: /2/ |3: /2/ ] (**) (*/3. is too slow *)
  45 | #V #V1 #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV12 #IHW12 #IHT12 #d #e #X1 #HX1 #X2 #HX2
  46   elim (lift_inv_flat1 … HX1) -HX1 #V0 #X #HV10 #HX #HX1 destruct -X1;
  47   elim (lift_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT10 #HX destruct -X;
  48   elim (lift_inv_bind1 … HX2) -HX2 #W3 #X #HW23 #HX #HX2 destruct -X2;
  49   elim (lift_inv_flat1 … HX) -HX #V3 #T3 #HV3 #HT23 #HX destruct -X;
  50   elim (lift_trans_ge … HV2 … HV3 ?) -HV2 HV3 V // /3/
  51 | #V #T #T1 #T2 #HT1 #_ #IHT12 #d #e #X #HX #T0 #HT20
  52   elim (lift_inv_bind1 … HX) -HX #V3 #T3 #_ #HT3 #HX destruct -X;
  53   elim (lift_trans_ge … HT1 … HT3 ?) -HT1 HT3 T // /3 width=6/
  54 | #V #T1 #T2 #_ #IHT12 #d #e #X #HX #T #HT2
  55   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #_ #HT0 #HX destruct -X /3/
  56 ]
  57 qed.
  58
  59 lemma tpr_inv_lift: ∀T1,T2. T1 ⇒ T2 →
  60                     ∀d,e,U1. ↑[d, e] U1 ≡ T1 →
  61                     ∃∃U2. ↑[d, e] U2 ≡ T2 & U1 ⇒ U2.
  62 #T1 #T2 #H elim H -H T1 T2
  63 [ #k #d #e #U1 #HU1
  64   lapply (lift_inv_sort2 … HU1) -HU1 #H destruct -U1 /2/
  65 | #i #d #e #U1 #HU1
  66   lapply (lift_inv_lref2 … HU1) -HU1 * * #Hid #H destruct -U1 /3/
  67 | #I #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #d #e #X #HX
  68   elim (lift_inv_bind2 … HX) -HX #V0 #T0 #HV01 #HT01 #HX destruct -X;
  69   elim (IHV12 … HV01) -IHV12 HV01;
  70   elim (IHT12 … HT01) -IHT12 HT01 /3 width=5/
  71 | #I #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #d #e #X #HX
  72   elim (lift_inv_flat2 … HX) -HX #V0 #T0 #HV01 #HT01 #HX destruct -X;
  73   elim (IHV12 … HV01) -IHV12 HV01;
  74   elim (IHT12 … HT01) -IHT12 HT01 /3 width=5/
  75 | #V1 #V2 #W1 #T1 #T2 #_ #_ #IHV12 #IHT12 #d #e #X #HX
  76   elim (lift_inv_flat2 … HX) -HX #V0 #Y #HV01 #HY #HX destruct -X;
  77   elim (lift_inv_bind2 … HY) -HY #W0 #T0 #HW01 #HT01 #HY destruct -Y;
  78   elim (IHV12 … HV01) -IHV12 HV01;
  79   elim (IHT12 … HT01) -IHT12 HT01 /3 width=5/
  80 | #V1 #V2 #T1 #T2 #T0 #_ #_ #HT20 #IHV12 #IHT12 #d #e #X #HX
  81   elim (lift_inv_bind2 … HX) -HX #W1 #U1 #HWV1 #HUT1 #HX destruct -X;
  82   elim (IHV12 … HWV1) -IHV12 HWV1 #W2 #HWV2 #HW12
  83   elim (IHT12 … HUT1) -IHT12 HUT1 #U2 #HUT2 #HU12
  84   elim (tps_inv_lift1_le … HT20 … HUT2 ?) -HT20 HUT2 // [3: /2 width=5/ |2: skip ] #U0 #HU20 #HUT0
  85   @ex2_1_intro  [2: /2/ |1: skip |3: /2/ ] (**) (* /3 width=5/ is slow *)
  86 | #V #V1 #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV12 #IHW12 #IHT12 #d #e #X #HX
  87   elim (lift_inv_flat2 … HX) -HX #V0 #Y #HV01 #HY #HX destruct -X;
  88   elim (lift_inv_bind2 … HY) -HY #W0 #T0 #HW01 #HT01 #HY destruct -Y;
  89   elim (IHV12 … HV01) -IHV12 HV01 #V3 #HV32 #HV03
  90   elim (IHW12 … HW01) -IHW12 HW01 #W3 #HW32 #HW03
  91   elim (IHT12 … HT01) -IHT12 HT01 #T3 #HT32 #HT03
  92   elim (lift_trans_le … HV32 … HV2 ?) -HV32 HV2 V2 // #V2 #HV32 #HV2
  93   @ex2_1_intro [2: /3/ |1: skip |3: /2/ ] (**) (* /4 width=5/ is slow *)
  94 | #V #T #T1 #T2 #HT1 #_ #IHT12 #d #e #X #HX
  95   elim (lift_inv_bind2 … HX) -HX #V0 #T0 #_ #HT0 #H destruct -X;
  96   elim (lift_div_le … HT1 … HT0 ?) -HT1 HT0 T // #T #HT0 #HT1
  97   elim (IHT12 … HT1) -IHT12 HT1 /3 width=5/
  98 | #V #T1 #T2 #_ #IHT12 #d #e #X #HX
  99   elim (lift_inv_flat2 … HX) -HX #V0 #T0 #_ #HT01 #H destruct -X;
 100   elim (IHT12 … HT01) -IHT12 HT01 /3/
 101 ]
 102 qed.