matita/matita/lib/lambda-delta/substitution/drop_defs.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/substitution/leq_defs.ma".
  13 include "lambda-delta/substitution/lift_defs.ma".
  14
  15 (* DROPPING *****************************************************************)
  16
  17 inductive drop: lenv → nat → nat → lenv → Prop ≝
  18 | drop_refl: ∀L. drop L 0 0 L
  19 | drop_drop: ∀L1,L2,I,V,e. drop L1 0 e L2 → drop (L1. 𝕓{I} V) 0 (e + 1) L2
  20 | drop_skip: ∀L1,L2,I,V1,V2,d,e.
  21              drop L1 d e L2 → ↑[d,e] V2 ≡ V1 →
  22              drop (L1. 𝕓{I} V1) (d + 1) e (L2. 𝕓{I} V2)
  23 .
  24
  25 interpretation "dropping" 'RDrop L1 d e L2 = (drop L1 d e L2).
  26
  27 (* Basic inversion lemmas ***************************************************)
  28
  29 lemma drop_inv_refl_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 → e = 0 → L1 = L2.
  30 #d #e #L1 #L2 * -d e L1 L2
  31 [ //
  32 | #L1 #L2 #I #V #e #_ #_ #H
  33   elim (plus_S_eq_O_false … H)
  34 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H
  35   elim (plus_S_eq_O_false … H)
  36 ]
  37 qed.
  38
  39 lemma drop_inv_refl: ∀L1,L2. ↓[0, 0] L1 ≡ L2 → L1 = L2.
  40 /2 width=5/ qed.
  41
  42 lemma drop_inv_sort1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → L1 = ⋆ →
  43                           ∧∧ L2 = ⋆ & d = 0 & e = 0.
  44 #d #e #L1 #L2 * -d e L1 L2
  45 [ /2/
  46 | #L1 #L2 #I #V #e #_ #H destruct
  47 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  48 ]
  49 qed.
  50
  51 lemma drop_inv_sort1: ∀d,e,L2. ↓[d, e] ⋆ ≡ L2 →
  52                       ∧∧ L2 = ⋆ & d = 0 & e = 0.
  53 /2/ qed.
  54
  55 lemma drop_inv_O1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 →
  56                        ∀K,I,V. L1 = K. 𝕓{I} V →
  57                        (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  58                        (0 < e ∧ ↓[d, e - 1] K ≡ L2).
  59 #d #e #L1 #L2 * -d e L1 L2
  60 [ /3/
  61 | #L1 #L2 #I #V #e #HL12 #_ #K #J #W #H destruct -L1 I V /3/
  62 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H elim (plus_S_eq_O_false … H)
  63 ]
  64 qed.
  65
  66 lemma drop_inv_O1: ∀e,K,I,V,L2. ↓[0, e] K. 𝕓{I} V ≡ L2 →
  67                    (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  68                    (0 < e ∧ ↓[0, e - 1] K ≡ L2).
  69 /2/ qed.
  70
  71 lemma drop_inv_drop1: ∀e,K,I,V,L2.
  72                       ↓[0, e] K. 𝕓{I} V ≡ L2 → 0 < e → ↓[0, e - 1] K ≡ L2.
  73 #e #K #I #V #L2 #H #He
  74 elim (drop_inv_O1 … H) -H * // #H destruct -e;
  75 elim (lt_refl_false … He)
  76 qed.
  77
  78 lemma drop_inv_skip2_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → 0 < d →
  79                           ∀I,K2,V2. L2 = K2. 𝕓{I} V2 →
  80                           ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 &
  81                                    ↑[d - 1, e] V2 ≡ V1 &
  82                                    L1 = K1. 𝕓{I} V1.
  83 #d #e #L1 #L2 * -d e L1 L2
  84 [ #L #H elim (lt_refl_false … H)
  85 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
  86 | #L1 #X #Y #V1 #Z #d #e #HL12 #HV12 #_ #I #L2 #V2 #H destruct -X Y Z;
  87   /2 width=5/
  88 ]
  89 qed.
  90
  91 lemma drop_inv_skip2: ∀d,e,I,L1,K2,V2. ↓[d, e] L1 ≡ K2. 𝕓{I} V2 → 0 < d →
  92                       ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 & ↑[d - 1, e] V2 ≡ V1 &
  93                                L1 = K1. 𝕓{I} V1.
  94 /2/ qed.
  95
  96 (* Basic properties *********************************************************)
  97
  98 lemma drop_drop_lt: ∀L1,L2,I,V,e.
  99                     ↓[0, e - 1] L1 ≡ L2 → 0 < e → ↓[0, e] L1. 𝕓{I} V ≡ L2.
 100 #L1 #L2 #I #V #e #HL12 #He >(plus_minus_m_m e 1) /2/
 101 qed.
 102
 103 lemma drop_fwd_drop2: ∀L1,I2,K2,V2,e. ↓[O, e] L1 ≡ K2. 𝕓{I2} V2 →
 104                       ↓[O, e + 1] L1 ≡ K2.
 105 #L1 elim L1 -L1
 106 [ #I2 #K2 #V2 #e #H elim (drop_inv_sort1 … H) -H #H destruct
 107 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 108   elim (drop_inv_O1 … H) -H * #He #H
 109   [ -IHL1; destruct -e K2 I2 V2 /2/
 110   | @drop_drop >(plus_minus_m_m e 1) /2/
 111   ]
 112 ]
 113 qed.
 114
 115 lemma drop_leq_drop1: ∀L1,L2,d,e. L1 [d, e] ≈ L2 →
 116                       ∀I,K1,V,i. ↓[0, i] L1 ≡ K1. 𝕓{I} V →
 117                       d ≤ i → i < d + e →
 118                       ∃∃K2. K1 [0, d + e - i - 1] ≈ K2 &
 119                             ↓[0, i] L2 ≡ K2. 𝕓{I} V.
 120 #L1 #L2 #d #e #H elim H -H L1 L2 d e
 121 [ #d #e #I #K1 #V #i #H
 122   elim (drop_inv_sort1 … H) -H #H destruct
 123 | #L1 #L2 #I1 #I2 #V1 #V2 #_ #_ #I #K1 #V #i #_ #_ #H
 124   elim (lt_zero_false … H)
 125 | #L1 #L2 #I #V #e #HL12 #IHL12 #J #K1 #W #i #H #_ #Hie
 126   elim (drop_inv_O1 … H) -H * #Hi #HLK1
 127   [ -IHL12 Hie; destruct -i K1 J W;
 128     <minus_n_O <minus_plus_m_m /2/
 129   | -HL12;
 130     elim (IHL12 … HLK1 ? ?) -IHL12 HLK1 // [2: /2/ ] -Hie >arith_g1 // /3/
 131   ]
 132 | #L1 #L2 #I1 #I2 #V1 #V2 #d #e #_ #IHL12 #I #K1 #V #i #H #Hdi >plus_plus_comm_23 #Hide
 133   lapply (plus_S_le_to_pos … Hdi) #Hi
 134   lapply (drop_inv_drop1 … H ?) -H // #HLK1
 135   elim (IHL12 … HLK1 ? ?) -IHL12 HLK1 [2: /2/ |3: /2/ ] -Hdi Hide >arith_g1 // /3/
 136 ]
 137 qed.