matita/matita/lib/lambda-delta/substitution/drop_drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "lambda-delta/substitution/lift_lift.ma".
  16 include "lambda-delta/substitution/drop.ma".
  17
  18 (* DROPPING *****************************************************************)
  19
  20 (* Main properties **********************************************************)
  21
  22 theorem drop_mono: ∀d,e,L,L1. ↓[d, e] L ≡ L1 →
  23                    ∀L2. ↓[d, e] L ≡ L2 → L1 = L2.
  24 #d #e #L #L1 #H elim H -H d e L L1
  25 [ #d #e #L2 #H
  26   >(drop_inv_sort1 … H) -H L2 //
  27 | #K1 #K2 #I #V #HK12 #_ #L2 #HL12
  28    <(drop_inv_refl … HK12) -HK12 K2
  29    <(drop_inv_refl … HL12) -HL12 L2 //
  30 | #L #K #I #V #e #_ #IHLK #L2 #H
  31   lapply (drop_inv_drop1 … H ?) -H /2/
  32 | #L #K1 #I #T #V1 #d #e #_ #HVT1 #IHLK1 #X #H
  33   elim (drop_inv_skip1 … H ?) -H // <minus_plus_m_m #K2 #V2 #HLK2 #HVT2 #H destruct -X
  34   >(lift_inj … HVT1 … HVT2) -HVT1 HVT2
  35   >(IHLK1 … HLK2) -IHLK1 HLK2 //
  36 ]
  37 qed.
  38
  39 theorem drop_conf_ge: ∀d1,e1,L,L1. ↓[d1, e1] L ≡ L1 →
  40                       ∀e2,L2. ↓[0, e2] L ≡ L2 → d1 + e1 ≤ e2 →
  41                       ↓[0, e2 - e1] L1 ≡ L2.
  42 #d1 #e1 #L #L1 #H elim H -H d1 e1 L L1
  43 [ #d #e #e2 #L2 #H
  44   >(drop_inv_sort1 … H) -H L2 //
  45 | #K1 #K2 #I #V #HK12 #_ #e2 #L2 #H #_ <minus_n_O
  46    <(drop_inv_refl … HK12) -HK12 K2 //
  47 | #L #K #I #V #e #_ #IHLK #e2 #L2 #H #He2
  48   lapply (drop_inv_drop1 … H ?) -H /2/ #HL2
  49   <minus_plus_comm /3/
  50 | #L #K #I #V1 #V2 #d #e #_ #_ #IHLK #e2 #L2 #H #Hdee2
  51   lapply (transitive_le 1 … Hdee2) // #He2
  52   lapply (drop_inv_drop1 … H ?) -H // -He2 #HL2
  53   lapply (transitive_le (1 + e) … Hdee2) // #Hee2
  54   @drop_drop_lt >minus_minus_comm /3/ (**) (* explicit constructor *)
  55 ]
  56 qed.
  57
  58 theorem drop_conf_lt: ∀d1,e1,L,L1. ↓[d1, e1] L ≡ L1 →
  59                       ∀e2,K2,I,V2. ↓[0, e2] L ≡ K2. 𝕓{I} V2 →
  60                       e2 < d1 → let d ≝ d1 - e2 - 1 in
  61                       ∃∃K1,V1. ↓[0, e2] L1 ≡ K1. 𝕓{I} V1 &
  62                                ↓[d, e1] K2 ≡ K1 & ↑[d, e1] V1 ≡ V2.
  63 #d1 #e1 #L #L1 #H elim H -H d1 e1 L L1
  64 [ #d #e #e2 #K2 #I #V2 #H
  65   lapply (drop_inv_sort1 … H) -H #H destruct
  66 | #L1 #L2 #I #V #_ #_ #e2 #K2 #J #V2 #_ #H
  67   elim (lt_zero_false … H)
  68 | #L1 #L2 #I #V #e #_ #_ #e2 #K2 #J #V2 #_ #H
  69   elim (lt_zero_false … H)
  70 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #IHL12 #e2 #K2 #J #V #H #He2d
  71   elim (drop_inv_O1 … H) -H *
  72   [ -IHL12 He2d #H1 #H2 destruct -e2 K2 J V /2 width=5/
  73   | -HL12 -HV12 #He #HLK
  74     elim (IHL12 … HLK ?) -IHL12 HLK [ <minus_minus /3 width=5/ | /2/ ] (**) (* a bit slow *)
  75   ]
  76 ]
  77 qed.
  78
  79 theorem drop_trans_le: ∀d1,e1,L1,L. ↓[d1, e1] L1 ≡ L →
  80                        ∀e2,L2. ↓[0, e2] L ≡ L2 → e2 ≤ d1 →
  81                        ∃∃L0. ↓[0, e2] L1 ≡ L0 & ↓[d1 - e2, e1] L0 ≡ L2.
  82 #d1 #e1 #L1 #L #H elim H -H d1 e1 L1 L
  83 [ #d #e #e2 #L2 #H
  84   >(drop_inv_sort1 … H) -H L2 /2/
  85 | #K1 #K2 #I #V #HK12 #_ #e2 #L2 #HL2 #H
  86   >(drop_inv_refl … HK12) -HK12 K1;
  87   lapply (le_O_to_eq_O … H) -H #H destruct -e2 /2/
  88 | #L1 #L2 #I #V #e #_ #IHL12 #e2 #L #HL2 #H
  89   lapply (le_O_to_eq_O … H) -H #H destruct -e2;
  90   elim (IHL12 … HL2 ?) -IHL12 HL2 // #L0 #H #HL0
  91   lapply (drop_inv_refl … H) -H #H destruct -L1 /3 width=5/
  92 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #IHL12 #e2 #L #H #He2d
  93   elim (drop_inv_O1 … H) -H *
  94   [ -He2d IHL12 #H1 #H2 destruct -e2 L /3 width=5/
  95   | -HL12 HV12 #He2 #HL2
  96     elim (IHL12 … HL2 ?) -IHL12 HL2 L2
  97     [ >minus_le_minus_minus_comm // /3/ | /2/ ]
  98   ]
  99 ]
 100 qed.
 101
 102 theorem drop_trans_ge: ∀d1,e1,L1,L. ↓[d1, e1] L1 ≡ L →
 103                        ∀e2,L2. ↓[0, e2] L ≡ L2 → d1 ≤ e2 → ↓[0, e1 + e2] L1 ≡ L2.
 104 #d1 #e1 #L1 #L #H elim H -H d1 e1 L1 L
 105 [ #d #e #e2 #L2 #H
 106   >(drop_inv_sort1 … H) -H L2 //
 107 | #K1 #K2 #I #V #HK12 #_ #e2 #L2 #H #_ normalize
 108   >(drop_inv_refl … HK12) -HK12 K1 //
 109 | /3/
 110 | #L1 #L2 #I #V1 #V2 #d #e #H_ #_ #IHL12 #e2 #L #H #Hde2
 111   lapply (lt_to_le_to_lt 0 … Hde2) // #He2
 112   lapply (lt_to_le_to_lt … (e + e2) He2 ?) // #Hee2
 113   lapply (drop_inv_drop1 … H ?) -H // #HL2
 114   @drop_drop_lt // >le_plus_minus // @IHL12 /2/ (**) (* explicit constructor *)
 115 ]
 116 qed.
 117
 118 theorem drop_trans_ge_comm: ∀d1,e1,e2,L1,L2,L.
 119                             ↓[d1, e1] L1 ≡ L → ↓[0, e2] L ≡ L2 → d1 ≤ e2 →
 120                             ↓[0, e2 + e1] L1 ≡ L2.
 121 #e1 #e1 #e2 >commutative_plus /2 width=5/
 122 qed.
 123
 124 axiom drop_div: ∀e1,L1,L. ↓[0, e1] L1 ≡ L → ∀e2,L2. ↓[0, e2] L2 ≡ L →
 125                 ∃∃L0. ↓[0, e1] L0 ≡ L2 & ↓[e1, e2] L0 ≡ L1.