matita/matita/lib/lambda-delta/substitution/tps_lift.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/substitution/drop_drop.ma".
  13 include "lambda-delta/substitution/tps.ma".
  14
  15 (* PARTIAL SUBSTITUTION ON TERMS ********************************************)
  16
  17 (* Relocation properties ****************************************************)
  18
  19 lemma tps_lift_le: ∀K,T1,T2,dt,et. K ⊢ T1 [dt, et] ≫ T2 →
  20                    ∀L,U1,U2,d,e. ↓[d, e] L ≡ K →
  21                    ↑[d, e] T1 ≡ U1 → ↑[d, e] T2 ≡ U2 →
  22                    dt + et ≤ d →
  23                    L ⊢ U1 [dt, et] ≫ U2.
  24 #K #T1 #T2 #dt #et #H elim H -H K T1 T2 dt et
  25 [ #K #k #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  26   lapply (lift_mono … H1 … H2) -H1 H2 #H destruct -U1 //
  27 | #K #i #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  28   lapply (lift_mono … H1 … H2) -H1 H2 #H destruct -U1 //
  29 | #K #KV #V #V1 #V2 #i #dt #et #Hdti #Hidet #HKV #_ #HV12 #IHV12 #L #U1 #U2 #d #e #HLK #H #HVU2 #Hdetd
  30   lapply (lt_to_le_to_lt … Hidet … Hdetd) #Hid
  31   lapply (lift_inv_lref1_lt … H … Hid) -H #H destruct -U1;
  32   elim (lift_trans_ge … HV12 … HVU2 ?) -HV12 HVU2 V2 // <minus_plus #V2 #HV12 #HVU2
  33   elim (drop_trans_le … HLK … HKV ?) -HLK HKV K /2/ #X #HLK #H
  34   elim (drop_inv_skip2 … H ?) -H /2/ -Hid #K #W #HKV #HVW #H destruct -X
  35   @tps_subst [4,5,6,8: // |1,2,3: skip | @IHV12 /2 width=6/ ] (**) (* explicit constructor *)
  36 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  37   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  38   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  39   @tps_bind [ /2 width=6/ | @IHT12 [3,4,5: /2/ |1,2: skip | /2/ ] ] (**) (* /3 width=6/ is too slow, arith3 needed to avoid crash *)
  40 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  41   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  42   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  43   /3 width=6/
  44 ]
  45 qed.
  46
  47 lemma tps_lift_ge: ∀K,T1,T2,dt,et. K ⊢ T1 [dt, et] ≫ T2 →
  48                    ∀L,U1,U2,d,e. ↓[d, e] L ≡ K →
  49                    ↑[d, e] T1 ≡ U1 → ↑[d, e] T2 ≡ U2 →
  50                    d ≤ dt →
  51                    L ⊢ U1 [dt + e, et] ≫ U2.
  52 #K #T1 #T2 #dt #et #H elim H -H K T1 T2 dt et
  53 [ #K #k #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  54   lapply (lift_mono … H1 … H2) -H1 H2 #H destruct -U1 //
  55 | #K #i #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  56   lapply (lift_mono … H1 … H2) -H1 H2 #H destruct -U1 //
  57 | #K #KV #V #V1 #V2 #i #dt #et #Hdti #Hidet #HKV #HV1 #HV12 #_ #L #U1 #U2 #d #e #HLK #H #HVU2 #Hddt
  58   <(arith_c1x ? ? ? e) in HV1 #HV1 (**) (* explicit athmetical rewrite and ?'s *)
  59   lapply (transitive_le … Hddt … Hdti) -Hddt #Hid
  60   lapply (lift_inv_lref1_ge … H … Hid) -H #H destruct -U1;
  61   lapply (lift_trans_be … HV12 … HVU2 ? ?) -HV12 HVU2 V2 /2/ >plus_plus_comm_23 #HV1U2
  62   lapply (drop_trans_ge_comm … HLK … HKV ?) -HLK HKV K // -Hid #HLKV
  63   @tps_subst [4,5: /2/ |6,7,8: // |1,2,3: skip ] (**) (* /3 width=8/ is too slow *)
  64 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  65   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  66   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  67   @tps_bind [ /2 width=5/ | /3 width=5/ ] (**) (* explicit constructor *)
  68 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  69   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  70   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  71   /3 width=5/
  72 ]
  73 qed.
  74
  75 lemma tps_inv_lift1_le: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
  76                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
  77                         dt + et ≤ d →
  78                         ∃∃T2. K ⊢ T1 [dt, et] ≫ T2 & ↑[d, e] T2 ≡ U2.
  79 #L #U1 #U2 #dt #et #H elim H -H L U1 U2 dt et
  80 [ #L #k #dt #et #K #d #e #_ #T1 #H #_
  81   lapply (lift_inv_sort2 … H) -H #H destruct -T1 /2/
  82 | #L #i #dt #et #K #d #e #_ #T1 #H #_
  83   elim (lift_inv_lref2 … H) -H * #Hid #H destruct -T1 /3/
  84 | #L #KV #V #V1 #V2 #i #dt #et #Hdti #Hidet #HLKV #_ #HV12 #IHV12 #K #d #e #HLK #T1 #H #Hdetd
  85   lapply (lt_to_le_to_lt … Hidet … Hdetd) #Hid
  86   lapply (lift_inv_lref2_lt … H … Hid) -H #H destruct -T1;
  87   elim (drop_conf_lt … HLK … HLKV ?) -HLK HLKV L // #L #W #HKL #HKVL #HWV
  88   elim (IHV12 … HKVL … HWV ?) -HKVL HWV /2/ -Hdetd #W1 #HW1 #HWV1
  89   elim (lift_trans_le … HWV1 … HV12 ?) -HWV1 HV12 V1 // >arith_a2 /3 width=6/
  90 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
  91   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
  92   elim (IHV12 … HLK … HWV1 ?) -IHV12 //
  93   elim (IHU12 … HTU1 ?) -IHU12 HTU1 [3: /2/ |4: @drop_skip // |2: skip ] -HLK HWV1 Hdetd /3 width=5/ (**) (* just /3 width=5/ is too slow *)
  94 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
  95   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
  96   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 //
  97   elim (IHU12 … HLK … HTU1 ?) -IHU12 HLK HTU1 // /3 width=5/
  98 ]
  99 qed.
 100
 101 lemma tps_inv_lift1_ge: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
 102                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
 103                         d + e ≤ dt →
 104                         ∃∃T2. K ⊢ T1 [dt - e, et] ≫ T2 & ↑[d, e] T2 ≡ U2.
 105 #L #U1 #U2 #dt #et #H elim H -H L U1 U2 dt et
 106 [ #L #k #dt #et #K #d #e #_ #T1 #H #_
 107   lapply (lift_inv_sort2 … H) -H #H destruct -T1 /2/
 108 | #L #i #dt #et #K #d #e #_ #T1 #H #_
 109   elim (lift_inv_lref2 … H) -H * #Hid #H destruct -T1 /3/
 110 | #L #KV #V #V1 #V2 #i #dt #et #Hdti #Hidet #HLKV #HV1 #HV12 #_ #K #d #e #HLK #T1 #H #Hdedt
 111   lapply (transitive_le … Hdedt … Hdti) #Hdei
 112   lapply (plus_le_weak … Hdedt) -Hdedt #Hedt
 113   lapply (plus_le_weak … Hdei) #Hei
 114   <(arith_h1 ? ? ? e ? ?) in HV1 // #HV1
 115   lapply (lift_inv_lref2_ge … H … Hdei) -H #H destruct -T1;
 116   lapply (drop_conf_ge … HLK … HLKV ?) -HLK HLKV L // #HKV
 117   elim (lift_split … HV12 d (i - e + 1) ? ? ?) -HV12; [2,3,4: normalize /2/ ] -Hdei >arith_e2 // #V0 #HV10 #HV02
 118   @ex2_1_intro
 119   [2: @tps_subst [4: /2/ |6,7,8: // |1,2,3: skip |5: @arith5 // ]
 120   |1: skip
 121   | //
 122   ] (**) (* explicitc constructors *)
 123 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 124   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 125   lapply (plus_le_weak … Hdetd) #Hedt
 126   elim (IHV12 … HLK … HWV1 ?) -IHV12 // #W2 #HW12 #HWV2
 127   elim (IHU12 … HTU1 ?) -IHU12 HTU1 [4: @drop_skip // |2: skip |3: /2/ ]
 128   <plus_minus // /3 width=5/
 129 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 130   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 131   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 //
 132   elim (IHU12 … HLK … HTU1 ?) -IHU12 HLK HTU1 // /3 width=5/
 133 ]
 134 qed.
 135
 136 lemma tps_inv_lift1_eq: ∀L,U1,U2,d,e.
 137                         L ⊢ U1 [d, e] ≫ U2 → ∀T1. ↑[d, e] T1 ≡ U1 → U1 = U2.
 138 #L #U1 #U2 #d #e #H elim H -H L U1 U2 d e
 139 [ //
 140 | //
 141 | #L #K #V #V1 #V2 #i #d #e #Hdi #Hide #_ #_ #_ #_ #T1 #H
 142   elim (lift_inv_lref2 … H) -H * #H
 143   [ lapply (le_to_lt_to_lt … Hdi … H) -Hdi H #H
 144     elim (lt_refl_false … H)
 145   | lapply (lt_to_le_to_lt … Hide … H) -Hide H #H
 146     elim (lt_refl_false … H)
 147   ]
 148 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 149   elim (lift_inv_bind2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
 150   >IHV12 // >IHT12 //
 151 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 152   elim (lift_inv_flat2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
 153   >IHV12 // >IHT12 //
 154 ]
 155 qed.
 156 (*
 157       Theorem subst0_gen_lift_ge : (u,t1,x:?; i,h,d:?) (subst0 i u (lift h d t1) x) ->
 158                                    (le (plus d h) i) ->
 159                                    (EX t2 | x = (lift h d t2) & (subst0 (minus i h) u t1 t2)).
 160
 161       Theorem subst0_gen_lift_rev_ge: (t1,v,u2:?; i,h,d:?)
 162                                       (subst0 i v t1 (lift h d u2)) ->
 163                                       (le (plus d h) i) ->
 164                                       (EX u1 | (subst0 (minus i h) v u1 u2) &
 165                                                t1 = (lift h d u1)
 166                                       ).
 167
 168
 169       Theorem subst0_gen_lift_rev_lelt: (t1,v,u2:?; i,h,d:?)
 170                                         (subst0 i v t1 (lift h d u2)) ->
 171                                         (le d i) -> (lt i (plus d h)) ->
 172                                         (EX u1 | t1 = (lift (minus (plus d h) (S i)) (S i) u1)).
 173 *)