matita/matita/lib/lambda-delta/substitution/lift_main.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "lambda-delta/substitution/lift_defs.ma".
  16
  17 (* RELOCATION ***************************************************************)
  18
  19 (* Main properies ***********************************************************)
  20
  21 lemma lift_inj:  ∀d,e,T1,U. ↑[d,e] T1 ≡ U → ∀T2. ↑[d,e] T2 ≡ U → T1 = T2.
  22 #d #e #T1 #U #H elim H -H d e T1 U
  23 [ #k #d #e #X #HX
  24   lapply (lift_inv_sort2 … HX) -HX //
  25 | #i #d #e #Hid #X #HX
  26   lapply (lift_inv_lref2_lt … HX ?) -HX //
  27 | #i #d #e #Hdi #X #HX
  28   lapply (lift_inv_lref2_ge … HX ?) -HX /2/
  29 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  30   elim (lift_inv_bind2 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  31 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  32   elim (lift_inv_flat2 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  33 ]
  34 qed.
  35
  36 lemma lift_div_le: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
  37                    ∀d2,e2,T2. ↑[d2 + e1, e2] T2 ≡ T →
  38                    d1 ≤ d2 →
  39                    ∃∃T0. ↑[d1, e1] T0 ≡ T2 & ↑[d2, e2] T0 ≡ T1.
  40 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
  41 [ #k #d1 #e1 #d2 #e2 #T2 #Hk #Hd12
  42   lapply (lift_inv_sort2 … Hk) -Hk #Hk destruct -T2 /3/
  43 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  44   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2
  45   lapply (lift_inv_lref2_lt … Hi ?) -Hi /3/
  46 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  47   elim (lift_inv_lref2 … Hi) -Hi * #Hid2 #H destruct -T2
  48   [ -Hd12; lapply (lt_plus_to_lt_l … Hid2) -Hid2 #Hid2 /3/
  49   | -Hid1; lapply (arith1 … Hid2) -Hid2 #Hid2
  50     @(ex2_1_intro … #(i - e2))
  51     [ >le_plus_minus_comm [ @lift_lref_ge @(transitive_le … Hd12) -Hd12 /2/ | -Hd12 /2/ ]
  52     | -Hd12 >(plus_minus_m_m i e2) in ⊢ (? ? ? ? %) /3/
  53     ]
  54   ]
  55 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
  56   lapply (lift_inv_bind2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
  57   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
  58   >plus_plus_comm_23 in HU2 #HU2 elim (IHU … HU2 ?) /3 width = 5/
  59 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
  60   lapply (lift_inv_flat2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
  61   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
  62   elim (IHU … HU2 ?) /3 width = 5/
  63 ]
  64 qed.
  65
  66 lemma lift_free: ∀d1,e2,T1,T2. ↑[d1, e2] T1 ≡ T2 → ∀d2,e1.
  67                                d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
  68                                ∃∃T. ↑[d1, e1] T1 ≡ T & ↑[d2, e2 - e1] T ≡ T2.
  69 #d1 #e2 #T1 #T2 #H elim H -H d1 e2 T1 T2
  70 [ /3/
  71 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
  72   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4/
  73 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
  74   lapply (transitive_le …(i+e1) Hd21 ?) /2/ -Hd21 #Hd21
  75   <(arith_d1 i e2 e1) // /3/
  76 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  77   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  78   elim (IHT (d2+1) … ? ? He12) /3 width = 5/
  79 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  80   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  81   elim (IHT d2 … ? ? He12) /3 width = 5/
  82 ]
  83 qed.
  84
  85 lemma lift_mono:  ∀d,e,T,U1. ↑[d,e] T ≡ U1 → ∀U2. ↑[d,e] T ≡ U2 → U1 = U2.
  86 #d #e #T #U1 #H elim H -H d e T U1
  87 [ #k #d #e #X #HX
  88   lapply (lift_inv_sort1 … HX) -HX //
  89 | #i #d #e #Hid #X #HX
  90   lapply (lift_inv_lref1_lt … HX ?) -HX //
  91 | #i #d #e #Hdi #X #HX
  92   lapply (lift_inv_lref1_ge … HX ?) -HX //
  93 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  94   elim (lift_inv_bind1 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  95 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  96   elim (lift_inv_flat1 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  97 ]
  98 qed.
  99
 100 lemma lift_trans_be: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 101                      ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 →
 102                      d1 ≤ d2 → d2 ≤ d1 + e1 → ↑[d1, e1 + e2] T1 ≡ T2.
 103 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
 104 [ #k #d1 #e1 #d2 #e2 #T2 #HT2 #_ #_
 105   >(lift_inv_sort1 … HT2) -HT2 //
 106 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #Hd12 #_
 107   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2
 108   lapply (lift_inv_lref1_lt … HT2 Hid2) /2/
 109 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #_ #Hd21
 110   lapply (lift_inv_lref1_ge … HT2 ?) -HT2
 111   [ @(transitive_le … Hd21 ?) -Hd21 /2/
 112   | -Hd21 /2/
 113   ]
 114 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
 115   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 116   lapply (IHV12 … HV20 ? ?) // -IHV12 HV20 #HV10
 117   lapply (IHT12 … HT20 ? ?) /2/
 118 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
 119   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 120   lapply (IHV12 … HV20 ? ?) // -IHV12 HV20 #HV10
 121   lapply (IHT12 … HT20 ? ?) /2/
 122 ]
 123 qed.
 124
 125 lemma lift_trans_le: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 126                      ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 → d2 ≤ d1 →
 127                      ∃∃T0. ↑[d2, e2] T1 ≡ T0 & ↑[d1 + e2, e1] T0 ≡ T2.
 128 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
 129 [ #k #d1 #e1 #d2 #e2 #X #HX #_
 130   >(lift_inv_sort1 … HX) -HX /2/
 131 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #_
 132   lapply (lt_to_le_to_lt … (d1+e2) Hid1 ?) // #Hie2
 133   elim (lift_inv_lref1 … HX) -HX * #Hid2 #HX destruct -X /4/
 134 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #Hd21
 135   lapply (transitive_le … Hd21 Hid1) -Hd21 #Hid2
 136   lapply (lift_inv_lref1_ge … HX ?) -HX /2/ #HX destruct -X;
 137   >plus_plus_comm_23 /4/
 138 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd21
 139   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 140   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 141   elim (IHT12 … HT20 ?) -IHT12 HT20 /3 width=5/
 142 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd21
 143   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 144   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 145   elim (IHT12 … HT20 ?) -IHT12 HT20 /3 width=5/
 146 ]
 147 qed.
 148
 149 lemma lift_trans_ge: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 150                      ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 → d1 + e1 ≤ d2 →
 151                      ∃∃T0. ↑[d2 - e1, e2] T1 ≡ T0 & ↑[d1, e1] T0 ≡ T2.
 152 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
 153 [ #k #d1 #e1 #d2 #e2 #X #HX #_
 154   >(lift_inv_sort1 … HX) -HX /2/
 155 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #Hded
 156   lapply (lt_to_le_to_lt … (d1+e1) Hid1 ?) // #Hid1e
 157   lapply (lt_to_le_to_lt … (d2-e1) Hid1 ?) /2/ #Hid2e
 158   lapply (lt_to_le_to_lt … Hid1e Hded) -Hid1e Hded #Hid2
 159   lapply (lift_inv_lref1_lt … HX ?) -HX // #HX destruct -X /3/
 160 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #_
 161   elim (lift_inv_lref1 … HX) -HX * #Hied #HX destruct -X;
 162   [2: >plus_plus_comm_23] /4/
 163 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hded
 164   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 165   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 166   elim (IHT12 … HT20 ?) -IHT12 HT20 /2/ #T
 167   <plus_minus /3 width=5/
 168 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hded
 169   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 170   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 171   elim (IHT12 … HT20 ?) -IHT12 HT20 /3 width=5/
 172 ]
 173 qed.