matita/matita/lib/lambda-delta/substitution/tps.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/substitution/drop.ma".
  13
  14 (* PARTIAL SUBSTITUTION ON TERMS ********************************************)
  15
  16 inductive tps: lenv → term → nat → nat → term → Prop ≝
  17 | tps_sort : ∀L,k,d,e. tps L (⋆k) d e (⋆k)
  18 | tps_lref : ∀L,i,d,e. tps L (#i) d e (#i)
  19 | tps_subst: ∀L,K,V,U1,U2,i,d,e.
  20              d ≤ i → i < d + e →
  21              ↓[0, i] L ≡ K. 𝕓{Abbr} V → tps K V 0 (d + e - i - 1) U1 →
  22              ↑[0, i + 1] U1 ≡ U2 → tps L (#i) d e U2
  23 | tps_bind : ∀L,I,V1,V2,T1,T2,d,e.
  24              tps L V1 d e V2 → tps (L. 𝕓{I} V1) T1 (d + 1) e T2 →
  25              tps L (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  26 | tps_flat : ∀L,I,V1,V2,T1,T2,d,e.
  27              tps L V1 d e V2 → tps L T1 d e T2 →
  28              tps L (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  29 .
  30
  31 interpretation "partial telescopic substritution"
  32    'PSubst L T1 d e T2 = (tps L T1 d e T2).
  33
  34 (* Basic properties *********************************************************)
  35
  36 lemma tps_leq_repl: ∀L1,T1,T2,d,e. L1 ⊢ T1 [d, e] ≫ T2 →
  37                     ∀L2. L1 [d, e] ≈ L2 → L2 ⊢ T1 [d, e] ≫ T2.
  38 #L1 #T1 #T2 #d #e #H elim H -H L1 T1 T2 d e
  39 [ //
  40 | //
  41 | #L1 #K1 #V #V1 #V2 #i #d #e #Hdi #Hide #HLK1 #_ #HV12 #IHV12 #L2 #HL12
  42   elim (drop_leq_drop1 … HL12 … HLK1 ? ?) -HL12 HLK1 // #K2 #HK12 #HLK2
  43   @tps_subst [4,5,6,8: // |1,2,3: skip | /2/ ] (**) (* /3 width=6/ is too slow *)
  44 | /4/
  45 | /3/
  46 ]
  47 qed.
  48
  49 lemma tps_refl: ∀T,L,d,e. L ⊢ T [d, e] ≫ T.
  50 #T elim T -T //
  51 #I elim I -I /2/
  52 qed.
  53
  54 lemma tps_weak: ∀L,T1,T2,d1,e1. L ⊢ T1 [d1, e1] ≫ T2 →
  55                 ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  56                 L ⊢ T1 [d2, e2] ≫ T2.
  57 #L #T1 #T #d1 #e1 #H elim H -L T1 T d1 e1
  58 [ //
  59 | //
  60 | #L #K #V #V1 #V2 #i #d1 #e1 #Hid1 #Hide1 #HLK #_ #HV12 #IHV12 #d2 #e2 #Hd12 #Hde12
  61   lapply (transitive_le … Hd12 … Hid1) -Hd12 Hid1 #Hid2
  62   lapply (lt_to_le_to_lt … Hide1 … Hde12) -Hide1 #Hide2
  63   @tps_subst [4,5,6,8: // |1,2,3: skip | @IHV12 /2/ ] (**) (* /4 width=6/ is too slow *)
  64 | /4/
  65 | /4/
  66 ]
  67 qed.
  68
  69 lemma tps_weak_top: ∀L,T1,T2,d,e.
  70                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [d, |L| - d] ≫ T2.
  71 #L #T1 #T #d #e #H elim H -L T1 T d e
  72 [ //
  73 | //
  74 | #L #K #V #V1 #V2 #i #d #e #Hdi #_ #HLK #_ #HV12 #IHV12
  75   lapply (drop_fwd_drop2_length … HLK) #Hi
  76   lapply (le_to_lt_to_lt … Hdi Hi) #Hd
  77   lapply (plus_minus_m_m_comm (|L|) d ?) [ /2/ ] -Hd #Hd
  78   lapply (drop_fwd_O1_length … HLK) normalize #HKL
  79   lapply (tps_weak … IHV12 0 (|L| - i - 1) ? ?) -IHV12 // -HKL /2 width=6/
  80 | normalize /2/
  81 | /2/
  82 ]
  83 qed.
  84
  85 lemma tps_weak_all: ∀L,T1,T2,d,e.
  86                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [0, |L|] ≫ T2.
  87 #L #T1 #T #d #e #HT12
  88 lapply (tps_weak … HT12 0 (d + e) ? ?) -HT12 // #HT12
  89 lapply (tps_weak_top … HT12) //
  90 qed.
  91
  92 (* Basic inversion lemmas ***************************************************)
  93
  94 lemma tps_inv_lref1_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → ∀i. T1 = #i →
  95                          T2 = #i ∨
  96                          ∃∃K,V1,V2,i. d ≤ i & i < d + e &
  97                                       ↓[O, i] L ≡ K. 𝕓{Abbr} V1 &
  98                                       K ⊢ V1 [O, d + e - i - 1] ≫ V2 &
  99                                       ↑[O, i + 1] V2 ≡ T2.
 100 #L #T1 #T2 #d #e * -L T1 T2 d e
 101 [ #L #k #d #e #i #H destruct
 102 | /2/
 103 | #L #K #V1 #V2 #T2 #i #d #e #Hdi #Hide #HLK #HV12 #HVT2 #j #H destruct -i /3 width=9/
 104 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 105 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 106 ]
 107 qed.
 108
 109 lemma tps_inv_lref1: ∀L,T2,i,d,e. L ⊢ #i [d, e] ≫ T2 →
 110                      T2 = #i ∨
 111                      ∃∃K,V1,V2,i. d ≤ i & i < d + e &
 112                                   ↓[O, i] L ≡ K. 𝕓{Abbr} V1 &
 113                                   K ⊢ V1 [O, d + e - i - 1] ≫ V2 &
 114                                   ↑[O, i + 1] V2 ≡ T2.
 115 /2/ qed.
 116
 117 lemma tps_inv_bind1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 118                          ∀I,V1,T1. U1 = 𝕓{I} V1. T1 →
 119                          ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 120                                   L. 𝕓{I} V1 ⊢ T1 [d + 1, e] ≫ T2 &
 121                                   U2 =  𝕓{I} V2. T2.
 122 #d #e #L #U1 #U2 * -d e L U1 U2
 123 [ #L #k #d #e #I #V1 #T1 #H destruct
 124 | #L #i #d #e #I #V1 #T1 #H destruct
 125 | #L #K #V #U1 #U2 #i #d #e #_ #_ #_ #_ #_ #I #V1 #T1 #H destruct
 126 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 127 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 128 ]
 129 qed.
 130
 131 lemma tps_inv_bind1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕓{I} V1. T1 [d, e] ≫ U2 →
 132                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 133                               L. 𝕓{I} V1 ⊢ T1 [d + 1, e] ≫ T2 &
 134                               U2 =  𝕓{I} V2. T2.
 135 /2/ qed.
 136
 137 lemma tps_inv_flat1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 138                          ∀I,V1,T1. U1 = 𝕗{I} V1. T1 →
 139                          ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 140                                   U2 =  𝕗{I} V2. T2.
 141 #d #e #L #U1 #U2 * -d e L U1 U2
 142 [ #L #k #d #e #I #V1 #T1 #H destruct
 143 | #L #i #d #e #I #V1 #T1 #H destruct
 144 | #L #K #V #U1 #U2 #i #d #e #_ #_ #_ #_ #_ #I #V1 #T1 #H destruct
 145 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 146 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 147 ]
 148 qed.
 149
 150 lemma tps_inv_flat1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕗{I} V1. T1 [d, e] ≫ U2 →
 151                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 152                               U2 =  𝕗{I} V2. T2.
 153 /2/ qed.