matita/matita/lib/turing/if_machine.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_____________________________________________________________*)
  11
  12 include "turing/mono.ma".
  13
  14 (**************************** single final machine ****************************)
  15
  16 definition single_finalTM ≝
  17   λsig.λM:TM sig.seq ? M (nop ?).
  18
  19 lemma sem_single_final: ∀sig.∀M: TM sig.∀R.
  20   M ⊨ R → single_finalTM sig M ⊨ R.
  21 #sig #M #R #HR #intape
  22 cases (sem_seq ????? HR (sem_nop …) intape)
  23 #k * #outc * #Hloop * #ta * #Hta whd in ⊢ (%→?); #Houtc
  24 @(ex_intro ?? k) @(ex_intro ?? outc) %  [ @Hloop | >Houtc // ]
  25 qed.
  26
  27 lemma single_final: ∀sig.∀M: TM sig.∀q1,q2.
  28   halt ? (single_finalTM sig M) q1 = true
  29     →  halt ? (single_finalTM sig M) q2 = true → q1=q2.
  30 #sig #M *
  31   [#q1M #q2 whd in match (halt ???); #H destruct
  32   |#q1nop *
  33     [#q2M #_ whd in match (halt ???); #H destruct
  34     |#q2nop #_ #_ @eq_f normalize @nop_single_state
  35     ]
  36   ]
  37 qed.
  38
  39 (******************************** if machine **********************************)
  40
  41 definition if_trans ≝ λsig. λM1,M2,M3 : TM sig. λq:states sig M1.
  42 λp. let 〈s,a〉 ≝ p in
  43   match s with
  44   [ inl s1 ⇒
  45       if halt sig M1 s1 then
  46         if s1==q then 〈inr … (inl … (start sig M2)), None ?〉
  47         else 〈inr … (inr … (start sig M3)), None ?〉
  48       else let 〈news1,m〉 ≝ trans sig M1 〈s1,a〉 in
  49        〈inl … news1,m〉
  50   | inr s' ⇒
  51       match s' with
  52       [ inl s2 ⇒ let 〈news2,m〉 ≝ trans sig M2 〈s2,a〉 in
  53          〈inr … (inl … news2),m〉
  54       | inr s3 ⇒ let 〈news3,m〉 ≝ trans sig M3 〈s3,a〉 in
  55          〈inr … (inr … news3),m〉
  56       ]
  57   ].
  58
  59 definition ifTM ≝ λsig. λcondM,thenM,elseM : TM sig.
  60   λqacc: states sig condM.
  61   mk_TM sig
  62     (FinSum (states sig condM) (FinSum (states sig thenM) (states sig elseM)))
  63     (if_trans sig condM thenM elseM qacc)
  64     (inl … (start sig condM))
  65     (λs.match s with
  66       [ inl _ ⇒ false
  67       | inr s' ⇒ match s' with
  68         [ inl s2 ⇒ halt sig thenM s2
  69         | inr s3 ⇒ halt sig elseM s3 ]]).
  70
  71 (****************************** lifting lemmas ********************************)
  72 lemma trans_if_liftM1 : ∀sig,M1,M2,M3,acc,s,a,news,move.
  73   halt ? M1 s = false →
  74   trans sig M1 〈s,a〉 = 〈news,move〉 →
  75   trans sig (ifTM sig M1 M2 M3 acc) 〈inl … s,a〉 = 〈inl … news,move〉.
  76 #sig * #Q1 #T1 #init1 #halt1 #M2 #M3 #acc #s #a #news #move
  77 #Hhalt #Htrans whd in ⊢ (??%?); >Hhalt >Htrans %
  78 qed.
  79
  80 lemma trans_if_liftM2 : ∀sig,M1,M2,M3,acc,s,a,news,move.
  81   halt ? M2 s = false →
  82   trans sig M2 〈s,a〉 = 〈news,move〉 →
  83   trans sig (ifTM sig M1 M2 M3 acc) 〈inr … (inl … s),a〉 = 〈inr… (inl … news),move〉.
  84 #sig #M1 * #Q2 #T2 #init2 #halt2 #M3 #acc #s #a #news #move
  85 #Hhalt #Htrans whd in ⊢ (??%?); >Hhalt >Htrans %
  86 qed.
  87
  88 lemma trans_if_liftM3 : ∀sig,M1,M2,M3,acc,s,a,news,move.
  89   halt ? M3 s = false →
  90   trans sig M3 〈s,a〉 = 〈news,move〉 →
  91   trans sig (ifTM sig M1 M2 M3 acc) 〈inr … (inr … s),a〉 = 〈inr… (inr … news),move〉.
  92 #sig #M1 * #Q2 #T2 #init2 #halt2 #M3 #acc #s #a #news #move
  93 #Hhalt #Htrans whd in ⊢ (??%?); >Hhalt >Htrans %
  94 qed.
  95
  96 lemma step_if_liftM1 : ∀sig,M1,M2,M3,acc,c0.
  97  halt ? M1 (cstate ?? c0) = false →
  98  step sig (ifTM sig M1 M2 M3 acc) (lift_confL sig (states ? M1) ? c0) =
  99  lift_confL sig (states ? M1) ? (step sig M1 c0).
 100 #sig #M1 #M2 #M3 #acc * #s #t
 101   lapply (refl ? (trans ?? 〈s,current sig t〉))
 102   cases (trans ?? 〈s,current sig t〉) in ⊢ (???% → %);
 103   #s0 #m0 cases t
 104   [ #Heq #Hhalt
 105   | 2,3: #s1 #l1 #Heq #Hhalt
 106   |#ls #s1 #rs #Heq #Hhalt ]
 107   whd in ⊢ (???(????%)); >Heq whd in ⊢ (???%);
 108   whd in ⊢ (??(???%)?); whd in ⊢ (??%?); >(trans_if_liftM1 … Hhalt Heq) //
 109 qed.
 110
 111 lemma step_if_liftM2 : ∀sig,M1,M2,M3,acc,c0.
 112  halt ? M2 (cstate ?? c0) = false →
 113  step sig (ifTM sig M1 M2 M3 acc) (lift_confR sig ?? (lift_confL sig ?? c0)) =
 114  lift_confR sig ?? (lift_confL sig ?? (step sig M2 c0)).
 115 #sig #M1 (* * #Q1 #T1 #init1 #halt1 *) #M2 #M3 #acc * #s #t
 116   lapply (refl ? (trans ?? 〈s,current sig t〉))
 117   cases (trans ?? 〈s,current sig t〉) in ⊢ (???% → %);
 118   #s0 #m0 cases t
 119   [ #Heq #Hhalt
 120   | 2,3: #s1 #l1 #Heq #Hhalt
 121   |#ls #s1 #rs #Heq #Hhalt ]
 122   whd in match (step ? M2 ?); >Heq whd in ⊢ (???%);
 123   whd in ⊢ (??(???%)?); whd in ⊢ (??%?); >(trans_if_liftM2 … Hhalt Heq) //
 124 qed.
 125
 126 lemma step_if_liftM3 : ∀sig,M1,M2,M3,acc,c0.
 127  halt ? M3 (cstate ?? c0) = false →
 128  step sig (ifTM sig M1 M2 M3 acc) (lift_confR sig ?? (lift_confR sig ?? c0)) =
 129  lift_confR sig ?? (lift_confR sig ?? (step sig M3 c0)).
 130 #sig #M1 (* * #Q1 #T1 #init1 #halt1 *) #M2 #M3 #acc * #s #t
 131   lapply (refl ? (trans ?? 〈s,current sig t〉))
 132   cases (trans ?? 〈s,current sig t〉) in ⊢ (???% → %);
 133   #s0 #m0 cases t
 134   [ #Heq #Hhalt
 135   | 2,3: #s1 #l1 #Heq #Hhalt
 136   |#ls #s1 #rs #Heq #Hhalt ]
 137   whd in match (step ? M3 ?); >Heq whd in ⊢ (???%);
 138   whd in ⊢ (??(???%)?); whd in ⊢ (??%?); >(trans_if_liftM3 … Hhalt Heq) //
 139 qed.
 140
 141 lemma trans_if_M1true_acc : ∀sig,M1,M2,M3,acc,s,a.
 142   halt ? M1 s = true → s==acc = true →
 143   trans sig (ifTM sig M1 M2 M3 acc) 〈inl … s,a〉 = 〈inr … (inl … (start ? M2)),None ?〉.
 144 #sig #M1 #M2 #M3 #acc #s #a #Hhalt #Hacc whd in ⊢ (??%?); >Hhalt >Hacc %
 145 qed.
 146
 147 lemma trans_if_M1true_notacc : ∀sig,M1,M2,M3,acc,s,a.
 148   halt ? M1 s = true → s==acc = false →
 149   trans sig (ifTM sig M1 M2 M3 acc) 〈inl … s,a〉 = 〈inr … (inr … (start ? M3)),None ?〉.
 150 #sig #M1 #M2 #M3 #acc #s #a #Hhalt #Hacc whd in ⊢ (??%?); >Hhalt >Hacc %
 151 qed.
 152
 153 (******************************** semantics ***********************************)
 154 lemma sem_if: ∀sig.∀M1,M2,M3:TM sig.∀Rtrue,Rfalse,R2,R3,acc.
 155   accRealize sig M1 acc Rtrue Rfalse → M2 ⊨ R2 → M3 ⊨ R3 →
 156     ifTM sig M1 M2 M3 acc ⊨ (Rtrue ∘ R2) ∪ (Rfalse ∘ R3).
 157 #sig #M1 #M2 #M3 #Rtrue #Rfalse #R2 #R3 #acc #HaccR #HR2 #HR3 #t
 158 cases (HaccR t) #k1 * #outc1 * * #Hloop1 #HMtrue #HMfalse
 159 cases (true_or_false (cstate ?? outc1 == acc)) #Hacc
 160   [cases (HR2 (ctape sig ? outc1)) #k2 * #outc2 * #Hloop2 #HM2
 161    @(ex_intro … (k1+k2)) @(ex_intro … (lift_confR … (lift_confL … outc2))) %
 162     [@(loop_merge ?????????
 163      (mk_config ? (FinSum (states sig M1) (FinSum (states sig M2) (states sig M3)))
 164       (inr (states sig M1) ? (inl (states sig M2) (states sig M3) (start sig M2))) (ctape ?? outc1) )
 165      ?
 166      (loop_lift ???
 167        (lift_confL sig (states ? M1) (FinSum (states ? M2) (states ? M3)))
 168        (step sig M1) (step sig (ifTM sig M1 M2 M3 acc))
 169        (λc.halt sig M1 (cstate … c))
 170        (λc.halt_liftL ?? (halt sig M1) (cstate … c))
 171        … Hloop1))
 172       [* *
 173         [ #sl #tl whd in ⊢ (??%? → ?); #Hl %
 174         | #sr #tr whd in ⊢ (??%? → ?); #Hr destruct (Hr) ]
 175       |#c0 #Hhalt >(step_if_liftM1 … Hhalt) //
 176       |#x <p_halt_liftL %
 177       |whd in ⊢ (??%?); >(config_expand ?? outc1);
 178        whd in match (lift_confL ????);
 179        >(trans_if_M1true_acc … Hacc)
 180         [% | @(loop_Some ?????? Hloop1)]
 181       |cases outc1 #s1 #t1 %
 182       |@(loop_lift ???
 183          (λc.(lift_confR … (lift_confL sig (states ? M2) (states ? M3) c)))
 184          … Hloop2)
 185         [ * #s2 #t2 %
 186         | #c0 #Hhalt >(step_if_liftM2 … Hhalt) // ]
 187       ]
 188     |%1 @(ex_intro … (ctape ?? outc1)) %
 189       [@HMtrue @(\P Hacc) | >(config_expand ?? outc2) @HM2 ]
 190     ]
 191   |cases (HR3 (ctape sig ? outc1)) #k2 * #outc2 * #Hloop2 #HM3
 192    @(ex_intro … (k1+k2)) @(ex_intro … (lift_confR … (lift_confR … outc2))) %
 193     [@(loop_merge ?????????
 194      (mk_config ? (FinSum (states sig M1) (FinSum (states sig M2) (states sig M3)))
 195       (inr (states sig M1) ? (inr (states sig M2) (states sig M3) (start sig M3))) (ctape ?? outc1) )
 196      ?
 197      (loop_lift ???
 198        (lift_confL sig (states ? M1) (FinSum (states ? M2) (states ? M3)))
 199        (step sig M1) (step sig (ifTM sig M1 M2 M3 acc))
 200        (λc.halt sig M1 (cstate … c))
 201        (λc.halt_liftL ?? (halt sig M1) (cstate … c))
 202        … Hloop1))
 203       [* *
 204         [ #sl #tl whd in ⊢ (??%? → ?); #Hl %
 205         | #sr #tr whd in ⊢ (??%? → ?); #Hr destruct (Hr) ]
 206       |#c0 #Hhalt >(step_if_liftM1 … Hhalt) //
 207       |#x <p_halt_liftL %
 208       |whd in ⊢ (??%?); >(config_expand ?? outc1);
 209        whd in match (lift_confL ????);
 210        >(trans_if_M1true_notacc … Hacc)
 211         [% | @(loop_Some ?????? Hloop1)]
 212       |cases outc1 #s1 #t1 %
 213       |@(loop_lift ???
 214          (λc.(lift_confR … (lift_confR sig (states ? M2) (states ? M3) c)))
 215          … Hloop2)
 216         [ * #s2 #t2 %
 217         | #c0 #Hhalt >(step_if_liftM3 … Hhalt) // ]
 218       ]
 219     |%2 @(ex_intro … (ctape ?? outc1)) %
 220       [@HMfalse @(\Pf Hacc) | >(config_expand ?? outc2) @HM3 ]
 221     ]
 222   ]
 223 qed.
 224
 225 lemma sem_if_app: ∀sig,M1,M2,M3,Rtrue,Rfalse,R2,R3,R4,acc.
 226   accRealize sig M1 acc Rtrue Rfalse  → M2 ⊨ R2  → M3 ⊨ R3 →
 227     (∀t1,t2,t3. (Rtrue t1 t3 → R2 t3 t2) ∨ (Rfalse t1 t3 → R3 t3 t2) → R4 t1 t2) →
 228     ifTM sig M1 M2 M3 acc ⊨ R4.
 229 #sig #M1 #M2 #M3 #Rtrue #Rfalse #R2 #R3 #R4 #acc
 230 #HRacc #HRtrue #HRfalse #Hsub
 231 #t cases (sem_if … HRacc HRtrue HRfalse t)
 232 #k * #outc * #Hloop #Houtc @(ex_intro … k) @(ex_intro … outc)
 233 % [@Hloop] cases Houtc
 234   [* #t3 * #Hleft #Hright @(Hsub … t3) %1 /2/
 235   |* #t3 * #Hleft #Hright @(Hsub … t3) %2 /2/ ]
 236 qed.
 237
 238 (* we can probably use acc_sem_if to prove sem_if *)
 239 lemma acc_sem_if: ∀sig,M1,M2,M3,Rtrue,Rfalse,R2,R3,acc.
 240   accRealize sig M1 acc Rtrue Rfalse → M2 ⊨ R2 → M3 ⊨ R3 →
 241     accRealize sig
 242      (ifTM sig M1 (single_finalTM … M2) M3 acc)
 243      (inr … (inl … (inr … start_nop)))
 244      (Rtrue ∘ R2)
 245      (Rfalse ∘ R3).
 246 #sig #M1 #M2 #M3 #Rtrue #Rfalse #R2 #R3 #acc #HaccR #HR2 #HR3 #t
 247 cases (HaccR t) #k1 * #outc1 * * #Hloop1 #HMtrue #HMfalse
 248 cases (true_or_false (cstate ?? outc1 == acc)) #Hacc
 249   [lapply (sem_single_final … HR2) -HR2 #HR2
 250    cases (HR2 (ctape sig ? outc1)) #k2 * #outc2 * #Hloop2 #HM2
 251    @(ex_intro … (k1+k2))
 252    @(ex_intro … (lift_confR … (lift_confL … outc2))) %
 253     [%
 254       [@(loop_merge ?????????
 255          (mk_config ? (states sig (ifTM sig M1 (single_finalTM … M2) M3 acc))
 256           (inr (states sig M1) ? (inl ? (states sig M3) (start sig (single_finalTM sig M2)))) (ctape ?? outc1) )
 257          ?
 258          (loop_lift ???
 259           (lift_confL sig (states ? M1) (FinSum (states ? (single_finalTM … M2)) (states ? M3)))
 260           (step sig M1) (step sig (ifTM sig M1 (single_finalTM ? M2) M3 acc))
 261           (λc.halt sig M1 (cstate … c))
 262           (λc.halt_liftL ?? (halt sig M1) (cstate … c))
 263           … Hloop1))
 264         [* *
 265           [ #sl #tl whd in ⊢ (??%? → ?); #Hl %
 266           | #sr #tr whd in ⊢ (??%? → ?); #Hr destruct (Hr) ]
 267         |#c0 #Hhalt >(step_if_liftM1 … Hhalt) //
 268         |#x <p_halt_liftL %
 269         |whd in ⊢ (??%?); >(config_expand ?? outc1);
 270          whd in match (lift_confL ????);
 271          >(trans_if_M1true_acc … Hacc)
 272           [% | @(loop_Some ?????? Hloop1)]
 273         |cases outc1 #s1 #t1 %
 274         |@(loop_lift ???
 275            (λc.(lift_confR … (lift_confL sig (states ? (single_finalTM ? M2)) (states ? M3) c)))
 276            … Hloop2)
 277           [ * #s2 #t2 %
 278           | #c0 #Hhalt >(step_if_liftM2 … Hhalt) // ]
 279         ]
 280       |#_ @(ex_intro … (ctape ?? outc1)) %
 281         [@HMtrue @(\P Hacc) | >(config_expand ?? outc2) @HM2 ]
 282       ]
 283     |>(config_expand ?? outc2) whd in match (lift_confR ????);
 284      * #H @False_ind @H @eq_f @eq_f >(config_expand ?? outc2)
 285      @single_final // @(loop_Some ?????? Hloop2)
 286     ]
 287   |cases (HR3 (ctape sig ? outc1)) #k2 * #outc2 * #Hloop2 #HM3
 288    @(ex_intro … (k1+k2)) @(ex_intro … (lift_confR … (lift_confR … outc2))) %
 289     [%
 290       [@(loop_merge ?????????
 291          (mk_config ? (states sig (ifTM sig M1 (single_finalTM … M2) M3 acc))
 292           (inr (states sig M1) ? (inr (states sig (single_finalTM ? M2)) ? (start sig M3))) (ctape ?? outc1) )
 293          ?
 294          (loop_lift ???
 295           (lift_confL sig (states ? M1) (FinSum (states ? (single_finalTM … M2)) (states ? M3)))
 296           (step sig M1) (step sig (ifTM sig M1 (single_finalTM ? M2) M3 acc))
 297           (λc.halt sig M1 (cstate … c))
 298           (λc.halt_liftL ?? (halt sig M1) (cstate … c))
 299           … Hloop1))
 300         [* *
 301           [ #sl #tl whd in ⊢ (??%? → ?); #Hl %
 302           | #sr #tr whd in ⊢ (??%? → ?); #Hr destruct (Hr) ]
 303         |#c0 #Hhalt >(step_if_liftM1 … Hhalt) //
 304         |#x <p_halt_liftL %
 305         |whd in ⊢ (??%?); >(config_expand ?? outc1);
 306          whd in match (lift_confL ????);
 307          >(trans_if_M1true_notacc … Hacc)
 308           [% | @(loop_Some ?????? Hloop1)]
 309         |cases outc1 #s1 #t1 %
 310         |@(loop_lift ???
 311            (λc.(lift_confR … (lift_confR sig (states ? (single_finalTM ? M2)) (states ? M3) c)))
 312            … Hloop2)
 313           [ * #s2 #t2 %
 314           | #c0 #Hhalt >(step_if_liftM3 … Hhalt) // ]
 315         ]
 316       |>(config_expand ?? outc2) whd in match (lift_confR ????);
 317        #H destruct (H)
 318       ]
 319     |#_ @(ex_intro … (ctape ?? outc1)) %
 320       [@HMfalse @(\Pf Hacc) | >(config_expand ?? outc2) @HM3 ]
 321     ]
 322   ]
 323 qed.
 324
 325 lemma acc_sem_if_app: ∀sig,M1,M2,M3,Rtrue,Rfalse,R2,R3,R4,R5,acc.
 326   accRealize sig M1 acc Rtrue Rfalse → Realize sig M2 R2 → Realize sig M3 R3 →
 327     (∀t1,t2,t3. Rtrue t1 t3 → R2 t3 t2 → R4 t1 t2) →
 328     (∀t1,t2,t3. Rfalse t1 t3 → R3 t3 t2 → R5 t1 t2) →
 329     accRealize sig
 330      (ifTM sig M1 (single_finalTM … M2) M3 acc)
 331      (inr … (inl … (inr … start_nop)))
 332      R4 R5.
 333 #sig #M1 #M2 #M3 #Rtrue #Rfalse #R2 #R3 #R4 #R5 #acc
 334 #HRacc #HRtrue #HRfalse #Hsub1 #Hsub2
 335 #t cases (acc_sem_if … HRacc HRtrue HRfalse t)
 336 #k * #outc * * #Hloop #Houtc1 #Houtc2 @(ex_intro … k) @(ex_intro … outc)
 337 % [% [@Hloop
 338      |#H cases (Houtc1 H) #t3 * #Hleft #Hright @Hsub1 // ]
 339   |#H cases (Houtc2 H) #t3 * #Hleft #Hright @Hsub2 // ]
 340 qed.