matita/matita/lib/lambda-delta/substitution/lift.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/language/term.ma".
  13
  14 (* RELOCATION ***************************************************************)
  15
  16 inductive lift: term → nat → nat → term → Prop ≝
  17    | lift_sort   : ∀k,d,e. lift (⋆k) d e (⋆k)
  18    | lift_lref_lt: ∀i,d,e. i < d → lift (#i) d e (#i)
  19    | lift_lref_ge: ∀i,d,e. d ≤ i → lift (#i) d e (#(i + e))
  20    | lift_con2   : ∀I,V1,V2,T1,T2,d,e.
  21                    lift V1 d e V2 → lift T1 (d + 1) e T2 →
  22                    lift (♭I V1. T1) d e (♭I V2. T2)
  23 .
  24
  25 interpretation "relocation" 'RLift T1 d e T2 = (lift T1 d e T2).
  26
  27 (* The basic properties *****************************************************)
  28
  29 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ↑[d,e] #(i - e) ≡ #i.
  30 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %) /3/
  31 qed.
  32
  33 (* The basic inversion lemmas ***********************************************)
  34
  35 lemma lift_inv_sort2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
  36 #d #e #T1 #T2 #H elim H -H d e T1 T2 //
  37    [ #i #d #e #_ #k #H destruct
  38    | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
  39    ]
  40 qed.
  41
  42 lemma lift_inv_sort2: ∀d,e,T1,k. ↑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
  43 #d #e #T1 #k #H lapply (lift_inv_sort2_aux … H) /2/
  44 qed.
  45
  46 lemma lift_inv_lref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
  47                           (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
  48 #d #e #T1 #T2 #H elim H -H d e T1 T2
  49    [ #k #d #e #i #H destruct
  50    | #j #d #e #Hj #i #Hi destruct /3/
  51    | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4/
  52    | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
  53    ]
  54 qed.
  55
  56 lemma lift_inv_lref2: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i →
  57                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
  58 #d #e #T1 #i #H lapply (lift_inv_lref2_aux … H) /2/
  59 qed.
  60
  61 lemma lift_inv_con22_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
  62                           ∀I,V2,U2. T2 = ♭I V2.U2 →
  63                           ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
  64                                    T1 = ♭I V1.U1.
  65 #d #e #T1 #T2 #H elim H -H d e T1 T2
  66    [ #k #d #e #I #V2 #U2 #H destruct
  67    | #i #d #e #_ #I #V2 #U2 #H destruct
  68    | #i #d #e #_ #I #V2 #U2 #H destruct
  69    | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct
  70      /2 width = 5/
  71    ]
  72 qed.
  73
  74 lemma lift_inv_con22: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  ♭I V2. U2 →
  75                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
  76                                T1 = ♭I V1. U1.
  77 #d #e #T1 #I #V2 #U2 #H lapply (lift_inv_con22_aux … H) /2/
  78 qed.
  79
  80 (* the main properies *******************************************************)
  81
  82 theorem lift_trans_rev: ∀d1,e1,T1,T. ↑[d1,e1] T1 ≡ T →
  83                         ∀d2,e2,T2. ↑[d2 + e1, e2] T2 ≡ T →
  84                         d1 ≤ d2 →
  85                         ∃∃T0. ↑[d1, e1] T0 ≡ T2 & ↑[d2, e2] T0 ≡ T1.
  86 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
  87    [ #k #d1 #e1 #d2 #e2 #T2 #Hk #Hd12
  88      lapply (lift_inv_sort2 … Hk) -Hk #Hk destruct -T2 /3/
  89    | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  90      lapply (lift_inv_lref2 … Hi) -Hi * * #Hid2 #H destruct -T2
  91      [ -Hid2 /4/
  92      | elim (lt_false d1 ?)
  93        @(le_to_lt_to_lt … Hd12) -Hd12 @(le_to_lt_to_lt … Hid1) -Hid1 /2/
  94      ]
  95    | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  96      lapply (lift_inv_lref2 … Hi) -Hi * * #Hid2 #H destruct -T2
  97      [ -Hd12; lapply (lt_plus_to_lt_l … Hid2) -Hid2 #Hid2 /3/
  98      | -Hid1; lapply (arith1 … Hid2) -Hid2 #Hid2
  99        @(ex2_1_intro … #(i - e2))
 100        [ >le_plus_minus_comm [ @lift_lref_ge @(transitive_le … Hd12) -Hd12 /2/ | -Hd12 /2/ ]
 101        | -Hd12 >(plus_minus_m_m i e2) in ⊢ (? ? ? ? %) /3/
 102        ]
 103      ]
 104    | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
 105      lapply (lift_inv_con22 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
 106      elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
 107      >plus_plus_comm_23 in HU2 #HU2 elim (IHU … HU2 ?) /3 width = 5/
 108    ]
 109 qed.
 110
 111 theorem lift_free: ∀d1,e2,T1,T2. ↑[d1, e2] T1 ≡ T2 → ∀d2,e1.
 112                                  d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
 113                                  ∃∃T. ↑[d1, e1] T1 ≡ T & ↑[d2, e2 - e1] T ≡ T2.
 114 #d1 #e2 #T1 #T2 #H elim H -H d1 e2 T1 T2
 115    [ /3/
 116    | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
 117      lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4/
 118    | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
 119      lapply (transitive_le …(i+e1) Hd21 ?) /2/ -Hd21 #Hd21
 120      <(plus_plus_minus_m_m e1 e2 i) /3/
 121    | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 122      elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 123      elim (IHT (d2+1) … ? ? He12) /3 width = 5/
 124    ]
 125 qed.