matita/matita/lib/pts_dummy_new/subst.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambdaN/terms.ma".
  13
  14 (* arguments: k is the depth (starts from 0), p is the height (starts from 0) *)
  15 let rec lift t k p ≝
  16   match t with
  17     [ Sort n ⇒ Sort n
  18     | Rel n ⇒ if_then_else T (leb k n) (Rel (n+p)) (Rel n)
  19     | App m n ⇒ App (lift m k p) (lift n k p)
  20     | Lambda m n ⇒ Lambda (lift m k p) (lift n (k+1) p)
  21     | Prod m n ⇒ Prod (lift m k p) (lift n (k+1) p)
  22     | D n m ⇒ D (lift n k p) (lift m k p)
  23     ].
  24
  25 (*
  26 ndefinition lift ≝ λt.λp.lift_aux t 0 p.
  27
  28 notation "↑ ^ n ( M )" non associative with precedence 40 for @{'Lift O $M}.
  29 notation "↑ _ k ^ n ( M )" non associative with precedence 40 for @{'Lift $n $k $M}.
  30 *)
  31 (* interpretation "Lift" 'Lift n M = (lift M n). *)
  32 interpretation "Lift" 'Lift n k M = (lift M k n).
  33
  34 let rec subst t k a ≝
  35   match t with
  36     [ Sort n ⇒ Sort n
  37     | Rel n ⇒ if_then_else T (leb k n)
  38         (if_then_else T (eqb k n) (lift a 0 n) (Rel (n-1))) (Rel n)
  39     | App m n ⇒ App (subst m k a) (subst n k a)
  40     | Lambda m n ⇒ Lambda (subst m k a) (subst n (k+1) a)
  41     | Prod m n ⇒ Prod (subst m k a) (subst n (k+1) a)
  42     | D n m ⇒ D (subst n k a) (subst m k a)
  43     ].
  44
  45 (* meglio non definire
  46 ndefinition subst ≝ λa.λt.subst_aux t 0 a.
  47 notation "M [ N ]" non associative with precedence 90 for @{'Subst $N $M}.
  48 *)
  49
  50 (* interpretation "Subst" 'Subst N M = (subst N M). *)
  51 interpretation "Subst" 'Subst1 M k N = (subst M k N).
  52
  53 (*** properties of lift and subst ***)
  54
  55 lemma lift_0: ∀t:T.∀k. lift t k 0 = t.
  56 #t (elim t) normalize // #n #k cases (leb k n) normalize //
  57 qed.
  58
  59 (* nlemma lift_0: ∀t:T. lift t 0 = t.
  60 #t; nelim t; nnormalize; //; nqed. *)
  61
  62 lemma lift_sort: ∀i,k,n. lift (Sort i) k n = Sort i.
  63 // qed.
  64
  65 lemma lift_rel: ∀i,n. lift (Rel i) 0 n = Rel (i+n).
  66 // qed.
  67
  68 lemma lift_rel1: ∀i.lift (Rel i) 0 1 = Rel (S i).
  69 #i (change with (lift (Rel i) 0 1 = Rel (1 + i))) //
  70 qed.
  71
  72 lemma lift_rel_lt : ∀n,k,i. i < k → lift (Rel i) k n = Rel i.
  73 #n #k #i #ltik change with
  74 (if_then_else ? (leb k i) (Rel (i+n)) (Rel i) = Rel i)
  75 >(lt_to_leb_false … ltik) //
  76 qed.
  77
  78 lemma lift_rel_ge : ∀n,k,i. k ≤ i → lift (Rel i) k n = Rel (i+n).
  79 #n #k #i #leki change with
  80 (if_then_else ? (leb k i) (Rel (i+n)) (Rel i) = Rel (i+n))
  81 >le_to_leb_true //
  82 qed.
  83
  84 lemma lift_lift: ∀t.∀m,j.j ≤ m  → ∀n,k.
  85   lift (lift t k m) (j+k) n = lift t k (m+n).
  86 #t #i #j #h (elim t) normalize // #n #h #k
  87 @(leb_elim k n) #Hnk normalize
  88   [>(le_to_leb_true (j+k) (n+i) ?)
  89      normalize // >(commutative_plus j k) @le_plus //
  90   |>(lt_to_leb_false (j+k) n ?) normalize //
  91    @(transitive_le ? k) // @not_le_to_lt //
  92   ]
  93 qed.
  94
  95 lemma lift_lift_up: ∀n,m,t,k,i.
  96   lift (lift t i m) (m+k+i) n = lift (lift t (k+i) n) i m.
  97 #n #m #N (elim N)
  98   [1,3,4,5,6: normalize //
  99   |#p #k #i @(leb_elim i p);
 100     [#leip >lift_rel_ge // @(leb_elim (k+i) p);
 101       [#lekip >lift_rel_ge;
 102         [>lift_rel_ge // >lift_rel_ge // @(transitive_le … leip) //
 103         |>associative_plus >commutative_plus @monotonic_le_plus_l //
 104         ]
 105       |#lefalse (cut (p < k+i)) [@not_le_to_lt //] #ltpki
 106        >lift_rel_lt; [|>associative_plus >commutative_plus @monotonic_lt_plus_r //]
 107        >lift_rel_lt // >lift_rel_ge //
 108       ]
 109     |#lefalse (cut (p < i)) [@not_le_to_lt //] #ltpi
 110      >lift_rel_lt // >lift_rel_lt; [|@(lt_to_le_to_lt … ltpi) //]
 111      >lift_rel_lt; [|@(lt_to_le_to_lt … ltpi) //]
 112      >lift_rel_lt //
 113     ]
 114   ]
 115 qed.
 116
 117 lemma lift_lift1: ∀t.∀i,j,k.
 118   lift(lift t k j) k i = lift t k (j+i).
 119 /2/ qed.
 120
 121 lemma lift_lift2: ∀t.∀i,j,k.
 122   lift (lift t k j) (j+k) i = lift t k (j+i).
 123 /2/ qed.
 124
 125 (*
 126 nlemma lift_lift: ∀t.∀i,j. lift (lift t j) i = lift t (j+i).
 127 nnormalize; //; nqed. *)
 128
 129 lemma subst_lift_k: ∀A,B.∀k. (lift B k 1)[k ≝ A] = B.
 130 #A #B (elim B) normalize /2/ #n #k
 131 @(leb_elim k n) normalize #Hnk
 132   [cut (k ≤ n+1) [@transitive_le //] #H
 133    >(le_to_leb_true … H) normalize
 134    >(not_eq_to_eqb_false k (n+1)) normalize /2/
 135   |>(lt_to_leb_false … (not_le_to_lt … Hnk)) normalize //
 136   ]
 137 qed.
 138
 139 (*
 140 nlemma subst_lift: ∀A,B. subst A (lift B 1) = B.
 141 nnormalize; //; nqed. *)
 142
 143 lemma subst_sort: ∀A.∀n,k.(Sort n) [k ≝ A] = Sort n.
 144 // qed.
 145
 146 lemma subst_rel: ∀A.(Rel 0) [0 ≝ A] = A.
 147 normalize // qed.
 148
 149 lemma subst_rel1: ∀A.∀k,i. i < k →
 150   (Rel i) [k ≝ A] = Rel i.
 151 #A #k #i normalize #ltik >(lt_to_leb_false … ltik) //
 152 qed.
 153
 154 lemma subst_rel2: ∀A.∀k.
 155   (Rel k) [k ≝ A] = lift A 0 k.
 156 #A #k normalize >(le_to_leb_true k k) // >(eq_to_eqb_true … (refl …)) //
 157 qed.
 158
 159 lemma subst_rel3: ∀A.∀k,i. k < i →
 160   (Rel i) [k ≝ A] = Rel (i-1).
 161 #A #k #i normalize #ltik >(le_to_leb_true k i) /2/
 162 >(not_eq_to_eqb_false k i) // @lt_to_not_eq //
 163 qed.
 164
 165 lemma lift_subst_ijk: ∀A,B.∀i,j,k.
 166   lift (B [j+k := A]) k i = (lift B k i) [j+k+i ≝ A].
 167 #A #B #i #j (elim B) normalize /2/ #n #k
 168 @(leb_elim (j+k) n) normalize #Hnjk
 169   [@(eqb_elim (j+k) n) normalize #Heqnjk
 170     [>(le_to_leb_true k n) //
 171      (cut (j+k+i = n+i)) [//] #Heq
 172      >Heq >(subst_rel2 A ?) (applyS lift_lift) //
 173     |(cut (j + k < n))
 174       [@not_eq_to_le_to_lt; /2/] #ltjkn
 175      (cut (O < n)) [/2/] #posn (cut (k ≤ n)) [/2/] #lekn
 176      >(le_to_leb_true k (n-1)) normalize
 177       [>(le_to_leb_true … lekn)
 178        >(subst_rel3 A (j+k+i) (n+i)); [/3/ |/2/]
 179       |(applyS monotonic_pred) @le_plus_b //
 180       ]
 181     ]
 182   |(elim (leb k n))
 183     [>(subst_rel1 A (j+k+i) (n+i)) // @monotonic_lt_plus_l /2/
 184     |>(subst_rel1 A (j+k+i) n) // @(lt_to_le_to_lt ? (j+k)) /2/
 185     ]
 186   ]
 187 qed.
 188
 189 lemma lift_subst_up: ∀M,N,n,i,j.
 190   lift M[i≝N] (i+j) n = (lift M (i+j+1) n)[i≝ (lift N j n)].
 191 #M (elim M)
 192   [//
 193   |#p #N #n #i #j (cases (true_or_false (leb p i)))
 194     [#lepi (cases (le_to_or_lt_eq … (leb_true_to_le … lepi)))
 195       [#ltpi >(subst_rel1 … ltpi)
 196        (cut (p < i+j)) [@(lt_to_le_to_lt … ltpi) //] #ltpij
 197        >(lift_rel_lt … ltpij); >(lift_rel_lt ?? p ?);
 198         [>subst_rel1 // | @(lt_to_le_to_lt … ltpij) //]
 199       |#eqpi >eqpi >subst_rel2 >lift_rel_lt;
 200         [>subst_rel2 >(plus_n_O (i+j))
 201          applyS lift_lift_up
 202         |@(le_to_lt_to_lt ? (i+j)) //
 203         ]
 204       ]
 205     |#lefalse (cut (i < p)) [@not_le_to_lt /2/] #ltip
 206      (cut (0 < p)) [@(le_to_lt_to_lt … ltip) //] #posp
 207      >(subst_rel3 … ltip) (cases (true_or_false (leb (S p) (i+j+1))))
 208       [#Htrue (cut (p < i+j+1)) [@(leb_true_to_le … Htrue)] #Hlt
 209        >lift_rel_lt;
 210         [>lift_rel_lt // >(subst_rel3 … ltip) // | @lt_plus_to_minus //]
 211       |#Hfalse >lift_rel_ge;
 212         [>lift_rel_ge;
 213           [>subst_rel3; [@eq_f /2/ | @(lt_to_le_to_lt … ltip) //]
 214           |@not_lt_to_le @(leb_false_to_not_le … Hfalse)
 215           ]
 216         |@le_plus_to_minus_r @not_lt_to_le
 217          @(leb_false_to_not_le … Hfalse)
 218         ]
 219       ]
 220     ]
 221   |#P #Q #HindP #HindQ #N #n #i #j normalize
 222    @eq_f2; [@HindP |@HindQ ]
 223   |#P #Q #HindP #HindQ #N #n #i #j normalize
 224    @eq_f2; [@HindP |>associative_plus >(commutative_plus j 1)
 225    <associative_plus @HindQ]
 226   |#P #Q #HindP #HindQ #N #n #i #j normalize
 227    @eq_f2; [@HindP |>associative_plus >(commutative_plus j 1)
 228    <associative_plus @HindQ]
 229   |#P #Q #HindP #HindQ #N #n #i #j normalize
 230    @eq_f2; [@HindP |@HindQ ]
 231   ]
 232 qed.
 233
 234 theorem delift : ∀A,B.∀i,j,k. i ≤ j → j ≤ i + k →
 235   (lift B i (S k)) [j ≝ A] = lift B i k.
 236 #A #B (elim B) normalize /2/
 237   [2,3,4,5: #T #T0 #Hind1 #Hind2 #i #j #k #leij #lejk
 238    @eq_f2 /2/ @Hind2 (applyS (monotonic_le_plus_l 1)) //
 239   |#n #i #j #k #leij #ltjk @(leb_elim i n) normalize #len
 240     [cut (j < n + S k)
 241       [<plus_n_Sm @le_S_S @(transitive_le … ltjk) /2/] #H
 242      >(le_to_leb_true j (n+S k));
 243       [normalize >(not_eq_to_eqb_false j (n+S k)) normalize /2/
 244       |/2/
 245       ]
 246     |>(lt_to_leb_false j n) // @(lt_to_le_to_lt … leij)
 247      @not_le_to_lt //
 248     ]
 249   ]
 250 qed.
 251
 252 (********************* substitution lemma ***********************)
 253
 254 lemma subst_lemma: ∀A,B,C.∀k,i.
 255   (A [i ≝ B]) [k+i ≝ C] =
 256     (A [(k+i)+1:= C]) [i ≝ B [k ≝ C]].
 257 #A #B #C #k (elim A) normalize // (* WOW *)
 258 #n #i @(leb_elim i n) #Hle
 259   [@(eqb_elim i n) #eqni
 260     [<eqni >(lt_to_leb_false (k+i+1) i) // >(subst_rel2 …);
 261      normalize @sym_eq (applyS (lift_subst_ijk C B i k O))
 262     |(cut (i < n))
 263       [cases (le_to_or_lt_eq … Hle) // #eqin @False_ind /2/] #ltin
 264      (cut (O < n)) [@(le_to_lt_to_lt … ltin) //] #posn
 265      normalize @(leb_elim (k+i) (n-1)) #nk
 266       [@(eqb_elim (k+i) (n-1)) #H normalize
 267         [cut (k+i+1 = n); [/2/] #H1
 268          >(le_to_leb_true (k+i+1) n) /2/
 269          >(eq_to_eqb_true … H1) normalize
 270          (generalize in match ltin)
 271          @(lt_O_n_elim … posn) #m #leim >delift // /2/
 272         |(cut (k+i < n-1)) [@not_eq_to_le_to_lt; //] #Hlt
 273          >(le_to_leb_true (k+i+1) n);
 274           [>(not_eq_to_eqb_false (k+i+1) n);
 275             [>(subst_rel3 ? i (n-1));
 276              // @(le_to_lt_to_lt … Hlt) //
 277             |@(not_to_not … H) #Hn /2/
 278             ]
 279           |@le_minus_to_plus_r //
 280           ]
 281         ]
 282       |>(not_le_to_leb_false (k+i+1) n);
 283         [>(subst_rel3 ? i n) normalize //
 284         |@(not_to_not … nk) #H @le_plus_to_minus_r //
 285         ]
 286       ]
 287     ]
 288   |(cut (n < k+i)) [@(lt_to_le_to_lt ? i) /2/] #ltn (* lento *)
 289    (* (cut (n ≤ k+i)) [/2/] #len *)
 290    >(subst_rel1 C (k+i) n ltn) >(lt_to_leb_false (k+i+1) n);
 291     [>subst_rel1 /2/ | @(transitive_lt …ltn) // ]
 292   ]
 293 qed.