matita/matita/lib/re/re.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "re/lang.ma".
  16
  17 inductive re (S: DeqSet) : Type[0] ≝
  18    z: re S
  19  | e: re S
  20  | s: S → re S
  21  | c: re S → re S → re S
  22  | o: re S → re S → re S
  23  | k: re S → re S.
  24
  25 interpretation "re epsilon" 'epsilon = (e ?).
  26 interpretation "re or" 'plus a b = (o ? a b).
  27 interpretation "re cat" 'middot a b = (c ? a b).
  28 interpretation "re star" 'star a = (k ? a).
  29
  30 notation < "a" non associative with precedence 90 for @{ 'ps $a}.
  31 notation > "` term 90 a" non associative with precedence 90 for @{ 'ps $a}.
  32 interpretation "atom" 'ps a = (s ? a).
  33
  34 notation "`∅" non associative with precedence 90 for @{ 'empty }.
  35 interpretation "empty" 'empty = (z ?).
  36
  37 let rec in_l (S : DeqSet) (r : re S) on r : word S → Prop ≝
  38 match r with
  39 [ z ⇒ ∅
  40 | e ⇒ {ϵ}
  41 | s x ⇒ {[x]}
  42 | c r1 r2 ⇒ (in_l ? r1) · (in_l ? r2)
  43 | o r1 r2 ⇒ (in_l ? r1) ∪ (in_l ? r2)
  44 | k r1 ⇒ (in_l ? r1) ^*].
  45
  46 notation "\sem{term 19 E}" non associative with precedence 75 for @{'in_l $E}.
  47 interpretation "in_l" 'in_l E = (in_l ? E).
  48 interpretation "in_l mem" 'mem w l = (in_l ? l w).
  49
  50 lemma rsem_star : ∀S.∀r: re S. \sem{r^*} = \sem{r}^*.
  51 // qed.
  52
  53
  54 (* pointed items *)
  55 inductive pitem (S: DeqSet) : Type[0] ≝
  56    pz: pitem S
  57  | pe: pitem S
  58  | ps: S → pitem S
  59  | pp: S → pitem S
  60  | pc: pitem S → pitem S → pitem S
  61  | po: pitem S → pitem S → pitem S
  62  | pk: pitem S → pitem S.
  63
  64 definition pre ≝ λS.pitem S × bool.
  65
  66 interpretation "pitem star" 'star a = (pk ? a).
  67 interpretation "pitem or" 'plus a b = (po ? a b).
  68 interpretation "pitem cat" 'middot a b = (pc ? a b).
  69 notation < ".a" non associative with precedence 90 for @{ 'pp $a}.
  70 notation > "`. term 90 a" non associative with precedence 90 for @{ 'pp $a}.
  71 interpretation "pitem pp" 'pp a = (pp ? a).
  72 interpretation "pitem ps" 'ps a = (ps ? a).
  73 interpretation "pitem epsilon" 'epsilon = (pe ?).
  74 interpretation "pitem empty" 'empty = (pz ?).
  75
  76 let rec forget (S: DeqSet) (l : pitem S) on l: re S ≝
  77  match l with
  78   [ pz ⇒ `∅
  79   | pe ⇒ ϵ
  80   | ps x ⇒ `x
  81   | pp x ⇒ `x
  82   | pc E1 E2 ⇒ (forget ? E1) · (forget ? E2)
  83   | po E1 E2 ⇒ (forget ? E1) + (forget ? E2)
  84   | pk E ⇒ (forget ? E)^* ].
  85
  86 (* notation < "|term 19 e|" non associative with precedence 70 for @{'forget $e}.*)
  87 interpretation "forget" 'norm a = (forget ? a).
  88
  89 lemma erase_dot : ∀S.∀e1,e2:pitem S. |e1 · e2| = c ? (|e1|) (|e2|).
  90 // qed.
  91
  92 lemma erase_plus : ∀S.∀i1,i2:pitem S.
  93   |i1 + i2| = |i1| + |i2|.
  94 // qed.
  95
  96 lemma erase_star : ∀S.∀i:pitem S.|i^*| = |i|^*.
  97 // qed.
  98
  99 (* boolean equality *)
 100 let rec beqitem S (i1,i2: pitem S) on i1 ≝
 101   match i1 with
 102   [ pz ⇒ match i2 with [ pz ⇒ true | _ ⇒ false]
 103   | pe ⇒ match i2 with [ pe ⇒ true | _ ⇒ false]
 104   | ps y1 ⇒ match i2 with [ ps y2 ⇒ y1==y2 | _ ⇒ false]
 105   | pp y1 ⇒ match i2 with [ pp y2 ⇒ y1==y2 | _ ⇒ false]
 106   | po i11 i12 ⇒ match i2 with
 107     [ po i21 i22 ⇒ beqitem S i11 i21 ∧ beqitem S i12 i22
 108     | _ ⇒ false]
 109   | pc i11 i12 ⇒ match i2 with
 110     [ pc i21 i22 ⇒ beqitem S i11 i21 ∧ beqitem S i12 i22
 111     | _ ⇒ false]
 112   | pk i11 ⇒ match i2 with [ pk i21 ⇒ beqitem S i11 i21 | _ ⇒ false]
 113   ].
 114
 115 lemma beqitem_true: ∀S,i1,i2. iff (beqitem S i1 i2 = true) (i1 = i2).
 116 #S #i1 elim i1
 117   [#i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] % // normalize #H destruct
 118   |#i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] % // normalize #H destruct
 119   |#x #i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] % normalize #H destruct
 120     [>(\P H) // | @(\b (refl …))]
 121   |#x #i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] % normalize #H destruct
 122     [>(\P H) // | @(\b (refl …))]
 123   |#i11 #i12 #Hind1 #Hind2 #i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] %
 124    normalize #H destruct
 125     [cases (true_or_false (beqitem S i11 i21)) #H1
 126       [>(proj1 … (Hind1 i21) H1) >(proj1 … (Hind2 i22)) // >H1 in H; #H @H
 127       |>H1 in H; normalize #abs @False_ind /2/
 128       ]
 129     |>(proj2 … (Hind1 i21) (refl …)) >(proj2 … (Hind2 i22) (refl …)) //
 130     ]
 131   |#i11 #i12 #Hind1 #Hind2 #i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i3] %
 132    normalize #H destruct
 133     [cases (true_or_false (beqitem S i11 i21)) #H1
 134       [>(proj1 … (Hind1 i21) H1) >(proj1 … (Hind2 i22)) // >H1 in H; #H @H
 135       |>H1 in H; normalize #abs @False_ind /2/
 136       ]
 137     |>(proj2 … (Hind1 i21) (refl …)) >(proj2 … (Hind2 i22) (refl …)) //
 138     ]
 139   |#i3 #Hind #i2 cases i2 [||#a|#a|#i21 #i22| #i21 #i22|#i4] %
 140    normalize #H destruct
 141     [>(proj1 … (Hind i4) H) // |>(proj2 … (Hind i4) (refl …)) //]
 142   ]
 143 qed.
 144
 145 definition DeqItem ≝ λS.
 146   mk_DeqSet (pitem S) (beqitem S) (beqitem_true S).
 147
 148 unification hint  0 ≔ S;
 149     X ≟ mk_DeqSet (pitem S) (beqitem S) (beqitem_true S)
 150 (* ---------------------------------------- *) ⊢
 151     pitem S ≡ carr X.
 152
 153 unification hint  0 ≔ S,i1,i2;
 154     X ≟ mk_DeqSet (pitem S) (beqitem S) (beqitem_true S)
 155 (* ---------------------------------------- *) ⊢
 156     beqitem S i1 i2 ≡ eqb X i1 i2.
 157
 158 (* semantics *)
 159
 160 let rec in_pl (S : DeqSet) (r : pitem S) on r : word S → Prop ≝
 161 match r with
 162 [ pz ⇒ ∅
 163 | pe ⇒ ∅
 164 | ps _ ⇒ ∅
 165 | pp x ⇒ { [x] }
 166 | pc r1 r2 ⇒ (in_pl ? r1) · \sem{forget ? r2} ∪ (in_pl ? r2)
 167 | po r1 r2 ⇒ (in_pl ? r1) ∪ (in_pl ? r2)
 168 | pk r1 ⇒ (in_pl ? r1) · \sem{forget ? r1}^*  ].
 169
 170 interpretation "in_pl" 'in_l E = (in_pl ? E).
 171 interpretation "in_pl mem" 'mem w l = (in_pl ? l w).
 172
 173 definition in_prl ≝ λS : DeqSet.λp:pre S.
 174   if (\snd p) then \sem{\fst p} ∪ {ϵ} else \sem{\fst p}.
 175
 176 interpretation "in_prl mem" 'mem w l = (in_prl ? l w).
 177 interpretation "in_prl" 'in_l E = (in_prl ? E).
 178
 179 lemma sem_pre_true : ∀S.∀i:pitem S.
 180   \sem{〈i,true〉} = \sem{i} ∪ {ϵ}.
 181 // qed.
 182
 183 lemma sem_pre_false : ∀S.∀i:pitem S.
 184   \sem{〈i,false〉} = \sem{i}.
 185 // qed.
 186
 187 lemma sem_cat: ∀S.∀i1,i2:pitem S.
 188   \sem{i1 · i2} = \sem{i1} · \sem{|i2|} ∪ \sem{i2}.
 189 // qed.
 190
 191 lemma sem_cat_w: ∀S.∀i1,i2:pitem S.∀w.
 192   \sem{i1 · i2} w = ((\sem{i1} · \sem{|i2|}) w ∨ \sem{i2} w).
 193 // qed.
 194
 195 lemma sem_plus: ∀S.∀i1,i2:pitem S.
 196   \sem{i1 + i2} = \sem{i1} ∪ \sem{i2}.
 197 // qed.
 198
 199 lemma sem_plus_w: ∀S.∀i1,i2:pitem S.∀w.
 200   \sem{i1 + i2} w = (\sem{i1} w ∨ \sem{i2} w).
 201 // qed.
 202
 203 lemma sem_star : ∀S.∀i:pitem S.
 204   \sem{i^*} = \sem{i} · \sem{|i|}^*.
 205 // qed.
 206
 207 lemma sem_star_w : ∀S.∀i:pitem S.∀w.
 208   \sem{i^*} w = (∃w1,w2.w1 @ w2 = w ∧ \sem{i} w1 ∧ \sem{|i|}^* w2).
 209 // qed.
 210
 211 lemma append_eq_nil : ∀S.∀w1,w2:word S. w1 @ w2 = ϵ → w1 = ϵ.
 212 #S #w1 #w2 cases w1 // #a #tl normalize #H destruct qed.
 213
 214 lemma not_epsilon_lp : ∀S:DeqSet.∀e:pitem S. ¬ (ϵ ∈ e).
 215 #S #e elim e normalize /2/
 216   [#r1 #r2 * #n1 #n2 % * /2/ * #w1 * #w2 * * #H
 217    >(append_eq_nil …H…) /2/
 218   |#r1 #r2 #n1 #n2 % * /2/
 219   |#r #n % * #w1 * #w2 * * #H >(append_eq_nil …H…) /2/
 220   ]
 221 qed.
 222
 223 (* lemma 12 *)
 224 lemma epsilon_to_true : ∀S.∀e:pre S. ϵ ∈ e → \snd e = true.
 225 #S * #i #b cases b // normalize #H @False_ind /2/
 226 qed.
 227
 228 lemma true_to_epsilon : ∀S.∀e:pre S. \snd e = true → ϵ ∈ e.
 229 #S * #i #b #btrue normalize in btrue; >btrue %2 //
 230 qed.
 231
 232 lemma minus_eps_item: ∀S.∀i:pitem S. \sem{i} =1 \sem{i}-{[ ]}.
 233 #S #i #w %
 234   [#H whd % // normalize @(not_to_not … (not_epsilon_lp …i)) //
 235   |* //
 236   ]
 237 qed.
 238
 239 lemma minus_eps_pre: ∀S.∀e:pre S. \sem{\fst e} =1 \sem{e}-{[ ]}.
 240 #S * #i *
 241   [>sem_pre_true normalize in ⊢ (??%?); #w %
 242     [/3/ | * * // #H1 #H2 @False_ind @(absurd …H1 H2)]
 243   |>sem_pre_false normalize in ⊢ (??%?); #w % [ /3/ | * // ]
 244   ]
 245 qed.
 246
 247 definition lo ≝ λS:DeqSet.λa,b:pre S.〈\fst a + \fst b,\snd a ∨ \snd b〉.
 248 notation "a ⊕ b" left associative with precedence 60 for @{'oplus $a $b}.
 249 interpretation "oplus" 'oplus a b = (lo ? a b).
 250
 251 lemma lo_def: ∀S.∀i1,i2:pitem S.∀b1,b2. 〈i1,b1〉⊕〈i2,b2〉=〈i1+i2,b1∨b2〉.
 252 // qed.
 253
 254 definition pre_concat_r ≝ λS:DeqSet.λi:pitem S.λe:pre S.
 255   match e with [ mk_Prod i1 b ⇒ 〈i · i1, b〉].
 256
 257 notation "i ◃ e" left associative with precedence 60 for @{'lhd $i $e}.
 258 interpretation "pre_concat_r" 'lhd i e = (pre_concat_r ? i e).
 259
 260 lemma eq_to_ex_eq: ∀S.∀A,B:word S → Prop.
 261   A = B → A =1 B.
 262 #S #A #B #H >H /2/ qed.
 263
 264 lemma sem_pre_concat_r : ∀S,i.∀e:pre S.
 265   \sem{i ◃ e} =1 \sem{i} · \sem{|\fst e|} ∪ \sem{e}.
 266 #S #i * #i1 #b1 cases b1 [2: @eq_to_ex_eq //]
 267 >sem_pre_true >sem_cat >sem_pre_true /2/
 268 qed.
 269
 270 definition pre_concat_l ≝ λS:DeqSet.λbcast:∀S:DeqSet.pitem S → pre S.λe1:pre S.λi2:pitem S.
 271   match e1 with
 272   [ mk_Prod i1 b1 ⇒ match b1 with
 273     [ true ⇒ (i1 ◃ (bcast ? i2))
 274     | false ⇒ 〈i1 · i2,false〉
 275     ]
 276   ].
 277
 278 notation "a ▹ b" left associative with precedence 60 for @{'tril eclose $a $b}.
 279 interpretation "item-pre concat" 'tril op a b = (pre_concat_l ? op a b).
 280
 281 notation "•" non associative with precedence 60 for @{eclose ?}.
 282
 283 let rec eclose (S: DeqSet) (i: pitem S) on i : pre S ≝
 284  match i with
 285   [ pz ⇒ 〈 `∅, false 〉
 286   | pe ⇒ 〈 ϵ,  true 〉
 287   | ps x ⇒ 〈 `.x, false〉
 288   | pp x ⇒ 〈 `.x, false 〉
 289   | po i1 i2 ⇒ •i1 ⊕ •i2
 290   | pc i1 i2 ⇒ •i1 ▹ i2
 291   | pk i ⇒ 〈(\fst (•i))^*,true〉].
 292
 293 notation "• x" non associative with precedence 60 for @{'eclose $x}.
 294 interpretation "eclose" 'eclose x = (eclose ? x).
 295
 296 lemma eclose_plus: ∀S:DeqSet.∀i1,i2:pitem S.
 297   •(i1 + i2) = •i1 ⊕ •i2.
 298 // qed.
 299
 300 lemma eclose_dot: ∀S:DeqSet.∀i1,i2:pitem S.
 301   •(i1 · i2) = •i1 ▹ i2.
 302 // qed.
 303
 304 lemma eclose_star: ∀S:DeqSet.∀i:pitem S.
 305   •i^* = 〈(\fst(•i))^*,true〉.
 306 // qed.
 307
 308 definition lift ≝ λS.λf:pitem S →pre S.λe:pre S.
 309   match e with
 310   [ mk_Prod i b ⇒ 〈\fst (f i), \snd (f i) ∨ b〉].
 311
 312 definition preclose ≝ λS. lift S (eclose S).
 313 interpretation "preclose" 'eclose x = (preclose ? x).
 314
 315 (* theorem 16: 2 *)
 316 lemma sem_oplus: ∀S:DeqSet.∀e1,e2:pre S.
 317   \sem{e1 ⊕ e2} =1 \sem{e1} ∪ \sem{e2}.
 318 #S * #i1 #b1 * #i2 #b2 #w %
 319   [cases b1 cases b2 normalize /2/ * /3/ * /3/
 320   |cases b1 cases b2 normalize /2/ * /3/ * /3/
 321   ]
 322 qed.
 323
 324 lemma odot_true :
 325   ∀S.∀i1,i2:pitem S.
 326   〈i1,true〉 ▹ i2 = i1 ◃ (•i2).
 327 // qed.
 328
 329 lemma odot_true_bis :
 330   ∀S.∀i1,i2:pitem S.
 331   〈i1,true〉 ▹ i2 = 〈i1 · \fst (•i2), \snd (•i2)〉.
 332 #S #i1 #i2 normalize cases (•i2) // qed.
 333
 334 lemma odot_false:
 335   ∀S.∀i1,i2:pitem S.
 336   〈i1,false〉 ▹ i2 = 〈i1 · i2, false〉.
 337 // qed.
 338
 339 lemma LcatE : ∀S.∀e1,e2:pitem S.
 340   \sem{e1 · e2} = \sem{e1} · \sem{|e2|} ∪ \sem{e2}.
 341 // qed.
 342
 343 lemma erase_bull : ∀S.∀i:pitem S. |\fst (•i)| = |i|.
 344 #S #i elim i //
 345   [ #i1 #i2 #IH1 #IH2 >erase_dot <IH1 >eclose_dot
 346     cases (•i1) #i11 #b1 cases b1 // <IH2 >odot_true_bis //
 347   | #i1 #i2 #IH1 #IH2 >eclose_plus >(erase_plus … i1) <IH1 <IH2
 348     cases (•i1) #i11 #b1 cases (•i2) #i21 #b2 //
 349   | #i #IH >eclose_star >(erase_star … i) <IH cases (•i) //
 350   ]
 351 qed.
 352
 353 (*
 354 lemma sem_eclose_star: ∀S:DeqSet.∀i:pitem S.
 355   \sem{〈i^*,true〉} =1 \sem{〈i,false〉}·\sem{|i|}^* ∪ {ϵ}.
 356 /2/ qed.
 357 *)
 358
 359 (* theorem 16: 1 → 3 *)
 360 lemma odot_dot_aux : ∀S.∀e1:pre S.∀i2:pitem S.
 361    \sem{•i2} =1  \sem{i2} ∪ \sem{|i2|} →
 362    \sem{e1 ▹ i2} =1  \sem{e1} · \sem{|i2|} ∪ \sem{i2}.
 363 #S * #i1 #b1 #i2 cases b1
 364   [2:#th >odot_false >sem_pre_false >sem_pre_false >sem_cat /2/
 365   |#H >odot_true >sem_pre_true @(eqP_trans … (sem_pre_concat_r …))
 366    >erase_bull @eqP_trans [|@(eqP_union_l … H)]
 367     @eqP_trans [|@eqP_union_l[|@union_comm ]]
 368     @eqP_trans [|@eqP_sym @union_assoc ] /3/
 369   ]
 370 qed.
 371
 372 lemma minus_eps_pre_aux: ∀S.∀e:pre S.∀i:pitem S.∀A.
 373  \sem{e} =1 \sem{i} ∪ A → \sem{\fst e} =1 \sem{i} ∪ (A - {[ ]}).
 374 #S #e #i #A #seme
 375 @eqP_trans [|@minus_eps_pre]
 376 @eqP_trans [||@eqP_union_r [|@eqP_sym @minus_eps_item]]
 377 @eqP_trans [||@distribute_substract]
 378 @eqP_substract_r //
 379 qed.
 380
 381 (* theorem 16: 1 *)
 382 theorem sem_bull: ∀S:DeqSet. ∀i:pitem S.  \sem{•i} =1 \sem{i} ∪ \sem{|i|}.
 383 #S #e elim e
 384   [#w normalize % [/2/ | * //]
 385   |/2/
 386   |#x normalize #w % [ /2/ | * [@False_ind | //]]
 387   |#x normalize #w % [ /2/ | * // ]
 388   |#i1 #i2 #IH1 #IH2 >eclose_dot
 389    @eqP_trans [|@odot_dot_aux //] >sem_cat
 390    @eqP_trans
 391      [|@eqP_union_r
 392        [|@eqP_trans [|@(cat_ext_l … IH1)] @distr_cat_r]]
 393    @eqP_trans [|@union_assoc]
 394    @eqP_trans [||@eqP_sym @union_assoc]
 395    @eqP_union_l //
 396   |#i1 #i2 #IH1 #IH2 >eclose_plus
 397    @eqP_trans [|@sem_oplus] >sem_plus >erase_plus
 398    @eqP_trans [|@(eqP_union_l … IH2)]
 399    @eqP_trans [|@eqP_sym @union_assoc]
 400    @eqP_trans [||@union_assoc] @eqP_union_r
 401    @eqP_trans [||@eqP_sym @union_assoc]
 402    @eqP_trans [||@eqP_union_l [|@union_comm]]
 403    @eqP_trans [||@union_assoc] /2/
 404   |#i #H >sem_pre_true >sem_star >erase_bull >sem_star
 405    @eqP_trans [|@eqP_union_r [|@cat_ext_l [|@minus_eps_pre_aux //]]]
 406    @eqP_trans [|@eqP_union_r [|@distr_cat_r]]
 407    @eqP_trans [|@union_assoc] @eqP_union_l >erase_star
 408    @eqP_sym @star_fix_eps
 409   ]
 410 qed.
 411
 412 (* blank item *)
 413 let rec blank (S: DeqSet) (i: re S) on i :pitem S ≝
 414  match i with
 415   [ z ⇒ `∅
 416   | e ⇒ ϵ
 417   | s y ⇒ `y
 418   | o e1 e2 ⇒ (blank S e1) + (blank S e2)
 419   | c e1 e2 ⇒ (blank S e1) · (blank S e2)
 420   | k e ⇒ (blank S e)^* ].
 421
 422 lemma forget_blank: ∀S.∀e:re S.|blank S e| = e.
 423 #S #e elim e normalize //
 424 qed.
 425
 426 lemma sem_blank: ∀S.∀e:re S.\sem{blank S e} =1 ∅.
 427 #S #e elim e
 428   [1,2:@eq_to_ex_eq //
 429   |#s @eq_to_ex_eq //
 430   |#e1 #e2 #Hind1 #Hind2 >sem_cat
 431    @eqP_trans [||@(union_empty_r … ∅)]
 432    @eqP_trans [|@eqP_union_l[|@Hind2]] @eqP_union_r
 433    @eqP_trans [||@(cat_empty_l … ?)] @cat_ext_l @Hind1
 434   |#e1 #e2 #Hind1 #Hind2 >sem_plus
 435    @eqP_trans [||@(union_empty_r … ∅)]
 436    @eqP_trans [|@eqP_union_l[|@Hind2]] @eqP_union_r @Hind1
 437   |#e #Hind >sem_star
 438    @eqP_trans [||@(cat_empty_l … ?)] @cat_ext_l @Hind
 439   ]
 440 qed.
 441
 442 theorem re_embedding: ∀S.∀e:re S.
 443   \sem{•(blank S e)} =1 \sem{e}.
 444 #S #e @eqP_trans [|@sem_bull] >forget_blank
 445 @eqP_trans [|@eqP_union_r [|@sem_blank]]
 446 @eqP_trans [|@union_comm] @union_empty_r.
 447 qed.
 448
 449 (* lefted operations *)
 450 definition lifted_cat ≝ λS:DeqSet.λe:pre S.
 451   lift S (pre_concat_l S eclose e).
 452
 453 notation "e1 ⊙ e2" left associative with precedence 70 for @{'odot $e1 $e2}.
 454
 455 interpretation "lifted cat" 'odot e1 e2 = (lifted_cat ? e1 e2).
 456
 457 lemma odot_true_b : ∀S.∀i1,i2:pitem S.∀b.
 458   〈i1,true〉 ⊙ 〈i2,b〉 = 〈i1 · (\fst (•i2)),\snd (•i2) ∨ b〉.
 459 #S #i1 #i2 #b normalize in ⊢ (??%?); cases (•i2) //
 460 qed.
 461
 462 lemma odot_false_b : ∀S.∀i1,i2:pitem S.∀b.
 463   〈i1,false〉 ⊙ 〈i2,b〉 = 〈i1 · i2 ,b〉.
 464 //
 465 qed.
 466
 467 lemma erase_odot:∀S.∀e1,e2:pre S.
 468   |\fst (e1 ⊙ e2)| = |\fst e1| · (|\fst e2|).
 469 #S * #i1 * * #i2 #b2 // >odot_true_b //
 470 qed.
 471
 472 definition lk ≝ λS:DeqSet.λe:pre S.
 473   match e with
 474   [ mk_Prod i1 b1 ⇒
 475     match b1 with
 476     [true ⇒ 〈(\fst (eclose ? i1))^*, true〉
 477     |false ⇒ 〈i1^*,false〉
 478     ]
 479   ].
 480
 481 (* notation < "a \sup ⊛" non associative with precedence 90 for @{'lk $a}.*)
 482 interpretation "lk" 'lk a = (lk ? a).
 483 notation "a^⊛" non associative with precedence 90 for @{'lk $a}.
 484
 485
 486 lemma ostar_true: ∀S.∀i:pitem S.
 487   〈i,true〉^⊛ = 〈(\fst (•i))^*, true〉.
 488 // qed.
 489
 490 lemma ostar_false: ∀S.∀i:pitem S.
 491   〈i,false〉^⊛ = 〈i^*, false〉.
 492 // qed.
 493
 494 lemma erase_ostar: ∀S.∀e:pre S.
 495   |\fst (e^⊛)| = |\fst e|^*.
 496 #S * #i * // qed.
 497
 498 lemma sem_odot_true: ∀S:DeqSet.∀e1:pre S.∀i.
 499   \sem{e1 ⊙ 〈i,true〉} =1 \sem{e1 ▹ i} ∪ { [ ] }.
 500 #S #e1 #i
 501 cut (e1 ⊙ 〈i,true〉 = 〈\fst (e1 ▹ i), \snd(e1 ▹ i) ∨ true〉) [//]
 502 #H >H cases (e1 ▹ i) #i1 #b1 cases b1
 503   [>sem_pre_true @eqP_trans [||@eqP_sym @union_assoc]
 504    @eqP_union_l /2/
 505   |/2/
 506   ]
 507 qed.
 508
 509 lemma eq_odot_false: ∀S:DeqSet.∀e1:pre S.∀i.
 510   e1 ⊙ 〈i,false〉 = e1 ▹ i.
 511 #S #e1 #i
 512 cut (e1 ⊙ 〈i,false〉 = 〈\fst (e1 ▹ i), \snd(e1 ▹ i) ∨ false〉) [//]
 513 cases (e1 ▹ i) #i1 #b1 cases b1 #H @H
 514 qed.
 515
 516 lemma sem_odot:
 517   ∀S.∀e1,e2: pre S. \sem{e1 ⊙ e2} =1 \sem{e1}· \sem{|\fst e2|} ∪ \sem{e2}.
 518 #S #e1 * #i2 *
 519   [>sem_pre_true
 520    @eqP_trans [|@sem_odot_true]
 521    @eqP_trans [||@union_assoc] @eqP_union_r @odot_dot_aux //
 522   |>sem_pre_false >eq_odot_false @odot_dot_aux //
 523   ]
 524 qed.
 525
 526 (* theorem 16: 4 *)
 527 theorem sem_ostar: ∀S.∀e:pre S.
 528   \sem{e^⊛} =1  \sem{e} · \sem{|\fst e|}^*.
 529 #S * #i #b cases b
 530   [>sem_pre_true >sem_pre_true >sem_star >erase_bull
 531    @eqP_trans [|@eqP_union_r[|@cat_ext_l [|@minus_eps_pre_aux //]]]
 532    @eqP_trans [|@eqP_union_r [|@distr_cat_r]]
 533    @eqP_trans [||@eqP_sym @distr_cat_r]
 534    @eqP_trans [|@union_assoc] @eqP_union_l
 535    @eqP_trans [||@eqP_sym @epsilon_cat_l] @eqP_sym @star_fix_eps
 536   |>sem_pre_false >sem_pre_false >sem_star /2/
 537   ]
 538 qed.
 539