matita/matita/lib/lambda-delta/substitution/lift_defs.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/syntax/term.ma".
  13
  14 (* RELOCATION ***************************************************************)
  15
  16 inductive lift: term → nat → nat → term → Prop ≝
  17 | lift_sort   : ∀k,d,e. lift (⋆k) d e (⋆k)
  18 | lift_lref_lt: ∀i,d,e. i < d → lift (#i) d e (#i)
  19 | lift_lref_ge: ∀i,d,e. d ≤ i → lift (#i) d e (#(i + e))
  20 | lift_bind   : ∀I,V1,V2,T1,T2,d,e.
  21                 lift V1 d e V2 → lift T1 (d + 1) e T2 →
  22                 lift (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  23 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  24                 lift V1 d e V2 → lift T1 d e T2 →
  25                 lift (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  26 .
  27
  28 interpretation "relocation" 'RLift T1 d e T2 = (lift T1 d e T2).
  29
  30 (* Basic properties *********************************************************)
  31
  32 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ↑[d, e] #(i - e) ≡ #i.
  33 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %) /3/
  34 qed.
  35
  36 lemma lift_refl: ∀T,d. ↑[d, 0] T ≡ T.
  37 #T elim T -T
  38 [ //
  39 | #i #d elim (lt_or_ge i d) /2/
  40 | #I elim I -I /2/
  41 ]
  42 qed.
  43
  44 lemma lift_total: ∀T1,d,e. ∃T2. ↑[d,e] T1 ≡ T2.
  45 #T1 elim T1 -T1
  46 [ /2/
  47 | #i #d #e elim (lt_or_ge i d) /3/
  48 | * #I #V1 #T1 #IHV1 #IHT1 #d #e
  49   elim (IHV1 d e) -IHV1 #V2 #HV12
  50   [ elim (IHT1 (d+1) e) -IHT1 /3/
  51   | elim (IHT1 d e) -IHT1 /3/
  52   ]
  53 ]
  54 qed.
  55
  56 (* Basic inversion lemmas ***************************************************)
  57
  58 lemma lift_inv_refl_aux: ∀d,e,T1,T2. ↑[d, e] T1 ≡ T2 → e = 0 → T1 = T2.
  59 #d #e #T1 #T2 #H elim H -H d e T1 T2 /3/
  60 qed.
  61
  62 lemma lift_inv_refl: ∀d,T1,T2. ↑[d, 0] T1 ≡ T2 → T1 = T2.
  63 /2/ qed.
  64
  65 lemma lift_inv_sort1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  66 #d #e #T1 #T2 * -d e T1 T2 //
  67 [ #i #d #e #_ #k #H destruct
  68 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  69 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  70 ]
  71 qed.
  72
  73 lemma lift_inv_sort1: ∀d,e,T2,k. ↑[d,e] ⋆k ≡ T2 → T2 = ⋆k.
  74 /2 width=5/ qed.
  75
  76 lemma lift_inv_lref1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T1 = #i →
  77                           (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  78 #d #e #T1 #T2 * -d e T1 T2
  79 [ #k #d #e #i #H destruct
  80 | #j #d #e #Hj #i #Hi destruct /3/
  81 | #j #d #e #Hj #i #Hi destruct /3/
  82 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
  83 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
  84 ]
  85 qed.
  86
  87 lemma lift_inv_lref1: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 →
  88                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  89 /2/ qed.
  90
  91 lemma lift_inv_lref1_lt: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → i < d → T2 = #i.
  92 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  93 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
  94 elim (lt_refl_false … Hdd)
  95 qed.
  96
  97 lemma lift_inv_lref1_ge: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → d ≤ i → T2 = #(i + e).
  98 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  99 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 100 elim (lt_refl_false … Hdd)
 101 qed.
 102
 103 lemma lift_inv_bind1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 104                           ∀I,V1,U1. T1 = 𝕓{I} V1.U1 →
 105                           ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 106                                    T2 = 𝕓{I} V2. U2.
 107 #d #e #T1 #T2 * -d e T1 T2
 108 [ #k #d #e #I #V1 #U1 #H destruct
 109 | #i #d #e #_ #I #V1 #U1 #H destruct
 110 | #i #d #e #_ #I #V1 #U1 #H destruct
 111 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 112 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 113 ]
 114 qed.
 115
 116 lemma lift_inv_bind1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕓{I} V1. U1 ≡ T2 →
 117                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 118                                T2 = 𝕓{I} V2. U2.
 119 /2/ qed.
 120
 121 lemma lift_inv_flat1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 122                           ∀I,V1,U1. T1 = 𝕗{I} V1.U1 →
 123                           ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 124                                    T2 = 𝕗{I} V2. U2.
 125 #d #e #T1 #T2 * -d e T1 T2
 126 [ #k #d #e #I #V1 #U1 #H destruct
 127 | #i #d #e #_ #I #V1 #U1 #H destruct
 128 | #i #d #e #_ #I #V1 #U1 #H destruct
 129 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 130 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 131 ]
 132 qed.
 133
 134 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕗{I} V1. U1 ≡ T2 →
 135                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 136                                T2 = 𝕗{I} V2. U2.
 137 /2/ qed.
 138
 139 lemma lift_inv_sort2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 140 #d #e #T1 #T2 * -d e T1 T2 //
 141 [ #i #d #e #_ #k #H destruct
 142 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 143 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 144 ]
 145 qed.
 146
 147 lemma lift_inv_sort2: ∀d,e,T1,k. ↑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 148 /2 width=5/ qed.
 149
 150 lemma lift_inv_lref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 151                           (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 152 #d #e #T1 #T2 * -d e T1 T2
 153 [ #k #d #e #i #H destruct
 154 | #j #d #e #Hj #i #Hi destruct /3/
 155 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4/
 156 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 157 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 158 ]
 159 qed.
 160
 161 lemma lift_inv_lref2: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i →
 162                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 163 /2/ qed.
 164
 165 lemma lift_inv_lref2_lt: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → i < d → T1 = #i.
 166 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 167 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 168 elim (plus_lt_false … Hdd)
 169 qed.
 170
 171 lemma lift_inv_lref2_ge: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → d + e ≤ i → T1 = #(i - e).
 172 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 173 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 174 elim (plus_lt_false … Hdd)
 175 qed.
 176
 177 lemma lift_inv_bind2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 178                           ∀I,V2,U2. T2 = 𝕓{I} V2.U2 →
 179                           ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 180                                    T1 = 𝕓{I} V1. U1.
 181 #d #e #T1 #T2 * -d e T1 T2
 182 [ #k #d #e #I #V2 #U2 #H destruct
 183 | #i #d #e #_ #I #V2 #U2 #H destruct
 184 | #i #d #e #_ #I #V2 #U2 #H destruct
 185 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width=5/
 186 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 187 ]
 188 qed.
 189
 190 lemma lift_inv_bind2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕓{I} V2. U2 →
 191                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 192                                T1 = 𝕓{I} V1. U1.
 193 /2/ qed.
 194
 195 lemma lift_inv_flat2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 196                           ∀I,V2,U2. T2 = 𝕗{I} V2.U2 →
 197                           ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 198                                    T1 = 𝕗{I} V1. U1.
 199 #d #e #T1 #T2 * -d e T1 T2
 200 [ #k #d #e #I #V2 #U2 #H destruct
 201 | #i #d #e #_ #I #V2 #U2 #H destruct
 202 | #i #d #e #_ #I #V2 #U2 #H destruct
 203 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 204 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width = 5/
 205 ]
 206 qed.
 207
 208 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕗{I} V2. U2 →
 209                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 210                                T1 = 𝕗{I} V1. U1.
 211 /2/ qed.