matita/matita/lib/lambda-delta/substitution/pts_lift.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/substitution/lift_lift.ma".
  13 include "lambda-delta/substitution/drop_drop.ma".
  14 include "lambda-delta/substitution/pts.ma".
  15
  16 (* PARTIAL TELESCOPIC SUBSTITUTION ******************************************)
  17
  18 (* Relocation properties ****************************************************)
  19
  20 lemma pts_lift_le: ∀K,T1,T2,dt,et. K ⊢ T1 [dt, et] ≫ T2 →
  21                    ∀L,U1,U2,d,e. ↓[d, e] L ≡ K →
  22                    ↑[d, e] T1 ≡ U1 → ↑[d, e] T2 ≡ U2 →
  23                    dt + et ≤ d →
  24                    L ⊢ U1 [dt, et] ≫ U2.
  25 #K #T1 #T2 #dt #et #H elim H -H K T1 T2 dt et
  26 [ #K #k #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  27   lapply (lift_mono … H1 … H2) -H1 H2 #H destruct -U1 //
  28 | #K #i #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  29   lapply (lift_mono … H1 … H2) -H1 H2 #H destruct -U1 //
  30 | #K #KV #V #V1 #V2 #i #dt #et #Hdti #Hidet #HKV #_ #HV12 #IHV12 #L #U1 #U2 #d #e #HLK #H #HVU2 #Hdetd
  31   lapply (lt_to_le_to_lt … Hidet … Hdetd) #Hid
  32   lapply (lift_inv_lref1_lt … H … Hid) -H #H destruct -U1;
  33   elim (lift_trans_ge … HV12 … HVU2 ?) -HV12 HVU2 V2 // <minus_plus #V2 #HV12 #HVU2
  34   elim (drop_trans_le … HLK … HKV ?) -HLK HKV K /2/ #X #HLK #H
  35   elim (drop_inv_skip2 … H ?) -H /2/ -Hid #K #W #HKV #HVW #H destruct -X
  36   @pts_subst [4,5,6,8: // |1,2,3: skip | @IHV12 /2 width=6/ ] (**) (* explicit constructor *)
  37 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  38   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  39   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  40   @pts_bind [ /2 width=6/ | @IHT12 [3,4,5: /2/ |1,2: skip | /2/ ] ] (**) (* /3 width=6/ is too slow, arith3 needed to avoid crash *)
  41 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  42   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  43   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  44   /3 width=6/
  45 ]
  46 qed.
  47
  48 lemma pts_lift_ge: ∀K,T1,T2,dt,et. K ⊢ T1 [dt, et] ≫ T2 →
  49                    ∀L,U1,U2,d,e. ↓[d, e] L ≡ K →
  50                    ↑[d, e] T1 ≡ U1 → ↑[d, e] T2 ≡ U2 →
  51                    d ≤ dt →
  52                    L ⊢ U1 [dt + e, et] ≫ U2.
  53 #K #T1 #T2 #dt #et #H elim H -H K T1 T2 dt et
  54 [ #K #k #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  55   lapply (lift_mono … H1 … H2) -H1 H2 #H destruct -U1 //
  56 | #K #i #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  57   lapply (lift_mono … H1 … H2) -H1 H2 #H destruct -U1 //
  58 | #K #KV #V #V1 #V2 #i #dt #et #Hdti #Hidet #HKV #HV1 #HV12 #_ #L #U1 #U2 #d #e #HLK #H #HVU2 #Hddt
  59   <(arith_c1x ? ? ? e) in HV1 #HV1 (**) (* explicit athmetical rewrite and ?'s *)
  60   lapply (transitive_le … Hddt … Hdti) -Hddt #Hid
  61   lapply (lift_inv_lref1_ge … H … Hid) -H #H destruct -U1;
  62   lapply (lift_trans_be … HV12 … HVU2 ? ?) -HV12 HVU2 V2 /2/ >plus_plus_comm_23 #HV1U2
  63   lapply (drop_trans_ge_comm … HLK … HKV ?) -HLK HKV K // -Hid #HLKV
  64   @pts_subst [4,5: /2/ |6,7,8: // |1,2,3: skip ] (**) (* /3 width=8/ is too slow *)
  65 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  66   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  67   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  68   @pts_bind [ /2 width=5/ | /3 width=5/ ] (**) (* explicit constructor *)
  69 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  70   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  71   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  72   /3 width=5/
  73 ]
  74 qed.
  75
  76 lemma pts_inv_lift1_le: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
  77                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
  78                         dt + et ≤ d →
  79                         ∃∃T2. K ⊢ T1 [dt, et] ≫ T2 & ↑[d, e] T2 ≡ U2.
  80 #L #U1 #U2 #dt #et #H elim H -H L U1 U2 dt et
  81 [ #L #k #dt #et #K #d #e #_ #T1 #H #_
  82   lapply (lift_inv_sort2 … H) -H #H destruct -T1 /2/
  83 | #L #i #dt #et #K #d #e #_ #T1 #H #_
  84   elim (lift_inv_lref2 … H) -H * #Hid #H destruct -T1 /3/
  85 | #L #KV #V #V1 #V2 #i #dt #et #Hdti #Hidet #HLKV #_ #HV12 #IHV12 #K #d #e #HLK #T1 #H #Hdetd
  86   lapply (lt_to_le_to_lt … Hidet … Hdetd) #Hid
  87   lapply (lift_inv_lref2_lt … H … Hid) -H #H destruct -T1;
  88   elim (drop_conf_lt … HLK … HLKV ?) -HLK HLKV L // #L #W #HKL #HKVL #HWV
  89   elim (IHV12 … HKVL … HWV ?) -HKVL HWV /2/ -Hdetd #W1 #HW1 #HWV1
  90   elim (lift_trans_le … HWV1 … HV12 ?) -HWV1 HV12 V1 // >arith_a2 /3 width=6/
  91 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
  92   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
  93   elim (IHV12 … HLK … HWV1 ?) -IHV12 //
  94   elim (IHU12 … HTU1 ?) -IHU12 HTU1 [3: /2/ |4: @drop_skip // |2: skip ] -HLK HWV1 Hdetd /3 width=5/ (**) (* just /3 width=5/ is too slow *)
  95 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
  96   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
  97   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 //
  98   elim (IHU12 … HLK … HTU1 ?) -IHU12 HLK HTU1 // /3 width=5/
  99 ]
 100 qed.
 101
 102 lemma pts_inv_lift1_ge: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
 103                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
 104                         d + e ≤ dt →
 105                         ∃∃T2. K ⊢ T1 [dt - e, et] ≫ T2 & ↑[d, e] T2 ≡ U2.
 106 #L #U1 #U2 #dt #et #H elim H -H L U1 U2 dt et
 107 [ #L #k #dt #et #K #d #e #_ #T1 #H #_
 108   lapply (lift_inv_sort2 … H) -H #H destruct -T1 /2/
 109 | #L #i #dt #et #K #d #e #_ #T1 #H #_
 110   elim (lift_inv_lref2 … H) -H * #Hid #H destruct -T1 /3/
 111 | #L #KV #V #V1 #V2 #i #dt #et #Hdti #Hidet #HLKV #HV1 #HV12 #_ #K #d #e #HLK #T1 #H #Hdedt
 112   lapply (transitive_le … Hdedt … Hdti) #Hdei
 113   lapply (plus_le_weak … Hdedt) -Hdedt #Hedt
 114   lapply (plus_le_weak … Hdei) #Hei
 115   <(arith_h1 ? ? ? e ? ?) in HV1 // #HV1
 116   lapply (lift_inv_lref2_ge … H … Hdei) -H #H destruct -T1;
 117   lapply (drop_conf_ge … HLK … HLKV ?) -HLK HLKV L // #HKV
 118   elim (lift_split … HV12 d (i - e + 1) ? ? ?) -HV12; [2,3,4: normalize /2/ ] -Hdei >arith_e2 // #V0 #HV10 #HV02
 119   @ex2_1_intro
 120   [2: @pts_subst [4: /2/ |6,7,8: // |1,2,3: skip |5: @arith5 // ]
 121   |1: skip
 122   | //
 123   ] (**) (* explicitc constructors *)
 124 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 125   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 126   lapply (plus_le_weak … Hdetd) #Hedt
 127   elim (IHV12 … HLK … HWV1 ?) -IHV12 // #W2 #HW12 #HWV2
 128   elim (IHU12 … HTU1 ?) -IHU12 HTU1 [4: @drop_skip // |2: skip |3: /2/ ]
 129   <plus_minus // /3 width=5/
 130 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 131   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 132   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 //
 133   elim (IHU12 … HLK … HTU1 ?) -IHU12 HLK HTU1 // /3 width=5/
 134 ]
 135 qed.
 136
 137 lemma pts_inv_lift1_eq: ∀L,U1,U2,d,e.
 138                         L ⊢ U1 [d, e] ≫ U2 → ∀T1. ↑[d, e] T1 ≡ U1 → U1 = U2.
 139 #L #U1 #U2 #d #e #H elim H -H L U1 U2 d e
 140 [ //
 141 | //
 142 | #L #K #V #V1 #V2 #i #d #e #Hdi #Hide #_ #_ #_ #_ #T1 #H
 143   elim (lift_inv_lref2 … H) -H * #H
 144   [ lapply (le_to_lt_to_lt … Hdi … H) -Hdi H #H
 145     elim (lt_refl_false … H)
 146   | lapply (lt_to_le_to_lt … Hide … H) -Hide H #H
 147     elim (lt_refl_false … H)
 148   ]
 149 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 150   elim (lift_inv_bind2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
 151   >IHV12 // >IHT12 //
 152 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 153   elim (lift_inv_flat2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
 154   >IHV12 // >IHT12 //
 155 ]
 156 qed.
 157 (*
 158       Theorem subst0_gen_lift_ge : (u,t1,x:?; i,h,d:?) (subst0 i u (lift h d t1) x) ->
 159                                    (le (plus d h) i) ->
 160                                    (EX t2 | x = (lift h d t2) & (subst0 (minus i h) u t1 t2)).
 161
 162       Theorem subst0_gen_lift_rev_ge: (t1,v,u2:?; i,h,d:?)
 163                                       (subst0 i v t1 (lift h d u2)) ->
 164                                       (le (plus d h) i) ->
 165                                       (EX u1 | (subst0 (minus i h) v u1 u2) &
 166                                                t1 = (lift h d u1)
 167                                       ).
 168
 169
 170       Theorem subst0_gen_lift_rev_lelt: (t1,v,u2:?; i,h,d:?)
 171                                         (subst0 i v t1 (lift h d u2)) ->
 172                                         (le d i) -> (lt i (plus d h)) ->
 173                                         (EX u1 | t1 = (lift (minus (plus d h) (S i)) (S i) u1)).
 174 *)