matita/matita/lib/lambda-delta/substitution/lift.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/syntax/term.ma".
  13
  14 (* RELOCATION ***************************************************************)
  15
  16 inductive lift: term → nat → nat → term → Prop ≝
  17 | lift_sort   : ∀k,d,e. lift (⋆k) d e (⋆k)
  18 | lift_lref_lt: ∀i,d,e. i < d → lift (#i) d e (#i)
  19 | lift_lref_ge: ∀i,d,e. d ≤ i → lift (#i) d e (#(i + e))
  20 | lift_bind   : ∀I,V1,V2,T1,T2,d,e.
  21                 lift V1 d e V2 → lift T1 (d + 1) e T2 →
  22                 lift (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  23 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  24                 lift V1 d e V2 → lift T1 d e T2 →
  25                 lift (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  26 .
  27
  28 interpretation "relocation" 'RLift T1 d e T2 = (lift T1 d e T2).
  29
  30 (* The basic properties *****************************************************)
  31
  32 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ↑[d,e] #(i - e) ≡ #i.
  33 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %) /3/
  34 qed.
  35
  36 (* The basic inversion lemmas ***********************************************)
  37
  38 lemma lift_inv_sort2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
  39 #d #e #T1 #T2 #H elim H -H d e T1 T2 //
  40 [ #i #d #e #_ #k #H destruct
  41 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
  42 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
  43 ]
  44 qed.
  45
  46 lemma lift_inv_sort2: ∀d,e,T1,k. ↑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
  47 #d #e #T1 #k #H lapply (lift_inv_sort2_aux … H) /2/
  48 qed.
  49
  50 lemma lift_inv_lref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
  51                           (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
  52 #d #e #T1 #T2 #H elim H -H d e T1 T2
  53 [ #k #d #e #i #H destruct
  54 | #j #d #e #Hj #i #Hi destruct /3/
  55 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4/
  56 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
  57 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
  58 ]
  59 qed.
  60
  61 lemma lift_inv_lref2: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i →
  62                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
  63 #d #e #T1 #i #H lapply (lift_inv_lref2_aux … H) /2/
  64 qed.
  65
  66 lemma lift_inv_bind2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
  67                           ∀I,V2,U2. T2 = 𝕓{I} V2.U2 →
  68                           ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
  69                                    T1 = 𝕓{I} V1.U1.
  70 #d #e #T1 #T2 #H elim H -H d e T1 T2
  71 [ #k #d #e #I #V2 #U2 #H destruct
  72 | #i #d #e #_ #I #V2 #U2 #H destruct
  73 | #i #d #e #_ #I #V2 #U2 #H destruct
  74 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct /2 width = 5/
  75 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct
  76 ]
  77 qed.
  78
  79 lemma lift_inv_bind2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕓{I} V2. U2 →
  80                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
  81                                T1 = 𝕓{I} V1. U1.
  82 #d #e #T1 #I #V2 #U2 #H lapply (lift_inv_bind2_aux … H) /2/
  83 qed.
  84
  85 lemma lift_inv_flat2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
  86                           ∀I,V2,U2. T2 = 𝕗{I} V2.U2 →
  87                           ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
  88                                    T1 = 𝕗{I} V1.U1.
  89 #d #e #T1 #T2 #H elim H -H d e T1 T2
  90 [ #k #d #e #I #V2 #U2 #H destruct
  91 | #i #d #e #_ #I #V2 #U2 #H destruct
  92 | #i #d #e #_ #I #V2 #U2 #H destruct
  93 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct
  94 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct /2 width = 5/
  95 ]
  96 qed.
  97
  98 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕗{I} V2. U2 →
  99                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 100                                T1 = 𝕗{I} V1. U1.
 101 #d #e #T1 #I #V2 #U2 #H lapply (lift_inv_flat2_aux … H) /2/
 102 qed.
 103
 104 (* the main properies *******************************************************)
 105
 106 theorem lift_trans_rev: ∀d1,e1,T1,T. ↑[d1,e1] T1 ≡ T →
 107                         ∀d2,e2,T2. ↑[d2 + e1, e2] T2 ≡ T →
 108                         d1 ≤ d2 →
 109                         ∃∃T0. ↑[d1, e1] T0 ≡ T2 & ↑[d2, e2] T0 ≡ T1.
 110 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
 111 [ #k #d1 #e1 #d2 #e2 #T2 #Hk #Hd12
 112   lapply (lift_inv_sort2 … Hk) -Hk #Hk destruct -T2 /3/
 113 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
 114   lapply (lift_inv_lref2 … Hi) -Hi * * #Hid2 #H destruct -T2
 115   [ -Hid2 /4/
 116   | elim (lt_false d1 ?)
 117     @(le_to_lt_to_lt … Hd12) -Hd12 @(le_to_lt_to_lt … Hid1) -Hid1 /2/
 118   ]
 119 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
 120   lapply (lift_inv_lref2 … Hi) -Hi * * #Hid2 #H destruct -T2
 121   [ -Hd12; lapply (lt_plus_to_lt_l … Hid2) -Hid2 #Hid2 /3/
 122   | -Hid1; lapply (arith1 … Hid2) -Hid2 #Hid2
 123     @(ex2_1_intro … #(i - e2))
 124     [ >le_plus_minus_comm [ @lift_lref_ge @(transitive_le … Hd12) -Hd12 /2/ | -Hd12 /2/ ]
 125     | -Hd12 >(plus_minus_m_m i e2) in ⊢ (? ? ? ? %) /3/
 126     ]
 127   ]
 128 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
 129   lapply (lift_inv_bind2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
 130   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
 131   >plus_plus_comm_23 in HU2 #HU2 elim (IHU … HU2 ?) /3 width = 5/
 132 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
 133   lapply (lift_inv_flat2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
 134   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
 135   elim (IHU … HU2 ?) /3 width = 5/
 136 ]
 137 qed.
 138
 139 theorem lift_free: ∀d1,e2,T1,T2. ↑[d1, e2] T1 ≡ T2 → ∀d2,e1.
 140                                  d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
 141                                  ∃∃T. ↑[d1, e1] T1 ≡ T & ↑[d2, e2 - e1] T ≡ T2.
 142 #d1 #e2 #T1 #T2 #H elim H -H d1 e2 T1 T2
 143 [ /3/
 144 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
 145   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4/
 146 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
 147   lapply (transitive_le …(i+e1) Hd21 ?) /2/ -Hd21 #Hd21
 148   <(plus_plus_minus_m_m e1 e2 i) /3/
 149 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 150   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 151   elim (IHT (d2+1) … ? ? He12) /3 width = 5/
 152 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 153   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 154   elim (IHT d2 … ? ? He12) /3 width = 5/
 155 ]
 156 qed.