matita/matita/lib/lambda-delta/substitution/lift_main.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "lambda-delta/substitution/lift_defs.ma".
  16
  17 (* RELOCATION ***************************************************************)
  18
  19 (* the main properies *******************************************************)
  20
  21 theorem lift_conf_rev: ∀d1,e1,T1,T. ↑[d1,e1] T1 ≡ T →
  22                        ∀d2,e2,T2. ↑[d2 + e1, e2] T2 ≡ T →
  23                        d1 ≤ d2 →
  24                        ∃∃T0. ↑[d1, e1] T0 ≡ T2 & ↑[d2, e2] T0 ≡ T1.
  25 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
  26 [ #k #d1 #e1 #d2 #e2 #T2 #Hk #Hd12
  27   lapply (lift_inv_sort2 … Hk) -Hk #Hk destruct -T2 /3/
  28 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  29   lapply (lift_inv_lref2 … Hi) -Hi * * #Hid2 #H destruct -T2
  30   [ -Hid2 /4/
  31   | elim (lt_false d1 ?)
  32     @(le_to_lt_to_lt … Hd12) -Hd12 @(le_to_lt_to_lt … Hid1) -Hid1 /2/
  33   ]
  34 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  35   lapply (lift_inv_lref2 … Hi) -Hi * * #Hid2 #H destruct -T2
  36   [ -Hd12; lapply (lt_plus_to_lt_l … Hid2) -Hid2 #Hid2 /3/
  37   | -Hid1; lapply (arith1 … Hid2) -Hid2 #Hid2
  38     @(ex2_1_intro … #(i - e2))
  39     [ >le_plus_minus_comm [ @lift_lref_ge @(transitive_le … Hd12) -Hd12 /2/ | -Hd12 /2/ ]
  40     | -Hd12 >(plus_minus_m_m i e2) in ⊢ (? ? ? ? %) /3/
  41     ]
  42   ]
  43 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
  44   lapply (lift_inv_bind2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
  45   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
  46   >plus_plus_comm_23 in HU2 #HU2 elim (IHU … HU2 ?) /3 width = 5/
  47 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
  48   lapply (lift_inv_flat2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
  49   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
  50   elim (IHU … HU2 ?) /3 width = 5/
  51 ]
  52 qed.
  53
  54 theorem lift_free: ∀d1,e2,T1,T2. ↑[d1, e2] T1 ≡ T2 → ∀d2,e1.
  55                                  d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
  56                                  ∃∃T. ↑[d1, e1] T1 ≡ T & ↑[d2, e2 - e1] T ≡ T2.
  57 #d1 #e2 #T1 #T2 #H elim H -H d1 e2 T1 T2
  58 [ /3/
  59 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
  60   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4/
  61 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
  62   lapply (transitive_le …(i+e1) Hd21 ?) /2/ -Hd21 #Hd21
  63   <(plus_plus_minus_m_m e1 e2 i) /3/
  64 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  65   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  66   elim (IHT (d2+1) … ? ? He12) /3 width = 5/
  67 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  68   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  69   elim (IHT d2 … ? ? He12) /3 width = 5/
  70 ]
  71 qed.
  72
  73 theorem lift_trans: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
  74                     ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 →
  75                     d1 ≤ d2 → d2 ≤ d1 + e1 → ↑[d1, e1 + e2] T1 ≡ T2.
  76 #d1 #e1 #T1 #T #H elim H -d1 e1 T1 T
  77 [ #k #d1 #e1 #d2 #e2 #T2 #HT2 #_ #_
  78   >(lift_inv_sort1 … HT2) -HT2 //
  79 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #Hd12 #_
  80   lapply (lift_inv_lref1 … HT2) -HT2 * * #Hid2 #H destruct -T2
  81   [ -Hd12 Hid2 /2/
  82   | lapply (le_to_lt_to_lt … d1 Hid2 ?) // -Hid1 Hid2 #Hd21
  83     lapply (le_to_lt_to_lt … d1 Hd12 ?) // -Hd12 Hd21 #Hd11
  84     elim (lt_false … Hd11)
  85   ]
  86 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #_ #Hd21
  87   lapply (lift_inv_lref1 … HT2) -HT2 * * #Hid2 #H destruct -T2
  88   [ lapply (lt_to_le_to_lt … (d1+e1) Hid2 ?) // -Hid2 Hd21 #H
  89     lapply (lt_plus_to_lt_l … H) -H #H
  90     lapply (le_to_lt_to_lt … d1 Hid1 ?) // -Hid1 H #Hd11
  91     elim (lt_false … Hd11)
  92   | -Hd21 Hid2 /2/
  93   ]
  94 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
  95   lapply (lift_inv_bind1 … HX) -HX * #V0 #T0 #HV20 #HT20 #HX destruct -X;
  96   lapply (IHV12 … HV20 ? ?) // -IHV12 HV20 #HV10
  97   lapply (IHT12 … HT20 ? ?) /2/
  98 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
  99   lapply (lift_inv_flat1 … HX) -HX * #V0 #T0 #HV20 #HT20 #HX destruct -X;
 100   lapply (IHV12 … HV20 ? ?) // -IHV12 HV20 #HV10
 101   lapply (IHT12 … HT20 ? ?) /2/
 102 ]
 103 qed.
 104
 105 axiom lift_trans_le: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 106                      ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 → d2 ≤ d1 →
 107                      ∃∃T0. ↑[d2, e2] T1 ≡ T0 & ↑[d1 + e2, e1] T0 ≡ T2.
 108
 109 axiom lift_trans_ge: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 110                      ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 → d1 + e1 ≤ d2 →
 111                      ∃∃T0. ↑[d2 - e1, e2] T1 ≡ T0 & ↑[d1, e1] T0 ≡ T2.