matita/matita/lib/lambda-delta/substitution/lift_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "lambda-delta/substitution/lift.ma".
  16
  17 (* RELOCATION ***************************************************************)
  18
  19 (* Main properies ***********************************************************)
  20
  21 theorem lift_inj:  ∀d,e,T1,U. ↑[d,e] T1 ≡ U → ∀T2. ↑[d,e] T2 ≡ U → T1 = T2.
  22 #d #e #T1 #U #H elim H -H d e T1 U
  23 [ #k #d #e #X #HX
  24   lapply (lift_inv_sort2 … HX) -HX //
  25 | #i #d #e #Hid #X #HX
  26   lapply (lift_inv_lref2_lt … HX ?) -HX //
  27 | #i #d #e #Hdi #X #HX
  28   lapply (lift_inv_lref2_ge … HX ?) -HX /2/
  29 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  30   elim (lift_inv_bind2 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  31 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  32   elim (lift_inv_flat2 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  33 ]
  34 qed.
  35
  36 theorem lift_div_le: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
  37                      ∀d2,e2,T2. ↑[d2 + e1, e2] T2 ≡ T →
  38                      d1 ≤ d2 →
  39                      ∃∃T0. ↑[d1, e1] T0 ≡ T2 & ↑[d2, e2] T0 ≡ T1.
  40 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
  41 [ #k #d1 #e1 #d2 #e2 #T2 #Hk #Hd12
  42   lapply (lift_inv_sort2 … Hk) -Hk #Hk destruct -T2 /3/
  43 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  44   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2
  45   lapply (lift_inv_lref2_lt … Hi ?) -Hi /3/
  46 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  47   elim (lift_inv_lref2 … Hi) -Hi * #Hid2 #H destruct -T2
  48   [ -Hd12; lapply (lt_plus_to_lt_l … Hid2) -Hid2 #Hid2 /3/
  49   | -Hid1; lapply (arith1 … Hid2) -Hid2 #Hid2
  50     @(ex2_1_intro … #(i - e2))
  51     [ >le_plus_minus_comm [ @lift_lref_ge @(transitive_le … Hd12) -Hd12 /2/ | -Hd12 /2/ ]
  52     | -Hd12 >(plus_minus_m_m i e2) in ⊢ (? ? ? ? %) /3/
  53     ]
  54   ]
  55 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
  56   lapply (lift_inv_bind2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
  57   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
  58   >plus_plus_comm_23 in HU2 #HU2 elim (IHU … HU2 ?) /3 width = 5/
  59 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
  60   lapply (lift_inv_flat2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
  61   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
  62   elim (IHU … HU2 ?) /3 width = 5/
  63 ]
  64 qed.
  65
  66 theorem lift_mono:  ∀d,e,T,U1. ↑[d,e] T ≡ U1 → ∀U2. ↑[d,e] T ≡ U2 → U1 = U2.
  67 #d #e #T #U1 #H elim H -H d e T U1
  68 [ #k #d #e #X #HX
  69   lapply (lift_inv_sort1 … HX) -HX //
  70 | #i #d #e #Hid #X #HX
  71   lapply (lift_inv_lref1_lt … HX ?) -HX //
  72 | #i #d #e #Hdi #X #HX
  73   lapply (lift_inv_lref1_ge … HX ?) -HX //
  74 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  75   elim (lift_inv_bind1 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  76 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  77   elim (lift_inv_flat1 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  78 ]
  79 qed.
  80
  81 theorem lift_trans_be: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
  82                        ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 →
  83                        d1 ≤ d2 → d2 ≤ d1 + e1 → ↑[d1, e1 + e2] T1 ≡ T2.
  84 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
  85 [ #k #d1 #e1 #d2 #e2 #T2 #HT2 #_ #_
  86   >(lift_inv_sort1 … HT2) -HT2 //
  87 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #Hd12 #_
  88   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2
  89   lapply (lift_inv_lref1_lt … HT2 Hid2) /2/
  90 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #_ #Hd21
  91   lapply (lift_inv_lref1_ge … HT2 ?) -HT2
  92   [ @(transitive_le … Hd21 ?) -Hd21 /2/
  93   | -Hd21 /2/
  94   ]
  95 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
  96   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
  97   lapply (IHV12 … HV20 ? ?) // -IHV12 HV20 #HV10
  98   lapply (IHT12 … HT20 ? ?) /2/
  99 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
 100   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 101   lapply (IHV12 … HV20 ? ?) // -IHV12 HV20 #HV10
 102   lapply (IHT12 … HT20 ? ?) /2/
 103 ]
 104 qed.
 105
 106 theorem lift_trans_le: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 107                        ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 → d2 ≤ d1 →
 108                        ∃∃T0. ↑[d2, e2] T1 ≡ T0 & ↑[d1 + e2, e1] T0 ≡ T2.
 109 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
 110 [ #k #d1 #e1 #d2 #e2 #X #HX #_
 111   >(lift_inv_sort1 … HX) -HX /2/
 112 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #_
 113   lapply (lt_to_le_to_lt … (d1+e2) Hid1 ?) // #Hie2
 114   elim (lift_inv_lref1 … HX) -HX * #Hid2 #HX destruct -X /4/
 115 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #Hd21
 116   lapply (transitive_le … Hd21 Hid1) -Hd21 #Hid2
 117   lapply (lift_inv_lref1_ge … HX ?) -HX /2/ #HX destruct -X;
 118   >plus_plus_comm_23 /4/
 119 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd21
 120   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 121   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 122   elim (IHT12 … HT20 ?) -IHT12 HT20 /3 width=5/
 123 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd21
 124   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 125   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 126   elim (IHT12 … HT20 ?) -IHT12 HT20 /3 width=5/
 127 ]
 128 qed.
 129
 130 theorem lift_trans_ge: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 131                        ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 → d1 + e1 ≤ d2 →
 132                        ∃∃T0. ↑[d2 - e1, e2] T1 ≡ T0 & ↑[d1, e1] T0 ≡ T2.
 133 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
 134 [ #k #d1 #e1 #d2 #e2 #X #HX #_
 135   >(lift_inv_sort1 … HX) -HX /2/
 136 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #Hded
 137   lapply (lt_to_le_to_lt … (d1+e1) Hid1 ?) // #Hid1e
 138   lapply (lt_to_le_to_lt … (d2-e1) Hid1 ?) /2/ #Hid2e
 139   lapply (lt_to_le_to_lt … Hid1e Hded) -Hid1e Hded #Hid2
 140   lapply (lift_inv_lref1_lt … HX ?) -HX // #HX destruct -X /3/
 141 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #_
 142   elim (lift_inv_lref1 … HX) -HX * #Hied #HX destruct -X;
 143   [2: >plus_plus_comm_23] /4/
 144 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hded
 145   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 146   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 147   elim (IHT12 … HT20 ?) -IHT12 HT20 /2/ #T
 148   <plus_minus /3 width=5/
 149 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hded
 150   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 151   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 152   elim (IHT12 … HT20 ?) -IHT12 HT20 /3 width=5/
 153 ]
 154 qed.