matita/matita/lib/lambda-delta/substitution/lift_defs.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/syntax/term.ma".
  13
  14 (* RELOCATION ***************************************************************)
  15
  16 inductive lift: term → nat → nat → term → Prop ≝
  17 | lift_sort   : ∀k,d,e. lift (⋆k) d e (⋆k)
  18 | lift_lref_lt: ∀i,d,e. i < d → lift (#i) d e (#i)
  19 | lift_lref_ge: ∀i,d,e. d ≤ i → lift (#i) d e (#(i + e))
  20 | lift_bind   : ∀I,V1,V2,T1,T2,d,e.
  21                 lift V1 d e V2 → lift T1 (d + 1) e T2 →
  22                 lift (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  23 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  24                 lift V1 d e V2 → lift T1 d e T2 →
  25                 lift (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  26 .
  27
  28 interpretation "relocation" 'RLift T1 d e T2 = (lift T1 d e T2).
  29
  30 (* The basic properties *****************************************************)
  31
  32 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ↑[d, e] #(i - e) ≡ #i.
  33 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %) /3/
  34 qed.
  35
  36 lemma lift_refl: ∀T,d. ↑[d, 0] T ≡ T.
  37 #T elim T -T
  38 [ //
  39 | #i #d elim (lt_or_ge i d) /2/
  40 | #I elim I -I /2/
  41 ]
  42 qed.
  43
  44 (* The basic inversion lemmas ***********************************************)
  45
  46 lemma lift_inv_refl_aux: ∀d,e,T1,T2. ↑[d, e] T1 ≡ T2 → e = 0 → T1 = T2.
  47 #d #e #T1 #T2 #H elim H -H d e T1 T2 /3/
  48 qed.
  49
  50 lemma lift_inv_refl: ∀d,T1,T2. ↑[d, 0] T1 ≡ T2 → T1 = T2.
  51 /2/ qed.
  52
  53 lemma lift_inv_sort1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  54 #d #e #T1 #T2 #H elim H -H d e T1 T2 //
  55 [ #i #d #e #_ #k #H destruct
  56 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
  57 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
  58 ]
  59 qed.
  60
  61 lemma lift_inv_sort1: ∀d,e,T2,k. ↑[d,e] ⋆k ≡ T2 → T2 = ⋆k.
  62 /2 width=5/ qed.
  63
  64 lemma lift_inv_lref1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T1 = #i →
  65                           (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  66 #d #e #T1 #T2 #H elim H -H d e T1 T2
  67 [ #k #d #e #i #H destruct
  68 | #j #d #e #Hj #i #Hi destruct /3/
  69 | #j #d #e #Hj #i #Hi destruct /3/
  70 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
  71 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
  72 ]
  73 qed.
  74
  75 lemma lift_inv_lref1: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 →
  76                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  77 /2/ qed.
  78
  79 lemma lift_inv_lref1_lt: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → i < d → T2 = #i.
  80 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  81 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
  82 elim (lt_false … Hdd)
  83 qed.
  84
  85 lemma lift_inv_lref1_ge: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → d ≤ i → T2 = #(i + e).
  86 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  87 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
  88 elim (lt_false … Hdd)
  89 qed.
  90
  91 lemma lift_inv_bind1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
  92                           ∀I,V1,U1. T1 = 𝕓{I} V1.U1 →
  93                           ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
  94                                    T2 = 𝕓{I} V2. U2.
  95 #d #e #T1 #T2 #H elim H -H d e T1 T2
  96 [ #k #d #e #I #V1 #U1 #H destruct
  97 | #i #d #e #_ #I #V1 #U1 #H destruct
  98 | #i #d #e #_ #I #V1 #U1 #H destruct
  99 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V1 #U1 #H destruct /2 width=5/
 100 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V1 #U1 #H destruct
 101 ]
 102 qed.
 103
 104 lemma lift_inv_bind1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕓{I} V1. U1 ≡ T2 →
 105                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 106                                T2 = 𝕓{I} V2. U2.
 107 /2/ qed.
 108
 109 lemma lift_inv_flat1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 110                           ∀I,V1,U1. T1 = 𝕗{I} V1.U1 →
 111                           ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 112                                    T2 = 𝕗{I} V2. U2.
 113 #d #e #T1 #T2 #H elim H -H d e T1 T2
 114 [ #k #d #e #I #V1 #U1 #H destruct
 115 | #i #d #e #_ #I #V1 #U1 #H destruct
 116 | #i #d #e #_ #I #V1 #U1 #H destruct
 117 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V1 #U1 #H destruct
 118 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V1 #U1 #H destruct /2 width=5/
 119 ]
 120 qed.
 121
 122 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕗{I} V1. U1 ≡ T2 →
 123                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 124                                T2 = 𝕗{I} V2. U2.
 125 /2/ qed.
 126
 127 lemma lift_inv_sort2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 128 #d #e #T1 #T2 #H elim H -H d e T1 T2 //
 129 [ #i #d #e #_ #k #H destruct
 130 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
 131 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #k #H destruct
 132 ]
 133 qed.
 134
 135 lemma lift_inv_sort2: ∀d,e,T1,k. ↑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 136 /2 width=5/ qed.
 137
 138 lemma lift_inv_lref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 139                           (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 140 #d #e #T1 #T2 #H elim H -H d e T1 T2
 141 [ #k #d #e #i #H destruct
 142 | #j #d #e #Hj #i #Hi destruct /3/
 143 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4/
 144 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
 145 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #_ #_ #i #H destruct
 146 ]
 147 qed.
 148
 149 lemma lift_inv_lref2: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i →
 150                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 151 /2/ qed.
 152
 153 lemma lift_inv_lref2_lt: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → i < d → T1 = #i.
 154 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 155 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 156 elim (plus_lt_false … Hdd)
 157 qed.
 158
 159 lemma lift_inv_lref2_ge: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → d + e ≤ i → T1 = #(i - e).
 160 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 161 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 162 elim (plus_lt_false … Hdd)
 163 qed.
 164
 165 lemma lift_inv_bind2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 166                           ∀I,V2,U2. T2 = 𝕓{I} V2.U2 →
 167                           ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 168                                    T1 = 𝕓{I} V1. U1.
 169 #d #e #T1 #T2 #H elim H -H d e T1 T2
 170 [ #k #d #e #I #V2 #U2 #H destruct
 171 | #i #d #e #_ #I #V2 #U2 #H destruct
 172 | #i #d #e #_ #I #V2 #U2 #H destruct
 173 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct /2 width=5/
 174 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct
 175 ]
 176 qed.
 177
 178 lemma lift_inv_bind2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕓{I} V2. U2 →
 179                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 180                                T1 = 𝕓{I} V1. U1.
 181 /2/ qed.
 182
 183 lemma lift_inv_flat2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 184                           ∀I,V2,U2. T2 = 𝕗{I} V2.U2 →
 185                           ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 186                                    T1 = 𝕗{I} V1. U1.
 187 #d #e #T1 #T2 #H elim H -H d e T1 T2
 188 [ #k #d #e #I #V2 #U2 #H destruct
 189 | #i #d #e #_ #I #V2 #U2 #H destruct
 190 | #i #d #e #_ #I #V2 #U2 #H destruct
 191 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct
 192 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #_ #_ #I #V2 #U2 #H destruct /2 width = 5/
 193 ]
 194 qed.
 195
 196 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕗{I} V2. U2 →
 197                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 198                                T1 = 𝕗{I} V1. U1.
 199 /2/ qed.