matita/matita/lib/lambda-delta/reduction/tpr_tpr.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/substitution/lift_fun.ma".
  13 include "lambda-delta/substitution/lift_weight.ma".
  14 include "lambda-delta/substitution/ps_ps.ma".
  15 include "lambda-delta/reduction/tpr_main.ma".
  16 include "lambda-delta/reduction/tpr_ps.ma".
  17
  18 lemma ps_inv_lift_eq: ∀L,U1,U2,d,e.
  19                       L ⊢ U1 [d, e] ≫ U2 → ∀T1. ↑[d, e] T1 ≡ U1 → U1 = U2.
  20 #L #U1 #U2 #d #e #H elim H -H L U1 U2 d e
  21 [ //
  22 | //
  23 | #L #K #V #U1 #U2 #i #d #e #Hdi #Hide #_ #_ #_ #_ #T1 #H
  24   elim (lift_inv_lref2 … H) -H * #H
  25   [ lapply (le_to_lt_to_lt … Hdi … H) -Hdi H #H
  26     elim (lt_refl_false … H)
  27   | lapply (lt_to_le_to_lt … Hide … H) -Hide H #H
  28     elim (lt_refl_false … H)
  29   ]
  30 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  31   elim (lift_inv_bind2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
  32   >IHV12 // >IHT12 //
  33 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  34   elim (lift_inv_flat2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
  35   >IHV12 // >IHT12 //
  36 ]
  37 qed.
  38
  39 (* CONTEXT-FREE PARALLEL REDUCTION ON TERMS *********************************)
  40
  41 (* Confluence lemmas ********************************************************)
  42
  43 lemma tpr_conf_sort_sort: ∀k. ∃∃X. ⋆k ⇒ X & ⋆k ⇒ X.
  44 /2/ qed.
  45
  46 lemma tpr_conf_lref_lref: ∀i. ∃∃X. #i ⇒ X & #i ⇒ X.
  47 /2/ qed.
  48
  49 lemma tpr_conf_bind_bind:
  50    ∀I,V0,V1,T0,T1,V2,T2. (
  51       ∀X0:term. #X0 < #V0 + #T0 + 1 →
  52       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  53       ∃∃X. X1 ⇒ X & X2 ⇒ X
  54    ) →
  55    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
  56    ∃∃X. 𝕓{I} V1. T1 ⇒ X & 𝕓{I} V2. T2 ⇒ X.
  57 #I #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
  58 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  59 elim (IH … HT01 … HT02) -HT01 HT02 IH /3 width=5/
  60 qed.
  61
  62 lemma tpr_conf_bind_delta:
  63    ∀V0,V1,T0,T1,V2,T2,T. (
  64       ∀X0:term. #X0 < #V0 + #T0 + 1 →
  65       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  66       ∃∃X. X1 ⇒ X & X2 ⇒ X
  67    ) →
  68    V0 ⇒ V1 → V0 ⇒ V2 →
  69    T0 ⇒ T1 → T0 ⇒ T2 → ⋆. 𝕓{Abbr} V2 ⊢ T2 [O,1] ≫ T →
  70    ∃∃X. 𝕓{Abbr} V1. T1 ⇒ X & 𝕓{Abbr} V2. T ⇒ X.
  71 #V0 #V1 #T0 #T1 #V2 #T2 #T #IH #HV01 #HV02 #HT01 #HT02 #HT2
  72 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  73 elim (IH … HT01 … HT02) -HT01 HT02 IH // -V0 T0 #T0 #HT10 #HT20
  74 elim (tpr_ps_bind … HV2 HT20 … HT2) -HT20 HT2 /3 width=5/
  75 qed.
  76
  77 lemma tpr_conf_bind_zeta:
  78    ∀X2,V0,V1,T0,T1,T. (
  79       ∀X0:term. #X0 < #V0 + #T0 +1 →
  80       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  81       ∃∃X. X1 ⇒ X & X2 ⇒ X
  82    ) →
  83    V0 ⇒ V1 → T0 ⇒ T1 → T ⇒ X2 → ↑[O, 1] T ≡ T0 →
  84    ∃∃X. 𝕓{Abbr} V1. T1 ⇒ X & X2 ⇒ X.
  85 #X2 #V0 #V1 #T0 #T1 #T #IH #HV01 #HT01 #HTX2 #HT0
  86 elim (tpr_inv_lift … HT01 … HT0) -HT01 #U #HUT1 #HTU
  87 lapply (tw_lift … HT0) -HT0 #HT0
  88 elim (IH … HTX2 … HTU) -HTX2 HTU IH /3/
  89 qed.
  90
  91 lemma tpr_conf_flat_flat:
  92    ∀I,V0,V1,T0,T1,V2,T2. (
  93       ∀X0:term. #X0 < #V0 + #T0 + 1 →
  94       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  95       ∃∃X. X1 ⇒ X & X2 ⇒ X
  96    ) →
  97    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
  98    ∃∃T0. 𝕗{I} V1. T1 ⇒ T0 & 𝕗{I} V2. T2 ⇒ T0.
  99 #I #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
 100 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 101 elim (IH … HT01 … HT02) -HT01 HT02 /3 width=5/
 102 qed.
 103
 104 lemma tpr_conf_flat_beta:
 105    ∀V0,V1,T1,V2,W0,U0,T2. (
 106       ∀X0:term. #X0 < #V0 + (#W0 + #U0 + 1) + 1 →
 107       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 108       ∃∃X. X1 ⇒ X & X2 ⇒ X
 109    ) →
 110    V0 ⇒ V1 → V0 ⇒ V2 →
 111    U0 ⇒ T2 → 𝕓{Abst} W0. U0 ⇒ T1 →
 112    ∃∃X. 𝕗{Appl} V1. T1 ⇒ X & 𝕓{Abbr} V2. T2 ⇒ X.
 113 #V0 #V1 #T1 #V2 #W0 #U0 #T2 #IH #HV01 #HV02 #HT02 #H
 114 elim (tpr_inv_abst1 … H) -H #W1 #U1 #HW01 #HU01 #H destruct -T1;
 115 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 116 elim (IH … HT02 … HU01) -HT02 HU01 IH /3 width=5/
 117 qed.
 118
 119 lemma tpr_conf_flat_theta:
 120    ∀V0,V1,T1,V2,V,W0,W2,U0,U2. (
 121       ∀X0:term. #X0 < #V0 + (#W0 + #U0 + 1) + 1 →
 122       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 123       ∃∃X. X1 ⇒ X & X2 ⇒ X
 124    ) →
 125    V0 ⇒ V1 → V0 ⇒ V2 → ↑[O,1] V2 ≡ V →
 126    W0 ⇒ W2 → U0 ⇒ U2 →  𝕓{Abbr} W0. U0 ⇒ T1 →
 127    ∃∃X. 𝕗{Appl} V1. T1 ⇒ X & 𝕓{Abbr} W2. 𝕗{Appl} V. U2 ⇒ X.
 128 #V0 #V1 #T1 #V2 #V #W0 #W2 #U0 #U2 #IH #HV01 #HV02 #HV2 #HW02 #HU02 #H
 129 elim (IH … HV01 … HV02) -HV01 HV02 // #VV #HVV1 #HVV2
 130 elim (lift_total VV 0 1) #VVV #HVV
 131 lapply (tpr_lift … HVV2 … HV2 … HVV) #HVVV
 132 elim (tpr_inv_abbr1 … H) -H *
 133 (* case 1: bind *)
 134 [ -HV2 HVV2 #WW #UU #HWW0 #HUU0 #H destruct -T1;
 135   elim (IH … HW02 … HWW0) -HW02 HWW0 // #W #HW2 #HWW
 136   elim (IH … HU02 … HUU0) -HU02 HUU0 IH // #U #HU2 #HUU
 137   @ex2_1_intro [2: @tpr_theta |1:skip |3: @tpr_bind ] /2 width=7/ (**) (* /4 width=7/ is too slow *)
 138 (* case 2: delta *)
 139 | -HV2 HVV2 #WW2 #UU2 #UU #HWW2 #HUU02 #HUU2 #H destruct -T1;
 140   elim (IH … HW02 … HWW2) -HW02 HWW2 // #W #HW02 #HWW2
 141   elim (IH … HU02 … HUU02) -HU02 HUU02 IH // #U #HU2 #HUUU2
 142   elim (tpr_ps_bind … HWW2 HUUU2 … HUU2) -HUU2 HUUU2 #UUU #HUUU2 #HUUU1
 143   @ex2_1_intro
 144   [2: @tpr_theta
 145   |1:skip
 146   |3: @tpr_delta [3: @tpr_flat |1: skip ]
 147   ] /2 width=14/ (**) (* /5 width=14/ is too slow *)
 148 (* case 3: zeta *)
 149 | -HW02 HVV HVVV #UU1 #HUU10 #HUUT1
 150   elim (tpr_inv_lift … HU02 … HUU10) -HU02 #UU #HUU2 #HUU1
 151   lapply (tw_lift … HUU10) -HUU10 #HUU10
 152   elim (IH … HUUT1 … HUU1) -HUUT1 HUU1 IH // -HUU10 #U #HU2 #HUUU2
 153   @ex2_1_intro
 154   [2: @tpr_flat
 155   |1: skip
 156   |3: @tpr_zeta [2: @lift_flat |1: skip |3: @tpr_flat ]
 157   ] /2 width=5/ (**) (* /5 width=5/ is too slow *)
 158 ]
 159 qed.
 160
 161 lemma tpr_conf_flat_cast:
 162    ∀X2,V0,V1,T0,T1. (
 163       ∀X0:term. #X0 < #V0 + # T0 + 1 →
 164       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 165       ∃∃X. X1 ⇒ X & X2 ⇒ X
 166    ) →
 167    V0 ⇒ V1 → T0 ⇒ T1 → T0 ⇒ X2 →
 168    ∃∃X. 𝕗{Cast} V1. T1 ⇒ X & X2 ⇒ X.
 169 #X2 #V0 #V1 #T0 #T1 #IH #_ #HT01 #HT02
 170 elim (IH … HT01 … HT02) -HT01 HT02 IH /3/
 171 qed.
 172
 173 lemma tpr_conf_beta_beta:
 174    ∀W0:term. ∀V0,V1,T0,T1,V2,T2. (
 175       ∀X0:term. #X0 < #V0 + (#W0 + #T0 + 1) + 1 →
 176       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 177       ∃∃X. X1 ⇒ X & X2 ⇒ X
 178    ) →
 179    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 180    ∃∃X. 𝕓{Abbr} V1. T1 ⇒X & 𝕓{Abbr} V2. T2 ⇒ X.
 181 #W0 #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
 182 elim (IH … HV01 … HV02) -HV01 HV02 //
 183 elim (IH … HT01 … HT02) -HT01 HT02 IH /3 width=5/
 184 qed.
 185
 186 lemma tpr_conf_delta_delta:
 187    ∀V0,V1,T0,T1,TT1,V2,T2,TT2. (
 188       ∀X0:term. #X0 < #V0 +#T0 + 1→
 189       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 190       ∃∃X. X1 ⇒ X & X2 ⇒ X
 191    ) →
 192    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 193    ⋆. 𝕓{Abbr} V1 ⊢ T1 [O, 1] ≫ TT1 →
 194    ⋆. 𝕓{Abbr} V2 ⊢ T2 [O, 1] ≫ TT2 →
 195    ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & 𝕓{Abbr} V2. TT2 ⇒ X.
 196 #V0 #V1 #T0 #T1 #TT1 #V2 #T2 #TT2 #IH #HV01 #HV02 #HT01 #HT02 #HTT1 #HTT2
 197 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 198 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 199 elim (tpr_ps_bind … HV1 HT1 … HTT1) -HT1 HTT1 #U1 #TTU1 #HTU1
 200 elim (tpr_ps_bind … HV2 HT2 … HTT2) -HT2 HTT2 #U2 #TTU2 #HTU2
 201 elim (ps_conf … HTU1 … HTU2) -HTU1 HTU2 #U #HU1 #HU2
 202 @ex2_1_intro [2,3: @tpr_delta |1: skip ] /width=10/ (**) (* /3 width=10/ is too slow *)
 203 qed.
 204
 205 lemma tpr_conf_delta_zeta:
 206    ∀X2,V0,V1,T0,T1,TT1,T2. (
 207       ∀X0:term. #X0 < #V0 +#T0 + 1→
 208       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 209       ∃∃X. X1 ⇒ X & X2 ⇒ X
 210    ) →
 211    V0 ⇒ V1 → T0 ⇒ T1 → ⋆. 𝕓{Abbr} V1 ⊢ T1 [O,1] ≫ TT1 →
 212    T2 ⇒ X2 → ↑[O, 1] T2 ≡ T0 →
 213    ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & X2 ⇒ X.
 214 #X2 #V0 #V1 #T0 #T1 #TT1 #T2 #IH #_ #HT01 #HTT1 #HTX2 #HTT20
 215 elim (tpr_inv_lift … HT01 … HTT20) -HT01 #TT2 #HTT21 #HTT2
 216 lapply (ps_inv_lift_eq … HTT1 … HTT21) -HTT1 #HTT1 destruct -T1;
 217 lapply (tw_lift … HTT20) -HTT20 #HTT20
 218 elim (IH … HTX2 … HTT2) -HTX2 HTT2 IH /3/
 219 qed.
 220
 221 lemma tpr_conf_theta_theta:
 222    ∀VV1,V0,V1,W0,W1,T0,T1,V2,VV2,W2,T2. (
 223       ∀X0:term. #X0 < #V0 + (#W0 + #T0 + 1) + 1 →
 224       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 225       ∃∃X. X1 ⇒ X & X2 ⇒ X
 226    ) →
 227    V0 ⇒ V1 → V0 ⇒ V2 → W0 ⇒ W1 → W0 ⇒ W2 → T0 ⇒ T1 → T0 ⇒ T2 →
 228    ↑[O, 1] V1 ≡ VV1 → ↑[O, 1] V2 ≡ VV2 →
 229    ∃∃X. 𝕓{Abbr} W1. 𝕗{Appl} VV1. T1 ⇒ X & 𝕓{Abbr} W2. 𝕗{Appl} VV2. T2 ⇒ X.
 230 #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #V2 #VV2 #W2 #T2 #IH #HV01 #HV02 #HW01 #HW02 #HT01 #HT02 #HVV1 #HVV2
 231 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 232 elim (IH … HW01 … HW02) -HW01 HW02 // #W #HW1 #HW2
 233 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 234 elim (lift_total V 0 1) #VV #HVV
 235 lapply (tpr_lift … HV1 … HVV1 … HVV) -HV1 HVV1 #HVV1
 236 lapply (tpr_lift … HV2 … HVV2 … HVV) -HV2 HVV2 HVV #HVV2
 237 @ex2_1_intro [2,3: @tpr_bind |1:skip ] /2 width=5/ (**) (* /4 width=5/ is too slow *)
 238 qed.
 239
 240 lemma tpr_conf_zeta_zeta:
 241    ∀V0:term. ∀X2,TT0,T0,T1,T2. (
 242       ∀X0:term. #X0 < #V0 + #TT0 + 1 →
 243       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 244       ∃∃X. X1 ⇒ X & X2 ⇒ X
 245    ) →
 246    T0 ⇒ T1 → T2 ⇒ X2 →
 247    ↑[O, 1] T0 ≡ TT0 → ↑[O, 1] T2 ≡ TT0 →
 248    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 249 #V0 #X2 #TT0 #T0 #T1 #T2 #IH #HT01 #HTX2 #HTT0 #HTT20
 250 lapply (lift_inj … HTT0 … HTT20) -HTT0 #H destruct -T0;
 251 lapply (tw_lift … HTT20) -HTT20 #HTT20
 252 elim (IH … HT01 … HTX2) -HT01 HTX2 IH /2/
 253 qed.
 254
 255 lemma tpr_conf_tau_tau:
 256    ∀V0,T0:term. ∀X2,T1. (
 257       ∀X0:term. #X0 < #V0 + #T0 + 1 →
 258       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 259       ∃∃X. X1 ⇒ X & X2 ⇒ X
 260    ) →
 261    T0 ⇒ T1 → T0 ⇒ X2 →
 262    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 263 #V0 #T0 #X2 #T1 #IH #HT01 #HT02
 264 elim (IH … HT01 … HT02) -HT01 HT02 IH /2/
 265 qed.
 266
 267 (* Confluence ***************************************************************)
 268
 269 lemma tpr_conf_aux:
 270    ∀Y0:term. (
 271       ∀X0:term. #X0 < #Y0 → ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 272       ∃∃X. X1 ⇒ X & X2 ⇒ X
 273          ) →
 274    ∀X0,X1,X2. X0 ⇒ X1 → X0 ⇒ X2 → X0 = Y0 →
 275    ∃∃X. X1 ⇒ X & X2 ⇒ X.
 276 #Y0 #IH #X0 #X1 #X2 * -X0 X1
 277 [ #k1 #H1 #H2 destruct -Y0;
 278   lapply (tpr_inv_sort1 … H1) -H1
 279 (* case 1: sort, sort *)
 280   #H1 destruct -X2 //
 281 | #i1 #H1 #H2 destruct -Y0;
 282   lapply (tpr_inv_lref1 … H1) -H1
 283 (* case 2: lref, lref *)
 284   #H1 destruct -X2 //
 285 | #I #V0 #V1 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 286   elim (tpr_inv_bind1 … H1) -H1 *
 287 (* case 3: bind, bind *)
 288   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 289     /3 width=7 by tpr_conf_bind_bind/ (**) (* /3 width=7/ is too slow *)
 290 (* case 4: bind, delta *)
 291   | #V2 #T2 #T #HV02 #HT02 #HT2 #H1 #H2 destruct -X2 I
 292     /3 width=9 by tpr_conf_bind_delta/ (**) (* /3 width=9/ is too slow *)
 293 (* case 5: bind, zeta *)
 294   | #T #HT0 #HTX2 #H destruct -I
 295     /3 width=8 by tpr_conf_bind_zeta/ (**) (* /3 width=8/ is too slow *)
 296   ]
 297 | #I #V0 #V1 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 298   elim (tpr_inv_flat1 … H1) -H1 *
 299 (* case 6: flat, flat *)
 300   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 301     /3 width=7 by tpr_conf_flat_flat/ (**) (* /3 width=7/ is too slow *)
 302 (* case 7: flat, beta *)
 303   | #V2 #W #U0 #T2 #HV02 #HT02 #H1 #H2 #H3 destruct -T0 X2 I
 304     /3 width=8 by tpr_conf_flat_beta/ (**) (* /3 width=8/ is too slow *)
 305 (* case 8: flat, theta *)
 306   | #V2 #V #W0 #W2 #U0 #U2 #HV02 #HW02 #HT02 #HV2 #H1 #H2 #H3 destruct -T0 X2 I
 307     /3 width=11 by tpr_conf_flat_theta/ (**) (* /3 width=11/ is too slow *)
 308 (* case 9: flat, tau *)
 309   | #HT02 #H destruct -I
 310     /3 width=6 by tpr_conf_flat_cast/ (**) (* /3 width=6/ is too slow *)
 311   ]
 312 | #V0 #V1 #W0 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 313   elim (tpr_inv_appl1 … H1) -H1 *
 314 (* case 10: beta, flat (repeated) *)
 315   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 316     @ex2_1_comm /3 width=8 by tpr_conf_flat_beta/
 317 (* case 11: beta, beta *)
 318   | #V2 #WW0 #TT0 #T2 #HV02 #HT02 #H1 #H2 destruct -W0 T0 X2
 319     /3 width=8 by tpr_conf_beta_beta/ (**) (* /3 width=8/ is too slow *)
 320 (* case 12, beta, theta (excluded) *)
 321   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #_ #_ #_ #_ #H destruct
 322   ]
 323 | #V0 #V1 #T0 #T1 #TT1 #HV01 #HT01 #HTT1 #H1 #H2 destruct -Y0;
 324   elim (tpr_inv_abbr1 … H1) -H1 *
 325 (* case 13: delta, bind (repeated) *)
 326   [ #V2 #T2 #HV02 #T02 #H destruct -X2
 327     @ex2_1_comm /3 width=9 by tpr_conf_bind_delta/
 328 (* case 14: delta, delta *)
 329   | #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 330     /3 width=11 by tpr_conf_delta_delta/ (**) (* /3 width=11/ is too slow *)
 331 (* case 15: delta, zata *)
 332   | #T2 #HT20 #HTX2
 333     /3 width=10 by tpr_conf_delta_zeta/ (**) (* /3 width=10/ is too slow *)
 334   ]
 335 | #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #HV01 #HVV1 #HW01 #HT01 #H1 #H2 destruct -Y0;
 336   elim (tpr_inv_appl1 … H1) -H1 *
 337 (* case 16: theta, flat (repeated) *)
 338   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 339     @ex2_1_comm /3 width=11 by tpr_conf_flat_theta/
 340 (* case 17: theta, beta (repeated) *)
 341   | #V2 #WW0 #TT0 #T2 #_ #_ #H destruct
 342 (* case 18: theta, theta *)
 343   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #V02 #HW02 #HT02 #HVV2 #H1 #H2 destruct -W0 T0 X2
 344     /3 width=14 by tpr_conf_theta_theta/  (**) (* /3 width=14/ is too slow *)
 345   ]
 346 | #V0 #TT0 #T0 #T1 #HTT0 #HT01 #H1 #H2 destruct -Y0;
 347   elim (tpr_inv_abbr1 … H1) -H1 *
 348 (* case 19: zeta, bind (repeated) *)
 349   [ #V2 #T2 #HV02 #T02 #H destruct -X2
 350     @ex2_1_comm /3 width=8 by tpr_conf_bind_zeta/
 351 (* case 20: zeta, delta (repeated) *)
 352   | #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 353     @ex2_1_comm /3 width=10 by tpr_conf_delta_zeta/
 354 (* case 21: zeta, zeta *)
 355   | #T2 #HTT20 #HTX2
 356     /3 width=9 by tpr_conf_zeta_zeta/ (**) (* /3 width=9/ is too slow *)
 357   ]
 358 | #V0 #T0 #T1 #HT01 #H1 #H2 destruct -Y0;
 359   elim (tpr_inv_cast1 … H1) -H1
 360 (* case 22: tau, flat (repeated) *)
 361   [ * #V2 #T2 #HV02 #HT02 #H destruct -X2
 362     @ex2_1_comm /3 width=6 by tpr_conf_flat_cast/
 363 (* case 23: tau, tau *)
 364   | #HT02
 365     /2 by tpr_conf_tau_tau/
 366   ]
 367 ]
 368 qed.
 369
 370 theorem tpr_conf: ∀T0:term. ∀T1,T2. T0 ⇒ T1 → T0 ⇒ T2 →
 371                   ∃∃T. T1 ⇒ T & T2 ⇒ T.
 372 #T @(tw_wf_ind … T) -T /3 width=6 by tpr_conf_aux/
 373 qed.