matita/matita/lib/lambda-delta/substitution/lift.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/syntax/term.ma".
  13
  14 (* RELOCATION ***************************************************************)
  15
  16 inductive lift: term → nat → nat → term → Prop ≝
  17 | lift_sort   : ∀k,d,e. lift (⋆k) d e (⋆k)
  18 | lift_lref_lt: ∀i,d,e. i < d → lift (#i) d e (#i)
  19 | lift_lref_ge: ∀i,d,e. d ≤ i → lift (#i) d e (#(i + e))
  20 | lift_bind   : ∀I,V1,V2,T1,T2,d,e.
  21                 lift V1 d e V2 → lift T1 (d + 1) e T2 →
  22                 lift (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  23 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  24                 lift V1 d e V2 → lift T1 d e T2 →
  25                 lift (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  26 .
  27
  28 interpretation "relocation" 'RLift T1 d e T2 = (lift T1 d e T2).
  29
  30 (* The basic properties *****************************************************)
  31
  32 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ↑[d,e] #(i - e) ≡ #i.
  33 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %) /3/
  34 qed.
  35
  36 (* The basic inversion lemmas ***********************************************)
  37
  38 lemma lift_inv_sort1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  39 #d #e #T1 #T2 #H elim H -H d e T1 T2 //
  40 [ #i #d #e #_ #k #H destruct
  41 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
  42 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
  43 ]
  44 qed.
  45
  46 lemma lift_inv_sort1: ∀d,e,T2,k. ↑[d,e] ⋆k ≡ T2 → T2 = ⋆k.
  47 #d #e #T2 #k #H lapply (lift_inv_sort1_aux … H) /2/
  48 qed.
  49
  50 lemma lift_inv_lref1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T1 = #i →
  51                           (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  52 #d #e #T1 #T2 #H elim H -H d e T1 T2
  53 [ #k #d #e #i #H destruct
  54 | #j #d #e #Hj #i #Hi destruct /3/
  55 | #j #d #e #Hj #i #Hi destruct /3/
  56 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
  57 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
  58 ]
  59 qed.
  60
  61 lemma lift_inv_lref1: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 →
  62                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  63 #d #e #T2 #i #H lapply (lift_inv_lref1_aux … H) /2/
  64 qed.
  65
  66 lemma lift_inv_bind1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
  67                           ∀I,V1,U1. T1 = 𝕓{I} V1.U1 →
  68                           ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
  69                                    T2 = 𝕓{I} V2. U2.
  70 #d #e #T1 #T2 #H elim H -H d e T1 T2
  71 [ #k #d #e #I #V1 #U1 #H destruct
  72 | #i #d #e #_ #I #V1 #U1 #H destruct
  73 | #i #d #e #_ #I #V1 #U1 #H destruct
  74 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V1 #U1 #H destruct /2 width=5/
  75 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V1 #U1 #H destruct
  76 ]
  77 qed.
  78
  79 lemma lift_inv_bind1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕓{I} V1. U1 ≡ T2 →
  80                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
  81                                T2 = 𝕓{I} V2. U2.
  82 #d #e #T2 #I #V1 #U1 #H lapply (lift_inv_bind1_aux … H) /2/
  83 qed.
  84
  85 lemma lift_inv_flat1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
  86                           ∀I,V1,U1. T1 = 𝕗{I} V1.U1 →
  87                           ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
  88                                    T2 = 𝕗{I} V2. U2.
  89 #d #e #T1 #T2 #H elim H -H d e T1 T2
  90 [ #k #d #e #I #V1 #U1 #H destruct
  91 | #i #d #e #_ #I #V1 #U1 #H destruct
  92 | #i #d #e #_ #I #V1 #U1 #H destruct
  93 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V1 #U1 #H destruct
  94 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V1 #U1 #H destruct /2 width=5/
  95 ]
  96 qed.
  97
  98 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕗{I} V1. U1 ≡ T2 →
  99                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 100                                T2 = 𝕗{I} V2. U2.
 101 #d #e #T2 #I #V1 #U1 #H lapply (lift_inv_flat1_aux … H) /2/
 102 qed.
 103
 104 lemma lift_inv_sort2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 105 #d #e #T1 #T2 #H elim H -H d e T1 T2 //
 106 [ #i #d #e #_ #k #H destruct
 107 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
 108 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
 109 ]
 110 qed.
 111
 112 lemma lift_inv_sort2: ∀d,e,T1,k. ↑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 113 #d #e #T1 #k #H lapply (lift_inv_sort2_aux … H) /2/
 114 qed.
 115
 116 lemma lift_inv_lref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 117                           (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 118 #d #e #T1 #T2 #H elim H -H d e T1 T2
 119 [ #k #d #e #i #H destruct
 120 | #j #d #e #Hj #i #Hi destruct /3/
 121 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4/
 122 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
 123 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
 124 ]
 125 qed.
 126
 127 lemma lift_inv_lref2: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i →
 128                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 129 #d #e #T1 #i #H lapply (lift_inv_lref2_aux … H) /2/
 130 qed.
 131
 132 lemma lift_inv_bind2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 133                           ∀I,V2,U2. T2 = 𝕓{I} V2.U2 →
 134                           ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 135                                    T1 = 𝕓{I} V1. U1.
 136 #d #e #T1 #T2 #H elim H -H d e T1 T2
 137 [ #k #d #e #I #V2 #U2 #H destruct
 138 | #i #d #e #_ #I #V2 #U2 #H destruct
 139 | #i #d #e #_ #I #V2 #U2 #H destruct
 140 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct /2 width=5/
 141 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct
 142 ]
 143 qed.
 144
 145 lemma lift_inv_bind2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕓{I} V2. U2 →
 146                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 147                                T1 = 𝕓{I} V1. U1.
 148 #d #e #T1 #I #V2 #U2 #H lapply (lift_inv_bind2_aux … H) /2/
 149 qed.
 150
 151 lemma lift_inv_flat2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 152                           ∀I,V2,U2. T2 = 𝕗{I} V2.U2 →
 153                           ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 154                                    T1 = 𝕗{I} V1. U1.
 155 #d #e #T1 #T2 #H elim H -H d e T1 T2
 156 [ #k #d #e #I #V2 #U2 #H destruct
 157 | #i #d #e #_ #I #V2 #U2 #H destruct
 158 | #i #d #e #_ #I #V2 #U2 #H destruct
 159 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct
 160 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct /2 width = 5/
 161 ]
 162 qed.
 163
 164 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕗{I} V2. U2 →
 165                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 166                                T1 = 𝕗{I} V1. U1.
 167 #d #e #T1 #I #V2 #U2 #H lapply (lift_inv_flat2_aux … H) /2/
 168 qed.
 169
 170 (* the main properies *******************************************************)
 171
 172 axiom lift_mono:  ∀d,e,T,U1. ↑[d,e] T ≡ U1 → ∀U2. ↑[d,e] T ≡ U2 → U1 = U2.
 173
 174 theorem lift_conf_rev: ∀d1,e1,T1,T. ↑[d1,e1] T1 ≡ T →
 175                        ∀d2,e2,T2. ↑[d2 + e1, e2] T2 ≡ T →
 176                        d1 ≤ d2 →
 177                        ∃∃T0. ↑[d1, e1] T0 ≡ T2 & ↑[d2, e2] T0 ≡ T1.
 178 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
 179 [ #k #d1 #e1 #d2 #e2 #T2 #Hk #Hd12
 180   lapply (lift_inv_sort2 … Hk) -Hk #Hk destruct -T2 /3/
 181 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
 182   lapply (lift_inv_lref2 … Hi) -Hi * * #Hid2 #H destruct -T2
 183   [ -Hid2 /4/
 184   | elim (lt_false d1 ?)
 185     @(le_to_lt_to_lt … Hd12) -Hd12 @(le_to_lt_to_lt … Hid1) -Hid1 /2/
 186   ]
 187 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
 188   lapply (lift_inv_lref2 … Hi) -Hi * * #Hid2 #H destruct -T2
 189   [ -Hd12; lapply (lt_plus_to_lt_l … Hid2) -Hid2 #Hid2 /3/
 190   | -Hid1; lapply (arith1 … Hid2) -Hid2 #Hid2
 191     @(ex2_1_intro … #(i - e2))
 192     [ >le_plus_minus_comm [ @lift_lref_ge @(transitive_le … Hd12) -Hd12 /2/ | -Hd12 /2/ ]
 193     | -Hd12 >(plus_minus_m_m i e2) in ⊢ (? ? ? ? %) /3/
 194     ]
 195   ]
 196 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
 197   lapply (lift_inv_bind2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
 198   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
 199   >plus_plus_comm_23 in HU2 #HU2 elim (IHU … HU2 ?) /3 width = 5/
 200 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
 201   lapply (lift_inv_flat2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
 202   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
 203   elim (IHU … HU2 ?) /3 width = 5/
 204 ]
 205 qed.
 206
 207 theorem lift_free: ∀d1,e2,T1,T2. ↑[d1, e2] T1 ≡ T2 → ∀d2,e1.
 208                                  d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
 209                                  ∃∃T. ↑[d1, e1] T1 ≡ T & ↑[d2, e2 - e1] T ≡ T2.
 210 #d1 #e2 #T1 #T2 #H elim H -H d1 e2 T1 T2
 211 [ /3/
 212 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
 213   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4/
 214 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
 215   lapply (transitive_le …(i+e1) Hd21 ?) /2/ -Hd21 #Hd21
 216   <(plus_plus_minus_m_m e1 e2 i) /3/
 217 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 218   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 219   elim (IHT (d2+1) … ? ? He12) /3 width = 5/
 220 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 221   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 222   elim (IHT d2 … ? ? He12) /3 width = 5/
 223 ]
 224 qed.
 225
 226 theorem lift_trans: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 227                     ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 →
 228                     d1 ≤ d2 → d2 ≤ d1 + e1 → ↑[d1, e1 + e2] T1 ≡ T2.
 229 #d1 #e1 #T1 #T #H elim H -d1 e1 T1 T
 230 [ #k #d1 #e1 #d2 #e2 #T2 #HT2 #_ #_
 231   >(lift_inv_sort1 … HT2) -HT2 //
 232 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #Hd12 #_
 233   lapply (lift_inv_lref1 … HT2) -HT2 * * #Hid2 #H destruct -T2
 234   [ -Hd12 Hid2 /2/
 235   | lapply (le_to_lt_to_lt … d1 Hid2 ?) // -Hid1 Hid2 #Hd21
 236     lapply (le_to_lt_to_lt … d1 Hd12 ?) // -Hd12 Hd21 #Hd11
 237     elim (lt_false … Hd11)
 238   ]
 239 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #_ #Hd21
 240   lapply (lift_inv_lref1 … HT2) -HT2 * * #Hid2 #H destruct -T2
 241   [ lapply (lt_to_le_to_lt … (d1+e1) Hid2 ?) // -Hid2 Hd21 #H
 242     lapply (lt_plus_to_lt_l … H) -H #H
 243     lapply (le_to_lt_to_lt … d1 Hid1 ?) // -Hid1 H #Hd11
 244     elim (lt_false … Hd11)
 245   | -Hd21 Hid2 /2/
 246   ]
 247 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
 248   lapply (lift_inv_bind1 … HX) -HX * #V0 #T0 #HV20 #HT20 #HX destruct -X;
 249   lapply (IHV12 … HV20 ? ?) // -IHV12 HV20 #HV10
 250   lapply (IHT12 … HT20 ? ?) /2/
 251 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
 252   lapply (lift_inv_flat1 … HX) -HX * #V0 #T0 #HV20 #HT20 #HX destruct -X;
 253   lapply (IHV12 … HV20 ? ?) // -IHV12 HV20 #HV10
 254   lapply (IHT12 … HT20 ? ?) /2/
 255 ]
 256 qed.
 257
 258 axiom lift_trans_le: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 259                      ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 → d2 ≤ d1 →
 260                      ∃∃T0. ↑[d2, e2] T1 ≡ T0 & ↑[d1 + e2, e1] T0 ≡ T2.
 261
 262 axiom lift_trans_ge: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 263                      ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 → d1 + e1 ≤ d2 →
 264                      ∃∃T0. ↑[d2 - e1, e2] T1 ≡ T0 & ↑[d1, e1] T0 ≡ T2.