matita/matita/lib/lambda-delta/reduction/tpr_tpr.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/substitution/lift_weight.ma".
  13 include "lambda-delta/substitution/pts_pts.ma".
  14 include "lambda-delta/reduction/tpr_main.ma".
  15 include "lambda-delta/reduction/tpr_pts.ma".
  16
  17 (* CONTEXT-FREE PARALLEL REDUCTION ON TERMS *********************************)
  18
  19 (* Confluence lemmas ********************************************************)
  20
  21 lemma tpr_conf_sort_sort: ∀k. ∃∃X. ⋆k ⇒ X & ⋆k ⇒ X.
  22 /2/ qed.
  23
  24 lemma tpr_conf_lref_lref: ∀i. ∃∃X. #i ⇒ X & #i ⇒ X.
  25 /2/ qed.
  26
  27 lemma tpr_conf_bind_bind:
  28    ∀I,V0,V1,T0,T1,V2,T2. (
  29       ∀X0:term. #X0 < #V0 + #T0 + 1 →
  30       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  31       ∃∃X. X1 ⇒ X & X2 ⇒ X
  32    ) →
  33    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
  34    ∃∃X. 𝕓{I} V1. T1 ⇒ X & 𝕓{I} V2. T2 ⇒ X.
  35 #I #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
  36 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  37 elim (IH … HT01 … HT02) -HT01 HT02 IH /3 width=5/
  38 qed.
  39
  40 lemma tpr_conf_bind_delta:
  41    ∀V0,V1,T0,T1,V2,T2,T. (
  42       ∀X0:term. #X0 < #V0 + #T0 + 1 →
  43       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  44       ∃∃X. X1 ⇒ X & X2 ⇒ X
  45    ) →
  46    V0 ⇒ V1 → V0 ⇒ V2 →
  47    T0 ⇒ T1 → T0 ⇒ T2 → ⋆. 𝕓{Abbr} V2 ⊢ T2 [O,1] ≫ T →
  48    ∃∃X. 𝕓{Abbr} V1. T1 ⇒ X & 𝕓{Abbr} V2. T ⇒ X.
  49 #V0 #V1 #T0 #T1 #V2 #T2 #T #IH #HV01 #HV02 #HT01 #HT02 #HT2
  50 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  51 elim (IH … HT01 … HT02) -HT01 HT02 IH // -V0 T0 #T0 #HT10 #HT20
  52 elim (tpr_pts_bind … HV2 HT20 … HT2) -HT20 HT2 /3 width=5/
  53 qed.
  54
  55 lemma tpr_conf_bind_zeta:
  56    ∀X2,V0,V1,T0,T1,T. (
  57       ∀X0:term. #X0 < #V0 + #T0 +1 →
  58       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  59       ∃∃X. X1 ⇒ X & X2 ⇒ X
  60    ) →
  61    V0 ⇒ V1 → T0 ⇒ T1 → T ⇒ X2 → ↑[O, 1] T ≡ T0 →
  62    ∃∃X. 𝕓{Abbr} V1. T1 ⇒ X & X2 ⇒ X.
  63 #X2 #V0 #V1 #T0 #T1 #T #IH #HV01 #HT01 #HTX2 #HT0
  64 elim (tpr_inv_lift … HT01 … HT0) -HT01 #U #HUT1 #HTU
  65 lapply (tw_lift … HT0) -HT0 #HT0
  66 elim (IH … HTX2 … HTU) -HTX2 HTU IH /3/
  67 qed.
  68
  69 lemma tpr_conf_flat_flat:
  70    ∀I,V0,V1,T0,T1,V2,T2. (
  71       ∀X0:term. #X0 < #V0 + #T0 + 1 →
  72       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  73       ∃∃X. X1 ⇒ X & X2 ⇒ X
  74    ) →
  75    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
  76    ∃∃T0. 𝕗{I} V1. T1 ⇒ T0 & 𝕗{I} V2. T2 ⇒ T0.
  77 #I #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
  78 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  79 elim (IH … HT01 … HT02) -HT01 HT02 /3 width=5/
  80 qed.
  81
  82 lemma tpr_conf_flat_beta:
  83    ∀V0,V1,T1,V2,W0,U0,T2. (
  84       ∀X0:term. #X0 < #V0 + (#W0 + #U0 + 1) + 1 →
  85       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  86       ∃∃X. X1 ⇒ X & X2 ⇒ X
  87    ) →
  88    V0 ⇒ V1 → V0 ⇒ V2 →
  89    U0 ⇒ T2 → 𝕓{Abst} W0. U0 ⇒ T1 →
  90    ∃∃X. 𝕗{Appl} V1. T1 ⇒ X & 𝕓{Abbr} V2. T2 ⇒ X.
  91 #V0 #V1 #T1 #V2 #W0 #U0 #T2 #IH #HV01 #HV02 #HT02 #H
  92 elim (tpr_inv_abst1 … H) -H #W1 #U1 #HW01 #HU01 #H destruct -T1;
  93 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  94 elim (IH … HT02 … HU01) -HT02 HU01 IH /3 width=5/
  95 qed.
  96
  97 lemma tpr_conf_flat_theta:
  98    ∀V0,V1,T1,V2,V,W0,W2,U0,U2. (
  99       ∀X0:term. #X0 < #V0 + (#W0 + #U0 + 1) + 1 →
 100       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 101       ∃∃X. X1 ⇒ X & X2 ⇒ X
 102    ) →
 103    V0 ⇒ V1 → V0 ⇒ V2 → ↑[O,1] V2 ≡ V →
 104    W0 ⇒ W2 → U0 ⇒ U2 →  𝕓{Abbr} W0. U0 ⇒ T1 →
 105    ∃∃X. 𝕗{Appl} V1. T1 ⇒ X & 𝕓{Abbr} W2. 𝕗{Appl} V. U2 ⇒ X.
 106 #V0 #V1 #T1 #V2 #V #W0 #W2 #U0 #U2 #IH #HV01 #HV02 #HV2 #HW02 #HU02 #H
 107 elim (IH … HV01 … HV02) -HV01 HV02 // #VV #HVV1 #HVV2
 108 elim (lift_total VV 0 1) #VVV #HVV
 109 lapply (tpr_lift … HVV2 … HV2 … HVV) #HVVV
 110 elim (tpr_inv_abbr1 … H) -H *
 111 (* case 1: bind *)
 112 [ -HV2 HVV2 #WW #UU #HWW0 #HUU0 #H destruct -T1;
 113   elim (IH … HW02 … HWW0) -HW02 HWW0 // #W #HW2 #HWW
 114   elim (IH … HU02 … HUU0) -HU02 HUU0 IH // #U #HU2 #HUU
 115   @ex2_1_intro [2: @tpr_theta |1:skip |3: @tpr_bind ] /2 width=7/ (**) (* /4 width=7/ is too slow *)
 116 (* case 2: delta *)
 117 | -HV2 HVV2 #WW2 #UU2 #UU #HWW2 #HUU02 #HUU2 #H destruct -T1;
 118   elim (IH … HW02 … HWW2) -HW02 HWW2 // #W #HW02 #HWW2
 119   elim (IH … HU02 … HUU02) -HU02 HUU02 IH // #U #HU2 #HUUU2
 120   elim (tpr_pts_bind … HWW2 HUUU2 … HUU2) -HUU2 HUUU2 #UUU #HUUU2 #HUUU1
 121   @ex2_1_intro
 122   [2: @tpr_theta [6: @HVV |7: @HWW2 |8: @HUUU2 |1,2,3,4: skip | // ]
 123   |1:skip
 124   |3: @tpr_delta [3: @tpr_flat |1: skip ] /2 width=5/
 125   ] (**) (* /5 width=14/ is too slow *)
 126 (* case 3: zeta *)
 127 | -HW02 HVV HVVV #UU1 #HUU10 #HUUT1
 128   elim (tpr_inv_lift … HU02 … HUU10) -HU02 #UU #HUU2 #HUU1
 129   lapply (tw_lift … HUU10) -HUU10 #HUU10
 130   elim (IH … HUUT1 … HUU1) -HUUT1 HUU1 IH // -HUU10 #U #HU2 #HUUU2
 131   @ex2_1_intro
 132   [2: @tpr_flat
 133   |1: skip
 134   |3: @tpr_zeta [2: @lift_flat |1: skip |3: @tpr_flat ]
 135   ] /2 width=5/ (**) (* /5 width=5/ is too slow *)
 136 ]
 137 qed.
 138
 139 lemma tpr_conf_flat_cast:
 140    ∀X2,V0,V1,T0,T1. (
 141       ∀X0:term. #X0 < #V0 + # T0 + 1 →
 142       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 143       ∃∃X. X1 ⇒ X & X2 ⇒ X
 144    ) →
 145    V0 ⇒ V1 → T0 ⇒ T1 → T0 ⇒ X2 →
 146    ∃∃X. 𝕗{Cast} V1. T1 ⇒ X & X2 ⇒ X.
 147 #X2 #V0 #V1 #T0 #T1 #IH #_ #HT01 #HT02
 148 elim (IH … HT01 … HT02) -HT01 HT02 IH /3/
 149 qed.
 150
 151 lemma tpr_conf_beta_beta:
 152    ∀W0:term. ∀V0,V1,T0,T1,V2,T2. (
 153       ∀X0:term. #X0 < #V0 + (#W0 + #T0 + 1) + 1 →
 154       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 155       ∃∃X. X1 ⇒ X & X2 ⇒ X
 156    ) →
 157    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 158    ∃∃X. 𝕓{Abbr} V1. T1 ⇒X & 𝕓{Abbr} V2. T2 ⇒ X.
 159 #W0 #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
 160 elim (IH … HV01 … HV02) -HV01 HV02 //
 161 elim (IH … HT01 … HT02) -HT01 HT02 IH /3 width=5/
 162 qed.
 163
 164 lemma tpr_conf_delta_delta:
 165    ∀V0,V1,T0,T1,TT1,V2,T2,TT2. (
 166       ∀X0:term. #X0 < #V0 +#T0 + 1→
 167       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 168       ∃∃X. X1 ⇒ X & X2 ⇒ X
 169    ) →
 170    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 171    ⋆. 𝕓{Abbr} V1 ⊢ T1 [O, 1] ≫ TT1 →
 172    ⋆. 𝕓{Abbr} V2 ⊢ T2 [O, 1] ≫ TT2 →
 173    ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & 𝕓{Abbr} V2. TT2 ⇒ X.
 174 #V0 #V1 #T0 #T1 #TT1 #V2 #T2 #TT2 #IH #HV01 #HV02 #HT01 #HT02 #HTT1 #HTT2
 175 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 176 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 177 elim (tpr_pts_bind … HV1 HT1 … HTT1) -HT1 HTT1 #U1 #TTU1 #HTU1
 178 elim (tpr_pts_bind … HV2 HT2 … HTT2) -HT2 HTT2 #U2 #TTU2 #HTU2
 179 elim (pts_conf … HTU1 … HTU2) -HTU1 HTU2 #U #HU1 #HU2
 180 @ex2_1_intro [2,3: @tpr_delta |1: skip ] /width=10/ (**) (* /3 width=10/ is too slow *)
 181 qed.
 182
 183 lemma tpr_conf_delta_zeta:
 184    ∀X2,V0,V1,T0,T1,TT1,T2. (
 185       ∀X0:term. #X0 < #V0 +#T0 + 1→
 186       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 187       ∃∃X. X1 ⇒ X & X2 ⇒ X
 188    ) →
 189    V0 ⇒ V1 → T0 ⇒ T1 → ⋆. 𝕓{Abbr} V1 ⊢ T1 [O,1] ≫ TT1 →
 190    T2 ⇒ X2 → ↑[O, 1] T2 ≡ T0 →
 191    ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & X2 ⇒ X.
 192 #X2 #V0 #V1 #T0 #T1 #TT1 #T2 #IH #_ #HT01 #HTT1 #HTX2 #HTT20
 193 elim (tpr_inv_lift … HT01 … HTT20) -HT01 #TT2 #HTT21 #HTT2
 194 lapply (pts_inv_lift1_eq … HTT1 … HTT21) -HTT1 #HTT1 destruct -T1;
 195 lapply (tw_lift … HTT20) -HTT20 #HTT20
 196 elim (IH … HTX2 … HTT2) -HTX2 HTT2 IH /3/
 197 qed.
 198
 199 lemma tpr_conf_theta_theta:
 200    ∀VV1,V0,V1,W0,W1,T0,T1,V2,VV2,W2,T2. (
 201       ∀X0:term. #X0 < #V0 + (#W0 + #T0 + 1) + 1 →
 202       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 203       ∃∃X. X1 ⇒ X & X2 ⇒ X
 204    ) →
 205    V0 ⇒ V1 → V0 ⇒ V2 → W0 ⇒ W1 → W0 ⇒ W2 → T0 ⇒ T1 → T0 ⇒ T2 →
 206    ↑[O, 1] V1 ≡ VV1 → ↑[O, 1] V2 ≡ VV2 →
 207    ∃∃X. 𝕓{Abbr} W1. 𝕗{Appl} VV1. T1 ⇒ X & 𝕓{Abbr} W2. 𝕗{Appl} VV2. T2 ⇒ X.
 208 #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #V2 #VV2 #W2 #T2 #IH #HV01 #HV02 #HW01 #HW02 #HT01 #HT02 #HVV1 #HVV2
 209 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 210 elim (IH … HW01 … HW02) -HW01 HW02 // #W #HW1 #HW2
 211 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 212 elim (lift_total V 0 1) #VV #HVV
 213 lapply (tpr_lift … HV1 … HVV1 … HVV) -HV1 HVV1 #HVV1
 214 lapply (tpr_lift … HV2 … HVV2 … HVV) -HV2 HVV2 HVV #HVV2
 215 @ex2_1_intro [2,3: @tpr_bind |1:skip ] /2 width=5/ (**) (* /4 width=5/ is too slow *)
 216 qed.
 217
 218 lemma tpr_conf_zeta_zeta:
 219    ∀V0:term. ∀X2,TT0,T0,T1,T2. (
 220       ∀X0:term. #X0 < #V0 + #TT0 + 1 →
 221       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 222       ∃∃X. X1 ⇒ X & X2 ⇒ X
 223    ) →
 224    T0 ⇒ T1 → T2 ⇒ X2 →
 225    ↑[O, 1] T0 ≡ TT0 → ↑[O, 1] T2 ≡ TT0 →
 226    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 227 #V0 #X2 #TT0 #T0 #T1 #T2 #IH #HT01 #HTX2 #HTT0 #HTT20
 228 lapply (lift_inj … HTT0 … HTT20) -HTT0 #H destruct -T0;
 229 lapply (tw_lift … HTT20) -HTT20 #HTT20
 230 elim (IH … HT01 … HTX2) -HT01 HTX2 IH /2/
 231 qed.
 232
 233 lemma tpr_conf_tau_tau:
 234    ∀V0,T0:term. ∀X2,T1. (
 235       ∀X0:term. #X0 < #V0 + #T0 + 1 →
 236       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 237       ∃∃X. X1 ⇒ X & X2 ⇒ X
 238    ) →
 239    T0 ⇒ T1 → T0 ⇒ X2 →
 240    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 241 #V0 #T0 #X2 #T1 #IH #HT01 #HT02
 242 elim (IH … HT01 … HT02) -HT01 HT02 IH /2/
 243 qed.
 244
 245 (* Confluence ***************************************************************)
 246
 247 lemma tpr_conf_aux:
 248    ∀Y0:term. (
 249       ∀X0:term. #X0 < #Y0 → ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 250       ∃∃X. X1 ⇒ X & X2 ⇒ X
 251          ) →
 252    ∀X0,X1,X2. X0 ⇒ X1 → X0 ⇒ X2 → X0 = Y0 →
 253    ∃∃X. X1 ⇒ X & X2 ⇒ X.
 254 #Y0 #IH #X0 #X1 #X2 * -X0 X1
 255 [ #k1 #H1 #H2 destruct -Y0;
 256   lapply (tpr_inv_sort1 … H1) -H1
 257 (* case 1: sort, sort *)
 258   #H1 destruct -X2 //
 259 | #i1 #H1 #H2 destruct -Y0;
 260   lapply (tpr_inv_lref1 … H1) -H1
 261 (* case 2: lref, lref *)
 262   #H1 destruct -X2 //
 263 | #I #V0 #V1 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 264   elim (tpr_inv_bind1 … H1) -H1 *
 265 (* case 3: bind, bind *)
 266   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 267     /3 width=7 by tpr_conf_bind_bind/ (**) (* /3 width=7/ is too slow *)
 268 (* case 4: bind, delta *)
 269   | #V2 #T2 #T #HV02 #HT02 #HT2 #H1 #H2 destruct -X2 I
 270     /3 width=9 by tpr_conf_bind_delta/ (**) (* /3 width=9/ is too slow *)
 271 (* case 5: bind, zeta *)
 272   | #T #HT0 #HTX2 #H destruct -I
 273     /3 width=8 by tpr_conf_bind_zeta/ (**) (* /3 width=8/ is too slow *)
 274   ]
 275 | #I #V0 #V1 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 276   elim (tpr_inv_flat1 … H1) -H1 *
 277 (* case 6: flat, flat *)
 278   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 279     /3 width=7 by tpr_conf_flat_flat/ (**) (* /3 width=7/ is too slow *)
 280 (* case 7: flat, beta *)
 281   | #V2 #W #U0 #T2 #HV02 #HT02 #H1 #H2 #H3 destruct -T0 X2 I
 282     /3 width=8 by tpr_conf_flat_beta/ (**) (* /3 width=8/ is too slow *)
 283 (* case 8: flat, theta *)
 284   | #V2 #V #W0 #W2 #U0 #U2 #HV02 #HW02 #HT02 #HV2 #H1 #H2 #H3 destruct -T0 X2 I
 285     /3 width=11 by tpr_conf_flat_theta/ (**) (* /3 width=11/ is too slow *)
 286 (* case 9: flat, tau *)
 287   | #HT02 #H destruct -I
 288     /3 width=6 by tpr_conf_flat_cast/ (**) (* /3 width=6/ is too slow *)
 289   ]
 290 | #V0 #V1 #W0 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 291   elim (tpr_inv_appl1 … H1) -H1 *
 292 (* case 10: beta, flat (repeated) *)
 293   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 294     @ex2_1_comm /3 width=8 by tpr_conf_flat_beta/
 295 (* case 11: beta, beta *)
 296   | #V2 #WW0 #TT0 #T2 #HV02 #HT02 #H1 #H2 destruct -W0 T0 X2
 297     /3 width=8 by tpr_conf_beta_beta/ (**) (* /3 width=8/ is too slow *)
 298 (* case 12, beta, theta (excluded) *)
 299   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #_ #_ #_ #_ #H destruct
 300   ]
 301 | #V0 #V1 #T0 #T1 #TT1 #HV01 #HT01 #HTT1 #H1 #H2 destruct -Y0;
 302   elim (tpr_inv_abbr1 … H1) -H1 *
 303 (* case 13: delta, bind (repeated) *)
 304   [ #V2 #T2 #HV02 #T02 #H destruct -X2
 305     @ex2_1_comm /3 width=9 by tpr_conf_bind_delta/
 306 (* case 14: delta, delta *)
 307   | #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 308     /3 width=11 by tpr_conf_delta_delta/ (**) (* /3 width=11/ is too slow *)
 309 (* case 15: delta, zata *)
 310   | #T2 #HT20 #HTX2
 311     /3 width=10 by tpr_conf_delta_zeta/ (**) (* /3 width=10/ is too slow *)
 312   ]
 313 | #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #HV01 #HVV1 #HW01 #HT01 #H1 #H2 destruct -Y0;
 314   elim (tpr_inv_appl1 … H1) -H1 *
 315 (* case 16: theta, flat (repeated) *)
 316   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 317     @ex2_1_comm /3 width=11 by tpr_conf_flat_theta/
 318 (* case 17: theta, beta (repeated) *)
 319   | #V2 #WW0 #TT0 #T2 #_ #_ #H destruct
 320 (* case 18: theta, theta *)
 321   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #V02 #HW02 #HT02 #HVV2 #H1 #H2 destruct -W0 T0 X2
 322     /3 width=14 by tpr_conf_theta_theta/  (**) (* /3 width=14/ is too slow *)
 323   ]
 324 | #V0 #TT0 #T0 #T1 #HTT0 #HT01 #H1 #H2 destruct -Y0;
 325   elim (tpr_inv_abbr1 … H1) -H1 *
 326 (* case 19: zeta, bind (repeated) *)
 327   [ #V2 #T2 #HV02 #T02 #H destruct -X2
 328     @ex2_1_comm /3 width=8 by tpr_conf_bind_zeta/
 329 (* case 20: zeta, delta (repeated) *)
 330   | #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 331     @ex2_1_comm /3 width=10 by tpr_conf_delta_zeta/
 332 (* case 21: zeta, zeta *)
 333   | #T2 #HTT20 #HTX2
 334     /3 width=9 by tpr_conf_zeta_zeta/ (**) (* /3 width=9/ is too slow *)
 335   ]
 336 | #V0 #T0 #T1 #HT01 #H1 #H2 destruct -Y0;
 337   elim (tpr_inv_cast1 … H1) -H1
 338 (* case 22: tau, flat (repeated) *)
 339   [ * #V2 #T2 #HV02 #HT02 #H destruct -X2
 340     @ex2_1_comm /3 width=6 by tpr_conf_flat_cast/
 341 (* case 23: tau, tau *)
 342   | #HT02
 343     /2 by tpr_conf_tau_tau/
 344   ]
 345 ]
 346 qed.
 347
 348 theorem tpr_conf: ∀T0:term. ∀T1,T2. T0 ⇒ T1 → T0 ⇒ T2 →
 349                   ∃∃T. T1 ⇒ T & T2 ⇒ T.
 350 #T @(tw_wf_ind … T) -T /3 width=6 by tpr_conf_aux/
 351 qed.