matita/matita/lib/lambda-delta/substitution/lift.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/language/term.ma".
  13
  14 (* RELOCATION ***************************************************************)
  15
  16 inductive lift: term → nat → nat → term → Prop ≝
  17    | lift_sort   : ∀k,d,e. lift (⋆k) d e (⋆k)
  18    | lift_lref_lt: ∀i,d,e. i < d → lift (#i) d e (#i)
  19    | lift_lref_ge: ∀i,d,e. d ≤ i → lift (#i) d e (#(i + e))
  20    | lift_con2   : ∀I,V1,V2,T1,T2,d,e.
  21                    lift V1 d e V2 → lift T1 (d + 1) e T2 →
  22                    lift (♭I V1. T1) d e (♭I V2. T2)
  23 .
  24
  25 interpretation "relocation" 'RLift T1 d e T2 = (lift T1 d e T2).
  26
  27 (* The basic properties *****************************************************)
  28
  29 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ↑[d,e] #(i - e) ≡ #i.
  30 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %) /3/
  31 qed.
  32
  33 (* The basic inversion lemmas ***********************************************)
  34
  35 lemma lift_inv_sort2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
  36 #d #e #T1 #T2 #H elim H -H d e T1 T2 //
  37    [ #i #d #e #_ #k #H destruct
  38    | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
  39    ]
  40 qed.
  41
  42 lemma lift_inv_sort2: ∀d,e,T1,k. ↑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
  43 #d #e #T1 #k #H lapply (lift_inv_sort2_aux … H) /2/
  44 qed.
  45
  46 lemma lift_inv_lref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
  47                           (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
  48 #d #e #T1 #T2 #H elim H -H d e T1 T2
  49    [ #k #d #e #i #H destruct
  50    | #j #d #e #Hj #i #Hi destruct /3/
  51    | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4/
  52    | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
  53    ]
  54 qed.
  55
  56 lemma lift_inv_lref2: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i →
  57                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
  58 #d #e #T1 #i #H lapply (lift_inv_lref2_aux … H) /2/
  59 qed.
  60
  61 lemma lift_inv_con22_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
  62                           ∀I,V2,U2. T2 = ♭I V2.U2 →
  63                           ∃V1,U1. ↑[d,e] V1 ≡ V2 ∧ ↑[d+1,e] U1 ≡ U2 ∧
  64                                   T1 = ♭I V1.U1.
  65 #d #e #T1 #T2 #H elim H -H d e T1 T2
  66    [ #k #d #e #I #V2 #U2 #H destruct
  67    | #i #d #e #_ #I #V2 #U2 #H destruct
  68    | #i #d #e #_ #I #V2 #U2 #H destruct
  69    | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct /5/
  70 qed.
  71
  72 lemma lift_inv_con22: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  ♭I V2. U2 →
  73                       ∃V1,U1. ↑[d,e] V1 ≡ V2 ∧ ↑[d+1,e] U1 ≡ U2 ∧
  74                               T1 = ♭I V1. U1.
  75 #d #e #T1 #I #V2 #U2 #H lapply (lift_inv_con22_aux … H) /2/
  76 qed.
  77
  78 (* the main properies *******************************************************)
  79
  80 theorem lift_trans_rev: ∀d1,e1,T1,T. ↑[d1,e1] T1 ≡ T →
  81                         ∀d2,e2,T2. ↑[d2 + e1, e2] T2 ≡ T →
  82                         d1 ≤ d2 →
  83                         ∃T0. ↑[d1, e1] T0 ≡ T2 ∧ ↑[d2, e2] T0 ≡ T1.
  84 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
  85    [ #k #d1 #e1 #d2 #e2 #T2 #Hk #Hd12
  86      lapply (lift_inv_sort2 … Hk) -Hk #Hk destruct -T2 /3/
  87    | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  88      lapply (lift_inv_lref2 … Hi) -Hi #H
  89      elim H -H #H elim H -H #Hid2 #Hi (**) (* decompose*)
  90      destruct -T2
  91      [ -Hid2 /5/ (**) (* /4/ *)
  92      | elim (lt_false d1 ?)
  93        @(le_to_lt_to_lt … Hd12) -Hd12 @(le_to_lt_to_lt … Hid1) -Hid1 /2/
  94      ]
  95    | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  96      lapply (lift_inv_lref2 … Hi) -Hi #H
  97      elim H -H #H elim H -H #Hid2 #Hi (**) (* decompose*)
  98      destruct -T2
  99      [ -Hd12; lapply (lt_plus_to_lt_l … Hid2) -Hid2 #Hid2 /4/
 100      | -Hid1; lapply (arith1 … Hid2) -Hid2 #Hid2
 101        @(ex_intro … #(i - e2)) @conj
 102        [ >le_plus_minus_comm [ @lift_lref_ge @(transitive_le … Hd12) -Hd12 /2/ | -Hd12 /2/ ]
 103        | -Hd12 >(plus_minus_m_m i e2) in ⊢ (? ? ? ? %) /3/
 104        ]
 105      ]
 106    | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
 107      lapply (lift_inv_con22 … H) -H #H
 108      elim H -H #W2 #H elim H -H #U2 #H elim H -H #H elim H -H #HW2 #HU2 #H (**) (* decompose*)
 109      destruct -T2;
 110      elim (IHW … HW2 ?) // -IHW HW2 #W0 #H
 111      elim H -H #HW2 #HW1 (**) (* decompose*)
 112      >plus_plus_comm_23 in HU2 #HU2 elim (IHU … HU2 ?) /2/ -IHU HU2 Hd12 #U0 #H
 113      elim H -H #HU2 #HU1 (**) (* decompose*)
 114      @(ex_intro … ♭I W0. U0) /3/ (**) (* /4/ *)
 115    ]
 116 qed.
 117
 118 theorem lift_free: ∀d1,e2,T1,T2. ↑[d1, e2] T1 ≡ T2 → ∀d2,e1.
 119                                  d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
 120                                  ∃T. ↑[d1, e1] T1 ≡ T ∧ ↑[d2, e2 - e1] T ≡ T2.
 121 #d1 #e2 #T1 #T2 #H elim H -H d1 e2 T1 T2
 122    [ /3/
 123    | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
 124      lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4/
 125    | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
 126      lapply (transitive_le …(i+e1) Hd21 ?) /2/ -Hd21 #Hd21
 127      <(plus_plus_minus_m_m e1 e2 i) //
 128      @(ex_intro … #(i+e1)) /3/ (**) (* /4/ *)
 129    | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 130      elim (IHV … Hd12 Hd21 He12) -IHV #V0 #H
 131      elim H -H #HV0a #HV0b (**) (* decompose *)
 132      elim (IHT (d2+1) … ? ? He12) /2/ -IHT Hd12 Hd21 He12 #T0 #H
 133      elim H -H #HT0a #HT0b (**) (* decompose *)
 134      @(ex_intro … ♭I V0.T0) /3/ (**) (* /4/ *)
 135    ]
 136 qed.