matita/matita/lib/re/moves.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "re/re.ma".
  16 include "basics/lists/listb.ma".
  17
  18 let rec move (S: DeqSet) (x:S) (E: pitem S) on E : pre S ≝
  19  match E with
  20   [ pz ⇒ 〈 `∅, false 〉
  21   | pe ⇒ 〈 ϵ, false 〉
  22   | ps y ⇒ 〈 `y, false 〉
  23   | pp y ⇒ 〈 `y, x == y 〉
  24   | po e1 e2 ⇒ (move ? x e1) ⊕ (move ? x e2)
  25   | pc e1 e2 ⇒ (move ? x e1) ⊙ (move ? x e2)
  26   | pk e ⇒ (move ? x e)^⊛ ].
  27
  28 lemma move_plus: ∀S:DeqSet.∀x:S.∀i1,i2:pitem S.
  29   move S x (i1 + i2) = (move ? x i1) ⊕ (move ? x i2).
  30 // qed.
  31
  32 lemma move_cat: ∀S:DeqSet.∀x:S.∀i1,i2:pitem S.
  33   move S x (i1 · i2) = (move ? x i1) ⊙ (move ? x i2).
  34 // qed.
  35
  36 lemma move_star: ∀S:DeqSet.∀x:S.∀i:pitem S.
  37   move S x i^* = (move ? x i)^⊛.
  38 // qed.
  39
  40 definition pmove ≝ λS:DeqSet.λx:S.λe:pre S. move ? x (\fst e).
  41
  42 lemma pmove_def : ∀S:DeqSet.∀x:S.∀i:pitem S.∀b.
  43   pmove ? x 〈i,b〉 = move ? x i.
  44 // qed.
  45
  46 lemma eq_to_eq_hd: ∀A.∀l1,l2:list A.∀a,b.
  47   a::l1 = b::l2 → a = b.
  48 #A #l1 #l2 #a #b #H destruct //
  49 qed.
  50
  51 lemma same_kernel: ∀S:DeqSet.∀a:S.∀i:pitem S.
  52   |\fst (move ? a i)| = |i|.
  53 #S #a #i elim i //
  54   [#i1 #i2 >move_cat #H1 #H2 whd in ⊢ (???%); <H1 <H2 //
  55   |#i1 #i2 >move_plus #H1 #H2 whd in ⊢ (???%); <H1 <H2 //
  56   ]
  57 qed.
  58
  59 theorem move_ok:
  60  ∀S:DeqSet.∀a:S.∀i:pitem S.∀w: word S.
  61    \sem{move ? a i} w ↔ \sem{i} (a::w).
  62 #S #a #i elim i
  63   [normalize /2/
  64   |normalize /2/
  65   |normalize /2/
  66   |normalize #x #w cases (true_or_false (a==x)) #H >H normalize
  67     [>(proj1 … (eqb_true …) H) %
  68       [* // #bot @False_ind //| #H1 destruct /2/]
  69     |% [#bot @False_ind //
  70        | #H1 destruct @(absurd ((a==a)=true))
  71          [>(proj2 … (eqb_true …) (refl …)) // | /2/]
  72        ]
  73     ]
  74   |#i1 #i2 #HI1 #HI2 #w >(sem_cat S i1 i2) >move_cat
  75    @iff_trans[|@sem_odot] >same_kernel >sem_cat_w
  76    @iff_trans[||@(iff_or_l … (HI2 w))] @iff_or_r %
  77     [* #w1 * #w2 * * #eqw #w1in #w2in @(ex_intro … (a::w1))
  78      @(ex_intro … w2) % // % normalize // cases (HI1 w1) /2/
  79     |* #w1 * #w2 * cases w1
  80       [* #_ #H @False_ind /2/
  81       |#x #w3 * #eqaw normalize in eqaw; destruct #w3in #w2in
  82       @(ex_intro … w3) @(ex_intro … w2) % // % // cases (HI1 w3) /2/
  83       ]
  84     ]
  85   |#i1 #i2 #HI1 #HI2 #w >(sem_plus S i1 i2) >move_plus >sem_plus_w
  86    @iff_trans[|@sem_oplus]
  87    @iff_trans[|@iff_or_l [|@HI2]| @iff_or_r //]
  88   |#i1 #HI1 #w >move_star
  89    @iff_trans[|@sem_ostar] >same_kernel >sem_star_w %
  90     [* #w1 * #w2 * * #eqw #w1in #w2in
  91      @(ex_intro … (a::w1)) @(ex_intro … w2) % // % normalize //
  92      cases (HI1 w1 ) /2/
  93     |* #w1 * #w2 * cases w1
  94       [* #_ #H @False_ind /2/
  95       |#x #w3 * #eqaw normalize in eqaw; destruct #w3in #w2in
  96        @(ex_intro … w3) @(ex_intro … w2) % // % // cases (HI1 w3) /2/
  97       ]
  98     ]
  99   ]
 100 qed.
 101
 102 notation > "x ↦* E" non associative with precedence 60 for @{moves ? $x $E}.
 103 let rec moves (S : DeqSet) w e on w : pre S ≝
 104  match w with
 105   [ nil ⇒ e
 106   | cons x w' ⇒ w' ↦* (move S x (\fst e))].
 107
 108 lemma moves_empty: ∀S:DeqSet.∀e:pre S.
 109   moves ? [ ] e = e.
 110 // qed.
 111
 112 lemma moves_cons: ∀S:DeqSet.∀a:S.∀w.∀e:pre S.
 113   moves ? (a::w)  e = moves ? w (move S a (\fst e)).
 114 // qed.
 115
 116 lemma not_epsilon_sem: ∀S:DeqSet.∀a:S.∀w: word S. ∀e:pre S.
 117   iff ((a::w) ∈ e) ((a::w) ∈ \fst e).
 118 #S #a #w * #i #b >fst_eq cases b normalize
 119   [% /2/ * // #H destruct |% normalize /2/]
 120 qed.
 121
 122 lemma same_kernel_moves: ∀S:DeqSet.∀w.∀e:pre S.
 123   |\fst (moves ? w e)| = |\fst e|.
 124 #S #w elim w //
 125 qed.
 126
 127 theorem decidable_sem: ∀S:DeqSet.∀w: word S. ∀e:pre S.
 128    (\snd (moves ? w e) = true)  ↔ \sem{e} w.
 129 #S #w elim w
 130  [* #i #b >moves_empty cases b % /2/
 131  |#a #w1 #Hind #e >moves_cons
 132   @iff_trans [||@iff_sym @not_epsilon_sem]
 133   @iff_trans [||@move_ok] @Hind
 134  ]
 135 qed.
 136
 137 lemma not_true_to_false: ∀b.b≠true → b =false.
 138 #b * cases b // #H @False_ind /2/
 139 qed.
 140
 141 theorem equiv_sem: ∀S:DeqSet.∀e1,e2:pre S.
 142   iff (\sem{e1} =1 \sem{e2}) (∀w.\snd (moves ? w e1) = \snd (moves ? w e2)).
 143 #S #e1 #e2 %
 144 [#same_sem #w
 145   cut (∀b1,b2. iff (b1 = true) (b2 = true) → (b1 = b2))
 146     [* * // * #H1 #H2 [@sym_eq @H1 //| @H2 //]]
 147   #Hcut @Hcut @iff_trans [|@decidable_sem]
 148   @iff_trans [|@same_sem] @iff_sym @decidable_sem
 149 |#H #w1 @iff_trans [||@decidable_sem] <H @iff_sym @decidable_sem]
 150 qed.
 151
 152 axiom moves_left : ∀S,a,w,e.
 153   moves S (w@[a]) e = move S a (\fst (moves S w e)).
 154
 155 definition in_moves ≝ λS:DeqSet.λw.λe:pre S. \snd(w ↦* e).
 156
 157 coinductive equiv (S:DeqSet) : pre S → pre S → Prop ≝
 158  mk_equiv:
 159   ∀e1,e2: pre S.
 160    \snd e1  = \snd e2 →
 161     (∀x. equiv S (move ? x (\fst e1)) (move ? x (\fst e2))) →
 162      equiv S e1 e2.
 163
 164 definition beqb ≝ λb1,b2.
 165   match b1 with
 166   [ true ⇒ b2
 167   | false ⇒ notb b2
 168   ].
 169
 170 lemma beqb_ok: ∀b1,b2. iff (beqb b1 b2 = true) (b1 = b2).
 171 #b1 #b2 cases b1 cases b2 normalize /2/
 172 qed.
 173
 174 definition Bin ≝ mk_DeqSet bool beqb beqb_ok.
 175
 176 let rec beqitem S (i1,i2: pitem S) on i1 ≝
 177   match i1 with
 178   [ pz ⇒ match i2 with [ pz ⇒ true | _ ⇒ false]
 179   | pe ⇒ match i2 with [ pe ⇒ true | _ ⇒ false]
 180   | ps y1 ⇒ match i2 with [ ps y2 ⇒ y1==y2 | _ ⇒ false]
 181   | pp y1 ⇒ match i2 with [ pp y2 ⇒ y1==y2 | _ ⇒ false]
 182   | po i11 i12 ⇒ match i2 with
 183     [ po i21 i22 ⇒ beqitem S i11 i21 ∧ beqitem S i12 i22
 184     | _ ⇒ false]
 185   | pc i11 i12 ⇒ match i2 with
 186     [ pc i21 i22 ⇒ beqitem S i11 i21 ∧ beqitem S i12 i22
 187     | _ ⇒ false]
 188   | pk i11 ⇒ match i2 with [ pk i21 ⇒ beqitem S i11 i21 | _ ⇒ false]
 189   ].
 190
 191 axiom beqitem_ok: ∀S,i1,i2. iff (beqitem S i1 i2 = true) (i1 = i2).
 192
 193 definition BinItem ≝
 194   mk_DeqSet (pitem Bin) (beqitem Bin) (beqitem_ok Bin).
 195
 196 definition beqpre ≝ λS:DeqSet.λe1,e2:pre S.
 197   beqitem S (\fst e1) (\fst e2) ∧ beqb (\snd e1) (\snd e2).
 198
 199 definition beqpairs ≝ λS:DeqSet.λp1,p2:(pre S)×(pre S).
 200   beqpre S (\fst p1) (\fst p2) ∧ beqpre S (\snd p1) (\snd p2).
 201
 202 axiom beqpairs_ok: ∀S,p1,p2. iff (beqpairs S p1 p2 = true) (p1 = p2).
 203
 204 definition space ≝ λS.mk_DeqSet ((pre S)×(pre S)) (beqpairs S) (beqpairs_ok S).
 205
 206 definition sons ≝ λp:space Bin.
 207   [〈move Bin true (\fst (\fst p)), move Bin true (\fst (\snd p))〉;
 208    〈move Bin false (\fst (\fst p)), move Bin false (\fst (\snd p))〉
 209   ].
 210
 211 axiom memb_sons: ∀p,q. memb (space Bin) p (sons q) = true →
 212   ∃a.(move ? a (\fst (\fst q)) = \fst p ∧
 213       move ? a (\fst (\snd q)) = \snd p).
 214
 215 (*
 216 let rec test_sons (l:list (space Bin)) ≝
 217   match l with
 218   [ nil ⇒  true
 219   | cons hd tl ⇒
 220     beqb (\snd (\fst hd)) (\snd (\snd hd)) ∧ test_sons tl
 221   ]. *)
 222
 223 let rec bisim (n:nat) (frontier,visited: list (space Bin)) ≝
 224   match n with
 225   [ O ⇒ 〈false,visited〉 (* assert false *)
 226   | S m ⇒
 227     match frontier with
 228     [ nil ⇒ 〈true,visited〉
 229     | cons hd tl ⇒
 230       if beqb (\snd (\fst hd)) (\snd (\snd hd)) then
 231         bisim m (unique_append ? (filter ? (λx.notb (memb ? x (hd::visited)))
 232         (sons hd)) tl) (hd::visited)
 233       else 〈false,visited〉
 234     ]
 235   ].
 236
 237 lemma unfold_bisim: ∀n.∀frontier,visited: list (space Bin).
 238   bisim n frontier visited =
 239   match n with
 240   [ O ⇒ 〈false,visited〉 (* assert false *)
 241   | S m ⇒
 242     match frontier with
 243     [ nil ⇒ 〈true,visited〉
 244     | cons hd tl ⇒
 245       if beqb (\snd (\fst hd)) (\snd (\snd hd)) then
 246         bisim m (unique_append ? (filter ? (λx.notb(memb ? x (hd::visited))) (sons hd)) tl) (hd::visited)
 247       else 〈false,visited〉
 248     ]
 249   ].
 250 #n cases n // qed.
 251
 252 lemma bisim_never: ∀frontier,visited: list (space Bin).
 253   bisim O frontier visited = 〈false,visited〉.
 254 #frontier #visited >unfold_bisim //
 255 qed.
 256
 257 lemma bisim_end: ∀m.∀visited: list (space Bin).
 258   bisim (S m) [] visited = 〈true,visited〉.
 259 #n #visisted >unfold_bisim //
 260 qed.
 261
 262 lemma bisim_step_true: ∀m.∀p.∀frontier,visited: list (space Bin).
 263 beqb (\snd (\fst p)) (\snd (\snd p)) = true →
 264   bisim (S m) (p::frontier) visited =
 265   bisim m (unique_append ? (filter ? (λx.notb(memb (space Bin) x (p::visited))) (sons p)) frontier) (p::visited).
 266 #m #p #frontier #visited #test >unfold_bisim normalize nodelta >test //
 267 qed.
 268
 269 lemma bisim_step_false: ∀m.∀p.∀frontier,visited: list (space Bin).
 270 beqb (\snd (\fst p)) (\snd (\snd p)) = false →
 271   bisim (S m) (p::frontier) visited = 〈false,visited〉.
 272 #m #p #frontier #visited #test >unfold_bisim normalize nodelta >test //
 273 qed.
 274
 275 definition visited_inv ≝ λe1,e2:pre Bin.λvisited: list (space Bin).
 276 uniqueb ? visited = true ∧
 277   ∀p. memb ? p visited = true →
 278    (∃w.(moves Bin w e1 = \fst p) ∧ (moves Bin w e2 = \snd p)) ∧
 279    (beqb (\snd (\fst p)) (\snd (\snd p)) = true).
 280
 281 definition frontier_inv ≝ λfrontier,visited: list (space Bin).
 282 uniqueb ? frontier = true ∧
 283 ∀p. memb ? p frontier = true →
 284   memb ? p visited = false ∧
 285   ∃p1.((memb ? p1 visited = true) ∧
 286    (∃a. move ? a (\fst (\fst p1)) = \fst p ∧
 287         move ? a (\fst (\snd p1)) = \snd p)).
 288
 289 (* lemma andb_true: ∀b1,b2:bool.
 290   (b1 ∧ b2) = true → (b1 = true) ∧ (b2 = true).
 291 #b1 #b2 cases b1 normalize #H [>H /2/ |@False_ind /2/].
 292 qed.
 293
 294 lemma andb_true_r: ∀b1,b2:bool.
 295   (b1 = true) ∧ (b2 = true) → (b1 ∧ b2) = true.
 296 #b1 #b2 cases b1 normalize * //
 297 qed. *)
 298
 299 lemma notb_eq_true_l: ∀b. notb b = true → b = false.
 300 #b cases b normalize //
 301 qed.
 302
 303 lemma notb_eq_true_r: ∀b. b = false → notb b = true.
 304 #b cases b normalize //
 305 qed.
 306
 307 lemma notb_eq_false_l:∀b. notb b = false → b = true.
 308 #b cases b normalize //
 309 qed.
 310
 311 lemma notb_eq_false_r:∀b. b = true → notb b = false.
 312 #b cases b normalize //
 313 qed.
 314
 315
 316 (* include "arithmetics/exp.ma". *)
 317
 318 let rec pos S (i:re S) on i ≝
 319   match i with
 320   [ z ⇒ 0
 321   | e ⇒ 0
 322   | s y ⇒ 1
 323   | o i1 i2 ⇒ pos S i1 + pos S i2
 324   | c i1 i2 ⇒ pos S i1 + pos S i2
 325   | k i ⇒ pos S i
 326   ].
 327
 328
 329 let rec pitem_enum S (i:re S) on i ≝
 330   match i with
 331   [ z ⇒ [pz S]
 332   | e ⇒ [pe S]
 333   | s y ⇒ [ps S y; pp S y]
 334   | o i1 i2 ⇒ compose ??? (po S) (pitem_enum S i1) (pitem_enum S i2)
 335   | c i1 i2 ⇒ compose ??? (pc S) (pitem_enum S i1) (pitem_enum S i2)
 336   | k i ⇒ map ?? (pk S) (pitem_enum S i)
 337   ].
 338
 339 axiom pitem_enum_complete: ∀i: pitem Bin.
 340   memb BinItem i (pitem_enum ? (forget ? i)) = true.
 341 (*
 342 #i elim i
 343   [//
 344   |//
 345   |* //
 346   |* //
 347   |#i1 #i2 #Hind1 #Hind2 @memb_compose //
 348   |#i1 #i2 #Hind1 #Hind2 @memb_compose //
 349   |
 350 *)
 351
 352 definition pre_enum ≝ λS.λi:re S.
 353   compose ??? (λi,b.〈i,b〉) (pitem_enum S i) [true;false].
 354
 355 definition space_enum ≝ λS.λi1,i2:re S.
 356   compose ??? (λe1,e2.〈e1,e2〉) (pre_enum S i1) (pre_enum S i1).
 357
 358 axiom space_enum_complete : ∀S.∀e1,e2: pre S.
 359   memb (space S) 〈e1,e2〉 (space_enum S (|\fst e1|) (|\fst e2|)) = true.
 360
 361 lemma bisim_ok1: ∀e1,e2:pre Bin.\sem{e1}=1\sem{e2} →
 362  ∀n.∀frontier,visited:list (space Bin).
 363  |space_enum Bin (|\fst e1|) (|\fst e2|)| < n + |visited|→
 364  visited_inv e1 e2 visited →  frontier_inv frontier visited →
 365  \fst (bisim n frontier visited) = true.
 366 #e1 #e2 #same #n elim n
 367   [#frontier #visited #abs * #unique #H @False_ind @(absurd … abs)
 368    @le_to_not_lt @sublist_length // * #e11 #e21 #membp
 369    cut ((|\fst e11| = |\fst e1|) ∧ (|\fst e21| = |\fst e2|))
 370    [|* #H1 #H2 <H1 <H2 @space_enum_complete]
 371    cases (H … membp) * #w * >fst_eq >snd_eq #we1 #we2 #_
 372    <we1 <we2 % //
 373   |#m #HI * [#visited #vinv #finv >bisim_end //]
 374    #p #front_tl #visited #Hn * #u_visited #vinv * #u_frontier #finv
 375    cases (finv p (memb_hd …)) #Hp * #p2 * #visited_p2
 376    * #a * #movea1 #movea2
 377    cut (∃w.(moves Bin w e1 = \fst p) ∧ (moves Bin w e2 = \snd p))
 378      [cases (vinv … visited_p2) -vinv * #w1 * #mw1 #mw2 #_
 379       @(ex_intro … (w1@[a])) /2/]
 380    -movea2 -movea1 -a -visited_p2 -p2 #reachp
 381    cut (beqb (\snd (\fst p)) (\snd (\snd p)) = true)
 382      [cases reachp #w * #move_e1 #move_e2 <move_e1 <move_e2
 383       @(proj2 … (beqb_ok … )) @(proj1 … (equiv_sem … )) @same
 384      |#ptest >(bisim_step_true … ptest) @HI -HI
 385        [<plus_n_Sm //
 386        |% [whd in ⊢ (??%?); >Hp whd in ⊢ (??%?); //]
 387         #p1 #H (cases (orb_true_l … H))
 388          [#eqp <(proj1 … (eqb_true (space Bin) ? p1) eqp) % //
 389          |#visited_p1 @(vinv … visited_p1)
 390          ]
 391        |whd % [@unique_append_unique @(andb_true_r … u_frontier)]
 392         @unique_append_elim #q #H
 393          [%
 394            [@notb_eq_true_l @(filter_true … H)
 395            |@(ex_intro … p) % //
 396             @(memb_sons … (memb_filter_memb … H))
 397            ]
 398          |cases (finv q ?) [|@memb_cons //]
 399           #nvq * #p1 * #Hp1 #reach %
 400            [cut ((p==q) = false) [|#Hpq whd in ⊢ (??%?); >Hpq @nvq]
 401             cases (andb_true … u_frontier) #notp #_
 402             @(not_memb_to_not_eq … H) @notb_eq_true_l @notp
 403            |cases (proj2 … (finv q ?))
 404              [#p1 *  #Hp1 #reach @(ex_intro … p1) % // @memb_cons //
 405              |@memb_cons //
 406              ]
 407           ]
 408         ]
 409       ]
 410     ]
 411   ]
 412 qed.
 413
 414 definition all_true ≝ λl.∀p. memb (space Bin) p l = true →
 415   (beqb (\snd (\fst p)) (\snd (\snd p)) = true).
 416
 417 definition sub_sons ≝ λl1,l2.∀x,a.
 418 memb (space Bin) x l1 = true →
 419   memb (space Bin) 〈move ? a (\fst (\fst x)), move ? a (\fst (\snd x))〉 l2 = true.
 420
 421 lemma reachable_bisim:
 422  ∀n.∀frontier,visited,visited_res:list (space Bin).
 423  all_true visited →
 424  sub_sons visited (frontier@visited) →
 425  bisim n frontier visited = 〈true,visited_res〉 →
 426   (sub_sons visited_res visited_res ∧
 427    sublist ? visited visited_res ∧
 428    all_true visited_res).
 429 #n elim n
 430   [#fron #vis #vis_res #_ #_ >bisim_never #H destruct
 431   |#m #Hind *
 432     [-Hind #vis #vis_res #allv #H normalize in  ⊢ (%→?);
 433      #H1 destruct % // % // #p /2/
 434     |#hd cases (true_or_false (beqb (\snd (\fst hd)) (\snd (\snd hd))))
 435       [|#H #tl #vis #vis_res #allv >(bisim_step_false … H) #_ #H1 destruct]
 436      #H #tl #visited #visited_res #allv >(bisim_step_true … H)
 437      cut (all_true (hd::visited))
 438       [#p #H cases (orb_true_l … H)
 439         [#eqp <(proj1 … (eqb_true …) eqp) // |@allv]]
 440      #allh #subH #bisim cases (Hind … allh … bisim) -Hind
 441       [* #H1 #H2 #H3 % // % // #p #H4 @H2 @memb_cons //]
 442      #x #a #membx
 443      cases (orb_true_l … membx)
 444       [#eqhdx >(proj1 … (eqb_true …) eqhdx)
 445        letin xa ≝ 〈move Bin a (\fst (\fst x)), move Bin a (\fst (\snd x))〉
 446        cases (true_or_false … (memb (space Bin) xa (x::visited)))
 447         [#membxa @memb_append_l2 //
 448         |#membxa @memb_append_l1 @sublist_unique_append_l1 @memb_filter_l
 449           [>membxa //
 450           |whd in ⊢ (??(??%%)?); cases a [@memb_hd |@memb_cons @memb_hd]
 451           ]
 452         ]
 453       |#H1 letin xa ≝ 〈move Bin a (\fst (\fst x)), move Bin a (\fst (\snd x))〉
 454        cases (memb_append … (subH x a H1))
 455         [#H2 (cases (orb_true_l … H2))
 456           [#H3 @memb_append_l2 >(proj1 … (eqb_true …) H3) @memb_hd
 457           |#H3 @memb_append_l1 @sublist_unique_append_l2 @H3
 458           ]
 459         |#H2 @memb_append_l2 @memb_cons @H2
 460         ]
 461       ]
 462     ]
 463   ]
 464 qed.
 465
 466 axiom bisim_char: ∀e1,e2:pre Bin.
 467 (∀w.(beqb (\snd (moves ? w e1)) (\snd (moves ? w e2))) = true) →
 468 \sem{e1}=1\sem{e2}.
 469
 470 lemma bisim_ok2: ∀e1,e2:pre Bin.
 471  (beqb (\snd e1) (\snd e2) = true) →
 472  ∀n.∀frontier:list (space Bin).
 473  sub_sons [〈e1,e2〉] (frontier@[〈e1,e2〉]) →
 474  \fst (bisim n frontier [〈e1,e2〉]) = true → \sem{e1}=1\sem{e2}.
 475 #e1 #e2 #Hnil #n #frontier #init #bisim_true
 476 letin visited_res ≝ (\snd (bisim n frontier [〈e1,e2〉]))
 477 cut (bisim n frontier [〈e1,e2〉] = 〈true,visited_res〉)
 478   [<bisim_true <eq_pair_fst_snd //] #H
 479 cut (all_true [〈e1,e2〉])
 480   [#p #Hp cases (orb_true_l … Hp)
 481     [#eqp <(proj1 … (eqb_true …) eqp) //
 482     | whd in ⊢ ((??%?)→?); #abs @False_ind /2/
 483     ]] #allH
 484 cases (reachable_bisim … allH init … H) * #H1 #H2 #H3
 485 cut (∀w,p.memb (space Bin) p visited_res = true →
 486   memb (space Bin) 〈moves ? w (\fst p), moves ? w (\snd p)〉 visited_res = true)
 487   [#w elim w [* //]
 488    #a #w1 #Hind * #e11 #e21 #visp >fst_eq >snd_eq >moves_cons >moves_cons
 489    @(Hind 〈?,?〉) @(H1 〈?,?〉) //] #all_reach
 490 @bisim_char #w @(H3 〈?,?〉) @(all_reach w 〈?,?〉) @H2 //
 491 qed.
 492
 493 definition tt ≝ ps Bin true.
 494 definition ff ≝ ps Bin false.
 495 definition eps ≝ pe Bin.
 496 definition exp1 ≝ (ff + tt · ff).
 497 definition exp2 ≝  ff · (eps + tt).
 498
 499 definition exp3 ≝ move Bin true (\fst (•exp1)).
 500 definition exp4 ≝ move Bin true (\fst (•exp2)).
 501 definition exp5 ≝ move Bin false (\fst (•exp1)).
 502 definition exp6 ≝ move Bin false (\fst (•exp2)).
 503
 504
 505
 506