matita/matita/lib/turing/mono.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_____________________________________________________________*)
  11
  12 include "basics/vectors.ma".
  13 (* include "basics/relations.ma". *)
  14
  15 (******************************** tape ****************************************)
  16
  17 (* A tape is essentially a triple 〈left,current,right〉 where however the current
  18 symbol could be missing. This may happen for three different reasons: both tapes
  19 are empty; we are on the left extremity of a non-empty tape (left overflow), or
  20 we are on the right extremity of a non-empty tape (right overflow). *)
  21
  22 inductive tape (sig:FinSet) : Type[0] ≝
  23 | niltape : tape sig
  24 | leftof  : sig → list sig → tape sig
  25 | rightof : sig → list sig → tape sig
  26 | midtape : list sig → sig → list sig → tape sig.
  27
  28 definition left ≝
  29  λsig.λt:tape sig.match t with
  30  [ niltape ⇒ [] | leftof _ _ ⇒ [] | rightof s l ⇒ s::l | midtape l _ _ ⇒ l ].
  31
  32 definition right ≝
  33  λsig.λt:tape sig.match t with
  34  [ niltape ⇒ [] | leftof s r ⇒ s::r | rightof _ _ ⇒ []| midtape _ _ r ⇒ r ].
  35
  36 definition current ≝
  37  λsig.λt:tape sig.match t with
  38  [ midtape _ c _ ⇒ Some ? c | _ ⇒ None ? ].
  39
  40 definition mk_tape :
  41   ∀sig:FinSet.list sig → option sig → list sig → tape sig ≝
  42   λsig,lt,c,rt.match c with
  43   [ Some c' ⇒ midtape sig lt c' rt
  44   | None ⇒ match lt with
  45     [ nil ⇒ match rt with
  46       [ nil ⇒ niltape ?
  47       | cons r0 rs0 ⇒ leftof ? r0 rs0 ]
  48     | cons l0 ls0 ⇒ rightof ? l0 ls0 ] ].
  49
  50 lemma current_to_midtape: ∀sig,t,c. current sig t = Some ? c →
  51   ∃ls,rs. t = midtape ? ls c rs.
  52 #sig *
  53   [#c whd in ⊢ ((??%?)→?); #Hfalse destruct
  54   |#a #l #c whd in ⊢ ((??%?)→?); #Hfalse destruct
  55   |#a #l #c whd in ⊢ ((??%?)→?); #Hfalse destruct
  56   |#ls #a #rs #c whd in ⊢ ((??%?)→?); #H destruct
  57    @(ex_intro … ls) @(ex_intro … rs) //
  58   ]
  59 qed.
  60
  61 (*********************************** moves ************************************)
  62
  63 inductive move : Type[0] ≝
  64   | L : move | R : move | N : move.
  65
  66 (********************************** machine ***********************************)
  67
  68 record TM (sig:FinSet): Type[1] ≝
  69 { states : FinSet;
  70   trans : states × (option sig) → states × (option (sig × move));
  71   start: states;
  72   halt : states → bool
  73 }.
  74
  75 definition tape_move_left ≝ λsig:FinSet.λlt:list sig.λc:sig.λrt:list sig.
  76   match lt with
  77   [ nil ⇒ leftof sig c rt
  78   | cons c0 lt0 ⇒ midtape sig lt0 c0 (c::rt) ].
  79
  80 definition tape_move_right ≝ λsig:FinSet.λlt:list sig.λc:sig.λrt:list sig.
  81   match rt with
  82   [ nil ⇒ rightof sig c lt
  83   | cons c0 rt0 ⇒ midtape sig (c::lt) c0 rt0 ].
  84
  85 definition tape_move ≝ λsig.λt: tape sig.λm:option (sig × move).
  86   match m with
  87   [ None ⇒ t
  88   | Some m' ⇒
  89     let 〈s,m1〉 ≝ m' in
  90     match m1 with
  91       [ R ⇒ tape_move_right ? (left ? t) s (right ? t)
  92       | L ⇒ tape_move_left ? (left ? t) s (right ? t)
  93       | N ⇒ midtape ? (left ? t) s (right ? t)
  94       ] ].
  95
  96 record config (sig,states:FinSet): Type[0] ≝
  97 { cstate : states;
  98   ctape: tape sig
  99 }.
 100
 101 lemma config_expand: ∀sig,Q,c.
 102   c = mk_config sig Q (cstate ?? c) (ctape ?? c).
 103 #sig #Q * //
 104 qed.
 105
 106 lemma config_eq : ∀sig,M,c1,c2.
 107   cstate sig M c1 = cstate sig M c2 →
 108     ctape sig M c1 = ctape sig M c2 →  c1 = c2.
 109 #sig #M1 * #s1 #t1 * #s2 #t2 //
 110 qed.
 111
 112 definition step ≝ λsig.λM:TM sig.λc:config sig (states sig M).
 113   let current_char ≝ current ? (ctape ?? c) in
 114   let 〈news,mv〉 ≝ trans sig M 〈cstate ?? c,current_char〉 in
 115   mk_config ?? news (tape_move sig (ctape ?? c) mv).
 116
 117 (******************************** loop ****************************************)
 118 let rec loop (A:Type[0]) n (f:A→A) p a on n ≝
 119   match n with
 120   [ O ⇒ None ?
 121   | S m ⇒ if p a then (Some ? a) else loop A m f p (f a)
 122   ].
 123
 124 lemma loop_S_true :
 125   ∀A,n,f,p,a. p a = true →
 126     loop A (S n) f p a = Some ? a.
 127 #A #n #f #p #a #pa normalize >pa //
 128 qed.
 129
 130 lemma loop_S_false :
 131   ∀A,n,f,p,a.  p a = false →
 132     loop A (S n) f p a = loop A n f p (f a).
 133 normalize #A #n #f #p #a #Hpa >Hpa %
 134 qed.
 135
 136 lemma loop_incr : ∀A,f,p,k1,k2,a1,a2.
 137   loop A k1 f p a1 = Some ? a2 →
 138     loop A (k2+k1) f p a1 = Some ? a2.
 139 #A #f #p #k1 #k2 #a1 #a2 generalize in match a1; elim k1
 140 [normalize #a0 #Hfalse destruct
 141 |#k1' #IH #a0 <plus_n_Sm whd in ⊢ (??%? → ??%?);
 142  cases (true_or_false (p a0)) #Hpa0 >Hpa0 whd in ⊢ (??%? → ??%?); // @IH
 143 ]
 144 qed.
 145
 146 lemma loop_merge : ∀A,f,p,q.(∀b. p b = false → q b = false) →
 147  ∀k1,k2,a1,a2,a3,a4.
 148    loop A k1 f p a1 = Some ? a2 →
 149      f a2 = a3 → q a2 = false →
 150        loop A k2 f q a3 = Some ? a4 →
 151          loop A (k1+k2) f q a1 = Some ? a4.
 152 #Sig #f #p #q #Hpq #k1 elim k1
 153   [normalize #k2 #a1 #a2 #a3 #a4 #H destruct
 154   |#k1' #Hind #k2 #a1 #a2 #a3 #a4 normalize in ⊢ (%→?);
 155    cases (true_or_false (p a1)) #pa1 >pa1 normalize in ⊢ (%→?);
 156    [#eqa1a2 destruct #eqa2a3 #Hqa2 #H
 157     whd in ⊢ (??(??%???)?); >plus_n_Sm @loop_incr
 158     whd in ⊢ (??%?); >Hqa2 >eqa2a3 @H
 159    |normalize >(Hpq … pa1) normalize #H1 #H2 #H3 @(Hind … H2) //
 160    ]
 161  ]
 162 qed.
 163
 164 lemma loop_split : ∀A,f,p,q.(∀b. q b = true → p b = true) →
 165  ∀k,a1,a2.
 166    loop A k f q a1 = Some ? a2 →
 167    ∃k1,a3.
 168     loop A k1 f p a1 = Some ? a3 ∧
 169       loop A (S(k-k1)) f q a3 = Some ? a2.
 170 #A #f #p #q #Hpq #k elim k
 171   [#a1 #a2 normalize #Heq destruct
 172   |#i #Hind #a1 #a2 normalize
 173    cases (true_or_false (q a1)) #Hqa1 >Hqa1 normalize
 174     [ #Ha1a2 destruct
 175      @(ex_intro … 1) @(ex_intro … a2) %
 176        [normalize >(Hpq …Hqa1) // |>Hqa1 //]
 177     |#Hloop cases (true_or_false (p a1)) #Hpa1
 178        [@(ex_intro … 1) @(ex_intro … a1) %
 179          [normalize >Hpa1 // |>Hqa1 <Hloop normalize //]
 180        |cases (Hind …Hloop) #k2 * #a3 * #Hloop1 #Hloop2
 181         @(ex_intro … (S k2)) @(ex_intro … a3) %
 182          [normalize >Hpa1 normalize // | @Hloop2 ]
 183        ]
 184     ]
 185   ]
 186 qed.
 187
 188 lemma loop_eq : ∀sig,f,q,i,j,a,x,y.
 189   loop sig i f q a = Some ? x → loop sig j f q a = Some ? y → x = y.
 190 #sig #f #q #i #j @(nat_elim2 … i j)
 191 [ #n #a #x #y normalize #Hfalse destruct (Hfalse)
 192 | #n #a #x #y #H1 normalize #Hfalse destruct (Hfalse)
 193 | #n1 #n2 #IH #a #x #y normalize cases (q a) normalize
 194   [ #H1 #H2 destruct %
 195   | /2/ ]
 196 ]
 197 qed.
 198
 199 lemma loop_p_true :
 200   ∀A,k,f,p,a.p a = true → loop A (S k) f p a = Some ? a.
 201 #A #k #f #p #a #Ha normalize >Ha %
 202 qed.
 203
 204 lemma loop_Some :
 205   ∀A,k,f,p,a,b.loop A k f p a = Some ? b → p b = true.
 206 #A #k #f #p elim k
 207   [#a #b normalize #Hfalse destruct
 208   |#k0 #IH #a #b whd in ⊢ (??%? → ?); cases (true_or_false (p a)) #Hpa
 209     [ >Hpa normalize #H1 destruct // | >Hpa normalize @IH ]
 210   ]
 211 qed.
 212
 213 lemma loop_lift : ∀A,B,k,lift,f,g,h,hlift,c1,c2.
 214   (∀x.hlift (lift x) = h x) →
 215   (∀x.h x = false → lift (f x) = g (lift x)) →
 216   loop A k f h c1 = Some ? c2 →
 217   loop B k g hlift (lift c1) = Some ? (lift … c2).
 218 #A #B #k #lift #f #g #h #hlift #c1 #c2 #Hfg #Hhlift
 219 generalize in match c1; elim k
 220 [#c0 normalize in ⊢ (??%? → ?); #Hfalse destruct (Hfalse)
 221 |#k0 #IH #c0 whd in ⊢ (??%? → ??%?);
 222  cases (true_or_false (h c0)) #Hc0 >Hfg >Hc0 normalize
 223  [ #Heq destruct (Heq) % | <Hhlift // @IH ]
 224 qed.
 225
 226 (************************** Realizability *************************************)
 227 definition loopM ≝ λsig,M,i,cin.
 228   loop ? i (step sig M) (λc.halt sig M (cstate ?? c)) cin.
 229
 230 lemma loopM_unfold : ∀sig,M,i,cin.
 231   loopM sig M i cin = loop ? i (step sig M) (λc.halt sig M (cstate ?? c)) cin.
 232 // qed.
 233
 234 definition initc ≝ λsig.λM:TM sig.λt.
 235   mk_config sig (states sig M) (start sig M) t.
 236
 237 definition Realize ≝ λsig.λM:TM sig.λR:relation (tape sig).
 238 ∀t.∃i.∃outc.
 239   loopM sig M i (initc sig M t) = Some ? outc ∧ R t (ctape ?? outc).
 240
 241 definition WRealize ≝ λsig.λM:TM sig.λR:relation (tape sig).
 242 ∀t,i,outc.
 243   loopM sig M i (initc sig M t) = Some ? outc → R t (ctape ?? outc).
 244
 245 definition Terminate ≝ λsig.λM:TM sig.λt. ∃i,outc.
 246   loopM sig M i (initc sig M t) = Some ? outc.
 247
 248 notation "M \vDash R" non associative with precedence 45 for @{ 'models $M $R}.
 249 interpretation "realizability" 'models M R = (Realize ? M R).
 250
 251 notation "M \VDash R" non associative with precedence 45 for @{ 'wmodels $M $R}.
 252 interpretation "weak realizability" 'wmodels M R = (WRealize ? M R).
 253
 254 interpretation "termination" 'fintersects M t = (Terminate ? M t).
 255
 256 lemma WRealize_to_Realize : ∀sig.∀M: TM sig.∀R.
 257   (∀t.M ↓ t) → M ⊫ R → M ⊨ R.
 258 #sig #M #R #HT #HW #t cases (HT … t) #i * #outc #Hloop
 259 @(ex_intro … i) @(ex_intro … outc) % // @(HW … i) //
 260 qed.
 261
 262 theorem Realize_to_WRealize : ∀sig.∀M:TM sig.∀R.
 263   M ⊨ R → M ⊫ R.
 264 #sig #M #R #H1 #inc #i #outc #Hloop
 265 cases (H1 inc) #k * #outc1 * #Hloop1 #HR >(loop_eq … Hloop Hloop1) //
 266 qed.
 267
 268 definition accRealize ≝ λsig.λM:TM sig.λacc:states sig M.λRtrue,Rfalse.
 269 ∀t.∃i.∃outc.
 270   loopM sig M i (initc sig M t) = Some ? outc ∧
 271     (cstate ?? outc = acc → Rtrue t (ctape ?? outc)) ∧
 272     (cstate ?? outc ≠ acc → Rfalse t (ctape ?? outc)).
 273
 274 notation "M ⊨ [q: R1,R2]" non associative with precedence 45 for @{ 'cmodels $M $q $R1 $R2}.
 275 interpretation "conditional realizability" 'cmodels M q R1 R2 = (accRealize ? M q R1 R2).
 276
 277 (*************************** guarded realizablity *****************************)
 278 definition GRealize ≝ λsig.λM:TM sig.λPre:tape sig →Prop.λR:relation (tape sig).
 279 ∀t.Pre t → ∃i.∃outc.
 280   loopM sig M i (initc sig M t) = Some ? outc ∧ R t (ctape ?? outc).
 281
 282 definition accGRealize ≝ λsig.λM:TM sig.λacc:states sig M.
 283 λPre: tape sig → Prop.λRtrue,Rfalse.
 284 ∀t.Pre t → ∃i.∃outc.
 285   loopM sig M i (initc sig M t) = Some ? outc ∧
 286     (cstate ?? outc = acc → Rtrue t (ctape ?? outc)) ∧
 287     (cstate ?? outc ≠ acc → Rfalse t (ctape ?? outc)).
 288
 289 lemma WRealize_to_GRealize : ∀sig.∀M: TM sig.∀Pre,R.
 290   (∀t.Pre t → M ↓ t) → M ⊫ R → GRealize sig M Pre R.
 291 #sig #M #Pre #R #HT #HW #t #HPre cases (HT … t HPre) #i * #outc #Hloop
 292 @(ex_intro … i) @(ex_intro … outc) % // @(HW … i) //
 293 qed.
 294
 295
 296 (******************************** monotonicity ********************************)
 297 lemma Realize_to_Realize : ∀alpha,M,R1,R2.
 298   R1 ⊆ R2 → Realize alpha M R1 → Realize alpha M R2.
 299 #alpha #M #R1 #R2 #Himpl #HR1 #intape
 300 cases (HR1 intape) -HR1 #k * #outc * #Hloop #HR1
 301 @(ex_intro ?? k) @(ex_intro ?? outc) % /2/
 302 qed.
 303
 304 lemma WRealize_to_WRealize: ∀sig,M,R1,R2.
 305   R1 ⊆ R2 → WRealize sig M R1 → WRealize ? M R2.
 306 #alpha #M #R1 #R2 #Hsub #HR1 #intape #i #outc #Hloop
 307 @Hsub @(HR1 … i) @Hloop
 308 qed.
 309
 310 lemma GRealize_to_GRealize : ∀alpha,M,P,R1,R2.
 311   R1 ⊆ R2 → GRealize alpha M P R1 → GRealize alpha M P R2.
 312 #alpha #M #P #R1 #R2 #Himpl #HR1 #intape #HP
 313 cases (HR1 intape HP) -HR1 #k * #outc * #Hloop #HR1
 314 @(ex_intro ?? k) @(ex_intro ?? outc) % /2/
 315 qed.
 316
 317 lemma acc_Realize_to_acc_Realize: ∀sig,M.∀q:states sig M.∀R1,R2,R3,R4.
 318   R1 ⊆ R3 → R2 ⊆ R4 → M ⊨ [q:R1,R2] → M ⊨ [q:R3,R4].
 319 #alpha #M #q #R1 #R2 #R3 #R4 #Hsub13 #Hsub24 #HRa #intape
 320 cases (HRa intape) -HRa #k * #outc * * #Hloop #HRtrue #HRfalse
 321 @(ex_intro ?? k) @(ex_intro ?? outc) %
 322   [ % [@Hloop] #Hq @Hsub13 @HRtrue // | #Hq @Hsub24 @HRfalse //]
 323 qed.
 324
 325 (**************************** A canonical relation ****************************)
 326
 327 definition R_TM ≝ λsig.λM:TM sig.λq.λt1,t2.
 328 ∃i,outc.
 329   loopM ? M i (mk_config ?? q t1) = Some ? outc ∧
 330   t2 = (ctape ?? outc).
 331
 332 lemma R_TM_to_R: ∀sig,M,R. ∀t1,t2.
 333   M ⊫ R → R_TM ? M (start sig M) t1 t2 → R t1 t2.
 334 #sig #M #R #t1 #t2 whd in ⊢ (%→?); #HMR * #i * #outc *
 335 #Hloop #Ht2 >Ht2 @(HMR … Hloop)
 336 qed.
 337
 338 (******************************** NOP Machine *********************************)
 339
 340 (* NO OPERATION
 341    t1 = t2 *)
 342
 343 definition nop_states ≝ initN 1.
 344 definition start_nop : initN 1 ≝ mk_Sig ?? 0 (le_n … 1).
 345
 346 definition nop ≝
 347   λalpha:FinSet.mk_TM alpha nop_states
 348   (λp.let 〈q,a〉 ≝ p in 〈q,None ?〉)
 349   start_nop (λ_.true).
 350
 351 definition R_nop ≝ λalpha.λt1,t2:tape alpha.t2 = t1.
 352
 353 lemma sem_nop :
 354   ∀alpha.nop alpha ⊨ R_nop alpha.
 355 #alpha #intape @(ex_intro ?? 1)
 356 @(ex_intro … (mk_config ?? start_nop intape)) % %
 357 qed.
 358
 359 lemma nop_single_state: ∀sig.∀q1,q2:states ? (nop sig). q1 = q2.
 360 normalize #sig * #n #ltn1 * #m #ltm1
 361 generalize in match ltn1; generalize in match ltm1;
 362 <(le_n_O_to_eq … (le_S_S_to_le … ltn1)) <(le_n_O_to_eq … (le_S_S_to_le … ltm1))
 363 // qed.
 364
 365 (************************** Sequential Composition ****************************)
 366
 367 definition seq_trans ≝ λsig. λM1,M2 : TM sig.
 368 λp. let 〈s,a〉 ≝ p in
 369   match s with
 370   [ inl s1 ⇒
 371       if halt sig M1 s1 then 〈inr … (start sig M2), None ?〉
 372       else let 〈news1,m〉 ≝ trans sig M1 〈s1,a〉 in 〈inl … news1,m〉
 373   | inr s2 ⇒ let 〈news2,m〉 ≝ trans sig M2 〈s2,a〉 in 〈inr … news2,m〉
 374   ].
 375
 376 definition seq ≝ λsig. λM1,M2 : TM sig.
 377   mk_TM sig
 378     (FinSum (states sig M1) (states sig M2))
 379     (seq_trans sig M1 M2)
 380     (inl … (start sig M1))
 381     (λs.match s with
 382       [ inl _ ⇒ false | inr s2 ⇒ halt sig M2 s2]).
 383
 384 notation "a · b" right associative with precedence 65 for @{ 'middot $a $b}.
 385 interpretation "sequential composition" 'middot a b = (seq ? a b).
 386
 387 definition lift_confL ≝
 388   λsig,S1,S2,c.match c with
 389   [ mk_config s t ⇒ mk_config sig (FinSum S1 S2) (inl … s) t ].
 390
 391 definition lift_confR ≝
 392   λsig,S1,S2,c.match c with
 393   [ mk_config s t ⇒ mk_config sig (FinSum S1 S2) (inr … s) t ].
 394
 395 definition halt_liftL ≝
 396   λS1,S2,halt.λs:FinSum S1 S2.
 397   match s with
 398   [ inl s1 ⇒ halt s1
 399   | inr _ ⇒ true ]. (* should be vacuous in all cases we use halt_liftL *)
 400
 401 definition halt_liftR ≝
 402   λS1,S2,halt.λs:FinSum S1 S2.
 403   match s with
 404   [ inl _ ⇒ false
 405   | inr s2 ⇒ halt s2 ].
 406
 407 lemma p_halt_liftL : ∀sig,S1,S2,halt,c.
 408   halt (cstate sig S1 c) =
 409      halt_liftL S1 S2 halt (cstate … (lift_confL … c)).
 410 #sig #S1 #S2 #halt #c cases c #s #t %
 411 qed.
 412
 413 lemma trans_seq_liftL : ∀sig,M1,M2,s,a,news,move.
 414   halt ? M1 s = false →
 415   trans sig M1 〈s,a〉 = 〈news,move〉 →
 416   trans sig (seq sig M1 M2) 〈inl … s,a〉 = 〈inl … news,move〉.
 417 #sig (*#M1*) * #Q1 #T1 #init1 #halt1 #M2 #s #a #news #move
 418 #Hhalt #Htrans whd in ⊢ (??%?); >Hhalt >Htrans %
 419 qed.
 420
 421 lemma trans_seq_liftR : ∀sig,M1,M2,s,a,news,move.
 422   halt ? M2 s = false →
 423   trans sig M2 〈s,a〉 = 〈news,move〉 →
 424   trans sig (seq sig M1 M2) 〈inr … s,a〉 = 〈inr … news,move〉.
 425 #sig #M1 * #Q2 #T2 #init2 #halt2 #s #a #news #move
 426 #Hhalt #Htrans whd in ⊢ (??%?); >Hhalt >Htrans %
 427 qed.
 428
 429 lemma step_seq_liftR : ∀sig,M1,M2,c0.
 430  halt ? M2 (cstate ?? c0) = false →
 431  step sig (seq sig M1 M2) (lift_confR sig (states ? M1) (states ? M2) c0) =
 432  lift_confR sig (states ? M1) (states ? M2) (step sig M2 c0).
 433 #sig #M1 (* * #Q1 #T1 #init1 #halt1 *) #M2 * #s #t
 434   lapply (refl ? (trans ?? 〈s,current sig t〉))
 435   cases (trans ?? 〈s,current sig t〉) in ⊢ (???% → %);
 436   #s0 #m0 cases t
 437   [ #Heq #Hhalt
 438   | 2,3: #s1 #l1 #Heq #Hhalt
 439   |#ls #s1 #rs #Heq #Hhalt ]
 440   whd in ⊢ (???(????%)); >Heq whd in ⊢ (???%);
 441   whd in ⊢ (??(???%)?); whd in ⊢ (??%?); >(trans_seq_liftR … Heq) //
 442 qed.
 443
 444 lemma step_seq_liftL : ∀sig,M1,M2,c0.
 445  halt ? M1 (cstate ?? c0) = false →
 446  step sig (seq sig M1 M2) (lift_confL sig (states ? M1) (states ? M2) c0) =
 447  lift_confL sig ?? (step sig M1 c0).
 448 #sig #M1 (* * #Q1 #T1 #init1 #halt1 *) #M2 * #s #t
 449   lapply (refl ? (trans ?? 〈s,current sig t〉))
 450   cases (trans ?? 〈s,current sig t〉) in ⊢ (???% → %);
 451   #s0 #m0 cases t
 452   [ #Heq #Hhalt
 453   | 2,3: #s1 #l1 #Heq #Hhalt
 454   |#ls #s1 #rs #Heq #Hhalt ]
 455   whd in ⊢ (???(????%)); >Heq whd in ⊢ (???%);
 456   whd in ⊢ (??(???%)?); whd in ⊢ (??%?); >(trans_seq_liftL … Heq) //
 457 qed.
 458
 459 lemma trans_liftL_true : ∀sig,M1,M2,s,a.
 460   halt ? M1 s = true →
 461   trans sig (seq sig M1 M2) 〈inl … s,a〉 = 〈inr … (start ? M2),None ?〉.
 462 #sig #M1 #M2 #s #a #Hhalt whd in ⊢ (??%?); >Hhalt %
 463 qed.
 464
 465 lemma eq_ctape_lift_conf_L : ∀sig,S1,S2,outc.
 466   ctape sig (FinSum S1 S2) (lift_confL … outc) = ctape … outc.
 467 #sig #S1 #S2 #outc cases outc #s #t %
 468 qed.
 469
 470 lemma eq_ctape_lift_conf_R : ∀sig,S1,S2,outc.
 471   ctape sig (FinSum S1 S2) (lift_confR … outc) = ctape … outc.
 472 #sig #S1 #S2 #outc cases outc #s #t %
 473 qed.
 474
 475 theorem sem_seq: ∀sig.∀M1,M2:TM sig.∀R1,R2.
 476   M1 ⊨ R1 → M2 ⊨ R2 → M1 · M2 ⊨ R1 ∘ R2.
 477 #sig #M1 #M2 #R1 #R2 #HR1 #HR2 #t
 478 cases (HR1 t) #k1 * #outc1 * #Hloop1 #HM1
 479 cases (HR2 (ctape sig (states ? M1) outc1)) #k2 * #outc2 * #Hloop2 #HM2
 480 @(ex_intro … (k1+k2)) @(ex_intro … (lift_confR … outc2))
 481 %
 482 [@(loop_merge ???????????
 483    (loop_lift ??? (lift_confL sig (states sig M1) (states sig M2))
 484    (step sig M1) (step sig (seq sig M1 M2))
 485    (λc.halt sig M1 (cstate … c))
 486    (λc.halt_liftL ?? (halt sig M1) (cstate … c)) … Hloop1))
 487   [ * *
 488    [ #sl #tl whd in ⊢ (??%? → ?); #Hl %
 489    | #sr #tr whd in ⊢ (??%? → ?); #Hr destruct (Hr) ]
 490   || #c0 #Hhalt <step_seq_liftL //
 491   | #x <p_halt_liftL %
 492   |6:cases outc1 #s1 #t1 %
 493   |7:@(loop_lift … (initc ?? (ctape … outc1)) … Hloop2)
 494     [ * #s2 #t2 %
 495     | #c0 #Hhalt <step_seq_liftR // ]
 496   |whd in ⊢ (??(???%)?);whd in ⊢ (??%?);
 497    generalize in match Hloop1; cases outc1 #sc1 #tc1 #Hloop10
 498    >(trans_liftL_true sig M1 M2 ??)
 499     [ whd in ⊢ (??%?); whd in ⊢ (???%);
 500       @config_eq whd in ⊢ (???%); //
 501     | @(loop_Some ?????? Hloop10) ]
 502  ]
 503 | @(ex_intro … (ctape ? (FinSum (states ? M1) (states ? M2)) (lift_confL … outc1)))
 504   % // >eq_ctape_lift_conf_L >eq_ctape_lift_conf_R //
 505 ]
 506 qed.
 507
 508 theorem sem_seq_app: ∀sig.∀M1,M2:TM sig.∀R1,R2,R3.
 509   M1 ⊨ R1 → M2 ⊨ R2 → R1 ∘ R2 ⊆ R3 → M1 · M2 ⊨ R3.
 510 #sig #M1 #M2 #R1 #R2 #R3 #HR1 #HR2 #Hsub
 511 #t cases (sem_seq … HR1 HR2 t)
 512 #k * #outc * #Hloop #Houtc @(ex_intro … k) @(ex_intro … outc)
 513 % [@Hloop |@Hsub @Houtc]
 514 qed.
 515
 516 (* composition with guards *)
 517 theorem sem_seq_guarded: ∀sig.∀M1,M2:TM sig.∀Pre1,Pre2,R1,R2.
 518   GRealize sig M1 Pre1 R1 → GRealize sig M2 Pre2 R2 →
 519   (∀t1,t2.Pre1 t1 → R1 t1 t2 → Pre2 t2) →
 520   GRealize sig (M1 · M2) Pre1 (R1 ∘ R2).
 521 #sig #M1 #M2 #Pre1 #Pre2 #R1 #R2 #HGR1 #HGR2 #Hinv #t1 #HPre1
 522 cases (HGR1 t1 HPre1) #k1 * #outc1 * #Hloop1 #HM1
 523 cases (HGR2 (ctape sig (states ? M1) outc1) ?)
 524   [2: @(Hinv … HPre1 HM1)]
 525 #k2 * #outc2 * #Hloop2 #HM2
 526 @(ex_intro … (k1+k2)) @(ex_intro … (lift_confR … outc2))
 527 %
 528 [@(loop_merge ???????????
 529    (loop_lift ??? (lift_confL sig (states sig M1) (states sig M2))
 530    (step sig M1) (step sig (seq sig M1 M2))
 531    (λc.halt sig M1 (cstate … c))
 532    (λc.halt_liftL ?? (halt sig M1) (cstate … c)) … Hloop1))
 533   [ * *
 534    [ #sl #tl whd in ⊢ (??%? → ?); #Hl %
 535    | #sr #tr whd in ⊢ (??%? → ?); #Hr destruct (Hr) ]
 536   || #c0 #Hhalt <step_seq_liftL //
 537   | #x <p_halt_liftL %
 538   |6:cases outc1 #s1 #t1 %
 539   |7:@(loop_lift … (initc ?? (ctape … outc1)) … Hloop2)
 540     [ * #s2 #t2 %
 541     | #c0 #Hhalt <step_seq_liftR // ]
 542   |whd in ⊢ (??(???%)?);whd in ⊢ (??%?);
 543    generalize in match Hloop1; cases outc1 #sc1 #tc1 #Hloop10
 544    >(trans_liftL_true sig M1 M2 ??)
 545     [ whd in ⊢ (??%?); whd in ⊢ (???%);
 546       @config_eq whd in ⊢ (???%); //
 547     | @(loop_Some ?????? Hloop10) ]
 548  ]
 549 | @(ex_intro … (ctape ? (FinSum (states ? M1) (states ? M2)) (lift_confL … outc1)))
 550   % // >eq_ctape_lift_conf_L >eq_ctape_lift_conf_R //
 551 ]
 552 qed.
 553
 554 theorem sem_seq_app_guarded: ∀sig.∀M1,M2:TM sig.∀Pre1,Pre2,R1,R2,R3.
 555   GRealize sig M1 Pre1 R1 → GRealize sig M2 Pre2 R2 →
 556   (∀t1,t2.Pre1 t1 → R1 t1 t2 → Pre2 t2) → R1 ∘ R2 ⊆ R3 →
 557   GRealize sig (M1 · M2) Pre1 R3.
 558 #sig #M1 #M2 #Pre1 #Pre2 #R1 #R2 #R3 #HR1 #HR2 #Hinv #Hsub
 559 #t #HPre1 cases (sem_seq_guarded … HR1 HR2 Hinv t HPre1)
 560 #k * #outc * #Hloop #Houtc @(ex_intro … k) @(ex_intro … outc)
 561 % [@Hloop |@Hsub @Houtc]
 562 qed.