matita/matita/lib/turing/mono.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||
   8     \   /  This file is distributed under the terms of the
   9      \ /   GNU General Public License Version 2
  10       V_____________________________________________________________*)
  11
  12 include "basics/vectors.ma".
  13 (* include "basics/relations.ma". *)
  14
  15 (******************************** tape ****************************************)
  16
  17 (* A tape is essentially a triple 〈left,current,right〉 where however the current
  18 symbol could be missing. This may happen for three different reasons: both tapes
  19 are empty; we are on the left extremity of a non-empty tape (left overflow), or
  20 we are on the right extremity of a non-empty tape (right overflow). *)
  21
  22 inductive tape (sig:FinSet) : Type[0] ≝
  23 | niltape : tape sig
  24 | leftof  : sig → list sig → tape sig
  25 | rightof : sig → list sig → tape sig
  26 | midtape : list sig → sig → list sig → tape sig.
  27
  28 definition left ≝
  29  λsig.λt:tape sig.match t with
  30  [ niltape ⇒ [] | leftof _ _ ⇒ [] | rightof s l ⇒ s::l | midtape l _ _ ⇒ l ].
  31
  32 definition right ≝
  33  λsig.λt:tape sig.match t with
  34  [ niltape ⇒ [] | leftof s r ⇒ s::r | rightof _ _ ⇒ []| midtape _ _ r ⇒ r ].
  35
  36 definition current ≝
  37  λsig.λt:tape sig.match t with
  38  [ midtape _ c _ ⇒ Some ? c | _ ⇒ None ? ].
  39
  40 definition mk_tape :
  41   ∀sig:FinSet.list sig → option sig → list sig → tape sig ≝
  42   λsig,lt,c,rt.match c with
  43   [ Some c' ⇒ midtape sig lt c' rt
  44   | None ⇒ match lt with
  45     [ nil ⇒ match rt with
  46       [ nil ⇒ niltape ?
  47       | cons r0 rs0 ⇒ leftof ? r0 rs0 ]
  48     | cons l0 ls0 ⇒ rightof ? l0 ls0 ] ].
  49
  50 inductive move : Type[0] ≝
  51   | L : move | R : move | N : move.
  52
  53 (********************************** machine ***********************************)
  54
  55 record TM (sig:FinSet): Type[1] ≝
  56 { states : FinSet;
  57   trans : states × (option sig) → states × (option (sig × move));
  58   start: states;
  59   halt : states → bool
  60 }.
  61
  62 definition tape_move_left ≝ λsig:FinSet.λlt:list sig.λc:sig.λrt:list sig.
  63   match lt with
  64   [ nil ⇒ leftof sig c rt
  65   | cons c0 lt0 ⇒ midtape sig lt0 c0 (c::rt) ].
  66
  67 definition tape_move_right ≝ λsig:FinSet.λlt:list sig.λc:sig.λrt:list sig.
  68   match rt with
  69   [ nil ⇒ rightof sig c lt
  70   | cons c0 rt0 ⇒ midtape sig (c::lt) c0 rt0 ].
  71
  72 definition tape_move ≝ λsig.λt: tape sig.λm:option (sig × move).
  73   match m with
  74   [ None ⇒ t
  75   | Some m' ⇒
  76     let 〈s,m1〉 ≝ m' in
  77     match m1 with
  78       [ R ⇒ tape_move_right ? (left ? t) s (right ? t)
  79       | L ⇒ tape_move_left ? (left ? t) s (right ? t)
  80       | N ⇒ midtape ? (left ? t) s (right ? t)
  81       ] ].
  82
  83 record config (sig,states:FinSet): Type[0] ≝
  84 { cstate : states;
  85   ctape: tape sig
  86 }.
  87
  88 lemma config_expand: ∀sig,Q,c.
  89   c = mk_config sig Q (cstate ?? c) (ctape ?? c).
  90 #sig #Q * //
  91 qed.
  92
  93 lemma config_eq : ∀sig,M,c1,c2.
  94   cstate sig M c1 = cstate sig M c2 →
  95     ctape sig M c1 = ctape sig M c2 →  c1 = c2.
  96 #sig #M1 * #s1 #t1 * #s2 #t2 //
  97 qed.
  98
  99 definition step ≝ λsig.λM:TM sig.λc:config sig (states sig M).
 100   let current_char ≝ current ? (ctape ?? c) in
 101   let 〈news,mv〉 ≝ trans sig M 〈cstate ?? c,current_char〉 in
 102   mk_config ?? news (tape_move sig (ctape ?? c) mv).
 103
 104 (******************************** loop ****************************************)
 105 let rec loop (A:Type[0]) n (f:A→A) p a on n ≝
 106   match n with
 107   [ O ⇒ None ?
 108   | S m ⇒ if p a then (Some ? a) else loop A m f p (f a)
 109   ].
 110
 111 lemma loop_S_true :
 112   ∀A,n,f,p,a. p a = true →
 113     loop A (S n) f p a = Some ? a.
 114 #A #n #f #p #a #pa normalize >pa //
 115 qed.
 116
 117 lemma loop_S_false :
 118   ∀A,n,f,p,a.  p a = false →
 119     loop A (S n) f p a = loop A n f p (f a).
 120 normalize #A #n #f #p #a #Hpa >Hpa %
 121 qed.
 122
 123 lemma loop_incr : ∀A,f,p,k1,k2,a1,a2.
 124   loop A k1 f p a1 = Some ? a2 →
 125     loop A (k2+k1) f p a1 = Some ? a2.
 126 #A #f #p #k1 #k2 #a1 #a2 generalize in match a1; elim k1
 127 [normalize #a0 #Hfalse destruct
 128 |#k1' #IH #a0 <plus_n_Sm whd in ⊢ (??%? → ??%?);
 129  cases (true_or_false (p a0)) #Hpa0 >Hpa0 whd in ⊢ (??%? → ??%?); // @IH
 130 ]
 131 qed.
 132
 133 lemma loop_merge : ∀A,f,p,q.(∀b. p b = false → q b = false) →
 134  ∀k1,k2,a1,a2,a3,a4.
 135    loop A k1 f p a1 = Some ? a2 →
 136      f a2 = a3 → q a2 = false →
 137        loop A k2 f q a3 = Some ? a4 →
 138          loop A (k1+k2) f q a1 = Some ? a4.
 139 #Sig #f #p #q #Hpq #k1 elim k1
 140   [normalize #k2 #a1 #a2 #a3 #a4 #H destruct
 141   |#k1' #Hind #k2 #a1 #a2 #a3 #a4 normalize in ⊢ (%→?);
 142    cases (true_or_false (p a1)) #pa1 >pa1 normalize in ⊢ (%→?);
 143    [#eqa1a2 destruct #eqa2a3 #Hqa2 #H
 144     whd in ⊢ (??(??%???)?); >plus_n_Sm @loop_incr
 145     whd in ⊢ (??%?); >Hqa2 >eqa2a3 @H
 146    |normalize >(Hpq … pa1) normalize #H1 #H2 #H3 @(Hind … H2) //
 147    ]
 148  ]
 149 qed.
 150
 151 lemma loop_split : ∀A,f,p,q.(∀b. q b = true → p b = true) →
 152  ∀k,a1,a2.
 153    loop A k f q a1 = Some ? a2 →
 154    ∃k1,a3.
 155     loop A k1 f p a1 = Some ? a3 ∧
 156       loop A (S(k-k1)) f q a3 = Some ? a2.
 157 #A #f #p #q #Hpq #k elim k
 158   [#a1 #a2 normalize #Heq destruct
 159   |#i #Hind #a1 #a2 normalize
 160    cases (true_or_false (q a1)) #Hqa1 >Hqa1 normalize
 161     [ #Ha1a2 destruct
 162      @(ex_intro … 1) @(ex_intro … a2) %
 163        [normalize >(Hpq …Hqa1) // |>Hqa1 //]
 164     |#Hloop cases (true_or_false (p a1)) #Hpa1
 165        [@(ex_intro … 1) @(ex_intro … a1) %
 166          [normalize >Hpa1 // |>Hqa1 <Hloop normalize //]
 167        |cases (Hind …Hloop) #k2 * #a3 * #Hloop1 #Hloop2
 168         @(ex_intro … (S k2)) @(ex_intro … a3) %
 169          [normalize >Hpa1 normalize // | @Hloop2 ]
 170        ]
 171     ]
 172   ]
 173 qed.
 174
 175 lemma loop_eq : ∀sig,f,q,i,j,a,x,y.
 176   loop sig i f q a = Some ? x → loop sig j f q a = Some ? y → x = y.
 177 #sig #f #q #i #j @(nat_elim2 … i j)
 178 [ #n #a #x #y normalize #Hfalse destruct (Hfalse)
 179 | #n #a #x #y #H1 normalize #Hfalse destruct (Hfalse)
 180 | #n1 #n2 #IH #a #x #y normalize cases (q a) normalize
 181   [ #H1 #H2 destruct %
 182   | /2/ ]
 183 ]
 184 qed.
 185
 186 lemma loop_p_true :
 187   ∀A,k,f,p,a.p a = true → loop A (S k) f p a = Some ? a.
 188 #A #k #f #p #a #Ha normalize >Ha %
 189 qed.
 190
 191 lemma loop_Some :
 192   ∀A,k,f,p,a,b.loop A k f p a = Some ? b → p b = true.
 193 #A #k #f #p elim k
 194   [#a #b normalize #Hfalse destruct
 195   |#k0 #IH #a #b whd in ⊢ (??%? → ?); cases (true_or_false (p a)) #Hpa
 196     [ >Hpa normalize #H1 destruct // | >Hpa normalize @IH ]
 197   ]
 198 qed.
 199
 200 lemma loop_lift : ∀A,B,k,lift,f,g,h,hlift,c1,c2.
 201   (∀x.hlift (lift x) = h x) →
 202   (∀x.h x = false → lift (f x) = g (lift x)) →
 203   loop A k f h c1 = Some ? c2 →
 204   loop B k g hlift (lift c1) = Some ? (lift … c2).
 205 #A #B #k #lift #f #g #h #hlift #c1 #c2 #Hfg #Hhlift
 206 generalize in match c1; elim k
 207 [#c0 normalize in ⊢ (??%? → ?); #Hfalse destruct (Hfalse)
 208 |#k0 #IH #c0 whd in ⊢ (??%? → ??%?);
 209  cases (true_or_false (h c0)) #Hc0 >Hfg >Hc0 normalize
 210  [ #Heq destruct (Heq) % | <Hhlift // @IH ]
 211 qed.
 212
 213 (************************** Realizability *************************************)
 214 definition loopM ≝ λsig,M,i,cin.
 215   loop ? i (step sig M) (λc.halt sig M (cstate ?? c)) cin.
 216
 217 lemma loopM_unfold : ∀sig,M,i,cin.
 218   loopM sig M i cin = loop ? i (step sig M) (λc.halt sig M (cstate ?? c)) cin.
 219 // qed.
 220
 221 definition initc ≝ λsig.λM:TM sig.λt.
 222   mk_config sig (states sig M) (start sig M) t.
 223
 224 definition Realize ≝ λsig.λM:TM sig.λR:relation (tape sig).
 225 ∀t.∃i.∃outc.
 226   loopM sig M i (initc sig M t) = Some ? outc ∧ R t (ctape ?? outc).
 227
 228 definition WRealize ≝ λsig.λM:TM sig.λR:relation (tape sig).
 229 ∀t,i,outc.
 230   loopM sig M i (initc sig M t) = Some ? outc → R t (ctape ?? outc).
 231
 232 definition Terminate ≝ λsig.λM:TM sig.λt. ∃i,outc.
 233   loopM sig M i (initc sig M t) = Some ? outc.
 234
 235 notation "M \vDash R" non associative with precedence 45 for @{ 'models $M $R}.
 236 interpretation "realizability" 'models M R = (Realize ? M R).
 237
 238 notation "M \VDash R" non associative with precedence 45 for @{ 'wmodels $M $R}.
 239 interpretation "weak realizability" 'wmodels M R = (WRealize ? M R).
 240
 241 interpretation "termination" 'fintersects M t = (Terminate ? M t).
 242
 243 lemma WRealize_to_Realize : ∀sig.∀M: TM sig.∀R.
 244   (∀t.M ↓ t) → M ⊫ R → M ⊨ R.
 245 #sig #M #R #HT #HW #t cases (HT … t) #i * #outc #Hloop
 246 @(ex_intro … i) @(ex_intro … outc) % // @(HW … i) //
 247 qed.
 248
 249 theorem Realize_to_WRealize : ∀sig.∀M:TM sig.∀R.
 250   M ⊨ R → M ⊫ R.
 251 #sig #M #R #H1 #inc #i #outc #Hloop
 252 cases (H1 inc) #k * #outc1 * #Hloop1 #HR >(loop_eq … Hloop Hloop1) //
 253 qed.
 254
 255 definition accRealize ≝ λsig.λM:TM sig.λacc:states sig M.λRtrue,Rfalse.
 256 ∀t.∃i.∃outc.
 257   loopM sig M i (initc sig M t) = Some ? outc ∧
 258     (cstate ?? outc = acc → Rtrue t (ctape ?? outc)) ∧
 259     (cstate ?? outc ≠ acc → Rfalse t (ctape ?? outc)).
 260
 261 notation "M ⊨ [q: R1,R2]" non associative with precedence 45 for @{ 'cmodels $M $q $R1 $R2}.
 262 interpretation "conditional realizability" 'cmodels M q R1 R2 = (accRealize ? M q R1 R2).
 263
 264 (******************************** NOP Machine *********************************)
 265
 266 (* NO OPERATION
 267    t1 = t2 *)
 268
 269 definition nop_states ≝ initN 1.
 270 definition start_nop : initN 1 ≝ mk_Sig ?? 0 (le_n … 1).
 271
 272 definition nop ≝
 273   λalpha:FinSet.mk_TM alpha nop_states
 274   (λp.let 〈q,a〉 ≝ p in 〈q,None ?〉)
 275   start_nop (λ_.true).
 276
 277 definition R_nop ≝ λalpha.λt1,t2:tape alpha.t2 = t1.
 278
 279 lemma sem_nop :
 280   ∀alpha.nop alpha ⊨ R_nop alpha.
 281 #alpha #intape @(ex_intro ?? 1)
 282 @(ex_intro … (mk_config ?? start_nop intape)) % %
 283 qed.
 284
 285 lemma nop_single_state: ∀sig.∀q1,q2:states ? (nop sig). q1 = q2.
 286 normalize #sig * #n #ltn1 * #m #ltm1
 287 generalize in match ltn1; generalize in match ltm1;
 288 <(le_n_O_to_eq … (le_S_S_to_le … ltn1)) <(le_n_O_to_eq … (le_S_S_to_le … ltm1))
 289 // qed.
 290
 291 (************************** Sequential Composition ****************************)
 292
 293 definition seq_trans ≝ λsig. λM1,M2 : TM sig.
 294 λp. let 〈s,a〉 ≝ p in
 295   match s with
 296   [ inl s1 ⇒
 297       if halt sig M1 s1 then 〈inr … (start sig M2), None ?〉
 298       else let 〈news1,m〉 ≝ trans sig M1 〈s1,a〉 in 〈inl … news1,m〉
 299   | inr s2 ⇒ let 〈news2,m〉 ≝ trans sig M2 〈s2,a〉 in 〈inr … news2,m〉
 300   ].
 301
 302 definition seq ≝ λsig. λM1,M2 : TM sig.
 303   mk_TM sig
 304     (FinSum (states sig M1) (states sig M2))
 305     (seq_trans sig M1 M2)
 306     (inl … (start sig M1))
 307     (λs.match s with
 308       [ inl _ ⇒ false | inr s2 ⇒ halt sig M2 s2]).
 309
 310 notation "a · b" non associative with precedence 65 for @{ 'middot $a $b}.
 311 interpretation "sequential composition" 'middot a b = (seq ? a b).
 312
 313 definition lift_confL ≝
 314   λsig,S1,S2,c.match c with
 315   [ mk_config s t ⇒ mk_config sig (FinSum S1 S2) (inl … s) t ].
 316
 317 definition lift_confR ≝
 318   λsig,S1,S2,c.match c with
 319   [ mk_config s t ⇒ mk_config sig (FinSum S1 S2) (inr … s) t ].
 320
 321 definition halt_liftL ≝
 322   λS1,S2,halt.λs:FinSum S1 S2.
 323   match s with
 324   [ inl s1 ⇒ halt s1
 325   | inr _ ⇒ true ]. (* should be vacuous in all cases we use halt_liftL *)
 326
 327 definition halt_liftR ≝
 328   λS1,S2,halt.λs:FinSum S1 S2.
 329   match s with
 330   [ inl _ ⇒ false
 331   | inr s2 ⇒ halt s2 ].
 332
 333 lemma p_halt_liftL : ∀sig,S1,S2,halt,c.
 334   halt (cstate sig S1 c) =
 335      halt_liftL S1 S2 halt (cstate … (lift_confL … c)).
 336 #sig #S1 #S2 #halt #c cases c #s #t %
 337 qed.
 338
 339 lemma trans_seq_liftL : ∀sig,M1,M2,s,a,news,move.
 340   halt ? M1 s = false →
 341   trans sig M1 〈s,a〉 = 〈news,move〉 →
 342   trans sig (seq sig M1 M2) 〈inl … s,a〉 = 〈inl … news,move〉.
 343 #sig (*#M1*) * #Q1 #T1 #init1 #halt1 #M2 #s #a #news #move
 344 #Hhalt #Htrans whd in ⊢ (??%?); >Hhalt >Htrans %
 345 qed.
 346
 347 lemma trans_seq_liftR : ∀sig,M1,M2,s,a,news,move.
 348   halt ? M2 s = false →
 349   trans sig M2 〈s,a〉 = 〈news,move〉 →
 350   trans sig (seq sig M1 M2) 〈inr … s,a〉 = 〈inr … news,move〉.
 351 #sig #M1 * #Q2 #T2 #init2 #halt2 #s #a #news #move
 352 #Hhalt #Htrans whd in ⊢ (??%?); >Hhalt >Htrans %
 353 qed.
 354
 355 lemma step_seq_liftR : ∀sig,M1,M2,c0.
 356  halt ? M2 (cstate ?? c0) = false →
 357  step sig (seq sig M1 M2) (lift_confR sig (states ? M1) (states ? M2) c0) =
 358  lift_confR sig (states ? M1) (states ? M2) (step sig M2 c0).
 359 #sig #M1 (* * #Q1 #T1 #init1 #halt1 *) #M2 * #s #t
 360   lapply (refl ? (trans ?? 〈s,current sig t〉))
 361   cases (trans ?? 〈s,current sig t〉) in ⊢ (???% → %);
 362   #s0 #m0 cases t
 363   [ #Heq #Hhalt
 364   | 2,3: #s1 #l1 #Heq #Hhalt
 365   |#ls #s1 #rs #Heq #Hhalt ]
 366   whd in ⊢ (???(????%)); >Heq whd in ⊢ (???%);
 367   whd in ⊢ (??(???%)?); whd in ⊢ (??%?); >(trans_seq_liftR … Heq) //
 368 qed.
 369
 370 lemma step_seq_liftL : ∀sig,M1,M2,c0.
 371  halt ? M1 (cstate ?? c0) = false →
 372  step sig (seq sig M1 M2) (lift_confL sig (states ? M1) (states ? M2) c0) =
 373  lift_confL sig ?? (step sig M1 c0).
 374 #sig #M1 (* * #Q1 #T1 #init1 #halt1 *) #M2 * #s #t
 375   lapply (refl ? (trans ?? 〈s,current sig t〉))
 376   cases (trans ?? 〈s,current sig t〉) in ⊢ (???% → %);
 377   #s0 #m0 cases t
 378   [ #Heq #Hhalt
 379   | 2,3: #s1 #l1 #Heq #Hhalt
 380   |#ls #s1 #rs #Heq #Hhalt ]
 381   whd in ⊢ (???(????%)); >Heq whd in ⊢ (???%);
 382   whd in ⊢ (??(???%)?); whd in ⊢ (??%?); >(trans_seq_liftL … Heq) //
 383 qed.
 384
 385 lemma trans_liftL_true : ∀sig,M1,M2,s,a.
 386   halt ? M1 s = true →
 387   trans sig (seq sig M1 M2) 〈inl … s,a〉 = 〈inr … (start ? M2),None ?〉.
 388 #sig #M1 #M2 #s #a #Hhalt whd in ⊢ (??%?); >Hhalt %
 389 qed.
 390
 391 lemma eq_ctape_lift_conf_L : ∀sig,S1,S2,outc.
 392   ctape sig (FinSum S1 S2) (lift_confL … outc) = ctape … outc.
 393 #sig #S1 #S2 #outc cases outc #s #t %
 394 qed.
 395
 396 lemma eq_ctape_lift_conf_R : ∀sig,S1,S2,outc.
 397   ctape sig (FinSum S1 S2) (lift_confR … outc) = ctape … outc.
 398 #sig #S1 #S2 #outc cases outc #s #t %
 399 qed.
 400
 401 theorem sem_seq: ∀sig.∀M1,M2:TM sig.∀R1,R2.
 402   M1 ⊨ R1 → M2 ⊨ R2 → M1 · M2 ⊨ R1 ∘ R2.
 403 #sig #M1 #M2 #R1 #R2 #HR1 #HR2 #t
 404 cases (HR1 t) #k1 * #outc1 * #Hloop1 #HM1
 405 cases (HR2 (ctape sig (states ? M1) outc1)) #k2 * #outc2 * #Hloop2 #HM2
 406 @(ex_intro … (k1+k2)) @(ex_intro … (lift_confR … outc2))
 407 %
 408 [@(loop_merge ???????????
 409    (loop_lift ??? (lift_confL sig (states sig M1) (states sig M2))
 410    (step sig M1) (step sig (seq sig M1 M2))
 411    (λc.halt sig M1 (cstate … c))
 412    (λc.halt_liftL ?? (halt sig M1) (cstate … c)) … Hloop1))
 413   [ * *
 414    [ #sl #tl whd in ⊢ (??%? → ?); #Hl %
 415    | #sr #tr whd in ⊢ (??%? → ?); #Hr destruct (Hr) ]
 416   || #c0 #Hhalt <step_seq_liftL //
 417   | #x <p_halt_liftL %
 418   |6:cases outc1 #s1 #t1 %
 419   |7:@(loop_lift … (initc ?? (ctape … outc1)) … Hloop2)
 420     [ * #s2 #t2 %
 421     | #c0 #Hhalt <step_seq_liftR // ]
 422   |whd in ⊢ (??(???%)?);whd in ⊢ (??%?);
 423    generalize in match Hloop1; cases outc1 #sc1 #tc1 #Hloop10
 424    >(trans_liftL_true sig M1 M2 ??)
 425     [ whd in ⊢ (??%?); whd in ⊢ (???%);
 426       @config_eq whd in ⊢ (???%); //
 427     | @(loop_Some ?????? Hloop10) ]
 428  ]
 429 | @(ex_intro … (ctape ? (FinSum (states ? M1) (states ? M2)) (lift_confL … outc1)))
 430   % // >eq_ctape_lift_conf_L >eq_ctape_lift_conf_R //
 431 ]
 432 qed.
 433
 434 theorem sem_seq_app: ∀sig.∀M1,M2:TM sig.∀R1,R2,R3.
 435   M1 ⊨ R1 → M2 ⊨ R2 → R1 ∘ R2 ⊆ R3 → M1 · M2 ⊨ R3.
 436 #sig #M1 #M2 #R1 #R2 #R3 #HR1 #HR2 #Hsub
 437 #t cases (sem_seq … HR1 HR2 t)
 438 #k * #outc * #Hloop #Houtc @(ex_intro … k) @(ex_intro … outc)
 439 % [@Hloop |@Hsub @Houtc]
 440 qed.