matita/matita/lib/re/moves.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "re/re.ma".
  16
  17 let rec move (S: DeqSet) (x:S) (E: pitem S) on E : pre S ≝
  18  match E with
  19   [ pz ⇒ 〈 ∅, false 〉
  20   | pe ⇒ 〈 ϵ, false 〉
  21   | ps y ⇒ 〈 `y, false 〉
  22   | pp y ⇒ 〈 `y, x == y 〉
  23   | po e1 e2 ⇒ (move ? x e1) ⊕ (move ? x e2)
  24   | pc e1 e2 ⇒ (move ? x e1) ⊙ (move ? x e2)
  25   | pk e ⇒ (move ? x e)^⊛ ].
  26
  27 lemma move_plus: ∀S:DeqSet.∀x:S.∀i1,i2:pitem S.
  28   move S x (i1 + i2) = (move ? x i1) ⊕ (move ? x i2).
  29 // qed.
  30
  31 lemma move_cat: ∀S:DeqSet.∀x:S.∀i1,i2:pitem S.
  32   move S x (i1 · i2) = (move ? x i1) ⊙ (move ? x i2).
  33 // qed.
  34
  35 lemma move_star: ∀S:DeqSet.∀x:S.∀i:pitem S.
  36   move S x i^* = (move ? x i)^⊛.
  37 // qed.
  38
  39 lemma fst_eq : ∀A,B.∀a:A.∀b:B. \fst 〈a,b〉 = a.
  40 // qed.
  41
  42 lemma snd_eq : ∀A,B.∀a:A.∀b:B. \snd 〈a,b〉 = b.
  43 // qed.
  44
  45 definition pmove ≝ λS:DeqSet.λx:S.λe:pre S. move ? x (\fst e).
  46
  47 lemma pmove_def : ∀S:DeqSet.∀x:S.∀i:pitem S.∀b.
  48   pmove ? x 〈i,b〉 = move ? x i.
  49 // qed.
  50
  51 lemma eq_to_eq_hd: ∀A.∀l1,l2:list A.∀a,b.
  52   a::l1 = b::l2 → a = b.
  53 #A #l1 #l2 #a #b #H destruct //
  54 qed.
  55
  56 axiom same_kernel: ∀S:DeqSet.∀a:S.∀i:pitem S.
  57   |\fst (move ? a i)| = |i|.
  58 (* #S #a #i elim i //
  59   [#i1 #i2 >move_cat
  60    cases (move S a i1) #i11 #b1 >fst_eq #IH1
  61    cases (move S a i2) #i21 #b2 >fst_eq #IH2
  62    normalize *)
  63
  64 axiom epsilon_in_star: ∀S.∀A:word S → Prop. A^* [ ].
  65
  66 theorem move_ok:
  67  ∀S:DeqSet.∀a:S.∀i:pitem S.∀w: word S.
  68    \sem{move ? a i} w ↔ \sem{i} (a::w).
  69 #S #a #i elim i
  70   [normalize /2/
  71   |normalize /2/
  72   |normalize /2/
  73   |normalize #x #w cases (true_or_false (a==x)) #H >H normalize
  74     [>(proj1 … (eqb_true …) H) %
  75       [* // #bot @False_ind //| #H1 destruct /2/]
  76     |% [#bot @False_ind //
  77        | #H1 destruct @(absurd ((a==a)=true))
  78          [>(proj2 … (eqb_true …) (refl …)) // | /2/]
  79        ]
  80     ]
  81   |#i1 #i2 #HI1 #HI2 #w >(sem_cat S i1 i2) >move_cat
  82    @iff_trans[|@sem_odot] >same_kernel >sem_cat_w
  83    @iff_trans[||@(iff_or_l … (HI2 w))] @iff_or_r %
  84     [* #w1 * #w2 * * #eqw #w1in #w2in @(ex_intro … (a::w1))
  85      @(ex_intro … w2) % // % normalize // cases (HI1 w1) /2/
  86     |* #w1 * #w2 * cases w1
  87       [* #_ #H @False_ind /2/
  88       |#x #w3 * #eqaw normalize in eqaw; destruct #w3in #w2in
  89       @(ex_intro … w3) @(ex_intro … w2) % // % // cases (HI1 w3) /2/
  90       ]
  91     ]
  92   |#i1 #i2 #HI1 #HI2 #w >(sem_plus S i1 i2) >move_plus >sem_plus_w
  93    @iff_trans[|@sem_oplus]
  94    @iff_trans[|@iff_or_l [|@HI2]| @iff_or_r //]
  95   |#i1 #HI1 #w >move_star
  96    @iff_trans[|@sem_ostar] >same_kernel >sem_star_w %
  97     [* #w1 * #w2 * * #eqw #w1in #w2in
  98      @(ex_intro … (a::w1)) @(ex_intro … w2) % // % normalize //
  99      cases (HI1 w1 ) /2/
 100     |* #w1 * #w2 * cases w1
 101       [* #_ #H @False_ind /2/
 102       |#x #w3 * #eqaw normalize in eqaw; destruct #w3in #w2in
 103        @(ex_intro … w3) @(ex_intro … w2) % // % // cases (HI1 w3) /2/
 104       ]
 105     ]
 106   ]
 107 qed.
 108
 109 notation > "x ↦* E" non associative with precedence 60 for @{moves ? $x $E}.
 110 let rec moves (S : DeqSet) w e on w : pre S ≝
 111  match w with
 112   [ nil ⇒ e
 113   | cons x w' ⇒ w' ↦* (move S x (\fst e))].
 114
 115 lemma moves_empty: ∀S:DeqSet.∀e:pre S.
 116   moves ? [ ] e = e.
 117 // qed.
 118
 119 lemma moves_cons: ∀S:DeqSet.∀a:S.∀w.∀e:pre S.
 120   moves ? (a::w)  e = moves ? w (move S a (\fst e)).
 121 // qed.
 122
 123 lemma not_epsilon_sem: ∀S:DeqSet.∀a:S.∀w: word S. ∀e:pre S.
 124   iff ((a::w) ∈ e) ((a::w) ∈ \fst e).
 125 #S #a #w * #i #b >fst_eq cases b normalize
 126   [% /2/ * // #H destruct |% normalize /2/]
 127 qed.
 128
 129 lemma same_kernel_moves: ∀S:DeqSet.∀w.∀e:pre S.
 130   |\fst (moves ? w e)| = |\fst e|.
 131 #S #w elim w //
 132 qed.
 133
 134 theorem decidable_sem: ∀S:DeqSet.∀w: word S. ∀e:pre S.
 135    (\snd (moves ? w e) = true)  ↔ \sem{e} w.
 136 #S #w elim w
 137  [* #i #b >moves_empty cases b % /2/
 138  |#a #w1 #Hind #e >moves_cons
 139   @iff_trans [||@iff_sym @not_epsilon_sem]
 140   @iff_trans [||@move_ok] @Hind
 141  ]
 142 qed.
 143
 144 lemma not_true_to_false: ∀b.b≠true → b =false.
 145 #b * cases b // #H @False_ind /2/
 146 qed.
 147
 148 theorem equiv_sem: ∀S:DeqSet.∀e1,e2:pre S.
 149   iff (\sem{e1} =1 \sem{e2}) (∀w.\snd (moves ? w e1) = \snd (moves ? w e2)).
 150 #S #e1 #e2 %
 151 [#same_sem #w
 152   cut (∀b1,b2. iff (b1 = true) (b2 = true) → (b1 = b2))
 153     [* * // * #H1 #H2 [@sym_eq @H1 //| @H2 //]]
 154   #Hcut @Hcut @iff_trans [|@decidable_sem]
 155   @iff_trans [|@same_sem] @iff_sym @decidable_sem
 156 |#H #w1 @iff_trans [||@decidable_sem] <H @iff_sym @decidable_sem]
 157 qed.
 158
 159 axiom moves_left : ∀S,a,w,e.
 160   moves S (w@[a]) e = move S a (\fst (moves S w e)).
 161
 162 definition in_moves ≝ λS:DeqSet.λw.λe:pre S. \snd(w ↦* e).
 163
 164 coinductive equiv (S:DeqSet) : pre S → pre S → Prop ≝
 165  mk_equiv:
 166   ∀e1,e2: pre S.
 167    \snd e1  = \snd e2 →
 168     (∀x. equiv S (move ? x (\fst e1)) (move ? x (\fst e2))) →
 169      equiv S e1 e2.
 170
 171 definition beqb ≝ λb1,b2.
 172   match b1 with
 173   [ true ⇒ b2
 174   | false ⇒ notb b2
 175   ].
 176
 177 lemma beqb_ok: ∀b1,b2. iff (beqb b1 b2 = true) (b1 = b2).
 178 #b1 #b2 cases b1 cases b2 normalize /2/
 179 qed.
 180
 181 definition Bin ≝ mk_DeqSet bool beqb beqb_ok.
 182
 183 let rec beqitem S (i1,i2: pitem S) on i1 ≝
 184   match i1 with
 185   [ pz ⇒ match i2 with [ pz ⇒ true | _ ⇒ false]
 186   | pe ⇒ match i2 with [ pe ⇒ true | _ ⇒ false]
 187   | ps y1 ⇒ match i2 with [ ps y2 ⇒ y1==y2 | _ ⇒ false]
 188   | pp y1 ⇒ match i2 with [ pp y2 ⇒ y1==y2 | _ ⇒ false]
 189   | po i11 i12 ⇒ match i2 with
 190     [ po i21 i22 ⇒ beqitem S i11 i21 ∧ beqitem S i12 i22
 191     | _ ⇒ false]
 192   | pc i11 i12 ⇒ match i2 with
 193     [ pc i21 i22 ⇒ beqitem S i11 i21 ∧ beqitem S i12 i22
 194     | _ ⇒ false]
 195   | pk i11 ⇒ match i2 with [ pk i21 ⇒ beqitem S i11 i21 | _ ⇒ false]
 196   ].
 197
 198 axiom beqitem_ok: ∀S,i1,i2. iff (beqitem S i1 i2 = true) (i1 = i2).
 199
 200 definition BinItem ≝
 201   mk_DeqSet (pitem Bin) (beqitem Bin) (beqitem_ok Bin).
 202
 203 definition beqpre ≝ λS:DeqSet.λe1,e2:pre S.
 204   beqitem S (\fst e1) (\fst e2) ∧ beqb (\snd e1) (\snd e2).
 205
 206 definition beqpairs ≝ λS:DeqSet.λp1,p2:(pre S)×(pre S).
 207   beqpre S (\fst p1) (\fst p2) ∧ beqpre S (\snd p1) (\snd p2).
 208
 209 axiom beqpairs_ok: ∀S,p1,p2. iff (beqpairs S p1 p2 = true) (p1 = p2).
 210
 211 definition space ≝ λS.mk_DeqSet ((pre S)×(pre S)) (beqpairs S) (beqpairs_ok S).
 212
 213 definition sons ≝ λp:space Bin.
 214   [〈move Bin true (\fst (\fst p)), move Bin true (\fst (\snd p))〉;
 215    〈move Bin false (\fst (\fst p)), move Bin false (\fst (\snd p))〉
 216   ].
 217
 218 axiom memb_sons: ∀p,q. memb (space Bin) p (sons q) = true →
 219   ∃a.(move ? a (\fst (\fst q)) = \fst p ∧
 220       move ? a (\fst (\snd q)) = \snd p).
 221
 222 (*
 223 let rec test_sons (l:list (space Bin)) ≝
 224   match l with
 225   [ nil ⇒  true
 226   | cons hd tl ⇒
 227     beqb (\snd (\fst hd)) (\snd (\snd hd)) ∧ test_sons tl
 228   ]. *)
 229
 230 let rec bisim (n:nat) (frontier,visited: list (space Bin)) ≝
 231   match n with
 232   [ O ⇒ 〈false,visited〉 (* assert false *)
 233   | S m ⇒
 234     match frontier with
 235     [ nil ⇒ 〈true,visited〉
 236     | cons hd tl ⇒
 237       if beqb (\snd (\fst hd)) (\snd (\snd hd)) then
 238         bisim m (unique_append ? (filter ? (λx.notb (memb ? x (hd::visited)))
 239         (sons hd)) tl) (hd::visited)
 240       else 〈false,visited〉
 241     ]
 242   ].
 243
 244 lemma unfold_bisim: ∀n.∀frontier,visited: list (space Bin).
 245   bisim n frontier visited =
 246   match n with
 247   [ O ⇒ 〈false,visited〉 (* assert false *)
 248   | S m ⇒
 249     match frontier with
 250     [ nil ⇒ 〈true,visited〉
 251     | cons hd tl ⇒
 252       if beqb (\snd (\fst hd)) (\snd (\snd hd)) then
 253         bisim m (unique_append ? (filter ? (λx.notb(memb ? x (hd::visited))) (sons hd)) tl) (hd::visited)
 254       else 〈false,visited〉
 255     ]
 256   ].
 257 #n cases n // qed.
 258
 259 lemma bisim_never: ∀frontier,visited: list (space Bin).
 260   bisim O frontier visited = 〈false,visited〉.
 261 #frontier #visited >unfold_bisim //
 262 qed.
 263
 264 lemma bisim_end: ∀m.∀visited: list (space Bin).
 265   bisim (S m) [] visited = 〈true,visited〉.
 266 #n #visisted >unfold_bisim //
 267 qed.
 268
 269 lemma bisim_step_true: ∀m.∀p.∀frontier,visited: list (space Bin).
 270 beqb (\snd (\fst p)) (\snd (\snd p)) = true →
 271   bisim (S m) (p::frontier) visited =
 272   bisim m (unique_append ? (filter ? (λx.notb(memb (space Bin) x (p::visited))) (sons p)) frontier) (p::visited).
 273 #m #p #frontier #visited #test >unfold_bisim normalize nodelta >test //
 274 qed.
 275
 276 lemma bisim_step_false: ∀m.∀p.∀frontier,visited: list (space Bin).
 277 beqb (\snd (\fst p)) (\snd (\snd p)) = false →
 278   bisim (S m) (p::frontier) visited = 〈false,visited〉.
 279 #m #p #frontier #visited #test >unfold_bisim normalize nodelta >test //
 280 qed.
 281
 282 definition visited_inv ≝ λe1,e2:pre Bin.λvisited: list (space Bin).
 283 uniqueb ? visited = true ∧
 284   ∀p. memb ? p visited = true →
 285    (∃w.(moves Bin w e1 = \fst p) ∧ (moves Bin w e2 = \snd p)) ∧
 286    (beqb (\snd (\fst p)) (\snd (\snd p)) = true).
 287
 288 definition frontier_inv ≝ λfrontier,visited: list (space Bin).
 289 uniqueb ? frontier = true ∧
 290 ∀p. memb ? p frontier = true →
 291   memb ? p visited = false ∧
 292   ∃p1.((memb ? p1 visited = true) ∧
 293    (∃a. move ? a (\fst (\fst p1)) = \fst p ∧
 294         move ? a (\fst (\snd p1)) = \snd p)).
 295
 296 (* lemma andb_true: ∀b1,b2:bool.
 297   (b1 ∧ b2) = true → (b1 = true) ∧ (b2 = true).
 298 #b1 #b2 cases b1 normalize #H [>H /2/ |@False_ind /2/].
 299 qed.
 300
 301 lemma andb_true_r: ∀b1,b2:bool.
 302   (b1 = true) ∧ (b2 = true) → (b1 ∧ b2) = true.
 303 #b1 #b2 cases b1 normalize * //
 304 qed. *)
 305
 306 lemma notb_eq_true_l: ∀b. notb b = true → b = false.
 307 #b cases b normalize //
 308 qed.
 309
 310 lemma notb_eq_true_r: ∀b. b = false → notb b = true.
 311 #b cases b normalize //
 312 qed.
 313
 314 lemma notb_eq_false_l:∀b. notb b = false → b = true.
 315 #b cases b normalize //
 316 qed.
 317
 318 lemma notb_eq_false_r:∀b. b = true → notb b = false.
 319 #b cases b normalize //
 320 qed.
 321
 322
 323 include "arithmetics/exp.ma".
 324
 325 let rec pos S (i:re S) on i ≝
 326   match i with
 327   [ z ⇒ 0
 328   | e ⇒ 0
 329   | s y ⇒ 1
 330   | o i1 i2 ⇒ pos S i1 + pos S i2
 331   | c i1 i2 ⇒ pos S i1 + pos S i2
 332   | k i ⇒ pos S i
 333   ].
 334
 335
 336 let rec pitem_enum S (i:re S) on i ≝
 337   match i with
 338   [ z ⇒ [pz S]
 339   | e ⇒ [pe S]
 340   | s y ⇒ [ps S y; pp S y]
 341   | o i1 i2 ⇒ compose ??? (po S) (pitem_enum S i1) (pitem_enum S i2)
 342   | c i1 i2 ⇒ compose ??? (pc S) (pitem_enum S i1) (pitem_enum S i2)
 343   | k i ⇒ map ?? (pk S) (pitem_enum S i)
 344   ].
 345
 346 axiom pitem_enum_complete: ∀i: pitem Bin.
 347   memb BinItem i (pitem_enum ? (forget ? i)) = true.
 348 (*
 349 #i elim i
 350   [//
 351   |//
 352   |* //
 353   |* //
 354   |#i1 #i2 #Hind1 #Hind2 @memb_compose //
 355   |#i1 #i2 #Hind1 #Hind2 @memb_compose //
 356   |
 357 *)
 358
 359 definition pre_enum ≝ λS.λi:re S.
 360   compose ??? (λi,b.〈i,b〉) (pitem_enum S i) [true;false].
 361
 362 definition space_enum ≝ λS.λi1,i2:re S.
 363   compose ??? (λe1,e2.〈e1,e2〉) (pre_enum S i1) (pre_enum S i1).
 364
 365 axiom space_enum_complete : ∀S.∀e1,e2: pre S.
 366   memb (space S) 〈e1,e2〉 (space_enum S (|\fst e1|) (|\fst e2|)) = true.
 367
 368 lemma bisim_ok1: ∀e1,e2:pre Bin.\sem{e1}=1\sem{e2} →
 369  ∀n.∀frontier,visited:list (space Bin).
 370  |space_enum Bin (|\fst e1|) (|\fst e2|)| < n + |visited|→
 371  visited_inv e1 e2 visited →  frontier_inv frontier visited →
 372  \fst (bisim n frontier visited) = true.
 373 #e1 #e2 #same #n elim n
 374   [#frontier #visited #abs * #unique #H @False_ind @(absurd … abs)
 375    @le_to_not_lt @sublist_length // * #e11 #e21 #membp
 376    cut ((|\fst e11| = |\fst e1|) ∧ (|\fst e21| = |\fst e2|))
 377    [|* #H1 #H2 <H1 <H2 @space_enum_complete]
 378    cases (H … membp) * #w * >fst_eq >snd_eq #we1 #we2 #_
 379    <we1 <we2 % //
 380   |#m #HI * [#visited #vinv #finv >bisim_end //]
 381    #p #front_tl #visited #Hn * #u_visited #vinv * #u_frontier #finv
 382    cases (finv p (memb_hd …)) #Hp * #p2 * #visited_p2
 383    * #a * #movea1 #movea2
 384    cut (∃w.(moves Bin w e1 = \fst p) ∧ (moves Bin w e2 = \snd p))
 385      [cases (vinv … visited_p2) -vinv * #w1 * #mw1 #mw2 #_
 386       @(ex_intro … (w1@[a])) /2/]
 387    -movea2 -movea1 -a -visited_p2 -p2 #reachp
 388    cut (beqb (\snd (\fst p)) (\snd (\snd p)) = true)
 389      [cases reachp #w * #move_e1 #move_e2 <move_e1 <move_e2
 390       @(proj2 … (beqb_ok … )) @(proj1 … (equiv_sem … )) @same
 391      |#ptest >(bisim_step_true … ptest) @HI -HI
 392        [<plus_n_Sm //
 393        |% [@andb_true_r % [@notb_eq_false_l // | // ]]
 394         #p1 #H (cases (orb_true_l … H))
 395          [#eqp <(proj1 … (eqb_true (space Bin) ? p1) eqp) % //
 396          |#visited_p1 @(vinv … visited_p1)
 397          ]
 398        |whd % [@unique_append_unique @(andb_true_r … u_frontier)]
 399         @unique_append_elim #q #H
 400          [%
 401            [@notb_eq_true_l @(filter_true … H)
 402            |@(ex_intro … p) % //
 403             @(memb_sons … (memb_filter_memb … H))
 404            ]
 405          |cases (finv q ?) [|@memb_cons //]
 406           #nvq * #p1 * #Hp1 #reach %
 407            [cut ((p==q) = false) [|#Hpq whd in ⊢ (??%?); >Hpq @nvq]
 408             cases (andb_true_l … u_frontier) #notp #_
 409             @(not_memb_to_not_eq … H) @notb_eq_true_l @notp
 410            |cases (proj2 … (finv q ?))
 411              [#p1 *  #Hp1 #reach @(ex_intro … p1) % // @memb_cons //
 412              |@memb_cons //
 413              ]
 414           ]
 415         ]
 416       ]
 417     ]
 418   ]
 419 qed.
 420
 421 definition all_true ≝ λl.∀p. memb (space Bin) p l = true →
 422   (beqb (\snd (\fst p)) (\snd (\snd p)) = true).
 423
 424 definition sub_sons ≝ λl1,l2.∀x,a.
 425 memb (space Bin) x l1 = true →
 426   memb (space Bin) 〈move ? a (\fst (\fst x)), move ? a (\fst (\snd x))〉 l2 = true.
 427
 428 lemma reachable_bisim:
 429  ∀n.∀frontier,visited,visited_res:list (space Bin).
 430  all_true visited →
 431  sub_sons visited (frontier@visited) →
 432  bisim n frontier visited = 〈true,visited_res〉 →
 433   (sub_sons visited_res visited_res ∧
 434    sublist ? visited visited_res ∧
 435    all_true visited_res).
 436 #n elim n
 437   [#fron #vis #vis_res #_ #_ >bisim_never #H destruct
 438   |#m #Hind *
 439     [-Hind #vis #vis_res #allv #H normalize in  ⊢ (%→?);
 440      #H1 destruct % // % // #p /2/
 441     |#hd cases (true_or_false (beqb (\snd (\fst hd)) (\snd (\snd hd))))
 442       [|#H #tl #vis #vis_res #allv >(bisim_step_false … H) #_ #H1 destruct]
 443      #H #tl #visited #visited_res #allv >(bisim_step_true … H)
 444      cut (all_true (hd::visited))
 445       [#p #H cases (orb_true_l … H)
 446         [#eqp <(proj1 … (eqb_true …) eqp) // |@allv]]
 447      #allh #subH #bisim cases (Hind … allh … bisim) -Hind
 448       [* #H1 #H2 #H3 % // % // #p #H4 @H2 @memb_cons //]
 449      #x #a #membx
 450      cases (orb_true_l … membx)
 451       [#eqhdx >(proj1 … (eqb_true …) eqhdx)
 452        letin xa ≝ 〈move Bin a (\fst (\fst x)), move Bin a (\fst (\snd x))〉
 453        cases (true_or_false … (memb (space Bin) xa (x::visited)))
 454         [#membxa @memb_append_l2 //
 455         |#membxa @memb_append_l1 @sublist_unique_append_l1 @memb_filter_l
 456           [whd in ⊢ (??(??%%)?); cases a [@memb_hd |@memb_cons @memb_hd]
 457           |>membxa //
 458           ]
 459         ]
 460       |#H1 letin xa ≝ 〈move Bin a (\fst (\fst x)), move Bin a (\fst (\snd x))〉
 461        cases (memb_append … (subH x a H1))
 462         [#H2 (cases (orb_true_l … H2))
 463           [#H3 @memb_append_l2 >(proj1 … (eqb_true …) H3) @memb_hd
 464           |#H3 @memb_append_l1 @sublist_unique_append_l2 @H3
 465           ]
 466         |#H2 @memb_append_l2 @memb_cons @H2
 467         ]
 468       ]
 469     ]
 470   ]
 471 qed.
 472
 473 axiom bisim_char: ∀e1,e2:pre Bin.
 474 (∀w.(beqb (\snd (moves ? w e1)) (\snd (moves ? w e2))) = true) →
 475 \sem{e1}=1\sem{e2}.
 476
 477 lemma bisim_ok2: ∀e1,e2:pre Bin.
 478  (beqb (\snd e1) (\snd e2) = true) →
 479  ∀n.∀frontier:list (space Bin).
 480  sub_sons [〈e1,e2〉] (frontier@[〈e1,e2〉]) →
 481  \fst (bisim n frontier [〈e1,e2〉]) = true → \sem{e1}=1\sem{e2}.
 482 #e1 #e2 #Hnil #n #frontier #init #bisim_true
 483 letin visited_res ≝ (\snd (bisim n frontier [〈e1,e2〉]))
 484 cut (bisim n frontier [〈e1,e2〉] = 〈true,visited_res〉)
 485   [<bisim_true <eq_pair_fst_snd //] #H
 486 cut (all_true [〈e1,e2〉])
 487   [#p #Hp cases (orb_true_l … Hp)
 488     [#eqp <(proj1 … (eqb_true …) eqp) //
 489     | whd in ⊢ ((??%?)→?); #abs @False_ind /2/
 490     ]] #allH
 491 cases (reachable_bisim … allH init … H) * #H1 #H2 #H3
 492 cut (∀w,p.memb (space Bin) p visited_res = true →
 493   memb (space Bin) 〈moves ? w (\fst p), moves ? w (\snd p)〉 visited_res = true)
 494   [#w elim w [* //]
 495    #a #w1 #Hind * #e11 #e21 #visp >fst_eq >snd_eq >moves_cons >moves_cons
 496    @(Hind 〈?,?〉) @(H1 〈?,?〉) //] #all_reach
 497 @bisim_char #w @(H3 〈?,?〉) @(all_reach w 〈?,?〉) @H2 //
 498 qed.
 499
 500 definition tt ≝ ps Bin true.
 501 definition ff ≝ ps Bin false.
 502 definition eps ≝ pe Bin.
 503 definition exp1 ≝ (ff + tt · ff).
 504 definition exp2 ≝  ff · (eps + tt).
 505
 506 definition exp3 ≝ move Bin true (\fst (•exp1)).
 507 definition exp4 ≝ move Bin true (\fst (•exp2)).
 508 definition exp5 ≝ move Bin false (\fst (•exp1)).
 509 definition exp6 ≝ move Bin false (\fst (•exp2)).
 510
 511 example comp1 : bequiv 15 (•exp1) (•exp2) [ ] = false .
 512 normalize //
 513 qed.
 514
 515