matita/matita/lib/turing/mono.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_____________________________________________________________*)
  11
  12 include "basics/vectors.ma".
  13 (* include "basics/relations.ma". *)
  14
  15 (******************************** tape ****************************************)
  16
  17 (* A tape is essentially a triple 〈left,current,right〉 where however the current
  18 symbol could be missing. This may happen for three different reasons: both tapes
  19 are empty; we are on the left extremity of a non-empty tape (left overflow), or
  20 we are on the right extremity of a non-empty tape (right overflow). *)
  21
  22 inductive tape (sig:FinSet) : Type[0] ≝
  23 | niltape : tape sig
  24 | leftof  : sig → list sig → tape sig
  25 | rightof : sig → list sig → tape sig
  26 | midtape : list sig → sig → list sig → tape sig.
  27
  28 definition left ≝
  29  λsig.λt:tape sig.match t with
  30  [ niltape ⇒ [] | leftof _ _ ⇒ [] | rightof s l ⇒ s::l | midtape l _ _ ⇒ l ].
  31
  32 definition right ≝
  33  λsig.λt:tape sig.match t with
  34  [ niltape ⇒ [] | leftof s r ⇒ s::r | rightof _ _ ⇒ []| midtape _ _ r ⇒ r ].
  35
  36 definition current ≝
  37  λsig.λt:tape sig.match t with
  38  [ midtape _ c _ ⇒ Some ? c | _ ⇒ None ? ].
  39
  40 definition mk_tape :
  41   ∀sig:FinSet.list sig → option sig → list sig → tape sig ≝
  42   λsig,lt,c,rt.match c with
  43   [ Some c' ⇒ midtape sig lt c' rt
  44   | None ⇒ match lt with
  45     [ nil ⇒ match rt with
  46       [ nil ⇒ niltape ?
  47       | cons r0 rs0 ⇒ leftof ? r0 rs0 ]
  48     | cons l0 ls0 ⇒ rightof ? l0 ls0 ] ].
  49
  50 lemma current_to_midtape: ∀sig,t,c. current sig t = Some ? c →
  51   ∃ls,rs. t = midtape ? ls c rs.
  52 #sig *
  53   [#c whd in ⊢ ((??%?)→?); #Hfalse destruct
  54   |#a #l #c whd in ⊢ ((??%?)→?); #Hfalse destruct
  55   |#a #l #c whd in ⊢ ((??%?)→?); #Hfalse destruct
  56   |#ls #a #rs #c whd in ⊢ ((??%?)→?); #H destruct
  57    @(ex_intro … ls) @(ex_intro … rs) //
  58   ]
  59 qed.
  60
  61 (*********************************** moves ************************************)
  62
  63 inductive move : Type[0] ≝
  64   | L : move | R : move | N : move.
  65
  66 (********************************** machine ***********************************)
  67
  68 record TM (sig:FinSet): Type[1] ≝
  69 { states : FinSet;
  70   trans : states × (option sig) → states × (option sig) × move;
  71   start: states;
  72   halt : states → bool
  73 }.
  74
  75 definition tape_move_left ≝ λsig:FinSet.λt:tape sig.
  76   match t with
  77   [ niltape ⇒ niltape sig
  78   | leftof _ _ ⇒ t
  79   | rightof a ls ⇒ midtape sig ls a [ ]
  80   | midtape ls a rs ⇒
  81     match ls with
  82     [ nil ⇒ leftof sig a rs
  83     | cons a0 ls0 ⇒ midtape sig ls0 a0 (a::rs)
  84     ]
  85   ].
  86
  87 definition tape_move_right ≝ λsig:FinSet.λt:tape sig.
  88   match t with
  89   [ niltape ⇒ niltape sig
  90   | rightof _ _ ⇒ t
  91   | leftof a rs ⇒ midtape sig [ ] a rs
  92   | midtape ls a rs ⇒
  93     match rs with
  94     [ nil ⇒ rightof sig a ls
  95     | cons a0 rs0 ⇒ midtape sig (a::ls) a0 rs0
  96     ]
  97   ].
  98
  99 definition tape_write ≝ λsig.λt: tape sig.λs:option sig.
 100   match s with
 101   [ None ⇒ t
 102   | Some s0 ⇒ midtape ? (left ? t) s0 (right ? t)
 103   ].
 104
 105 definition tape_move ≝ λsig.λt: tape sig.λm:move.
 106   match m with
 107     [ R ⇒ tape_move_right ? t
 108     | L ⇒ tape_move_left ? t
 109     | N ⇒ t
 110     ].
 111
 112 definition tape_move_mono ≝
 113   λsig,t,mv.
 114   tape_move sig (tape_write sig t (\fst mv)) (\snd mv).
 115
 116 record config (sig,states:FinSet): Type[0] ≝
 117 { cstate : states;
 118   ctape: tape sig
 119 }.
 120
 121 lemma config_expand: ∀sig,Q,c.
 122   c = mk_config sig Q (cstate ?? c) (ctape ?? c).
 123 #sig #Q * //
 124 qed.
 125
 126 lemma config_eq : ∀sig,M,c1,c2.
 127   cstate sig M c1 = cstate sig M c2 →
 128     ctape sig M c1 = ctape sig M c2 →  c1 = c2.
 129 #sig #M1 * #s1 #t1 * #s2 #t2 //
 130 qed.
 131
 132 definition step ≝ λsig.λM:TM sig.λc:config sig (states sig M).
 133   let current_char ≝ current ? (ctape ?? c) in
 134   let 〈news,a,mv〉 ≝ trans sig M 〈cstate ?? c,current_char〉 in
 135   mk_config ?? news (tape_move sig (tape_write ? (ctape ?? c) a) mv).
 136
 137 (*
 138 lemma step_eq : ∀sig,M,c.
 139   let current_char ≝ current ? (ctape ?? c) in
 140   let 〈news,a,mv〉 ≝ trans sig M 〈cstate ?? c,current_char〉 in
 141   step sig M c =
 142     mk_config ?? news (tape_move sig (tape_write ? (ctape ?? c) a) mv).
 143 #sig #M #c
 144  whd in match (tape_move_mono sig ??);
 145 *)
 146
 147 (******************************** loop ****************************************)
 148 let rec loop (A:Type[0]) n (f:A→A) p a on n ≝
 149   match n with
 150   [ O ⇒ None ?
 151   | S m ⇒ if p a then (Some ? a) else loop A m f p (f a)
 152   ].
 153
 154 lemma loop_S_true :
 155   ∀A,n,f,p,a. p a = true →
 156     loop A (S n) f p a = Some ? a.
 157 #A #n #f #p #a #pa normalize >pa //
 158 qed.
 159
 160 lemma loop_S_false :
 161   ∀A,n,f,p,a.  p a = false →
 162     loop A (S n) f p a = loop A n f p (f a).
 163 normalize #A #n #f #p #a #Hpa >Hpa %
 164 qed.
 165
 166 lemma loop_incr : ∀A,f,p,k1,k2,a1,a2.
 167   loop A k1 f p a1 = Some ? a2 →
 168     loop A (k2+k1) f p a1 = Some ? a2.
 169 #A #f #p #k1 #k2 #a1 #a2 generalize in match a1; elim k1
 170 [normalize #a0 #Hfalse destruct
 171 |#k1' #IH #a0 <plus_n_Sm whd in ⊢ (??%? → ??%?);
 172  cases (true_or_false (p a0)) #Hpa0 >Hpa0 whd in ⊢ (??%? → ??%?); // @IH
 173 ]
 174 qed.
 175
 176 lemma loop_merge : ∀A,f,p,q.(∀b. p b = false → q b = false) →
 177  ∀k1,k2,a1,a2,a3,a4.
 178    loop A k1 f p a1 = Some ? a2 →
 179      f a2 = a3 → q a2 = false →
 180        loop A k2 f q a3 = Some ? a4 →
 181          loop A (k1+k2) f q a1 = Some ? a4.
 182 #Sig #f #p #q #Hpq #k1 elim k1
 183   [normalize #k2 #a1 #a2 #a3 #a4 #H destruct
 184   |#k1' #Hind #k2 #a1 #a2 #a3 #a4 normalize in ⊢ (%→?);
 185    cases (true_or_false (p a1)) #pa1 >pa1 normalize in ⊢ (%→?);
 186    [#eqa1a2 destruct #eqa2a3 #Hqa2 #H
 187     whd in ⊢ (??(??%???)?); >plus_n_Sm @loop_incr
 188     whd in ⊢ (??%?); >Hqa2 >eqa2a3 @H
 189    |normalize >(Hpq … pa1) normalize #H1 #H2 #H3 @(Hind … H2) //
 190    ]
 191  ]
 192 qed.
 193
 194 lemma loop_split : ∀A,f,p,q.(∀b. q b = true → p b = true) →
 195  ∀k,a1,a2.
 196    loop A k f q a1 = Some ? a2 →
 197    ∃k1,a3.
 198     loop A k1 f p a1 = Some ? a3 ∧
 199       loop A (S(k-k1)) f q a3 = Some ? a2.
 200 #A #f #p #q #Hpq #k elim k
 201   [#a1 #a2 normalize #Heq destruct
 202   |#i #Hind #a1 #a2 normalize
 203    cases (true_or_false (q a1)) #Hqa1 >Hqa1 normalize
 204     [ #Ha1a2 destruct
 205      @(ex_intro … 1) @(ex_intro … a2) %
 206        [normalize >(Hpq …Hqa1) // |>Hqa1 //]
 207     |#Hloop cases (true_or_false (p a1)) #Hpa1
 208        [@(ex_intro … 1) @(ex_intro … a1) %
 209          [normalize >Hpa1 // |>Hqa1 <Hloop normalize //]
 210        |cases (Hind …Hloop) #k2 * #a3 * #Hloop1 #Hloop2
 211         @(ex_intro … (S k2)) @(ex_intro … a3) %
 212          [normalize >Hpa1 normalize // | @Hloop2 ]
 213        ]
 214     ]
 215   ]
 216 qed.
 217
 218 lemma loop_eq : ∀sig,f,q,i,j,a,x,y.
 219   loop sig i f q a = Some ? x → loop sig j f q a = Some ? y → x = y.
 220 #sig #f #q #i #j @(nat_elim2 … i j)
 221 [ #n #a #x #y normalize #Hfalse destruct (Hfalse)
 222 | #n #a #x #y #H1 normalize #Hfalse destruct (Hfalse)
 223 | #n1 #n2 #IH #a #x #y normalize cases (q a) normalize
 224   [ #H1 #H2 destruct %
 225   | /2/ ]
 226 ]
 227 qed.
 228
 229 lemma loop_p_true :
 230   ∀A,k,f,p,a.p a = true → loop A (S k) f p a = Some ? a.
 231 #A #k #f #p #a #Ha normalize >Ha %
 232 qed.
 233
 234 lemma loop_Some :
 235   ∀A,k,f,p,a,b.loop A k f p a = Some ? b → p b = true.
 236 #A #k #f #p elim k
 237   [#a #b normalize #Hfalse destruct
 238   |#k0 #IH #a #b whd in ⊢ (??%? → ?); cases (true_or_false (p a)) #Hpa
 239     [ >Hpa normalize #H1 destruct // | >Hpa normalize @IH ]
 240   ]
 241 qed.
 242
 243 lemma loop_lift : ∀A,B,k,lift,f,g,h,hlift,c1,c2.
 244   (∀x.hlift (lift x) = h x) →
 245   (∀x.h x = false → lift (f x) = g (lift x)) →
 246   loop A k f h c1 = Some ? c2 →
 247   loop B k g hlift (lift c1) = Some ? (lift … c2).
 248 #A #B #k #lift #f #g #h #hlift #c1 #c2 #Hfg #Hhlift
 249 generalize in match c1; elim k
 250 [#c0 normalize in ⊢ (??%? → ?); #Hfalse destruct (Hfalse)
 251 |#k0 #IH #c0 whd in ⊢ (??%? → ??%?);
 252  cases (true_or_false (h c0)) #Hc0 >Hfg >Hc0 normalize
 253  [ #Heq destruct (Heq) % | <Hhlift // @IH ]
 254 qed.
 255
 256 (************************** Realizability *************************************)
 257 definition loopM ≝ λsig,M,i,cin.
 258   loop ? i (step sig M) (λc.halt sig M (cstate ?? c)) cin.
 259
 260 lemma loopM_unfold : ∀sig,M,i,cin.
 261   loopM sig M i cin = loop ? i (step sig M) (λc.halt sig M (cstate ?? c)) cin.
 262 // qed.
 263
 264 definition initc ≝ λsig.λM:TM sig.λt.
 265   mk_config sig (states sig M) (start sig M) t.
 266
 267 definition Realize ≝ λsig.λM:TM sig.λR:relation (tape sig).
 268 ∀t.∃i.∃outc.
 269   loopM sig M i (initc sig M t) = Some ? outc ∧ R t (ctape ?? outc).
 270
 271 definition WRealize ≝ λsig.λM:TM sig.λR:relation (tape sig).
 272 ∀t,i,outc.
 273   loopM sig M i (initc sig M t) = Some ? outc → R t (ctape ?? outc).
 274
 275 definition Terminate ≝ λsig.λM:TM sig.λt. ∃i,outc.
 276   loopM sig M i (initc sig M t) = Some ? outc.
 277
 278 notation "M \vDash R" non associative with precedence 45 for @{ 'models $M $R}.
 279 interpretation "realizability" 'models M R = (Realize ? M R).
 280
 281 notation "M \VDash R" non associative with precedence 45 for @{ 'wmodels $M $R}.
 282 interpretation "weak realizability" 'wmodels M R = (WRealize ? M R).
 283
 284 interpretation "termination" 'fintersects M t = (Terminate ? M t).
 285
 286 lemma WRealize_to_Realize : ∀sig.∀M: TM sig.∀R.
 287   (∀t.M ↓ t) → M ⊫ R → M ⊨ R.
 288 #sig #M #R #HT #HW #t cases (HT … t) #i * #outc #Hloop
 289 @(ex_intro … i) @(ex_intro … outc) % // @(HW … i) //
 290 qed.
 291
 292 theorem Realize_to_WRealize : ∀sig.∀M:TM sig.∀R.
 293   M ⊨ R → M ⊫ R.
 294 #sig #M #R #H1 #inc #i #outc #Hloop
 295 cases (H1 inc) #k * #outc1 * #Hloop1 #HR >(loop_eq … Hloop Hloop1) //
 296 qed.
 297
 298 definition accRealize ≝ λsig.λM:TM sig.λacc:states sig M.λRtrue,Rfalse.
 299 ∀t.∃i.∃outc.
 300   loopM sig M i (initc sig M t) = Some ? outc ∧
 301     (cstate ?? outc = acc → Rtrue t (ctape ?? outc)) ∧
 302     (cstate ?? outc ≠ acc → Rfalse t (ctape ?? outc)).
 303
 304 notation "M ⊨ [q: R1,R2]" non associative with precedence 45 for @{ 'cmodels $M $q $R1 $R2}.
 305 interpretation "conditional realizability" 'cmodels M q R1 R2 = (accRealize ? M q R1 R2).
 306
 307 (*************************** guarded realizablity *****************************)
 308 definition GRealize ≝ λsig.λM:TM sig.λPre:tape sig →Prop.λR:relation (tape sig).
 309 ∀t.Pre t → ∃i.∃outc.
 310   loopM sig M i (initc sig M t) = Some ? outc ∧ R t (ctape ?? outc).
 311
 312 definition accGRealize ≝ λsig.λM:TM sig.λacc:states sig M.
 313 λPre: tape sig → Prop.λRtrue,Rfalse.
 314 ∀t.Pre t → ∃i.∃outc.
 315   loopM sig M i (initc sig M t) = Some ? outc ∧
 316     (cstate ?? outc = acc → Rtrue t (ctape ?? outc)) ∧
 317     (cstate ?? outc ≠ acc → Rfalse t (ctape ?? outc)).
 318
 319 lemma WRealize_to_GRealize : ∀sig.∀M: TM sig.∀Pre,R.
 320   (∀t.Pre t → M ↓ t) → M ⊫ R → GRealize sig M Pre R.
 321 #sig #M #Pre #R #HT #HW #t #HPre cases (HT … t HPre) #i * #outc #Hloop
 322 @(ex_intro … i) @(ex_intro … outc) % // @(HW … i) //
 323 qed.
 324
 325 lemma Realize_to_GRealize : ∀sig,M.∀P,R.
 326   M ⊨ R → GRealize sig M P R.
 327 #alpha #M #Pre #R #HR #t #HPre
 328 cases (HR t) -HR #k * #outc * #Hloop #HR
 329 @(ex_intro ?? k) @(ex_intro ?? outc) %
 330   [ @Hloop | @HR ]
 331 qed.
 332
 333 lemma acc_Realize_to_acc_GRealize: ∀sig,M.∀q:states sig M.∀P,R1,R2.
 334   M ⊨ [q:R1,R2] → accGRealize sig M q P R1 R2.
 335 #alpha #M #q #Pre #R1 #R2 #HR #t #HPre
 336 cases (HR t) -HR #k * #outc * * #Hloop #HRtrue #HRfalse
 337 @(ex_intro ?? k) @(ex_intro ?? outc) %
 338   [ % [@Hloop] @HRtrue | @HRfalse]
 339 qed.
 340
 341 (******************************** monotonicity ********************************)
 342 lemma Realize_to_Realize : ∀alpha,M,R1,R2.
 343   R1 ⊆ R2 → Realize alpha M R1 → Realize alpha M R2.
 344 #alpha #M #R1 #R2 #Himpl #HR1 #intape
 345 cases (HR1 intape) -HR1 #k * #outc * #Hloop #HR1
 346 @(ex_intro ?? k) @(ex_intro ?? outc) % /2/
 347 qed.
 348
 349 lemma WRealize_to_WRealize: ∀sig,M,R1,R2.
 350   R1 ⊆ R2 → WRealize sig M R1 → WRealize ? M R2.
 351 #alpha #M #R1 #R2 #Hsub #HR1 #intape #i #outc #Hloop
 352 @Hsub @(HR1 … i) @Hloop
 353 qed.
 354
 355 lemma GRealize_to_GRealize : ∀alpha,M,P,R1,R2.
 356   R1 ⊆ R2 → GRealize alpha M P R1 → GRealize alpha M P R2.
 357 #alpha #M #P #R1 #R2 #Himpl #HR1 #intape #HP
 358 cases (HR1 intape HP) -HR1 #k * #outc * #Hloop #HR1
 359 @(ex_intro ?? k) @(ex_intro ?? outc) % /2/
 360 qed.
 361
 362 lemma GRealize_to_GRealize_2 : ∀alpha,M,P1,P2,R1,R2.
 363   P2 ⊆ P1 → R1 ⊆ R2 → GRealize alpha M P1 R1 → GRealize alpha M P2 R2.
 364 #alpha #M #P1 #P2 #R1 #R2 #Himpl1 #Himpl2 #H1 #intape #HP
 365 cases (H1 intape (Himpl1 … HP)) -H1 #k * #outc * #Hloop #H1
 366 @(ex_intro ?? k) @(ex_intro ?? outc) % /2/
 367 qed.
 368
 369 lemma acc_Realize_to_acc_Realize: ∀sig,M.∀q:states sig M.∀R1,R2,R3,R4.
 370   R1 ⊆ R3 → R2 ⊆ R4 → M ⊨ [q:R1,R2] → M ⊨ [q:R3,R4].
 371 #alpha #M #q #R1 #R2 #R3 #R4 #Hsub13 #Hsub24 #HRa #intape
 372 cases (HRa intape) -HRa #k * #outc * * #Hloop #HRtrue #HRfalse
 373 @(ex_intro ?? k) @(ex_intro ?? outc) %
 374   [ % [@Hloop] #Hq @Hsub13 @HRtrue // | #Hq @Hsub24 @HRfalse //]
 375 qed.
 376
 377 (**************************** A canonical relation ****************************)
 378
 379 definition R_TM ≝ λsig.λM:TM sig.λq.λt1,t2.
 380 ∃i,outc.
 381   loopM ? M i (mk_config ?? q t1) = Some ? outc ∧
 382   t2 = (ctape ?? outc).
 383
 384 lemma R_TM_to_R: ∀sig,M,R. ∀t1,t2.
 385   M ⊫ R → R_TM ? M (start sig M) t1 t2 → R t1 t2.
 386 #sig #M #R #t1 #t2 whd in ⊢ (%→?); #HMR * #i * #outc *
 387 #Hloop #Ht2 >Ht2 @(HMR … Hloop)
 388 qed.
 389
 390 (******************************** NOP Machine *********************************)
 391
 392 (* NO OPERATION
 393    t1 = t2 *)
 394
 395 definition nop_states ≝ initN 1.
 396 definition start_nop : initN 1 ≝ mk_Sig ?? 0 (le_n … 1).
 397
 398 definition nop ≝
 399   λalpha:FinSet.mk_TM alpha nop_states
 400   (λp.let 〈q,a〉 ≝ p in 〈q,None ?,N〉)
 401   start_nop (λ_.true).
 402
 403 definition R_nop ≝ λalpha.λt1,t2:tape alpha.t2 = t1.
 404
 405 lemma sem_nop :
 406   ∀alpha.nop alpha ⊨ R_nop alpha.
 407 #alpha #intape @(ex_intro ?? 1)
 408 @(ex_intro … (mk_config ?? start_nop intape)) % %
 409 qed.
 410
 411 lemma nop_single_state: ∀sig.∀q1,q2:states ? (nop sig). q1 = q2.
 412 normalize #sig * #n #ltn1 * #m #ltm1
 413 generalize in match ltn1; generalize in match ltm1;
 414 <(le_n_O_to_eq … (le_S_S_to_le … ltn1)) <(le_n_O_to_eq … (le_S_S_to_le … ltm1))
 415 // qed.
 416
 417 (************************** Sequential Composition ****************************)
 418
 419 definition seq_trans ≝ λsig. λM1,M2 : TM sig.
 420 λp. let 〈s,a〉 ≝ p in
 421   match s with
 422   [ inl s1 ⇒
 423       if halt sig M1 s1 then 〈inr … (start sig M2), None ?,N〉
 424       else let 〈news1,newa,m〉 ≝ trans sig M1 〈s1,a〉 in 〈inl … news1,newa,m〉
 425   | inr s2 ⇒ let 〈news2,newa,m〉 ≝ trans sig M2 〈s2,a〉 in 〈inr … news2,newa,m〉
 426   ].
 427
 428 definition seq ≝ λsig. λM1,M2 : TM sig.
 429   mk_TM sig
 430     (FinSum (states sig M1) (states sig M2))
 431     (seq_trans sig M1 M2)
 432     (inl … (start sig M1))
 433     (λs.match s with
 434       [ inl _ ⇒ false | inr s2 ⇒ halt sig M2 s2]).
 435
 436 notation "a · b" right associative with precedence 65 for @{ 'middot $a $b}.
 437 interpretation "sequential composition" 'middot a b = (seq ? a b).
 438
 439 definition lift_confL ≝
 440   λsig,S1,S2,c.match c with
 441   [ mk_config s t ⇒ mk_config sig (FinSum S1 S2) (inl … s) t ].
 442
 443 definition lift_confR ≝
 444   λsig,S1,S2,c.match c with
 445   [ mk_config s t ⇒ mk_config sig (FinSum S1 S2) (inr … s) t ].
 446
 447 definition halt_liftL ≝
 448   λS1,S2,halt.λs:FinSum S1 S2.
 449   match s with
 450   [ inl s1 ⇒ halt s1
 451   | inr _ ⇒ true ]. (* should be vacuous in all cases we use halt_liftL *)
 452
 453 definition halt_liftR ≝
 454   λS1,S2,halt.λs:FinSum S1 S2.
 455   match s with
 456   [ inl _ ⇒ false
 457   | inr s2 ⇒ halt s2 ].
 458
 459 lemma p_halt_liftL : ∀sig,S1,S2,halt,c.
 460   halt (cstate sig S1 c) =
 461      halt_liftL S1 S2 halt (cstate … (lift_confL … c)).
 462 #sig #S1 #S2 #halt #c cases c #s #t %
 463 qed.
 464
 465 lemma trans_seq_liftL : ∀sig,M1,M2,s,a,news,newa,move.
 466   halt ? M1 s = false →
 467   trans sig M1 〈s,a〉 = 〈news,newa,move〉 →
 468   trans sig (seq sig M1 M2) 〈inl … s,a〉 = 〈inl … news,newa,move〉.
 469 #sig (*#M1*) * #Q1 #T1 #init1 #halt1 #M2 #s #a #news #newa #move
 470 #Hhalt #Htrans whd in ⊢ (??%?); >Hhalt >Htrans %
 471 qed.
 472
 473 lemma trans_seq_liftR : ∀sig,M1,M2,s,a,news,newa,move.
 474   halt ? M2 s = false →
 475   trans sig M2 〈s,a〉 = 〈news,newa,move〉 →
 476   trans sig (seq sig M1 M2) 〈inr … s,a〉 = 〈inr … news,newa,move〉.
 477 #sig #M1 * #Q2 #T2 #init2 #halt2 #s #a #news #newa #move
 478 #Hhalt #Htrans whd in ⊢ (??%?); >Hhalt >Htrans %
 479 qed.
 480
 481 lemma step_seq_liftR : ∀sig,M1,M2,c0.
 482  halt ? M2 (cstate ?? c0) = false →
 483  step sig (seq sig M1 M2) (lift_confR sig (states ? M1) (states ? M2) c0) =
 484  lift_confR sig (states ? M1) (states ? M2) (step sig M2 c0).
 485 #sig #M1 (* * #Q1 #T1 #init1 #halt1 *) #M2 * #s #t
 486   lapply (refl ? (trans ?? 〈s,current sig t〉))
 487   cases (trans ?? 〈s,current sig t〉) in ⊢ (???% → %);
 488   * #s0 #a0 #m0 cases t
 489   [ #Heq #Hhalt
 490   | 2,3: #s1 #l1 #Heq #Hhalt
 491   |#ls #s1 #rs #Heq #Hhalt ]
 492   whd in ⊢ (???(????%)); >Heq whd in ⊢ (???%);
 493   whd in ⊢ (??(???%)?); whd in ⊢ (??%?); >(trans_seq_liftR … Heq) //
 494 qed.
 495
 496 lemma step_seq_liftL : ∀sig,M1,M2,c0.
 497  halt ? M1 (cstate ?? c0) = false →
 498  step sig (seq sig M1 M2) (lift_confL sig (states ? M1) (states ? M2) c0) =
 499  lift_confL sig ?? (step sig M1 c0).
 500 #sig #M1 (* * #Q1 #T1 #init1 #halt1 *) #M2 * #s #t
 501   lapply (refl ? (trans ?? 〈s,current sig t〉))
 502   cases (trans ?? 〈s,current sig t〉) in ⊢ (???% → %);
 503   * #s0 #a0 #m0 cases t
 504   [ #Heq #Hhalt
 505   | 2,3: #s1 #l1 #Heq #Hhalt
 506   |#ls #s1 #rs #Heq #Hhalt ]
 507   whd in ⊢ (???(????%)); >Heq whd in ⊢ (???%);
 508   whd in ⊢ (??(???%)?); whd in ⊢ (??%?); >(trans_seq_liftL … Heq) //
 509 qed.
 510
 511 lemma trans_liftL_true : ∀sig,M1,M2,s,a.
 512   halt ? M1 s = true →
 513   trans sig (seq sig M1 M2) 〈inl … s,a〉 = 〈inr … (start ? M2),None ?,N〉.
 514 #sig #M1 #M2 #s #a #Hhalt whd in ⊢ (??%?); >Hhalt %
 515 qed.
 516
 517 lemma eq_ctape_lift_conf_L : ∀sig,S1,S2,outc.
 518   ctape sig (FinSum S1 S2) (lift_confL … outc) = ctape … outc.
 519 #sig #S1 #S2 #outc cases outc #s #t %
 520 qed.
 521
 522 lemma eq_ctape_lift_conf_R : ∀sig,S1,S2,outc.
 523   ctape sig (FinSum S1 S2) (lift_confR … outc) = ctape … outc.
 524 #sig #S1 #S2 #outc cases outc #s #t %
 525 qed.
 526
 527 theorem sem_seq: ∀sig.∀M1,M2:TM sig.∀R1,R2.
 528   M1 ⊨ R1 → M2 ⊨ R2 → M1 · M2 ⊨ R1 ∘ R2.
 529 #sig #M1 #M2 #R1 #R2 #HR1 #HR2 #t
 530 cases (HR1 t) #k1 * #outc1 * #Hloop1 #HM1
 531 cases (HR2 (ctape sig (states ? M1) outc1)) #k2 * #outc2 * #Hloop2 #HM2
 532 @(ex_intro … (k1+k2)) @(ex_intro … (lift_confR … outc2))
 533 %
 534 [@(loop_merge ???????????
 535    (loop_lift ??? (lift_confL sig (states sig M1) (states sig M2))
 536    (step sig M1) (step sig (seq sig M1 M2))
 537    (λc.halt sig M1 (cstate … c))
 538    (λc.halt_liftL ?? (halt sig M1) (cstate … c)) … Hloop1))
 539   [ * *
 540    [ #sl #tl whd in ⊢ (??%? → ?); #Hl %
 541    | #sr #tr whd in ⊢ (??%? → ?); #Hr destruct (Hr) ]
 542   || #c0 #Hhalt <step_seq_liftL //
 543   | #x <p_halt_liftL %
 544   |6:cases outc1 #s1 #t1 %
 545   |7:@(loop_lift … (initc ?? (ctape … outc1)) … Hloop2)
 546     [ * #s2 #t2 %
 547     | #c0 #Hhalt <step_seq_liftR // ]
 548   |whd in ⊢ (??(???%)?);whd in ⊢ (??%?);
 549    generalize in match Hloop1; cases outc1 #sc1 #tc1 #Hloop10
 550    >(trans_liftL_true sig M1 M2 ??)
 551     [ whd in ⊢ (??%?); whd in ⊢ (???%);
 552       @config_eq whd in ⊢ (???%); //
 553     | @(loop_Some ?????? Hloop10) ]
 554  ]
 555 | @(ex_intro … (ctape ? (FinSum (states ? M1) (states ? M2)) (lift_confL … outc1)))
 556   % // >eq_ctape_lift_conf_L >eq_ctape_lift_conf_R //
 557 ]
 558 qed.
 559
 560 theorem sem_seq_app: ∀sig.∀M1,M2:TM sig.∀R1,R2,R3.
 561   M1 ⊨ R1 → M2 ⊨ R2 → R1 ∘ R2 ⊆ R3 → M1 · M2 ⊨ R3.
 562 #sig #M1 #M2 #R1 #R2 #R3 #HR1 #HR2 #Hsub
 563 #t cases (sem_seq … HR1 HR2 t)
 564 #k * #outc * #Hloop #Houtc @(ex_intro … k) @(ex_intro … outc)
 565 % [@Hloop |@Hsub @Houtc]
 566 qed.
 567
 568 (* composition with guards *)
 569 theorem sem_seq_guarded: ∀sig.∀M1,M2:TM sig.∀Pre1,Pre2,R1,R2.
 570   GRealize sig M1 Pre1 R1 → GRealize sig M2 Pre2 R2 →
 571   (∀t1,t2.Pre1 t1 → R1 t1 t2 → Pre2 t2) →
 572   GRealize sig (M1 · M2) Pre1 (R1 ∘ R2).
 573 #sig #M1 #M2 #Pre1 #Pre2 #R1 #R2 #HGR1 #HGR2 #Hinv #t1 #HPre1
 574 cases (HGR1 t1 HPre1) #k1 * #outc1 * #Hloop1 #HM1
 575 cases (HGR2 (ctape sig (states ? M1) outc1) ?)
 576   [2: @(Hinv … HPre1 HM1)]
 577 #k2 * #outc2 * #Hloop2 #HM2
 578 @(ex_intro … (k1+k2)) @(ex_intro … (lift_confR … outc2))
 579 %
 580 [@(loop_merge ???????????
 581    (loop_lift ??? (lift_confL sig (states sig M1) (states sig M2))
 582    (step sig M1) (step sig (seq sig M1 M2))
 583    (λc.halt sig M1 (cstate … c))
 584    (λc.halt_liftL ?? (halt sig M1) (cstate … c)) … Hloop1))
 585   [ * *
 586    [ #sl #tl whd in ⊢ (??%? → ?); #Hl %
 587    | #sr #tr whd in ⊢ (??%? → ?); #Hr destruct (Hr) ]
 588   || #c0 #Hhalt <step_seq_liftL //
 589   | #x <p_halt_liftL %
 590   |6:cases outc1 #s1 #t1 %
 591   |7:@(loop_lift … (initc ?? (ctape … outc1)) … Hloop2)
 592     [ * #s2 #t2 %
 593     | #c0 #Hhalt <step_seq_liftR // ]
 594   |whd in ⊢ (??(???%)?);whd in ⊢ (??%?);
 595    generalize in match Hloop1; cases outc1 #sc1 #tc1 #Hloop10
 596    >(trans_liftL_true sig M1 M2 ??)
 597     [ whd in ⊢ (??%?); whd in ⊢ (???%);
 598       @config_eq whd in ⊢ (???%); //
 599     | @(loop_Some ?????? Hloop10) ]
 600  ]
 601 | @(ex_intro … (ctape ? (FinSum (states ? M1) (states ? M2)) (lift_confL … outc1)))
 602   % // >eq_ctape_lift_conf_L >eq_ctape_lift_conf_R //
 603 ]
 604 qed.
 605
 606 theorem sem_seq_app_guarded: ∀sig.∀M1,M2:TM sig.∀Pre1,Pre2,R1,R2,R3.
 607   GRealize sig M1 Pre1 R1 → GRealize sig M2 Pre2 R2 →
 608   (∀t1,t2.Pre1 t1 → R1 t1 t2 → Pre2 t2) → R1 ∘ R2 ⊆ R3 →
 609   GRealize sig (M1 · M2) Pre1 R3.
 610 #sig #M1 #M2 #Pre1 #Pre2 #R1 #R2 #R3 #HR1 #HR2 #Hinv #Hsub
 611 #t #HPre1 cases (sem_seq_guarded … HR1 HR2 Hinv t HPre1)
 612 #k * #outc * #Hloop #Houtc @(ex_intro … k) @(ex_intro … outc)
 613 % [@Hloop |@Hsub @Houtc]
 614 qed.